🎄🎁✨ Holiday Season - are you ready to code?

[FellippeHeitor]

🎄☃️ Lights and jingly bells are already all around. It's time to start submitting your 2020 holiday samples! Let's group them under this thread, who'll start? ✨🎁

[Petr]

Hi Fellippe. I have done 0 rows of the code :). Some conditions, or it is in free style?

[SpriggsySpriggs]

Any requirements?

[FellippeHeitor]

Make it beautiful, preferably with no extra files.

[OldMoses]

Christmas 2020..... I don't think I'm quite up to flaming Xmas trees... :D

[bplus]

To start decorating you'll need some ornaments, how about ones that rotate color?

Code: QB64: [Select]

1. _TITLE "Ornaments with Rotating Colors, spacebar to change color set" '  B+ 2018-04-17
2. 'from figosdev post at http://smallbasic.sourceforge.net/?q=node/1684#comment-1955
3. 'translating fig to SmallBASIC for alittle cross pollination...
4. '2020-12-05 for Xmas decorating a little update
5.  
6. CONST xmax = 600, ymax = 600
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 360, 60
9. DIM SHARED rrr, ggg, bbb, ccc
10. cx = 300
11. ww = 3.14159 / 2 'fix to return back to this after each run
12. setRGB
13. WHILE 1
14.     IF INKEY$ = " " THEN setRGB: ccc = 0
15.     ccc = 0
16.     w = ww 'fix
17.     llc = llc + 1
18.     IF llc = 32000 THEN llc = 0: lc& = 0
19.     FOR r = 490 TO 300 STEP -.25
20.         e = w - _PI / 4 / (490 - 300)
21.         tmp = e: e = w: w = tmp
22.         FOR p = _PI(-1) TO _PI STEP _PI(1 / 101)
23.             e = INT((COS(w) * 380) / 2)
24.             x = INT(COS(p * 2) * e + cx)
25.             y = INT(SIN(p * 2) * e + r - 50)
26.             lc& = lc& + 1
27.             IF lc& MOD 90 = 0 THEN
28.                 ccc = ccc + .2
29.                 fcirc x, y, 12, changeRGB~&
30.             END IF
31.         NEXT
32.     NEXT
33.     _DISPLAY
34.     _LIMIT 10
35. WEND
36.  
37. SUB setRGB 'mod
38.     rrr = RND ^ 2: ggg = RND ^ 2: bbb = RND ^ 2
39. END SUB
40.  
41. FUNCTION changeRGB~& 'mod
42.     changeRGB~& = _RGB32(127 + 127 * SIN(rrr * ccc), 127 + 127 * SIN(ggg * ccc), 127 + 127 * SIN(bbb * ccc))
43. END SUB
44.  
45. 'from Steve Gold standard
46. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
47.     DIM Radius AS INTEGER, RadiusError AS INTEGER
48.     DIM X AS INTEGER, Y AS INTEGER
49.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
50.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
51.     LINE (CX - X, CY)-(CX + X, CY), C, BF
52.     WHILE X > Y
53.         RadiusError = RadiusError + Y * 2 + 1
54.         IF RadiusError >= 0 THEN
55.             IF X <> Y + 1 THEN
56.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
57.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
58.             END IF
59.             X = X - 1
60.             RadiusError = RadiusError - X * 2
61.         END IF
62.         Y = Y + 1
63.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
64.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
65.     WEND
66. END SUB
67.  
68.  
69.  

 

Looking for Andy's pine tree maker code to put them on.

[FellippeHeitor]

Thanks for getting it started, bplus!

Minor typo at line 30: I changed it by adding _DEFAULTCOLOR as the last parameter to fcirc. You may wanna review it.

[bplus]

Was that before I changed it in edit because I posted old version?

I changed changeRGB to a function and the old version had a call to a SUB before the call to old circle routine that didn't take color.

The version I edited should work.

[FellippeHeitor]

If there are no bugs in the latest version, then you've fixed it. 😄

[SierraKen]

Here is my Merry Christmas 2020 submission. I worked on this all afternoon. :) It has random falling glowing snow (I didn't need help this time! LOL), random hills, and random tiny Christmas Trees. Everything changes every 7 seconds. Enjoy!

Edit: I just added a photo of it.

Code: QB64: [Select]

1. 'Merry Christmas! From SierraKen
2. 'Made on December 6, 2020.
3.  
4. DIM snowx(2000), snowy(2000)
5. DIM yy AS SINGLE
6. DIM cx AS INTEGER
7. DIM cy AS INTEGER
8. DIM r AS INTEGER
9. DIM c AS _UNSIGNED LONG
10. DIM hills AS LONG
11. DIM c1 AS SINGLE
12. DIM c2 AS SINGLE
13. DIM c3 AS SINGLE
14. DIM hillx AS SINGLE
15. DIM sz AS SINGLE
16. DIM shape AS SINGLE
17. DIM tx AS SINGLE
18. DIM ty AS SINGLE
19. DIM col AS SINGLE
20.  
21. _TITLE "Merry Christmas! From SierraKen - Every 7 seconds new mountains and trees appear. Press Esc to quit."
22. RANDOMIZE TIMER
23. scene = _NEWIMAGE(800, 600, 32)
24. SCREEN scene
25. start:
26. FOR cc = 1 TO 200
27.     IF cc + 400 > 600 THEN GOTO nex:
28.     LINE (0, 400 + cc)-(_WIDTH, 400 + cc), _RGB32(0, c + 100, cc)
29. NEXT cc
30. nex:
31. 'Hills
32. FOR hills = 1 TO 10
33.     hillx = (RND * _WIDTH)
34.     sz = (RND * 300)
35.     shape = (RND + 1)
36.     c1 = (RND * 155)
37.     c2 = (RND * 155)
38.     c3 = (RND * 155)
39.     FOR size = .2 TO sz STEP .2
40.         CIRCLE (hillx, 400), size, _RGB32(c1, c2 + size, c3), 2 * _PI, _PI, shape
41.     NEXT size
42. NEXT hills
43. FOR trees = 1 TO 75
44.     tx = (RND * _WIDTH)
45.     ty = (RND * 200) + 430
46.     r = 1
47.     col = INT(RND * 5) + 1
48.     IF col = 1 THEN c = _RGB32(255, 0, 0)
49.     IF col = 2 THEN c = _RGB32(0, 0, 255)
50.     IF col = 3 THEN c = _RGB32(255, 127, 255)
51.     IF col = 4 THEN c = _RGB32(127, 255, 255)
52.     IF col = 5 THEN c = _RGB32(255, 139, 0)
53.  
54.     LINE (tx, ty)-(tx + 2, ty - 10), _RGB32(183, 127, 127), BF
55.  
56.     LINE (tx, ty - 10)-(tx - 5, ty - 10), _RGB32(127, 255, 127)
57.     LINE (tx - 5, ty - 10)-(tx, ty - 15), _RGB32(127, 255, 127)
58.     cx = tx - 5: cy = ty - 10
59.     fillCircle cx, cy, r, c
60.     LINE (tx, ty - 15)-(tx - 5, ty - 15), _RGB32(127, 255, 127)
61.     LINE (tx - 5, ty - 15)-(tx, ty - 20), _RGB32(127, 255, 127)
62.     cx = tx - 5: cy = ty - 15
63.     fillCircle cx, cy, r, c
64.     LINE (tx, ty - 20)-(tx - 5, ty - 20), _RGB32(127, 255, 127)
65.     LINE (tx - 5, ty - 20)-(tx + 1, ty - 25), _RGB32(127, 255, 127)
66.     cx = tx - 5: cy = ty - 20
67.     fillCircle cx, cy, r, c
68.     LINE (tx + 2, ty - 10)-(tx + 7, ty - 10), _RGB32(127, 255, 127)
69.     LINE (tx + 7, ty - 10)-(tx + 2, ty - 15), _RGB32(127, 255, 127)
70.     cx = tx + 7: cy = ty - 10
71.     fillCircle cx, cy, r, c
72.     LINE (tx + 2, ty - 15)-(tx + 7, ty - 15), _RGB32(127, 255, 127)
73.     LINE (tx + 7, ty - 15)-(tx + 2, ty - 20), _RGB32(127, 255, 127)
74.     cx = tx + 7: cy = ty - 15
75.     fillCircle cx, cy, r, c
76.     LINE (tx + 2, ty - 20)-(tx + 7, ty - 20), _RGB32(127, 255, 127)
77.     LINE (tx + 7, ty - 20)-(tx + 1, ty - 25), _RGB32(127, 255, 127)
78.     cx = tx + 7: cy = ty - 20
79.     fillCircle cx, cy, r, c
80.  
81.     'Yellow Star
82.     cx = tx + 1: cy = ty - 26
83.     r = 1
84.     c = _RGB32(255, 255, 127)
85.     fillCircle cx, cy, r, c
86. NEXT trees
87.  
88. hills = _COPYIMAGE(0)
89.  
90. DO
91.     _LIMIT 50
92.     _PUTIMAGE , hills
93.     a$ = INKEY$
94.     IF a$ = CHR$(27) THEN END
95.     snowing = INT(RND * 1000) + 1
96.     IF snowing > 900 THEN
97.         s = s + 1
98.         IF s > 1500 THEN s = 1
99.         snowx(s) = (RND * _WIDTH)
100.         snowy(s) = 0
101.     END IF
102.     IF yy > 640 THEN yy = 0
103.     FOR t = 1 TO 1500
104.         snowy(t) = snowy(t) + 1
105.         cx = snowx(t): cy = snowy(t)
106.         r = RND * 5
107.         c = _RGB32(255, 255, 255)
108.         fillCircle cx, cy, r, c
109.     NEXT t
110.     _DISPLAY
111.     CLS
112.     tim = tim + 1
113.     IF tim > 500 THEN tim = 0: CLS: _FREEIMAGE hills: GOTO start:
114. LOOP
115.  
116. 'from Steve Gold standard
117. SUB fillCircle (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
118.     DIM Radius AS INTEGER, RadiusError AS INTEGER
119.     DIM X AS INTEGER, Y AS INTEGER
120.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
121.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
122.     LINE (CX - X, CY)-(CX + X, CY), C, BF
123.     WHILE X > Y
124.         RadiusError = RadiusError + Y * 2 + 1
125.         IF RadiusError >= 0 THEN
126.             IF X <> Y + 1 THEN
127.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
128.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
129.             END IF
130.             X = X - 1
131.             RadiusError = RadiusError - X * 2
132.         END IF
133.         Y = Y + 1
134.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
135.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
136.     WEND
137. END SUB
138.  

[bplus]

Oh today's the 6th, I like that blinking effect with snowfall Ken.

Found Andy's tree, someone might be able to do something with this?

Code: QB64: [Select]

1. 'Original IFS fractal by Andy Amaya   copy 2019-12-09
2. 'ap3-191209-216
3. _TITLE "IFS Pine Tree"
4.  
5. scaleX! = 524.0 '424.0 to 1024.0 look OK for X scaling factor
6. scaleY! = 524.0
7. offsetX% = 370
8. offsetY% = 150
9. SCREEN _NEWIMAGE(800, 600, 32)
10. CLS , _RGB32(0, 0, 0)
11. COLOR _RGB32(0, 228, 0, 24)
12.  
13. FOR iter& = 0 TO 1000000
14.     SELECT CASE RND
15.         CASE 0 TO .60
16.             nx! = -0.858985 * lastX! + 0.008944 * lastY! + 0.092336
17.             ny! = 0.012263 * lastX! + 0.84816 * lastY! + -0.04103
18.         CASE .60 TO .96
19.             nx! = -0.373759 * lastX! + -0.353068 * lastY! + 0.296535
20.             ny! = 0.353068 * lastX! + -0.373759 * lastY! + 0.704598
21.         CASE ELSE
22.             nx! = 0.010276 * lastX! + 0 * lastY! + 0.053328
23.             ny! = -0.05138 * lastX! + 0.313416 * lastY! + 0.576552
24.     END SELECT
25.     IF iter& > 20& THEN PSET (nx! * scaleX! + offsetX%, ny! * scaleY! + offsetY%)
26.     lastX! = nx!
27.     lastY! = ny!
28. NEXT
29. SLEEP
30. SYSTEM
31.  

Who me?!

[SierraKen]

Thanks B+ :)

[FellippeHeitor]

Cool scene, @SierraKen!

[_vince]

Any requirements?

What about rewards?

[FellippeHeitor]

What's more rewarding than having your work featured for the whole community to gasp in awe?