🎄🎁✨ Holiday Season - are you ready to code?

[johnno56]

OK. Source code upgraded, font is now in the source code.  Try it again, please.  It is running correctly under Windows. (previous version also)

Petr,

Thank you for the upgrade. Everything functions as it should.

Very nicely done! Great job!

J

[Dav]

@bplus: Glad you enjoy the program!

Thanks @Dav what's your favorite charity?

As far as donations go, I don't have a favorite. Me and extra money don't seem to meet that often -- so my contributions are of a local volunteering nature.  Sometime those TV commercials (like for the hospital that helps sick kids 100% free) nearly makes my eyes puddle up and wish I did have money to contribute to charities.

- Dav

[SierraKen]

That's really awesome Dav! When I made my Starfield Clock I thought about something like this for the hourly chimes. Right now it only has the PLAY command. You did an impressive job here. Do you mind if I use 1 or 2 of your .ogg sound files for my clock? But I need to know something first, can the chimes play when there's other things going on in the background? That is why I couldn't use the chime example I found a long time ago.

[Dav]

@SierraKen: Thanks! Sure, you may use anything i make and post here in your projects.  The way the SPLAY SUB is set up (with my added delay) the sound playback would suspend your clock from running while chiming. But you could easily adapt the code to eliminate that problem. Cool thing about _SNDPLAYCOPY is that it won't suspend your program while playing a sound. All you need to do is call the sounds from in your main program (forget the SPLAY SUB) and perhaps set a special TIMER for calling each note in your main loop.

- Dav

[SierraKen]

Thanks Dav, I tried for a bit tonight but couldn't figure it out, it kept making the sound a bunch of times on each chime. But that's OK, I'm satisfied with what I have. :) If I decide to check it out later I might.

[SMcNeill]

Here's a little something Xmassy which I tossed together this afternoon.  It works better (as in much faster) with external files, but part of the rules here said we should avoid those, so this is what I've got at the moment:

[edit]

Grab the attachment below and run it; the data length in the BAS file is too large for the forum database to handle properly, and can't be included in a post.

If I'd known I couldn't get this to load as is, I wouldn't have bothered to turn it into a singluar file and would've just kept everything externally available.  :P

Ah well...  Now I need to decide what I want to do next to it (if anything).  I'm thinking of having Santa fly across the screen in his sled, with a ribbon trailing behind him, showing the words of the song as it plays for us...   And then maybe making this a screensaver for the holidays, on a soundplay loop...

Or maybe I'll just leave it as it is, and not worry over it...

I dunno yet what I'm going to end up doing with it, but here's my little Xmas contribution!
 

[Dav]

Well that's pretty, Steve.  I really like the floating snow effect.  Has a nice lilt to it that makes it more like snow than just dropping like rain drops.  Good screensaver.

Took a while for the converting on my slower laptop, but worth the wait.  Nice converting functions there you made....
 
- Dav

[SMcNeill]

Well that's pretty, Steve.  I really like the floating snow effect.  Has a nice lilt to it that makes it more like snow than just dropping like rain drops.  Good screensaver.

Took a while for the converting on my slower laptop, but worth the wait.  Nice converting functions there you made....
 
- Dav

If you're just interested in the conversion routines, you can find them alone here: https://www.qb64.org/forum/index.php?topic=3379.msg126862#msg126862

Compress and convert images/sound/resource files to BASE-128 encoding, so we can use them internally in DATA statements without any problems.  They need to be optimized for speed (use of readbit and setbit would help a lot, but they weren't in our language when I first did these routines), but they're functional and usage can often be hidden behind a startup splash screen, or such, in many cases.  ;)

[SierraKen]

Amazing Steve, very nice.

[bplus]

Beautiful snow scene Steve!

I finally found an oldie I did in 2015 and translated it to QB64 with some mods:

Code: QB64: [Select]

1. _TITLE "Sierpinski Decorated" 'b+ 2020-12-18 finally found this oldie
2. 'sierpinski decorated.bas 2015-12-06 SmallBASIC 0.12.1 [B+=MGA]
3. 'Thanks to PeterMaria W for code snips
4. RANDOMIZE TIMER
5. CONST SSQ = 700, horizon = 485 ' Side of Square Screen
6. DIM SHARED QB(15) 'modified old QB 16 color system
7. QB(0) = &HFF000000
8. QB(1) = &HFF000088
9. QB(2) = &HFF008800
10. QB(3) = &HFF008888
11. QB(4) = &HFF880000
12. QB(5) = &HFF880088
13. QB(6) = &HFF888800
14. QB(7) = &HFFCCCCCC
15. QB(8) = &HFF888888
16. QB(9) = &HFF0000FF
17. QB(10) = &HFF00FF00
18. QB(11) = &HFF00FFFF
19. QB(12) = &HFFFF0000
20. QB(13) = &HFFFF00FF
21. QB(14) = &HFFFFFF00
22. QB(15) = &HFFFFFFFF
23.  
24. SCREEN _NEWIMAGE(SSQ + 100, SSQ, 32)
25. _DELAY .25
26. _SCREENMOVE _MIDDLE
27.  
28. xplus = SSQ
29. yplus = horizon
30. nstars = 100
31. DIM xstar(100), ystar(100), rstar(100)
32. FOR i = 1 TO 100
33.     xstar(i) = RND * (SSQ + 100): ystar(i) = RND * horizon:
34.     IF i < 75 THEN
35.         rstar(i) = 0
36.     ELSEIF i < 95 THEN
37.         rstar(i) = 1
38.     ELSE
39.         rstar(i) = 2
40.     END IF
41. NEXT
42. WHILE 1
43.     CLS
44.     FOR i = 0 TO horizon
45.         LINE (0, i)-(SSQ + 100, i), _RGB32(i / horizon * 70, i / horizon * 22, 60 * (i) / horizon)
46.     NEXT
47.     land = SSQ - horizon
48.     FOR i = horizon TO SSQ
49.         cc = 128 + (i - horizon) / land * 127
50.         LINE (0, i)-(SSQ + 100, i), _RGB32(cc, cc, cc)
51.     NEXT
52.     FOR i = 1 TO 100
53.         fcirc xstar(i), ystar(i), rstar(i), QB(11)
54.     NEXT
55.     pinetree 200, 100
56.     star xplus, yplus
57.     xdist = 420 - xplus
58.     xplus = xplus + .1 * xdist
59.     ydist = 80 - yplus
60.     yplus = yplus + .1 * ydist
61.     _DISPLAY
62.     _LIMIT 7
63. WEND
64.  
65. SUB star (x, y)
66.     fcirc x, y, 3, &HFFAAFF00
67.     LINE (x - 7, y)-(x - 3, y), &HFFAAFF00
68.     LINE (x + 3, y)-(x + 7, y), &HFFAAFF00
69.     LINE (x, y - 7)-(x, y - 3), &HFFAAFF00
70.     LINE (x, y + 3)-(x, y + 7), &HFFAAFF00
71.     IF x > 419 AND x < 421 AND y > 79 AND y < 81 THEN
72.         CIRCLE (x, y), 12, &HFFAAFF00
73.         COLOR &HFFFFFF88, &H00000000
74.         Text 35, horizon + 90, 85, &HFFAA0000, "Seasons Greetings"
75.         sier 210, 125, 420, 340
76.         SLEEP
77.     END IF
78. END SUB
79.  
80. SUB sier (tlx, tly, width, height)
81.     ' Sierpinski Christmas.bas modified from Petermaria's
82.     ax = tlx
83.     ay = tly + height
84.     bx = tlx + width
85.     by = tly + height
86.     cx = tlx + width / 2
87.     cy = tly
88.     px = tlx
89.     py = tly + height
90.     FOR n = 0 TO 4000
91.         fcirc px, py, 2, QB(INT(RND * 16))
92.         SELECT CASE INT(RND * 3)
93.             CASE 0
94.                 px = (px + ax) / 2.0
95.                 py = (py + ay) / 2.0
96.             CASE 1
97.                 px = (px + bx) / 2.0
98.                 py = (py + by) / 2.0
99.             CASE 2
100.                 px = (px + cx) / 2.0
101.                 py = (py + cy) / 2.0
102.         END SELECT
103.     NEXT
104.     _DISPLAY
105. END SUB
106.  
107. SUB pinetree (x, y)
108.     'tannen baum by PeterMaria W  orig 440x460
109.     bpx = 220: bpy = 410
110.     tpx = bpx
111.     FOR aa = -4 TO 4
112.         bpxx = bpx + aa
113.         bpyy = bpy - 390
114.         LINE (x + bpxx, y + bpy)-(x + bpx, y + bpyy), _RGB32(30, 30, 0)
115.     NEXT
116.     ra = 160
117.     tpy = bpy - 40
118.     FOR ht = 1 TO 40
119.         FOR xs = -100 TO 100 STEP 40
120.             xsh = xs / 100
121.             rs = RND * 4 / 10
122.             tpxx = tpx + (xsh * ra)
123.             tpyy = tpy - rs * ra
124.             LINE (x + tpx, y + tpy)-(x + tpxx, y + tpyy), _RGB32(50, 40, 20)
125.             FOR aa = 1 TO 30
126.                 fra = RND * 10 / 10 * ra
127.                 x1 = tpx + (xsh * fra)
128.                 y1 = tpy - rs * fra
129.                 x2 = tpx + xsh * (fra + ra / 5)
130.                 y2 = tpy - rs * fra + (-rs + (RND * 8) / 10 - 0.4) * (ra / 5)
131.                 LINE (x + x1, y + y1)-(x + x2, y + y2), _RGB32(RND * 120, RND * 70 + 70, RND * 80)
132.             NEXT
133.         NEXT
134.         ra = ra - 4
135.         tpy = tpy - 9
136.     NEXT
137.     _DISPLAY
138. END SUB
139.  
140. 'from Steve Gold standard
141. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
142.     DIM Radius AS INTEGER, RadiusError AS INTEGER
143.     DIM X AS INTEGER, Y AS INTEGER
144.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
145.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
146.     LINE (CX - X, CY)-(CX + X, CY), C, BF
147.     WHILE X > Y
148.         RadiusError = RadiusError + Y * 2 + 1
149.         IF RadiusError >= 0 THEN
150.             IF X <> Y + 1 THEN
151.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
152.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
153.             END IF
154.             X = X - 1
155.             RadiusError = RadiusError - X * 2
156.         END IF
157.         Y = Y + 1
158.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
159.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
160.     WEND
161. END SUB
162.  
163. SUB Text (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
164.     DIM fg AS _UNSIGNED LONG, cur&, I&, multi, xlen
165.     fg = _DEFAULTCOLOR
166.     'screen snapshot
167.     cur& = _DEST
168.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
169.     _DEST I&
170.     COLOR K, _RGBA32(0, 0, 0, 0)
171.     _PRINTSTRING (0, 0), txt$
172.     multi = textHeight / 16
173.     xlen = LEN(txt$) * 8 * multi
174.     _PUTIMAGE (x, y)-STEP(xlen, textHeight), I&, cur&
175.     COLOR fg
176.     _FREEIMAGE I&
177. END SUB
178.  
179.  

[Petr]

Very nice work, @Steve. Your program is also IDE destructor :) - goto to row with DATA and press "end" key on the keyboard :) That's why I cut long strings to 450 characters per line to do our IDE well.

@Nice work, BPlus! Better tree than mine :)

[Dav]

Nice one, @bplus. 

I was looking for an Christmas oldie to post too, but I think it was on my HD that died.  Anyone happen to save that old school Jingle Bell piano thing I posted a few years ago on the [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] forum?  It played jingle bells while showing the piano keyboard playing the notes, and displayed the words. 

- Dav

[_vince]

Nice work guys, I hope I can contribute something when I get some free time soon.

An honorable mention is TheBOB's christmas train.  It would get posted on TQBF every year as a tradition, would be nice if someone can pull it up and/or translate it to QB64. (@Pete ?)

[bplus]

Nice work guys, I hope I can contribute something when I get some free time soon.

An honorable mention is TheBOB's christmas train.  It would get posted on TQBF every year as a tradition, would be nice if someone can pull it up and/or translate it to QB64. (@Pete ?)

Here 'tis: https://www.qb64.org/forum/index.php?topic=820.msg100360#msg100360

[STxAxTIC]

Here is the Sanctum Winter Wonderland update. Let it load, and walk forward. Look all around, find the snowmen and the christmas trees. When you're bored with that, you can wander some more: through the desert, up in space, inside a planet -- or you may go down, down, down all the way to hell.

Code: QB64: [Select]

1. ' Version 2020-12-18
2.  
3. OPTION _EXPLICIT
4.  
5. DO UNTIL _SCREENEXISTS: LOOP
6. _TITLE "Sanctum"
7.  
8. ' Hardware.
9. 'SCREEN _NEWIMAGE(640, 480, 32)
10. SCREEN _NEWIMAGE(800, 600, 32)
11. 'SCREEN _NEWIMAGE(1024, 768, 32)
12.  
13. ' Meta
14. RANDOMIZE TIMER
15. _FULLSCREEN
16. _MOUSEHIDE
17.  
18. ' Color constants.
19. CONST Aquamarine = _RGB32(127, 255, 212)
20. CONST Black = _RGB32(0, 0, 0)
21. CONST Blue = _RGB32(0, 0, 255)
22. CONST BlueViolet = _RGB32(138, 43, 226)
23. CONST Chocolate = _RGB32(210, 105, 30)
24. CONST Cyan = _RGB32(0, 255, 255)
25. CONST DarkBlue = _RGB32(0, 0, 139)
26. CONST DarkGoldenRod = _RGB32(184, 134, 11)
27. CONST DarkGray = _RGB32(169, 169, 169)
28. CONST DarkKhaki = _RGB32(189, 183, 107)
29. CONST DeepPink = _RGB32(255, 20, 147)
30. CONST DodgerBlue = _RGB32(30, 144, 255)
31. CONST ForestGreen = _RGB32(34, 139, 34)
32. CONST Gray = _RGB32(128, 128, 128)
33. CONST Green = _RGB32(0, 128, 0)
34. CONST Indigo = _RGB32(75, 0, 130)
35. CONST Ivory = _RGB32(255, 255, 240)
36. CONST LightSeaGreen = _RGB32(32, 178, 170)
37. CONST Lime = _RGB32(0, 255, 0)
38. CONST LimeGreen = _RGB32(50, 205, 50)
39. CONST Magenta = _RGB32(255, 0, 255)
40. CONST PaleGoldenRod = _RGB32(238, 232, 170)
41. CONST Purple = _RGB32(128, 0, 128)
42. CONST Red = _RGB32(255, 0, 0)
43. CONST RoyalBlue = _RGB32(65, 105, 225)
44. CONST SaddleBrown = _RGB32(139, 69, 19)
45. CONST Sienna = _RGB32(160, 82, 45)
46. CONST SlateGray = _RGB32(112, 128, 144)
47. CONST Snow = _RGB32(255, 250, 250)
48. CONST Sunglow = _RGB32(255, 207, 72)
49. CONST SunsetOrange = _RGB32(253, 94, 83)
50. CONST Teal = _RGB32(0, 128, 128)
51. CONST White = _RGB32(255, 255, 255)
52. CONST Yellow = _RGB32(255, 255, 0)
53.  
54. ' Mathematical constants.
55. CONST pi = 4 * ATN(1)
56. CONST ee = EXP(1)
57.  
58. ' Types.
59.  
60. TYPE Vector
61.     x AS DOUBLE
62.     y AS DOUBLE
63.     z AS DOUBLE
64. END TYPE
65.  
66. TYPE Camera
67.     Position AS Vector
68.     Velocity AS Vector
69.     Shade AS _UNSIGNED LONG
70. END TYPE
71.  
72. TYPE ClusterElement
73.     Index AS LONG
74.     FirstGroup AS LONG
75.     LastGroup AS LONG
76.     Centroid AS Vector
77.     Velocity AS Vector
78.     Visible AS INTEGER
79.     MotionType AS INTEGER
80. END TYPE
81.  
82. TYPE GroupElement
83.     Identity AS LONG
84.     GroupName AS STRING
85.     Pointer AS LONG
86.     Lagger AS LONG
87.     Volume AS Vector
88.     FirstVector AS LONG
89.     LastVector AS LONG
90.     Centroid AS Vector
91.     Velocity AS Vector
92.     Visible AS INTEGER
93.     Distance2 AS DOUBLE
94. END TYPE
95.  
96. TYPE MissionGroup
97.     Label AS STRING
98.     Discovered AS INTEGER
99. END TYPE
100.  
101. ' Scale.
102. DIM SHARED bignumber AS LONG
103. bignumber = 6000000
104.  
105. ' Cluster setup.
106. DIM SHARED ClusterIndexTicker AS LONG
107. DIM SHARED ClusterFillCounter AS INTEGER
108. DIM SHARED Cluster(bignumber / 100) AS ClusterElement
109. ClusterIndexTicker = 0
110. ClusterFillCounter = 0
111.  
112. ' Group linked list setup.
113. DIM SHARED Group(bignumber / 10) AS GroupElement
114. DIM SHARED GroupIdTicker AS LONG
115. GroupIdTicker = 0
116.  
117. ' Path
118. DIM SHARED FixedPath(25, 86400) AS Vector
119. DIM SHARED PathIndexTicker AS LONG
120. PathIndexTicker = 0
121.  
122. ' Basis vectors defined in three-space.
123. DIM SHARED xhat(3), yhat(3), zhat(3)
124. xhat(1) = 1: xhat(2) = 0: xhat(3) = 0
125. yhat(1) = 0: yhat(2) = 1: yhat(3) = 0
126. zhat(1) = 0: zhat(2) = 0: zhat(3) = 1
127.  
128. ' Camera orientation vectors.
129. DIM SHARED uhat(3), vhat(3), nhat(3)
130.  
131. ' Camera position.
132. DIM SHARED PlayerCamera AS Camera
133.  
134. ' Field-of-view distance.
135. DIM SHARED fovd
136. fovd = -192
137.  
138. ' Clipping planes.
139. DIM SHARED nearplane(4), farplane(4), rightplane(4), leftplane(4), topplane(4), bottomplane(4)
140. nearplane(4) = 1
141. farplane(4) = -180
142. rightplane(4) = -17 ' (17=35/2=tilesize/2 looks better than 1.)
143. leftplane(4) = -17
144. topplane(4) = -17
145. bottomplane(4) = -17
146.  
147. ' World vectors.
148. DIM SHARED vec(bignumber, 3) ' Relative Position
149. DIM SHARED vec3Dpos(bignumber, 3) ' Absolute osition
150. DIM SHARED vec3Dvel(bignumber, 3) ' Linear velocity
151. DIM SHARED vec3Dvis(bignumber) ' Visible toggle
152. DIM SHARED vec2D(bignumber, 2) ' Projection onto 2D plane
153. DIM SHARED vec3Dcolor(bignumber) AS LONG ' Original color
154. DIM SHARED vec2Dcolor(bignumber) AS LONG ' Projected color
155.  
156. ' Mission.
157. DIM SHARED MissionTicker AS INTEGER
158. DIM SHARED Mission(20) AS MissionGroup
159.  
160. ' Interface.
161. DIM SHARED ToggleHUD AS INTEGER
162. DIM SHARED ToggleAnimate AS INTEGER
163. DIM SHARED FPSReport AS INTEGER
164. DIM SHARED NumClusterVisible AS LONG
165. DIM SHARED NumVectorVisible AS LONG
166. DIM SHARED NumGroupVisible AS LONG
167. DIM SHARED ClosestGroup AS LONG
168.  
169. ' Initialize.
170. ToggleAnimate = 1
171. ToggleHUD = 1
172. PlayerCamera.Position.x = -40
173. PlayerCamera.Position.y = 500 '30
174. PlayerCamera.Position.z = 40
175. uhat(1) = COS(0): uhat(2) = SIN(0): uhat(3) = 0
176. vhat(1) = 0: vhat(2) = 0: vhat(3) = 1
177. CALL CalculateScreenVectors
178.  
179. ' Prime main loop.
180. CALL CreateLevel
181. CALL CreateMission(10)
182.  
183. ' Start main loop.
184. CALL MainLoop
185.  
186. END
187.  
188. ' Subs and Functions
189.  
190. SUB CreateMission (ListSize AS INTEGER)
191.     DIM k AS INTEGER
192.     DIM a AS STRING
193.     DIM b AS STRING
194.     a = ""
195.     b = ""
196.     REDIM MissionPool(0) AS STRING
197.  
198.     '''
199.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Atmospheric dust"
200.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Black hole"
201.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Cloudy sky"
202.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 1"
203.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 2"
204.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 3"
205.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Demon orb"
206.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Dirt and sand"
207.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Grave"
208.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Hell sparks"
209.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Laser"
210.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Lush terrain"
211.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 1"
212.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 2"
213.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 3"
214.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet center"
215.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet column"
216.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet interior"
217.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Plasma core"
218.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Pyramid"
219.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Rain"
220.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Singularity"
221.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Snowman 1"
222.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Snowman 2"
223.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Snowman 3"
224.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tree 1"
225.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tree 2"
226.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tree 3"
227.  
228.     '''
229.  
230.     MissionTicker = 0
231.     DO
232.         k = 1 + INT(RND * UBOUND(MissionPool))
233.         a = MissionPool(k)
234.         IF (INSTR(b, a) = 0) THEN
235.             b = b + a
236.             MissionTicker = MissionTicker + 1
237.             Mission(MissionTicker).Label = a
238.             Mission(MissionTicker).Discovered = 0
239.         END IF
240.     LOOP UNTIL (MissionTicker = ListSize)
241. END SUB
242.  
243. SUB CreateLevel
244.     DIM gtmp AS LONG
245.     DIM p AS LONG
246.     DIM n AS SINGLE
247.     DIM i, j, k AS SINGLE
248.     DIM u, v, w AS SINGLE
249.     DIM x0, y0, z0 AS SINGLE
250.  
251.     ' Initialize linked list.
252.     gtmp = CreateNewGroup&(0, 0, 0, 0, 0, 1)
253.  
254.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
255.  
256.     ' Atmospheric dust
257.     FOR u = -1400 TO 1400 - 350 STEP 350
258.         FOR v = -1400 TO 1400 - 350 STEP 350
259.             FOR i = u TO u + 350 STEP 35
260.                 FOR j = v TO v + 350 STEP 35
261.                     FOR w = (100 + 35 / 2) TO (800 - 35 + 35 / 2) STEP 35
262.                         gtmp = NewCube&(gtmp, "Atmospheric dust", 5 * (1 - w / 800), i, j, w, 35, 35, 35, DarkGray, White, Snow, -1)
263.                     NEXT
264.                 NEXT
265.             NEXT
266.             CALL ClusterPinch(gtmp)
267.         NEXT
268.     NEXT
269.     CALL ClusterPinch(gtmp)
270.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
271.  
272.  
273.  
274.  
275.  
276.  
277.  
278.  
279.  
280.  
281.     'GOTO moo
282.  
283.  
284.  
285.  
286.  
287.  
288.     ' Black hole
289.     k = RND * 2 * pi
290.     x0 = 1000 * COS(k)
291.     y0 = 1000 * SIN(k)
292.     z0 = 300
293.     i = 100
294.     j = 25
295.     FOR u = -i TO i STEP j
296.         FOR v = -i TO i STEP j
297.             FOR w = -i TO i STEP j
298.                 k = SQR(u * u + v * v + w * w)
299.                 IF k <= i AND k >= i - j THEN
300.                     gtmp = NewCube&(gtmp, "Black hole", j, x0 + u, y0 + v, z0 + w, j, j, j, DarkGray, White, Snow, -1)
301.                     CALL SetParticleVelocity(gtmp, -.25 * u / k, -.25 * v / k, -.25 * w / k)
302.                 END IF
303.             NEXT
304.         NEXT
305.     NEXT
306.     gtmp = NewShell&("Singularity", 10, x0, y0, z0, Black, Black, Black, 2, 5, -1)
307.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
308.  
309.     ' Comet
310.     FOR n = 1 TO 3
311.         u = RND * 2 * pi
312.         PathIndexTicker = PathIndexTicker + 1
313.         FOR p = 1 TO 86400
314.             FixedPath(PathIndexTicker, p).x = .25 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
315.             FixedPath(PathIndexTicker, p).y = .25 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
316.             FixedPath(PathIndexTicker, p).z = .15 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
317.         NEXT
318.         x0 = 150 + (RND - .5) * 2 * 550
319.         y0 = 150 + (RND - .5) * 2 * 550
320.         z0 = 200 + RND * 100
321.         gtmp = NewCube&(gtmp, "Comet" + STR$(n), 300, x0, y0, z0, 25, 25, 25, Teal, Cyan, DodgerBlue, PathIndexTicker)
322.         FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
323.             vec3Dvel(k, 1) = (RND - .5) * .20
324.             vec3Dvel(k, 2) = (RND - .5) * .20
325.             vec3Dvel(k, 3) = (RND - .5) * .20
326.         NEXT
327.         gtmp = NewShell&("Comet" + STR$(n), 15, x0, y0, z0, Teal, Cyan, DodgerBlue, 1, 80, PathIndexTicker)
328.         CALL ClusterPinch(gtmp)
329.     NEXT
330.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
331.  
332.     ' Demon orb
333.     FOR n = 1 TO 6
334.         u = RND * 2 * pi
335.         PathIndexTicker = PathIndexTicker + 1
336.         FOR p = 1 TO 86400
337.             FixedPath(PathIndexTicker, p).x = .25 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
338.             FixedPath(PathIndexTicker, p).y = .25 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
339.             FixedPath(PathIndexTicker, p).z = .15 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
340.         NEXT
341.         x0 = (RND - .5) * 2 * 1000
342.         y0 = (RND - .5) * 2 * 1000
343.         z0 = -700 - RND * 100
344.         gtmp = NewCube&(gtmp, "Demon orb", 300, x0, y0, z0, 25, 25, 25, Red, SunsetOrange, Sunglow, PathIndexTicker)
345.         FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
346.             vec3Dvel(k, 1) = (RND - .5) * .20
347.             vec3Dvel(k, 2) = (RND - .5) * .20
348.             vec3Dvel(k, 3) = (RND - .5) * .20
349.         NEXT
350.         gtmp = NewShell&("Demon orb", 15, x0, y0, z0, Red, SunsetOrange, Sunglow, 1, 80, PathIndexTicker)
351.         CALL ClusterPinch(gtmp)
352.     NEXT
353.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
354.  
355.     ' Death Star
356.     PathIndexTicker = PathIndexTicker + 1
357.     FOR p = 1 TO 86400
358.         FixedPath(PathIndexTicker, p).x = -.1 * COS(2 * pi * (24 * 60) * (p - 1) / 86400)
359.         FixedPath(PathIndexTicker, p).y = -.1 * SIN(2 * pi * (24 * 60) * (p - 1) / 86400)
360.         FixedPath(PathIndexTicker, p).z = 0
361.     NEXT
362.     x0 = 100 + (RND - .5) * 2 * 250
363.     y0 = 100 + (RND - .5) * 2 * 250
364.     gtmp = NewShell&("Death Star", 75, x0, y0, 400, Gray, DarkGray, White, 0, 0, PathIndexTicker)
365.     gtmp = NewShell&("Death Star reactor", 15, x0, y0, 400, Cyan, Teal, Blue, 1, 20, PathIndexTicker)
366.     gtmp = NewCube&(gtmp, "Plasma core", 300, x0, y0, 400, 25, 25, 25, Cyan, Teal, Blue, PathIndexTicker)
367.     FOR p = Group(gtmp).FirstVector TO Group(gtmp).LastVector
368.         vec3Dvel(p, 1) = (RND - .5) * .20
369.         vec3Dvel(p, 2) = (RND - .5) * .20
370.         vec3Dvel(p, 3) = (RND - .5) * .20
371.     NEXT
372.     FOR n = 10 TO 1 STEP -.5
373.         gtmp = NewCube&(gtmp, "Laser", 300, x0 + 75 / SQR(2) + (n - 1) * 25, y0 + .5 * n * 25, 400 + 75 / SQR(2) + .5 * (n - 1) * 25, 25, 25, 25, Lime, Green, White, PathIndexTicker)
374.         FOR p = Group(gtmp).FirstVector TO Group(gtmp).LastVector
375.             vec3Dvel(p, 1) = (RND - .5) * .50
376.             vec3Dvel(p, 2) = (RND - .5) * .50
377.             vec3Dvel(p, 3) = (RND - .5) * .50
378.         NEXT
379.     NEXT
380.     CALL ClusterPinch(gtmp)
381.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
382.  
383.     ' Dirt and sand
384.     FOR u = -1400 TO 1400 - 350 STEP 350
385.         FOR v = -1400 TO 1400 - 350 STEP 350
386.             FOR i = u TO u + 350 STEP 35
387.                 FOR j = v TO v + 350 STEP 35
388.                     FOR w = 0 - 35 / 2 TO -770 - 35 / 2 STEP -35
389.                         gtmp = NewCube&(gtmp, "Dirt and sand", 5, i, j, w, 35, 35, 35, SaddleBrown, DarkKhaki, Sienna, -1)
390.                     NEXT
391.                 NEXT
392.             NEXT
393.             CALL ClusterPinch(gtmp)
394.         NEXT
395.     NEXT
396.     CALL ClusterPinch(gtmp)
397.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
398.  
399.     ' Grave and Pyramid (1/2)
400.     k = RND * pi / 2 - pi / 4
401.     x0 = 1000 * COS(k)
402.     y0 = 1000 * SIN(k)
403.     FOR u = x0 - 160 TO x0 + 160 STEP 80
404.         FOR v = y0 - 160 TO y0 + 160 STEP 80
405.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (1) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
406.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (2) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
407.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (3) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
408.             gtmp = NewCube&(gtmp, "Grave", 200, u - 10, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
409.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
410.             gtmp = NewCube&(gtmp, "Grave", 200, u + 10, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
411.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (5) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
412.         NEXT
413.     NEXT
414.     CALL ClusterPinch(gtmp)
415.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
416.  
417.     ' Grave and Pyramid (2/2)
418.     k = k + pi
419.     x0 = 1000 * COS(k)
420.     y0 = 1000 * SIN(k)
421.     FOR w = 0 TO 75 STEP 15
422.         FOR u = -75 + w TO 75 - w STEP 15
423.             FOR v = -75 + w TO 75 - w STEP 15
424.                 gtmp = NewCube&(gtmp, "Pyramid", 35, x0 + u, y0 + v, w, 13, 13, 13, DarkKhaki, SunsetOrange, DarkGoldenRod, -1)
425.             NEXT
426.         NEXT
427.     NEXT
428.     CALL ClusterPinch(gtmp)
429.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
430.  
431.     ' Hell Sparks
432.     FOR u = -1400 TO 1400 - 350 STEP 350
433.         FOR v = -1400 TO 1400 - 350 STEP 350
434.             FOR i = u TO u + 350 STEP 35
435.                 FOR j = v TO v + 350 STEP 35
436.                     gtmp = NewCube&(gtmp, "Hell sparks", 15, i, j, -850, 35, 35, 100, Red, SunsetOrange, Sunglow, -1)
437.                     CALL SetParticleVelocity(gtmp, 0, 0, .75 + RND * .25)
438.                 NEXT
439.             NEXT
440.         NEXT
441.     NEXT
442.     CALL ClusterPinch(gtmp)
443.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
444.  
445.     ' Lake of Fire
446.     gtmp = NewTerrain&("Lake of Fire", 2800, 2800, 35, 0, 0, -900, Red, SunsetOrange, Sunglow, 4, 30)
447.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
448.  
449.     ' Planet
450.     PathIndexTicker = PathIndexTicker + 1
451.     FOR p = 1 TO 86400
452.         FixedPath(PathIndexTicker, p).x = .1 * COS(2 * pi * (24 * 60) * (p - 1) / 86400)
453.         FixedPath(PathIndexTicker, p).y = .1 * SIN(2 * pi * (24 * 60) * (p - 1) / 86400)
454.         FixedPath(PathIndexTicker, p).z = 0
455.     NEXT
456.     x0 = 100 + (RND - .5) * 2 * 250
457.     y0 = 100 + (RND - .5) * 2 * 250
458.     gtmp = NewPlanet&(350, 35, x0, y0, 900, PathIndexTicker)
459.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
460.  
461.     ' Rain
462.     FOR u = -350 TO 350 STEP 35
463.         FOR v = -350 TO 350 STEP 35
464.             IF (u * u + v * v <= 350 ^ 2) THEN
465.                 gtmp = NewCube&(gtmp, "Rain", 15, u, v, 50, 35, 35, 100, Blue, DodgerBlue, Blue, -1)
466.                 CALL SetParticleVelocity(gtmp, 0, 0, -.75 - RND * .25)
467.             END IF
468.         NEXT
469.     NEXT
470.     CALL ClusterPinch(gtmp)
471.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
472.  
473.     ' Realm of Heaven
474.     gtmp = NewTerrain&("Realm of Heaven", 2800, 2800, 35, 0, 0, 1400, BlueViolet, Cyan, White, 4, 30)
475.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
476.  
477.     ' Sky and Terrain: Center
478.     gtmp = NewTerrain&("Cloudy sky", 1400, 1400, 35, 0, 0, 100, RoyalBlue, DarkGray, Snow, 4, 30)
479.     gtmp = NewTerrain&("Lush terrain", 1400, 1400, 35, 0, 0, 0, Green, LightSeaGreen, Blue, 4, 30)
480.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
481.  
482.     ' Sky and Terrain: North
483.     gtmp = NewTerrain&("Northern winter sky", 2800, 700, 35, 0, 700 + 350, 100, White, DarkBlue, SlateGray, 4, 30)
484.     gtmp = NewTerrain&("Northern winter terrain", 2800, 700, 35, 0, 700 + 350, 0, White, Snow, SlateGray, 4, 30)
485.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
486.  
487.     ' Sky and Terrain: South
488.     gtmp = NewTerrain&("Southern desert sky", 2800, 700, 35, 0, -700 - 350, 100, RoyalBlue, SunsetOrange, Indigo, 4, 30)
489.     gtmp = NewTerrain&("Southern desert terrain", 2800, 700, 35, 0, -700 - 350, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
490.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
491.  
492.     ' Sky and Terrain: West
493.     gtmp = NewTerrain&("Western desert sky", 700, 1400, 35, -700 - 350, 0, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
494.     gtmp = NewTerrain&("Western desert terrain", 700, 1400, 35, -700 - 350, 0, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
495.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
496.  
497.     ' Sky and Terrain: East
498.     gtmp = NewTerrain&("Eastern desert sky", 700, 1400, 35, 700 + 350, 0, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
499.     gtmp = NewTerrain&("Eastern desert terrain", 700, 1400, 35, 700 + 350, 0, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
500.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
501.  
502.     ' Snow
503.     FOR u = -175 TO 175 STEP 35
504.         FOR v = -175 TO 175 STEP 35
505.             IF (u * u + v * v <= 175 ^ 2) THEN
506.                 gtmp = NewCube&(gtmp, "Snow", 15, u, v + 1050, 50, 35, 35, 100, White, Snow, SlateGray, -1)
507.                 CALL SetParticleVelocity(gtmp, 0, 0, -.75 - RND * .25)
508.             END IF
509.         NEXT
510.     NEXT
511.     CALL ClusterPinch(gtmp)
512.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
513.  
514.     ' Snowman
515.     FOR j = 1 TO 10
516.         u = 5 + RND * 20
517.         v = 0
518.         x0 = RND * 2800
519.         y0 = RND * 700 + 700
520.         FOR n = 1 TO 3
521.             z0 = u + v
522.             gtmp = NewCube&(gtmp, "Snowman" + STR$(n), 300, x0, y0, z0, u * 2 / SQR(3), u * 2 / SQR(3), u * 2 / SQR(3), Teal, Cyan, DodgerBlue, -1)
523.             FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
524.                 vec3Dvel(k, 1) = (RND - .5) * .20
525.                 vec3Dvel(k, 2) = (RND - .5) * .20
526.                 vec3Dvel(k, 3) = (RND - .5) * .20
527.             NEXT
528.             gtmp = NewShell&("Snowman" + STR$(n), u, x0, y0, z0, Teal, Cyan, DodgerBlue, 1, 80, -1)
529.             CALL ClusterPinch(gtmp)
530.             v = v + 2 * u
531.             u = u / 1.618
532.         NEXT
533.     NEXT
534.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
535.  
536.     ' Tornado
537.     FOR n = 1 TO 3
538.         u = RND * 2 * pi
539.         PathIndexTicker = PathIndexTicker + 1
540.         FOR p = 1 TO 86400
541.             FixedPath(PathIndexTicker, p).x = 1 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
542.             FixedPath(PathIndexTicker, p).y = 1 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
543.             FixedPath(PathIndexTicker, p).z = 0
544.         NEXT
545.         x0 = (RND - .5) * 2 * 750
546.         y0 = (RND - .5) * 2 * 750
547.         FOR k = 1 TO 30
548.             u = RND * 100
549.             v = RND * u / 3
550.             w = RND * 2 * pi
551.             gtmp = NewCube&(gtmp, "Tornado" + STR$(n), 35, x0 + v * COS(w), y0 + v * SIN(w), u, 15, 15, 15, DarkGray, SunsetOrange, DarkGoldenRod, PathIndexTicker)
552.             CALL SetParticleVelocity(gtmp, -SIN(w), COS(w), 0)
553.         NEXT
554.         CALL ClusterPinch(gtmp)
555.     NEXT
556.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
557.  
558.     ' Tree
559.     FOR n = 1 TO 10
560.         v = 30 + RND * 60
561.         u = v / 10
562.         w = u
563.         x0 = RND * 2800
564.         y0 = RND * 700 + 700
565.         z0 = u / 2
566.         FOR j = 0 TO v STEP u
567.             gtmp = NewCube&(gtmp, "Tree" + STR$(n), 5 * (v - j), x0, y0, z0 + j, w, w, u, Chocolate, SaddleBrown, Gray, -1)
568.             w = w * .9
569.             CALL ClusterPinch(gtmp)
570.         NEXT
571.         w = v / 1.618
572.         FOR j = u TO (v + 3 * u) STEP u
573.             gtmp = NewCube&(gtmp, "Tree" + STR$(n), 5 * (v - j), x0, y0, z0 + j, w, w, u, Lime, Green, Teal, -1)
574.             w = w * .8
575.             CALL ClusterPinch(gtmp)
576.         NEXT
577.         z0 = u / 2 + v
578.         gtmp = NewCube&(gtmp, "Tree" + STR$(n), 100, x0, y0, z0, u, u, u, White, Yellow, Teal, -1)
579.         FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
580.             vec3Dvel(k, 1) = (RND - .5) * .20
581.             vec3Dvel(k, 2) = (RND - .5) * .20
582.             vec3Dvel(k, 3) = (RND - .5) * .20
583.         NEXT
584.         CALL ClusterPinch(gtmp)
585.     NEXT
586.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
587.  
588.     ' Stellar dust
589.     FOR u = -1400 TO 1400 - 350 STEP 350
590.         FOR v = -1400 TO 1400 - 350 STEP 350
591.             FOR i = u TO u + 350 STEP 35
592.                 FOR j = v TO v + 350 STEP 35
593.                     gtmp = NewCube&(gtmp, "Stellar dust", 15, i, j, 1350, 35, 35, 100, BlueViolet, Cyan, White, -1)
594.                     CALL SetParticleVelocity(gtmp, 0, 0, -.75 - RND * .25)
595.                 NEXT
596.             NEXT
597.         NEXT
598.     NEXT
599.     CALL ClusterPinch(gtmp)
600.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
601.  
602.     ''' Rocket
603.     gtmp = NewCube&(gtmp, "Rocket", 200, 0, 0, 0, 15, 15, 35, Green, Green, Green, 0)
604.     gtmp = NewCube&(gtmp, "Rocket", 200, 0, 0, 0, 15, 15, 15, Red, Red, Red, 0)
605.     Cluster(ClusterIndexTicker).Velocity.x = 0
606.     Cluster(ClusterIndexTicker).Velocity.y = 0
607.     Cluster(ClusterIndexTicker).Velocity.z = 1
608.     CALL ClusterPinch(gtmp)
609.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
610.  
611.     moo:
612.  
613.     'PRINT
614.     'PRINT "Total clusters:  " + STR$(ClusterIndexTicker)
615.     'PRINT "Total groups:    " + STR$(GroupIdTicker)
616.     'PRINT "Total particles: " + STR$(Group(gtmp).LastVector)
617.     '_DISPLAY
618.     'SLEEP 3
619.  
620. END SUB
621.  
622. SUB MainLoop
623.     DIM fps AS INTEGER
624.     DIM fpstimer AS INTEGER
625.     DIM tt AS INTEGER
626.     fps = 0
627.     fpstimer = INT(TIMER)
628.     CALL CalculateScreenVectors
629.     DO
630.         CALL PlayerDynamics
631.         CALL ComputeVisibleScene
632.         CALL PlotWorld
633.         CALL DisplayHUD
634.         CALL KeyProcess
635.  
636.         fps = fps + 1
637.         tt = INT(TIMER)
638.         IF (tt = fpstimer + 1) THEN
639.             fpstimer = tt
640.             FPSReport = fps
641.             fps = 0
642.         END IF
643.  
644.         _DISPLAY
645.         _LIMIT 30
646.     LOOP
647. END SUB
648.  
649. ' Elevated-order primitive group.
650.  
651. FUNCTION NewPlanet& (TheRadius AS DOUBLE, ChunkSize AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, TheDynamic AS INTEGER)
652.     DIM ShadeA AS _UNSIGNED LONG
653.     DIM ShadeB AS _UNSIGNED LONG
654.     DIM ShadeC AS _UNSIGNED LONG
655.     DIM gtmp AS LONG
656.     DIM rtemp AS DOUBLE
657.     DIM u AS DOUBLE
658.     DIM v AS DOUBLE
659.     DIM w AS DOUBLE
660.     DIM r AS DOUBLE
661.     FOR rtemp = ChunkSize TO TheRadius STEP ChunkSize
662.         FOR u = -rtemp TO rtemp STEP ChunkSize
663.             FOR v = -rtemp TO rtemp STEP ChunkSize
664.                 FOR w = -rtemp TO rtemp STEP ChunkSize
665.                     r = SQR(u * u + v * v + w * w)
666.                     IF r <= rtemp AND r >= rtemp - ChunkSize THEN
667.                         ShadeA = ShadeMix~&(Red, SaddleBrown, r / TheRadius)
668.                         ShadeB = ShadeMix~&(SunsetOrange, DarkKhaki, r / TheRadius)
669.                         ShadeC = DarkKhaki
670.                         gtmp = NewCube&(1, "Planet Interior", ChunkSize, PosX + u, PosY + v, PosZ + w, ChunkSize, ChunkSize, ChunkSize, ShadeA, ShadeB, ShadeC, TheDynamic)
671.                         IF (r < TheRadius / 2.5) THEN
672.                             Group(gtmp).GroupName = "Planet center"
673.                             CALL SetParticleVelocity(gtmp, .25 * u / r, .25 * v / r, .25 * w / r)
674.                         END IF
675.                     END IF
676.                 NEXT
677.             NEXT
678.         NEXT
679.         CALL ClusterPinch(gtmp)
680.     NEXT
681.     CALL ClusterPinch(gtmp)
682.     gtmp = NewShell&("Planet surface", TheRadius, PosX, PosY, PosZ, Green, DarkKhaki, DodgerBlue, 2, 20, TheDynamic)
683.     gtmp = NewShell&("Planet core", TheRadius / 10, PosX, PosY, PosZ, Red, Yellow, DarkGoldenRod, 2, 5, TheDynamic)
684.     FOR w = 0 + ChunkSize / 4 TO PosZ - TheRadius - ChunkSize / 4 STEP ChunkSize / 2
685.         gtmp = NewCube&(1, "Planet column", 2 * ChunkSize, PosX, PosY, w, ChunkSize / 2, ChunkSize / 2, ChunkSize / 2, Cyan, Teal, Blue, TheDynamic)
686.         CALL SetParticleVelocity(gtmp, .15 * (RND - .5), .15 * (RND - .5), .25 * RND)
687.     NEXT
688.     CALL ClusterPinch(gtmp)
689.     NewPlanet& = gtmp
690. END FUNCTION
691.  
692. ' Medium-order primitive group(s).
693.  
694. FUNCTION NewTerrain& (TheName AS STRING, SizeX AS DOUBLE, SizeY AS DOUBLE, TheResolution AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, BumpFactor AS DOUBLE, SmoothFactor AS INTEGER)
695.     DIM g AS LONG
696.     DIM q AS LONG
697.     DIM vindex AS LONG
698.     DIM k AS INTEGER
699.     DIM factor1 AS DOUBLE
700.     DIM factor2 AS DOUBLE
701.     DIM a AS DOUBLE
702.     DIM b AS DOUBLE
703.     DIM i AS DOUBLE
704.     DIM j AS DOUBLE
705.     DIM u AS DOUBLE
706.     DIM v AS DOUBLE
707.     DIM w AS DOUBLE
708.     DIM ia AS DOUBLE
709.     DIM jb AS DOUBLE
710.     DIM rr AS DOUBLE
711.     DIM wi AS INTEGER
712.     DIM wj AS INTEGER
713.     DIM wa AS INTEGER
714.     DIM wb AS INTEGER
715.     DIM ci AS INTEGER
716.     DIM cj AS INTEGER
717.     DIM ca AS INTEGER
718.     DIM cb AS INTEGER
719.  
720.     factor1 = TheResolution
721.     factor2 = factor1 / 10
722.     wi = 0
723.     wj = 0
724.     wa = 0
725.     wb = 0
726.     FOR i = -SizeX / 2 + factor1 / 2 TO SizeX / 2 - factor1 / 2 STEP factor1
727.         wi = wi + 1
728.     NEXT
729.     FOR j = -SizeY / 2 + factor1 / 2 TO SizeY / 2 - factor1 / 2 STEP factor1
730.         wj = wj + 1
731.     NEXT
732.     FOR a = 0 TO factor1 - 0 * factor2 STEP factor2
733.         wa = wa + 1
734.     NEXT
735.     FOR b = 0 TO factor1 - 0 * factor2 STEP factor2
736.         wb = wb + 1
737.     NEXT
738.  
739.     DIM vgrid(wi * wa, wj * wb, 2) AS DOUBLE
740.     DIM vgrid2(wi * wa, wj * wb) AS DOUBLE
741.     FOR ia = 1 TO wi * wa
742.         FOR jb = 1 TO wj * wb
743.             SELECT CASE (RND)
744.                 CASE IS < .005
745.                     vgrid(ia, jb, 1) = factor1 * RND
746.                     vgrid(ia, jb, 2) = 1
747.                 CASE IS > 1 - .005
748.                     vgrid(ia, jb, 1) = -factor1 * RND / 2
749.                     vgrid(ia, jb, 2) = 1
750.                 CASE ELSE
751.                     vgrid(ia, jb, 1) = 0
752.                     vgrid(ia, jb, 2) = 0
753.             END SELECT
754.         NEXT
755.     NEXT
756.  
757.     IF (SmoothFactor > 0) THEN
758.         FOR k = 1 TO SmoothFactor
759.             FOR ia = 1 TO wi * wa
760.                 FOR jb = 1 TO wj * wb
761.                     vgrid2(ia, jb) = vgrid(ia, jb, 1)
762.                 NEXT
763.             NEXT
764.             FOR ia = 1 + 1 TO wi * wa - 1
765.                 FOR jb = 1 + 1 TO wj * wb - 1
766.                     IF (k = SmoothFactor - 5) THEN
767.                         vgrid(ia, jb, 2) = 0
768.                     END IF
769.                     IF vgrid(ia, jb, 2) = 0 THEN
770.                         vgrid(ia, jb, 1) = (1 / 4) * (vgrid2(ia - 1, jb) + vgrid2(ia + 1, jb) + vgrid2(ia, jb - 1) + vgrid2(ia, jb + 1))
771.                     END IF
772.                 NEXT
773.             NEXT
774.         NEXT
775.     END IF
776.  
777.     ci = 0
778.     cj = 0
779.     ca = 0
780.     cb = 0
781.     g = 1
782.     FOR i = -SizeX / 2 + factor1 / 2 - TheResolution / 2 TO SizeX / 2 - factor1 / 2 - TheResolution / 2 STEP factor1
783.         ci = ci + 1
784.         cj = 0
785.         FOR j = -SizeY / 2 + factor1 / 2 - TheResolution / 2 TO SizeY / 2 - factor1 / 2 - TheResolution / 2 STEP factor1
786.             cj = cj + 1
787.             u = i
788.             v = j
789.             w = 0
790.             q = LatestIdentity&(g)
791.             vindex = Group(q).LastVector
792.             g = CreateNewGroup&(q, PosX + u, PosY + v, PosZ + w, 0, 24)
793.             Group(g).GroupName = TheName
794.             Group(g).Volume.x = SizeX
795.             Group(g).Volume.y = SizeY
796.             Group(g).Volume.z = SQR(SizeX * SizeX + SizeY * SizeY)
797.             Group(g).FirstVector = vindex + 1
798.             ca = 0
799.             FOR a = i TO i + factor1 - 0 * factor2 STEP factor2
800.                 ca = ca + 1
801.                 cb = 0
802.                 FOR b = j TO j + factor1 - 0 * factor2 STEP factor2
803.                     cb = cb + 1
804.                     rr = vgrid((ci - 1) * wa + ca, (cj - 1) * wb + cb, 1)
805.                     vindex = vindex + 1
806.                     vec3Dpos(vindex, 1) = -u + a + BumpFactor * (RND - .5)
807.                     vec3Dpos(vindex, 2) = -v + b + BumpFactor * (RND - .5)
808.                     vec3Dpos(vindex, 3) = -w + rr + BumpFactor * (RND - .5)
809.                     IF (rr > 0) THEN
810.                         vec3Dcolor(vindex) = ShadeMix~&(ShadeA, ShadeB, rr / 10)
811.                     ELSE
812.                         vec3Dcolor(vindex) = ShadeC
813.                     END IF
814.                 NEXT
815.             NEXT
816.             Group(g).LastVector = vindex
817.         NEXT
818.         CALL ClusterPinch(g)
819.     NEXT
820.     CALL ClusterPinch(g)
821.     NewTerrain& = g
822. END FUNCTION
823.  
824. FUNCTION NewShell& (TheName AS STRING, TheRadius AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, BumpFactor AS DOUBLE, SmoothFactor AS INTEGER, TheDynamic AS INTEGER)
825.     DIM g AS LONG
826.     DIM q AS LONG
827.     DIM vindex AS LONG
828.     DIM k AS INTEGER
829.     DIM factor1 AS DOUBLE
830.     DIM factor2 AS DOUBLE
831.     DIM a AS DOUBLE
832.     DIM b AS DOUBLE
833.     DIM i AS DOUBLE
834.     DIM j AS DOUBLE
835.     DIM u AS DOUBLE
836.     DIM v AS DOUBLE
837.     DIM w AS DOUBLE
838.     DIM ia AS DOUBLE
839.     DIM jb AS DOUBLE
840.     DIM rr AS DOUBLE
841.     DIM wi AS LONG
842.     DIM wj AS LONG
843.     DIM wa AS LONG
844.     DIM wb AS LONG
845.     DIM ci AS LONG
846.     DIM cj AS LONG
847.     DIM ca AS LONG
848.     DIM cb AS LONG
849.  
850.     IF (TheRadius > 200) THEN
851.         factor1 = (2) * 2 * pi / (10 ^ (INT(LOG(TheRadius) / LOG(10))))
852.         factor2 = factor1 / (10)
853.     ELSE
854.         factor1 = 2 * pi / (10)
855.         factor2 = factor1 / (5)
856.     END IF
857.  
858.  
859.     wi = 0
860.     wj = 0
861.     wa = 0
862.     wb = 0
863.     FOR i = 0 TO 2 * pi - factor1 STEP factor1
864.         wi = wi + 1
865.     NEXT
866.     FOR j = factor2 TO pi - 0 STEP factor1
867.         wj = wj + 1
868.     NEXT
869.     FOR a = 0 TO factor1 STEP factor2
870.         wa = wa + 1
871.     NEXT
872.     FOR b = 0 TO factor1 STEP factor2
873.         wb = wb + 1
874.     NEXT
875.  
876.     DIM vgrid(wi * wa, wj * wb, 2) AS DOUBLE
877.     DIM vgrid2(wi * wa, wj * wb) AS DOUBLE
878.  
879.     FOR ia = 1 TO wi * wa
880.         FOR jb = 1 TO wj * wb
881.             SELECT CASE (RND)
882.                 CASE IS < .025
883.                     vgrid(ia, jb, 1) = TheRadius - BumpFactor * (TheRadius / 50)
884.                     vgrid(ia, jb, 2) = 1
885.                 CASE IS > 1 - .025
886.                     vgrid(ia, jb, 1) = TheRadius + BumpFactor * (TheRadius / 50)
887.                     vgrid(ia, jb, 2) = 1
888.                 CASE ELSE
889.                     vgrid(ia, jb, 1) = TheRadius
890.                     vgrid(ia, jb, 2) = 0
891.             END SELECT
892.         NEXT
893.     NEXT
894.  
895.     IF (SmoothFactor > 0) THEN
896.         FOR k = 1 TO SmoothFactor
897.             FOR ia = 1 TO wi * wa
898.                 FOR jb = 1 TO wj * wb
899.                     vgrid2(ia, jb) = vgrid(ia, jb, 1)
900.                 NEXT
901.             NEXT
902.             FOR ia = 1 + 1 TO wi * wa - 1
903.                 FOR jb = 1 + 1 TO wj * wb - 1
904.                     IF (k = SmoothFactor - 5) THEN
905.                         vgrid(ia, jb, 2) = 0
906.                     END IF
907.                     IF vgrid(ia, jb, 2) = 0 THEN
908.                         vgrid(ia, jb, 1) = (1 / 4) * (vgrid2(ia - 1, jb) + vgrid2(ia + 1, jb) + vgrid2(ia, jb - 1) + vgrid2(ia, jb + 1))
909.                     END IF
910.                 NEXT
911.             NEXT
912.         NEXT
913.     END IF
914.  
915.     ci = 0
916.     cj = 0
917.     ca = 0
918.     cb = 0
919.     g = 1
920.     FOR i = 0 TO 2 * pi - factor1 STEP factor1
921.         ci = ci + 1
922.         cj = 0
923.         FOR j = factor2 TO pi - 0 STEP factor1
924.             cj = cj + 1
925.             u = TheRadius * SIN(j) * COS(i)
926.             v = TheRadius * SIN(j) * SIN(i)
927.             w = TheRadius * COS(j)
928.             q = LatestIdentity&(g)
929.             vindex = Group(q).LastVector
930.             g = CreateNewGroup&(q, PosX + u, PosY + v, PosZ + w, TheDynamic, 64)
931.             Group(g).GroupName = TheName
932.             Group(g).Volume.x = TheRadius
933.             Group(g).Volume.y = TheRadius
934.             Group(g).Volume.z = TheRadius
935.             Group(g).FirstVector = vindex + 1
936.             ca = 0
937.             FOR a = i TO i + factor1 STEP factor2
938.                 ca = ca + 1
939.                 cb = 0
940.                 FOR b = j TO j + factor1 STEP factor2
941.                     cb = cb + 1
942.                     rr = vgrid((ci - 1) * wa + ca, (cj - 1) * wb + cb, 1)
943.                     vindex = vindex + 1
944.                     vec3Dpos(vindex, 1) = -u + rr * SIN(b) * COS(a) + BumpFactor * (RND - .5) * 2
945.                     vec3Dpos(vindex, 2) = -v + rr * SIN(b) * SIN(a) + BumpFactor * (RND - .5) * 2
946.                     vec3Dpos(vindex, 3) = -w + rr * COS(b) + BumpFactor * (RND - .5) * 2
947.                     IF (rr > TheRadius) THEN
948.                         vec3Dcolor(vindex) = ShadeMix~&(ShadeA, ShadeB, COS(j) ^ 2)
949.                     ELSE
950.                         vec3Dcolor(vindex) = ShadeC
951.                     END IF
952.                 NEXT
953.             NEXT
954.             Group(g).LastVector = vindex
955.         NEXT
956.         CALL ClusterPinch(g)
957.     NEXT
958.     CALL ClusterPinch(g)
959.  
960.     NewShell& = g
961. END SUB
962.  
963. ' Low-order primitive group(s).
964.  
965. FUNCTION NewCube& (StartingIdentity AS LONG, TheName AS STRING, Weight AS INTEGER, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, VolX AS DOUBLE, VolY AS DOUBLE, VolZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, TheDynamic AS INTEGER)
966.     DIM k AS INTEGER
967.     DIM g AS LONG
968.     DIM q AS LONG
969.     DIM vindex AS LONG
970.     q = LatestIdentity&(StartingIdentity)
971.     vindex = Group(q).LastVector
972.     g = CreateNewGroup(q, PosX, PosY, PosZ, TheDynamic, 64)
973.     Group(g).GroupName = TheName
974.     Group(g).Volume.x = VolX
975.     Group(g).Volume.y = VolY
976.     Group(g).Volume.z = VolZ
977.     Group(g).FirstVector = vindex + 1
978.     FOR k = 1 TO Weight
979.         vindex = vindex + 1
980.         vec3Dpos(vindex, 1) = (RND - .5) * VolX
981.         vec3Dpos(vindex, 2) = (RND - .5) * VolY
982.         vec3Dpos(vindex, 3) = (RND - .5) * VolZ
983.         IF (RND > .5) THEN
984.             vec3Dcolor(vindex) = ShadeA
985.         ELSE
986.             IF (RND > .5) THEN
987.                 vec3Dcolor(vindex) = ShadeB
988.             ELSE
989.                 vec3Dcolor(vindex) = ShadeC
990.             END IF
991.         END IF
992.     NEXT
993.     Group(g).LastVector = vindex
994.     NewCube& = g
995. END FUNCTION
996.  
997. ' Linked list utility.
998.  
999. FUNCTION LatestIdentity& (StartingID AS LONG)
1000.     DIM TheReturn AS LONG
1001.     DIM p AS LONG
1002.     DIM q AS LONG
1003.     p = StartingID
1004.     DO
1005.         q = p
1006.         p = Group(q).Pointer
1007.         IF (p = -999) THEN EXIT DO
1008.     LOOP
1009.     TheReturn = q
1010.     LatestIdentity& = TheReturn
1011. END FUNCTION
1012.  
1013. FUNCTION CreateNewGroup& (TheLaggerIn AS LONG, CenterX AS DOUBLE, CenterY AS DOUBLE, CenterZ AS DOUBLE, TheDynamic AS INTEGER, ClusterSize AS INTEGER)
1014.     GroupIdTicker = GroupIdTicker + 1
1015.     Group(GroupIdTicker).Identity = GroupIdTicker
1016.     Group(GroupIdTicker).Pointer = -999
1017.     Group(GroupIdTicker).Lagger = TheLaggerIn
1018.     Group(GroupIdTicker).Centroid.x = CenterX
1019.     Group(GroupIdTicker).Centroid.y = CenterY
1020.     Group(GroupIdTicker).Centroid.z = CenterZ
1021.     IF (TheLaggerIn <> 0) THEN
1022.         Group(TheLaggerIn).Pointer = Group(GroupIdTicker).Identity
1023.     END IF
1024.     '''
1025.     ClusterFillCounter = ClusterFillCounter + 1
1026.  
1027.     IF (ClusterFillCounter = 1) THEN
1028.         ClusterIndexTicker = ClusterIndexTicker + 1
1029.         Cluster(ClusterIndexTicker).FirstGroup = Group(GroupIdTicker).Identity
1030.         Cluster(ClusterIndexTicker).MotionType = TheDynamic
1031.     END IF
1032.  
1033.     IF (ClusterFillCounter = ClusterSize) THEN
1034.         CALL ClusterPinch(Group(GroupIdTicker).Identity)
1035.     END IF
1036.     '''
1037.     CreateNewGroup& = Group(GroupIdTicker).Identity
1038. END FUNCTION
1039.  
1040. SUB ClusterPinch (TheLastGroup AS LONG)
1041.     ClusterFillCounter = 0
1042.     Cluster(ClusterIndexTicker).LastGroup = TheLastGroup
1043.     CALL ClusterCentroidCalc(ClusterIndexTicker)
1044. END SUB
1045.  
1046. SUB ClusterCentroidCalc (TheClusterIndex AS LONG)
1047.     DIM k AS LONG
1048.     DIM n AS INTEGER
1049.     Cluster(TheClusterIndex).Centroid.x = 0
1050.     Cluster(TheClusterIndex).Centroid.y = 0
1051.     Cluster(TheClusterIndex).Centroid.z = 0
1052.     k = Cluster(TheClusterIndex).FirstGroup
1053.     n = 0
1054.     DO
1055.         Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x + Group(k).Centroid.x
1056.         Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y + Group(k).Centroid.y
1057.         Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z + Group(k).Centroid.z
1058.         n = n + 1
1059.         IF (k = Cluster(TheClusterIndex).LastGroup) THEN EXIT DO
1060.         k = Group(k).Pointer
1061.     LOOP
1062.     Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x / n
1063.     Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y / n
1064.     Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z / n
1065. END SUB
1066.  
1067. ' Vector manipulation.
1068.  
1069. SUB SetParticleVelocity (TheGroup AS LONG, vx AS DOUBLE, vy AS DOUBLE, vz AS DOUBLE)
1070.     DIM j AS LONG
1071.     DIM m AS LONG
1072.     DIM n AS LONG
1073.     m = Group(TheGroup).FirstVector
1074.     n = Group(TheGroup).LastVector
1075.     FOR j = m TO n
1076.         vec3Dvel(j, 1) = vx
1077.         vec3Dvel(j, 2) = vy
1078.         vec3Dvel(j, 3) = vz
1079.     NEXT
1080. END SUB
1081.  
1082. ' Cluster manipulation.
1083.  
1084. SUB EvolveCluster (TheClusterIndex AS LONG)
1085.     DIM dx, dy, dz, t, u, v AS DOUBLE
1086.     IF (Cluster(TheClusterIndex).MotionType = 0) THEN
1087.         dx = Cluster(TheClusterIndex).Velocity.x
1088.         dy = Cluster(TheClusterIndex).Velocity.y
1089.         dz = Cluster(TheClusterIndex).Velocity.z
1090.     ELSE
1091.         t = TIMER
1092.         u = INT(t)
1093.         v = t - u
1094.         dx = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).x + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).x
1095.         dy = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).y + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).y
1096.         dz = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).z + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).z
1097.     END IF
1098.     IF ((dx <> 0) OR (dy <> 0) OR (dz <> 0)) THEN
1099.         CALL TranslateCluster(TheClusterIndex, dx, dy, dz)
1100.     END IF
1101. END SUB
1102.  
1103. SUB TranslateCluster (TheClusterIndex AS LONG, dx AS DOUBLE, dy AS DOUBLE, dz AS DOUBLE)
1104.     DIM k AS LONG
1105.     k = Cluster(TheClusterIndex).FirstGroup
1106.     DO
1107.         Group(k).Centroid.x = Group(k).Centroid.x + dx
1108.         Group(k).Centroid.y = Group(k).Centroid.y + dy
1109.         Group(k).Centroid.z = Group(k).Centroid.z + dz
1110.         IF (k = Cluster(TheClusterIndex).LastGroup) THEN EXIT DO
1111.         k = Group(k).Pointer
1112.     LOOP
1113.     Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x + dx
1114.     Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y + dy
1115.     Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z + dz
1116. END SUB
1117.  
1118. ' Particle manipulation.
1119.  
1120. SUB EvolveParticles (TheGroup AS LONG)
1121.     DIM xdim AS DOUBLE
1122.     DIM ydim AS DOUBLE
1123.     DIM zdim AS DOUBLE
1124.     DIM dx AS DOUBLE
1125.     DIM dy AS DOUBLE
1126.     DIM dz AS DOUBLE
1127.     DIM px AS DOUBLE
1128.     DIM py AS DOUBLE
1129.     DIM pz AS DOUBLE
1130.     DIM k AS LONG
1131.  
1132.     xdim = Group(TheGroup).Volume.x
1133.     ydim = Group(TheGroup).Volume.y
1134.     zdim = Group(TheGroup).Volume.z
1135.  
1136.     FOR k = Group(TheGroup).FirstVector TO Group(TheGroup).LastVector
1137.  
1138.         ' Position update with periodic boundaries inside group volume
1139.         dx = 1 * vec3Dvel(k, 1)
1140.         dy = 1 * vec3Dvel(k, 2)
1141.         dz = 1 * vec3Dvel(k, 3)
1142.         IF (dx <> 0) THEN
1143.             px = vec3Dpos(k, 1) + dx
1144.             IF ABS(px) > xdim / 2 THEN
1145.                 IF (px > xdim / 2) THEN
1146.                     px = -xdim / 2
1147.                 ELSE
1148.                     px = xdim / 2
1149.                 END IF
1150.             END IF
1151.             vec3Dpos(k, 1) = px
1152.         END IF
1153.         IF (dy <> 0) THEN
1154.             py = vec3Dpos(k, 2) + dy
1155.             IF ABS(py) > ydim / 2 THEN
1156.                 IF (py > ydim / 2) THEN
1157.                     py = -ydim / 2
1158.                 ELSE
1159.                     py = ydim / 2
1160.                 END IF
1161.             END IF
1162.             vec3Dpos(k, 2) = py
1163.         END IF
1164.         IF (dz <> 0) THEN
1165.             pz = vec3Dpos(k, 3) + dz
1166.             IF ABS(pz) > zdim / 2 THEN
1167.                 IF (pz > zdim / 2) THEN
1168.                     pz = -zdim / 2
1169.                 ELSE
1170.                     pz = zdim / 2
1171.                 END IF
1172.             END IF
1173.             vec3Dpos(k, 3) = pz
1174.         END IF
1175.     NEXT
1176. END SUB
1177.  
1178. SUB CalculateScreenVectors
1179.     DIM uhatmag AS DOUBLE
1180.     DIM vhatmag AS DOUBLE
1181.     DIM h2 AS DOUBLE
1182.     DIM w2 AS DOUBLE
1183.     DIM mag AS DOUBLE
1184.     DIM uhatdotvhat AS DOUBLE
1185.     uhatmag = SQR(uhat(1) * uhat(1) + uhat(2) * uhat(2) + uhat(3) * uhat(3))
1186.     uhat(1) = uhat(1) / uhatmag: uhat(2) = uhat(2) / uhatmag: uhat(3) = uhat(3) / uhatmag
1187.     vhatmag = SQR(vhat(1) * vhat(1) + vhat(2) * vhat(2) + vhat(3) * vhat(3))
1188.     vhat(1) = vhat(1) / vhatmag: vhat(2) = vhat(2) / vhatmag: vhat(3) = vhat(3) / vhatmag
1189.     uhatdotvhat = uhat(1) * vhat(1) + uhat(2) * vhat(2) + uhat(3) * vhat(3)
1190.     nhat(1) = uhat(2) * vhat(3) - uhat(3) * vhat(2)
1191.     nhat(2) = uhat(3) * vhat(1) - uhat(1) * vhat(3)
1192.     nhat(3) = uhat(1) * vhat(2) - uhat(2) * vhat(1)
1193.     h2 = _HEIGHT / 2
1194.     w2 = _WIDTH / 2
1195.     nearplane(1) = -nhat(1)
1196.     nearplane(2) = -nhat(2)
1197.     nearplane(3) = -nhat(3)
1198.     farplane(1) = nhat(1)
1199.     farplane(2) = nhat(2)
1200.     farplane(3) = nhat(3)
1201.     rightplane(1) = h2 * fovd * uhat(1) - h2 * w2 * nhat(1)
1202.     rightplane(2) = h2 * fovd * uhat(2) - h2 * w2 * nhat(2)
1203.     rightplane(3) = h2 * fovd * uhat(3) - h2 * w2 * nhat(3)
1204.     mag = SQR(rightplane(1) * rightplane(1) + rightplane(2) * rightplane(2) + rightplane(3) * rightplane(3))
1205.     rightplane(1) = rightplane(1) / mag
1206.     rightplane(2) = rightplane(2) / mag
1207.     rightplane(3) = rightplane(3) / mag
1208.     leftplane(1) = -h2 * fovd * uhat(1) - h2 * w2 * nhat(1)
1209.     leftplane(2) = -h2 * fovd * uhat(2) - h2 * w2 * nhat(2)
1210.     leftplane(3) = -h2 * fovd * uhat(3) - h2 * w2 * nhat(3)
1211.     mag = SQR(leftplane(1) * leftplane(1) + leftplane(2) * leftplane(2) + leftplane(3) * leftplane(3))
1212.     leftplane(1) = leftplane(1) / mag
1213.     leftplane(2) = leftplane(2) / mag
1214.     leftplane(3) = leftplane(3) / mag
1215.     topplane(1) = w2 * fovd * vhat(1) - h2 * w2 * nhat(1)
1216.     topplane(2) = w2 * fovd * vhat(2) - h2 * w2 * nhat(2)
1217.     topplane(3) = w2 * fovd * vhat(3) - h2 * w2 * nhat(3)
1218.     mag = SQR(topplane(1) * topplane(1) + topplane(2) * topplane(2) + topplane(3) * topplane(3))
1219.     topplane(1) = topplane(1) / mag
1220.     topplane(2) = topplane(2) / mag
1221.     topplane(3) = topplane(3) / mag
1222.     bottomplane(1) = -w2 * fovd * vhat(1) - h2 * w2 * nhat(1)
1223.     bottomplane(2) = -w2 * fovd * vhat(2) - h2 * w2 * nhat(2)
1224.     bottomplane(3) = -w2 * fovd * vhat(3) - h2 * w2 * nhat(3)
1225.     mag = SQR(bottomplane(1) * bottomplane(1) + bottomplane(2) * bottomplane(2) + bottomplane(3) * bottomplane(3))
1226.     bottomplane(1) = bottomplane(1) / mag
1227.     bottomplane(2) = bottomplane(2) / mag
1228.     bottomplane(3) = bottomplane(3) / mag
1229. END SUB
1230.  
1231. SUB ProjectGroup (TheGroup AS LONG)
1232.     DIM i AS LONG
1233.     DIM f AS INTEGER
1234.     DIM vectorinview AS INTEGER
1235.     DIM vec3Ddotnhat AS DOUBLE
1236.     FOR i = Group(TheGroup).FirstVector TO Group(TheGroup).LastVector
1237.         vec(i, 1) = Group(TheGroup).Centroid.x + vec3Dpos(i, 1) - PlayerCamera.Position.x
1238.         vec(i, 2) = Group(TheGroup).Centroid.y + vec3Dpos(i, 2) - PlayerCamera.Position.y
1239.         vec(i, 3) = Group(TheGroup).Centroid.z + vec3Dpos(i, 3) - PlayerCamera.Position.z
1240.         f = -1
1241.         vec3Dvis(i) = 0
1242.         vectorinview = 1
1243.         IF vec(i, 1) * nearplane(1) + vec(i, 2) * nearplane(2) + vec(i, 3) * nearplane(3) - nearplane(4) < 0 THEN vectorinview = 0
1244.         'IF vec(i, 1) * farplane(1) + vec(i, 2) * farplane(2) + vec(i, 3) * farplane(3) - farplane(4) < 0 THEN vectorinview = 0
1245.         IF vec(i, 1) * farplane(1) + vec(i, 2) * farplane(2) + vec(i, 3) * farplane(3) - farplane(4) * .85 < 0 THEN f = 1
1246.         'IF vec(i, 1) * rightplane(1) + vec(i, 2) * rightplane(2) + vec(i, 3) * rightplane(3) - rightplane(4) < 0 THEN vectorinview = 0
1247.         'IF vec(i, 1) * leftplane(1) + vec(i, 2) * leftplane(2) + vec(i, 3) * leftplane(3) - leftplane(4) < 0 THEN vectorinview = 0
1248.         'IF vec(i, 1) * topplane(1) + vec(i, 2) * topplane(2) + vec(i, 3) * topplane(3) - topplane(4) < 0 THEN vectorinview = 0
1249.         'IF vec(i, 1) * bottomplane(1) + vec(i, 2) * bottomplane(2) + vec(i, 3) * bottomplane(3) - bottomplane(4) < 0 THEN vectorinview = 0
1250.         IF (vectorinview = 1) THEN
1251.             vec3Dvis(i) = 1
1252.             vec3Ddotnhat = vec(i, 1) * nhat(1) + vec(i, 2) * nhat(2) + vec(i, 3) * nhat(3)
1253.             vec2D(i, 1) = (vec(i, 1) * uhat(1) + vec(i, 2) * uhat(2) + vec(i, 3) * uhat(3)) * fovd / vec3Ddotnhat
1254.             vec2D(i, 2) = (vec(i, 1) * vhat(1) + vec(i, 2) * vhat(2) + vec(i, 3) * vhat(3)) * fovd / vec3Ddotnhat
1255.             IF (f = 1) THEN
1256.                 vec2Dcolor(i) = Gray
1257.             ELSE
1258.                 vec2Dcolor(i) = vec3Dcolor(i)
1259.             END IF
1260.         END IF
1261.     NEXT
1262. END SUB
1263.  
1264. ' TheDynamics
1265.  
1266. SUB ComputeVisibleScene
1267.     DIM closestdist2 AS DOUBLE
1268.     DIM fp42 AS DOUBLE
1269.     DIM dist2 AS DOUBLE
1270.     DIM dx AS DOUBLE
1271.     DIM dy AS DOUBLE
1272.     DIM dz AS DOUBLE
1273.     DIM GroupInView AS INTEGER
1274.     DIM k AS LONG
1275.     DIM i AS LONG
1276.     ClosestGroup = 1
1277.     closestdist2 = 10000000
1278.     fp42 = farplane(4) * farplane(4)
1279.     FOR i = 1 TO ClusterIndexTicker
1280.         dx = Cluster(i).Centroid.x - PlayerCamera.Position.x
1281.         dy = Cluster(i).Centroid.y - PlayerCamera.Position.y
1282.         dz = Cluster(i).Centroid.z - PlayerCamera.Position.z
1283.         dist2 = dx * dx + dy * dy + dz * dz
1284.         IF (dist2 > 600 * 600) THEN
1285.             Cluster(i).Visible = 0
1286.             IF (Cluster(i).MotionType > -1) THEN
1287.                 CALL EvolveCluster(i)
1288.             END IF
1289.         ELSE
1290.             Cluster(i).Visible = 1
1291.             k = Cluster(i).FirstGroup
1292.             IF ((Cluster(i).MotionType > -1) AND (ToggleAnimate = 1)) THEN
1293.                 CALL EvolveCluster(i)
1294.             END IF
1295.             DO
1296.                 dx = Group(k).Centroid.x - PlayerCamera.Position.x
1297.                 dy = Group(k).Centroid.y - PlayerCamera.Position.y
1298.                 dz = Group(k).Centroid.z - PlayerCamera.Position.z
1299.                 dist2 = dx * dx + dy * dy + dz * dz
1300.                 Group(k).Visible = 0
1301.                 IF (dist2 < fp42) THEN
1302.                     GroupInView = 1
1303.                     IF dx * nearplane(1) + dy * nearplane(2) + dz * nearplane(3) - nearplane(4) < 0 THEN GroupInView = 0
1304.                     'IF dx * farplane(1) + dy * farplane(2) + dz * farplane(3) - farplane(4) < 0 THEN groupinview = 0 ''' Redundant
1305.                     IF dx * rightplane(1) + dy * rightplane(2) + dz * rightplane(3) - rightplane(4) < 0 THEN GroupInView = 0
1306.                     IF dx * leftplane(1) + dy * leftplane(2) + dz * leftplane(3) - leftplane(4) < 0 THEN GroupInView = 0
1307.                     IF dx * topplane(1) + dy * topplane(2) + dz * topplane(3) - topplane(4) < 0 THEN GroupInView = 0
1308.                     IF dx * bottomplane(1) + dy * bottomplane(2) + dz * bottomplane(3) - bottomplane(4) < 0 THEN GroupInView = 0
1309.                     IF (GroupInView = 1) THEN
1310.                         Group(k).Visible = 1
1311.                         IF (dist2 < closestdist2) THEN
1312.                             closestdist2 = dist2
1313.                             ClosestGroup = k
1314.                         END IF
1315.                         Group(k).Distance2 = dist2
1316.                         IF (ToggleAnimate = 1) THEN CALL EvolveParticles(k)
1317.                         CALL ProjectGroup(k)
1318.                     END IF
1319.                 END IF
1320.                 IF (k = Cluster(i).LastGroup) THEN EXIT DO
1321.                 k = Group(k).Pointer
1322.             LOOP
1323.         END IF
1324.     NEXT
1325. END SUB
1326.  
1327. ' Graphics
1328.  
1329. SUB PlotWorld
1330.     DIM a AS DOUBLE
1331.     DIM b AS DOUBLE
1332.     DIM c AS LONG
1333.     DIM d AS LONG
1334.     DIM i AS LONG
1335.     DIM j AS INTEGER
1336.     DIM k AS LONG
1337.     DIM x1 AS DOUBLE
1338.     DIM y1 AS DOUBLE
1339.     DIM x2 AS DOUBLE
1340.     DIM y2 AS DOUBLE
1341.     DIM clrtmp AS _UNSIGNED LONG
1342.     DIM SortedGroups(5000) AS LONG
1343.     DIM SortedGroupsCount AS INTEGER
1344.  
1345.     NumClusterVisible = 0
1346.     NumVectorVisible = 0
1347.  
1348.     SortedGroupsCount = 0
1349.     FOR i = 1 TO ClusterIndexTicker
1350.         IF (Cluster(i).Visible = 1) THEN
1351.             NumClusterVisible = NumClusterVisible + 1
1352.             k = Cluster(i).FirstGroup
1353.             DO
1354.                 IF (Group(k).Visible = 1) THEN
1355.                     SortedGroupsCount = SortedGroupsCount + 1
1356.                     SortedGroups(SortedGroupsCount) = k
1357.                 END IF
1358.                 IF (k = Cluster(i).LastGroup) THEN EXIT DO
1359.                 k = Group(k).Pointer
1360.             LOOP
1361.         END IF
1362.     NEXT
1363.  
1364.     NumGroupVisible = SortedGroupsCount
1365.  
1366.     ' Bubble sort might be a shitty choice but it works for now. Replace with quicksort prolly.
1367.     FOR j = SortedGroupsCount TO 1 STEP -1
1368.         FOR i = 2 TO SortedGroupsCount
1369.             a = Group(SortedGroups(i - 1)).Distance2
1370.             b = Group(SortedGroups(i)).Distance2
1371.             IF (a < b) THEN
1372.                 c = SortedGroups(i - 1)
1373.                 d = SortedGroups(i)
1374.                 SortedGroups(i - 1) = d
1375.                 SortedGroups(i) = c
1376.             END IF
1377.         NEXT
1378.     NEXT
1379.  
1380.     CLS
1381.     PlayerCamera.Shade = ShadeMix~&(PlayerCamera.Shade, vec3Dcolor(Group(ClosestGroup).FirstVector), .01)
1382.     PAINT (_WIDTH / 2, _HEIGHT / 2), _RGBA(_RED32(PlayerCamera.Shade), _GREEN32(PlayerCamera.Shade), _BLUE32(PlayerCamera.Shade), 100)
1383.     FOR j = 1 TO SortedGroupsCount
1384.         k = SortedGroups(j)
1385.         FOR i = Group(k).FirstVector TO Group(k).LastVector - 1
1386.             IF (vec3Dvis(i) = 1) THEN
1387.                 NumVectorVisible = NumVectorVisible + 1
1388.                 IF (k = ClosestGroup) THEN
1389.                     clrtmp = Yellow
1390.                 ELSE
1391.                     clrtmp = vec2Dcolor(i)
1392.                 END IF
1393.                 x1 = vec2D(i, 1)
1394.                 y1 = vec2D(i, 2)
1395.                 x2 = vec2D(i + 1, 1)
1396.                 y2 = vec2D(i + 1, 2)
1397.                 IF (((x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1)) < 225) THEN
1398.                     CALL cline(x1, y1, x2, y2, clrtmp) 'lineSmooth
1399.                 ELSE
1400.                     CALL ccircle(x1, y1, 1, clrtmp)
1401.                 END IF
1402.             END IF
1403.         NEXT
1404.     NEXT
1405. END SUB
1406.  
1407. SUB DisplayHUD
1408.     DIM a AS STRING
1409.     DIM k AS INTEGER
1410.     CALL lineSmooth(0, 0, 25 * (xhat(1) * uhat(1) + xhat(2) * uhat(2) + xhat(3) * uhat(3)), 25 * (xhat(1) * vhat(1) + xhat(2) * vhat(2) + xhat(3) * vhat(3)), _RGBA(255, 0, 0, 200))
1411.     CALL lineSmooth(0, 0, 25 * (yhat(1) * uhat(1) + yhat(2) * uhat(2) + yhat(3) * uhat(3)), 25 * (yhat(1) * vhat(1) + yhat(2) * vhat(2) + yhat(3) * vhat(3)), _RGBA(0, 255, 0, 200))
1412.     CALL lineSmooth(0, 0, 25 * (zhat(1) * uhat(1) + zhat(2) * uhat(2) + zhat(3) * uhat(3)), 25 * (zhat(1) * vhat(1) + zhat(2) * vhat(2) + zhat(3) * vhat(3)), _RGBA(30, 144, 255, 200))
1413.     IF (ToggleHUD = 1) THEN
1414.         COLOR LimeGreen
1415.         _PRINTSTRING ((1) * 8, _HEIGHT - (10) * 16), " Position "
1416.         COLOR Teal
1417.         _PRINTSTRING ((1) * 8, _HEIGHT - (9) * 16), " x:       "
1418.         _PRINTSTRING ((1) * 8, _HEIGHT - (8) * 16), " y:       "
1419.         _PRINTSTRING ((1) * 8, _HEIGHT - (7) * 16), " z:       "
1420.         _PRINTSTRING ((1) * 8, _HEIGHT - (9) * 16), " x: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.x))))
1421.         _PRINTSTRING ((1) * 8, _HEIGHT - (8) * 16), " y: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.y))))
1422.         _PRINTSTRING ((1) * 8, _HEIGHT - (7) * 16), " z: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.z))))
1423.         COLOR LimeGreen
1424.         _PRINTSTRING ((1) * 8, _HEIGHT - (6) * 16), " O: Reset "
1425.         COLOR LimeGreen
1426.         _PRINTSTRING ((1) * 8, _HEIGHT - (4) * 16), " Move  "
1427.         COLOR DarkKhaki
1428.         _PRINTSTRING ((1) * 8, _HEIGHT - (3) * 16), " q W e "
1429.         _PRINTSTRING ((1) * 8, _HEIGHT - (2) * 16), " A S D "
1430.         COLOR LimeGreen
1431.         _PRINTSTRING ((1) * 8, (1) * 16), " Abilities "
1432.         COLOR DarkKhaki
1433.         _PRINTSTRING ((1) * 8, (2) * 16), "t = Pause  "
1434.         _PRINTSTRING ((1) * 8, (3) * 16), "b = Create "
1435.         _PRINTSTRING ((1) * 8, (4) * 16), "n = Explode"
1436.         COLOR DarkGray
1437.         _PRINTSTRING ((1) * 8, (5) * 16), "k = Delete "
1438.         COLOR DarkKhaki
1439.         _PRINTSTRING ((1) * 8, (6) * 16), "Esc = Quit "
1440.         'COLOR LimeGreen
1441.         '_PRINTSTRING ((1) * 8, (9) * 16), "View"
1442.         'COLOR DarkKhaki
1443.         '_PRINTSTRING ((1) * 8, (9) * 16), "FPS: " + LTRIM$(RTRIM$(STR$(FPSReport))) + "/30"
1444.         '_PRINTSTRING ((1) * 8, (10) * 16), "Clusters: " + LTRIM$(RTRIM$(STR$(NumClusterVisible)))
1445.         '_PRINTSTRING ((1) * 8, (11) * 16), "Groups: " + LTRIM$(RTRIM$(STR$(NumGroupVisible)))
1446.         '_PRINTSTRING ((1) * 8, (12) * 16), "Particles: " + LTRIM$(RTRIM$(STR$(NumVectorVisible)))
1447.         COLOR LimeGreen
1448.         _PRINTSTRING (_WIDTH - (12) * 8, (1) * 16), " Locations "
1449.         FOR k = 1 TO MissionTicker
1450.             a = " " + Mission(k).Label + " "
1451.             IF (Mission(k).Discovered = 0) THEN
1452.                 COLOR DarkKhaki
1453.             ELSE
1454.                 COLOR DarkGray
1455.             END IF
1456.             _PRINTSTRING (_WIDTH - (LEN(a) + 1) * 8, (1 + k) * 16), a
1457.         NEXT
1458.         COLOR LimeGreen
1459.         _PRINTSTRING (_WIDTH - (12) * 8, (k + 1) * 16), " M = Reset "
1460.         COLOR LimeGreen
1461.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (10) * 16), " Aim    "
1462.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (9) * 16), " x      "
1463.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (8) * 16), " y      "
1464.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (7) * 16), " z      "
1465.         COLOR Teal
1466.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (9) * 16), " x: " + LTRIM$(RTRIM$(STR$(INT(-nhat(1) * 100))))
1467.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (8) * 16), " y: " + LTRIM$(RTRIM$(STR$(INT(-nhat(2) * 100))))
1468.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (7) * 16), " z: " + LTRIM$(RTRIM$(STR$(INT(-nhat(3) * 100))))
1469.         COLOR LimeGreen
1470.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (5) * 16), " Swivel "
1471.         COLOR DarkKhaki
1472.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (4) * 16), " 7 8 9  "
1473.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (3) * 16), " 4 5 6  "
1474.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (2) * 16), " 1 2 3  "
1475.         a = " - Closest - "
1476.         COLOR LimeGreen
1477.         _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (3) * 16), a
1478.         a = " SPACE = Hide "
1479.         COLOR LimeGreen
1480.         _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (1) * 16), a
1481.     END IF
1482.     a = " " + Group(ClosestGroup).GroupName + " "
1483.     COLOR DarkKhaki
1484.     _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (2) * 16), a
1485. END SUB
1486.  
1487. ' Interface
1488.  
1489. SUB KeyProcess
1490.     DIM modifier AS DOUBLE
1491.     modifier = 0.05
1492.  
1493.     'IF (_KEYDOWN(100303) <> 0) OR (_KEYDOWN(100304) <> 0) THEN
1494.     '    modifier = modifier * 10
1495.     'END IF
1496.     IF (_KEYDOWN(87) <> 0) OR (_KEYDOWN(119) <> 0) OR (_KEYDOWN(18432) <> 0) THEN ' W or w or uparrow
1497.         CALL StrafeCameraNhatMinus
1498.         IF (ToggleAnimate = 1) THEN
1499.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - modifier * nhat(1)
1500.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - modifier * nhat(2)
1501.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - modifier * nhat(3)
1502.         END IF
1503.     END IF
1504.     IF (_KEYDOWN(83) <> 0) OR (_KEYDOWN(115) <> 0) OR (_KEYDOWN(20480) <> 0) THEN ' S or s or downarrow
1505.         CALL StrafeCameraNhatPlus
1506.         IF (ToggleAnimate = 1) THEN
1507.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + modifier * nhat(1)
1508.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + modifier * nhat(2)
1509.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + modifier * nhat(3)
1510.         END IF
1511.     END IF
1512.     IF (_KEYDOWN(65) <> 0) OR (_KEYDOWN(97) <> 0) THEN ' A or a
1513.         CALL StrafeCameraUhatMinus
1514.         IF (ToggleAnimate = 1) THEN
1515.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - modifier * uhat(1)
1516.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - modifier * uhat(2)
1517.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - modifier * uhat(3)
1518.         END IF
1519.     END IF
1520.     IF (_KEYDOWN(68) <> 0) OR (_KEYDOWN(100) <> 0) THEN ' D or d
1521.         CALL StrafeCameraUhatPlus
1522.         IF (ToggleAnimate = 1) THEN
1523.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + modifier * uhat(1)
1524.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + modifier * uhat(2)
1525.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + modifier * uhat(3)
1526.         END IF
1527.     END IF
1528.     IF (_KEYDOWN(81) <> 0) OR (_KEYDOWN(113) <> 0) THEN ' Q or q
1529.         CALL StrafeCameraVhatMinus
1530.         IF (ToggleAnimate = 1) THEN
1531.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - modifier * vhat(1)
1532.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - modifier * vhat(2)
1533.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - modifier * vhat(3)
1534.         END IF
1535.     END IF
1536.     IF (_KEYDOWN(69) <> 0) OR (_KEYDOWN(101) <> 0) THEN ' E or e
1537.         CALL StrafeCameraVhatPlus
1538.         IF (ToggleAnimate = 1) THEN
1539.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + modifier * vhat(1)
1540.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + modifier * vhat(2)
1541.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + modifier * vhat(3)
1542.         END IF
1543.     END IF
1544.     IF (_KEYDOWN(19200) <> 0) OR (_KEYDOWN(52) <> 0) THEN CALL RotateUhatMinus: CALL CalculateScreenVectors ' 4
1545.     IF (_KEYDOWN(19712) <> 0) OR (_KEYDOWN(54) <> 0) THEN CALL RotateUhatPlus: CALL CalculateScreenVectors ' 6
1546.     IF (_KEYDOWN(56) <> 0) THEN CALL RotateVhatPlus: CALL CalculateScreenVectors ' 8
1547.     IF (_KEYDOWN(50) <> 0) THEN CALL RotateVhatMinus: CALL CalculateScreenVectors ' 2
1548.     IF (_KEYDOWN(55) <> 0) THEN CALL RotateClockwise ' 7
1549.     IF (_KEYDOWN(57) <> 0) THEN CALL RotateCounterclockwise ' 9
1550.     IF (_KEYDOWN(49) <> 0) THEN CALL RotateUhatMinus: CALL CalculateScreenVectors: CALL RotateClockwise ' 1
1551.     IF (_KEYDOWN(51) <> 0) THEN CALL RotateUhatPlus: CALL CalculateScreenVectors: CALL RotateCounterclockwise ' 3
1552.  
1553.     DIM k AS LONG
1554.     DIM p AS LONG
1555.     DIM l AS LONG
1556.     DIM kh AS INTEGER
1557.     kh = _KEYHIT
1558.     IF (kh <> 0) THEN
1559.         SELECT CASE kh
1560.             CASE 27
1561.                 SYSTEM
1562.             CASE ASC(" ")
1563.                 ToggleHUD = -ToggleHUD
1564.             CASE ASC("b"), ASC("B")
1565.                 DIM gtmp AS LONG
1566.                 gtmp = NewCube&(1, "Custom block", 350, PlayerCamera.Position.x - 40 * nhat(1), PlayerCamera.Position.y - 40 * nhat(2), PlayerCamera.Position.z - 40 * nhat(3), 10, 10, 10, Lime, Purple, Teal, 0)
1567.                 CALL ClusterPinch(gtmp)
1568.             CASE ASC("k"), ASC("K")
1569.                 ' set -999? delete actual vectors? deal with cluster headers
1570.                 p = Group(ClosestGroup).Pointer
1571.                 l = Group(ClosestGroup).Lagger
1572.                 Group(l).Pointer = p
1573.                 IF (p <> -999) THEN
1574.                     Group(p).Lagger = l
1575.                 END IF
1576.             CASE ASC("m"), ASC("M")
1577.                 CALL CreateMission(10)
1578.             CASE ASC("n"), ASC("N")
1579.                 FOR k = Group(ClosestGroup).FirstVector TO Group(ClosestGroup).LastVector
1580.                     vec3Dvel(k, 1) = (RND - .5) * .20
1581.                     vec3Dvel(k, 2) = (RND - .5) * .20
1582.                     vec3Dvel(k, 3) = (RND - .5) * .20
1583.                 NEXT
1584.             CASE ASC("o"), ASC("O")
1585.                 PlayerCamera.Position.x = -40
1586.                 PlayerCamera.Position.y = 30
1587.                 PlayerCamera.Position.z = 40
1588.                 uhat(1) = -.2078192: uhat(2) = -.9781672: uhat(3) = 0
1589.                 vhat(1) = 0: vhat(2) = 0: vhat(3) = 1
1590.                 CALL CalculateScreenVectors
1591.             CASE ASC("t"), ASC("T")
1592.                 ToggleAnimate = -ToggleAnimate
1593.         END SELECT
1594.     END IF
1595.     _KEYCLEAR
1596. END SUB
1597.  
1598. ' Color utility.
1599.  
1600. FUNCTION ShadeMix~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, Weight AS DOUBLE)
1601.     ShadeMix~& = _RGB32((1 - Weight) * _RED32(Shade1) + Weight * _RED32(Shade2), (1 - Weight) * _GREEN32(Shade1) + Weight * _GREEN32(Shade2), (1 - Weight) * _BLUE32(Shade1) + Weight * _BLUE32(Shade2))
1602. END FUNCTION
1603.  
1604. ' Cartesian plotting.
1605.  
1606. SUB cline (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
1607.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col
1608. END SUB
1609.  
1610. SUB cpset (x1, y1, col AS _UNSIGNED LONG)
1611.     PSET (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), col
1612. END SUB
1613.  
1614. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
1615.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col
1616. END SUB
1617.  
1618. SUB lineSmooth (x0, y0, x1, y1, c AS _UNSIGNED LONG)
1619.     'Inspiration credit: {(FellippeHeitor)(qb64.org)(2020)}
1620.     '                    {https://en.wikipedia.org/w/index.php?title=Xiaolin_Wu%27s_line_algorithm&oldid=852445548}
1621.     'Edit: {(STxAxTIC)(2020-11-20)(Correction to alpha channel.)}
1622.  
1623.     DIM plX AS INTEGER, plY AS INTEGER, plI
1624.  
1625.     DIM steep AS _BYTE
1626.     steep = ABS(y1 - y0) > ABS(x1 - x0)
1627.  
1628.     IF steep THEN
1629.         SWAP x0, y0
1630.         SWAP x1, y1
1631.     END IF
1632.  
1633.     IF x0 > x1 THEN
1634.         SWAP x0, x1
1635.         SWAP y0, y1
1636.     END IF
1637.  
1638.     DIM dx, dy, gradient
1639.     dx = x1 - x0
1640.     dy = y1 - y0
1641.     gradient = dy / dx
1642.  
1643.     IF dx = 0 THEN
1644.         gradient = 1
1645.     END IF
1646.  
1647.     'handle first endpoint
1648.     DIM xend, yend, xgap, xpxl1, ypxl1
1649.     xend = _ROUND(x0)
1650.     yend = y0 + gradient * (xend - x0)
1651.     xgap = (1 - ((x0 + .5) - INT(x0 + .5)))
1652.     xpxl1 = xend 'this will be used in the main loop
1653.     ypxl1 = INT(yend)
1654.     IF steep THEN
1655.         plX = ypxl1
1656.         plY = xpxl1
1657.         plI = (1 - (yend - INT(yend))) * xgap
1658.         GOSUB plot
1659.  
1660.         plX = ypxl1 + 1
1661.         plY = xpxl1
1662.         plI = (yend - INT(yend)) * xgap
1663.         GOSUB plot
1664.     ELSE
1665.         plX = xpxl1
1666.         plY = ypxl1
1667.         plI = (1 - (yend - INT(yend))) * xgap
1668.         GOSUB plot
1669.  
1670.         plX = xpxl1
1671.         plY = ypxl1 + 1
1672.         plI = (yend - INT(yend)) * xgap
1673.         GOSUB plot
1674.     END IF
1675.  
1676.     DIM intery
1677.     intery = yend + gradient 'first y-intersection for the main loop
1678.  
1679.     'handle second endpoint
1680.     DIM xpxl2, ypxl2
1681.     xend = _ROUND(x1)
1682.     yend = y1 + gradient * (xend - x1)
1683.     xgap = ((x1 + .5) - INT(x1 + .5))
1684.     xpxl2 = xend 'this will be used in the main loop
1685.     ypxl2 = INT(yend)
1686.     IF steep THEN
1687.         plX = ypxl2
1688.         plY = xpxl2
1689.         plI = (1 - (yend - INT(yend))) * xgap
1690.         GOSUB plot
1691.  
1692.         plX = ypxl2 + 1
1693.         plY = xpxl2
1694.         plI = (yend - INT(yend)) * xgap
1695.         GOSUB plot
1696.     ELSE
1697.         plX = xpxl2
1698.         plY = ypxl2
1699.         plI = (1 - (yend - INT(yend))) * xgap
1700.         GOSUB plot
1701.  
1702.         plX = xpxl2
1703.         plY = ypxl2 + 1
1704.         plI = (yend - INT(yend)) * xgap
1705.         GOSUB plot
1706.     END IF
1707.  
1708.     'main loop
1709.     DIM x
1710.     IF steep THEN
1711.         FOR x = xpxl1 + 1 TO xpxl2 - 1
1712.             plX = INT(intery)
1713.             plY = x
1714.             plI = (1 - (intery - INT(intery)))
1715.             GOSUB plot
1716.  
1717.             plX = INT(intery) + 1
1718.             plY = x
1719.             plI = (intery - INT(intery))
1720.             GOSUB plot
1721.  
1722.             intery = intery + gradient
1723.         NEXT
1724.     ELSE
1725.         FOR x = xpxl1 + 1 TO xpxl2 - 1
1726.             plX = x
1727.             plY = INT(intery)
1728.             plI = (1 - (intery - INT(intery)))
1729.             GOSUB plot
1730.  
1731.             plX = x
1732.             plY = INT(intery) + 1
1733.             plI = (intery - INT(intery))
1734.             GOSUB plot
1735.  
1736.             intery = intery + gradient
1737.         NEXT
1738.     END IF
1739.  
1740.     EXIT SUB
1741.  
1742.     plot:
1743.     ' Change to regular PSET for standard coordinate orientation.
1744.     CALL cpset(plX, plY, _RGB32(_RED32(c), _GREEN32(c), _BLUE32(c), plI * _ALPHA32(c)))
1745.     RETURN
1746. END SUB
1747.  
1748. ' Camera transformation
1749.  
1750. SUB PlayerDynamics
1751.     DIM k AS INTEGER
1752.  
1753.     IF (ToggleAnimate = 1) THEN
1754.         PlayerCamera.Velocity.x = .95 * PlayerCamera.Velocity.x
1755.         PlayerCamera.Velocity.y = .95 * PlayerCamera.Velocity.y
1756.         PlayerCamera.Velocity.z = .95 * PlayerCamera.Velocity.z
1757.         PlayerCamera.Position.x = PlayerCamera.Position.x + PlayerCamera.Velocity.x
1758.         PlayerCamera.Position.y = PlayerCamera.Position.y + PlayerCamera.Velocity.y
1759.         PlayerCamera.Position.z = PlayerCamera.Position.z + PlayerCamera.Velocity.z
1760.     END IF
1761.  
1762.     FOR k = 1 TO MissionTicker
1763.         IF (Group(ClosestGroup).GroupName = Mission(k).Label) THEN
1764.             IF (Mission(k).Discovered = 0) THEN
1765.                 Mission(k).Discovered = 1
1766.                 SOUND 500, .25
1767.             END IF
1768.         END IF
1769.     NEXT
1770. END SUB
1771.  
1772. SUB RotateUhatPlus
1773.     uhat(1) = uhat(1) + nhat(1) * .0333
1774.     uhat(2) = uhat(2) + nhat(2) * .0333
1775.     uhat(3) = uhat(3) + nhat(3) * .0333
1776. END SUB
1777.  
1778. SUB RotateUhatMinus
1779.     uhat(1) = uhat(1) - nhat(1) * .0333
1780.     uhat(2) = uhat(2) - nhat(2) * .0333
1781.     uhat(3) = uhat(3) - nhat(3) * .0333
1782. END SUB
1783.  
1784. SUB RotateVhatPlus
1785.     vhat(1) = vhat(1) + nhat(1) * .0333
1786.     vhat(2) = vhat(2) + nhat(2) * .0333
1787.     vhat(3) = vhat(3) + nhat(3) * .0333
1788. END SUB
1789.  
1790. SUB RotateVhatMinus
1791.     vhat(1) = vhat(1) - nhat(1) * .0333
1792.     vhat(2) = vhat(2) - nhat(2) * .0333
1793.     vhat(3) = vhat(3) - nhat(3) * .0333
1794. END SUB
1795.  
1796. SUB RotateCounterclockwise
1797.     DIM v1 AS DOUBLE
1798.     DIM v2 AS DOUBLE
1799.     DIM v3 AS DOUBLE
1800.     v1 = vhat(1)
1801.     v2 = vhat(2)
1802.     v3 = vhat(3)
1803.     vhat(1) = v1 + uhat(1) * .0333
1804.     vhat(2) = v2 + uhat(2) * .0333
1805.     vhat(3) = v3 + uhat(3) * .0333
1806.     uhat(1) = uhat(1) - v1 * .0333
1807.     uhat(2) = uhat(2) - v2 * .0333
1808.     uhat(3) = uhat(3) - v3 * .0333
1809. END SUB
1810.  
1811. SUB RotateClockwise
1812.     DIM v1 AS DOUBLE
1813.     DIM v2 AS DOUBLE
1814.     DIM v3 AS DOUBLE
1815.     v1 = vhat(1)
1816.     v2 = vhat(2)
1817.     v3 = vhat(3)
1818.     vhat(1) = v1 - uhat(1) * .0333
1819.     vhat(2) = v2 - uhat(2) * .0333
1820.     vhat(3) = v3 - uhat(3) * .0333
1821.     uhat(1) = uhat(1) + v1 * .0333
1822.     uhat(2) = uhat(2) + v2 * .0333
1823.     uhat(3) = uhat(3) + v3 * .0333
1824. END SUB
1825.  
1826. SUB StrafeCameraUhatPlus
1827.     PlayerCamera.Position.x = PlayerCamera.Position.x + uhat(1)
1828.     PlayerCamera.Position.y = PlayerCamera.Position.y + uhat(2)
1829.     PlayerCamera.Position.z = PlayerCamera.Position.z + uhat(3)
1830. END SUB
1831.  
1832. SUB StrafeCameraUhatMinus
1833.     PlayerCamera.Position.x = PlayerCamera.Position.x - uhat(1)
1834.     PlayerCamera.Position.y = PlayerCamera.Position.y - uhat(2)
1835.     PlayerCamera.Position.z = PlayerCamera.Position.z - uhat(3)
1836. END SUB
1837.  
1838. SUB StrafeCameraVhatPlus
1839.     PlayerCamera.Position.x = PlayerCamera.Position.x + vhat(1)
1840.     PlayerCamera.Position.y = PlayerCamera.Position.y + vhat(2)
1841.     PlayerCamera.Position.z = PlayerCamera.Position.z + vhat(3)
1842. END SUB
1843.  
1844. SUB StrafeCameraVhatMinus
1845.     PlayerCamera.Position.x = PlayerCamera.Position.x - vhat(1)
1846.     PlayerCamera.Position.y = PlayerCamera.Position.y - vhat(2)
1847.     PlayerCamera.Position.z = PlayerCamera.Position.z - vhat(3)
1848. END SUB
1849.  
1850. SUB StrafeCameraNhatPlus
1851.     PlayerCamera.Position.x = PlayerCamera.Position.x + nhat(1)
1852.     PlayerCamera.Position.y = PlayerCamera.Position.y + nhat(2)
1853.     PlayerCamera.Position.z = PlayerCamera.Position.z + nhat(3)
1854. END SUB
1855.  
1856. SUB StrafeCameraNhatMinus
1857.     PlayerCamera.Position.x = PlayerCamera.Position.x - nhat(1)
1858.     PlayerCamera.Position.y = PlayerCamera.Position.y - nhat(2)
1859.     PlayerCamera.Position.z = PlayerCamera.Position.z - nhat(3)
1860. END SUB
1861.  
1862. '''
1863.