Author Topic: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!) (Read 16422 times)

Petr · « **Reply #45 on:** January 04, 2021, 10:55:32 am »

My first version, named as qb64-memsound downloaded from github is 64bit. Which file you need? Created output WAV file or file on input (MP3)?

FellippeHeitor · « **Reply #46 on:** January 04, 2021, 10:57:50 am »

I tried in my machine and it worked with some files, not with others - which leads me to believe it has to do with the file generated and how OpenAL is decoding it - in which case debugging it beyond my abilities, since it's a third-party library. Let me know if you find something else that could be the cause.

FellippeHeitor · « **Reply #47 on:** January 04, 2021, 10:59:16 am »

Could you try playing the generated files with v1.4? I believe this has nothing to do with the new _MEMSOUND after all, since your issue is with regular _SNDPLAY.

Petr · « **Reply #48 on:** January 04, 2021, 11:02:23 am »

I'll try, but it will work. This cannot be a bug in OpenAl when the 64-bit version plays it. Even the 32-bit version reads correctly the length of the audio. But it won't start. 64 bit starts it. 32 bit sees the length of the music but does not start playing.

Petr · « **Reply #49 on:** January 04, 2021, 11:08:46 am »

This was wrong, I was too fast. Searching problems...

FellippeHeitor · « **Reply #50 on:** January 04, 2021, 11:10:27 am »

Something related to the audio library then, since none of that code has been touched recently.

Petr · « **Reply #51 on:** January 04, 2021, 11:38:01 am »

So..... IDIOT AM I. Again. Bad writed head in WAV file was the problem.

in SAVESOUND16S replace this row: H16.lenght = OFFSETasI64(arr.SIZE) - 2
We still using integers.... NOW 32 bit version works as expected!

BIG SORRY FOR THIS. -2 miss

Please try it also. I have five IDEs open here and I'm quickly losing track.

FellippeHeitor · « **Reply #52 on:** January 04, 2021, 11:38:52 am »

Hahaha, glad to hear all is solved.

Petr · « **Reply #53 on:** January 04, 2021, 11:44:12 am »

The big unknown is: Why the this bug is none problem for 64 bit version, but it is problem for 32 bit version? Just add -2 and is done...

I am also very glad, that it works and this nice function can be added!

Petr · « **Reply #54 on:** January 04, 2021, 11:51:47 am »

Fellippe, but still:

This code was work under 32 bit:

Code: QB64: [Select]

'Program create new WAV soundtrack + add echo
'if _fileexists("1d.mp3")
'_SNDPLAYFILE ("1d.mp3")
'SLEEP
 
'_SNDPLAYFILE ("tracks-mix4.wav")
 
'SLEEP
 
EchoLenght = 0.12 '0.06 seconds is echo duration
OverSampling = 10 'number of echoes sample passes
 
Echo& = _SNDRATE * EchoLenght
 
DO UNTIL Echo& MOD 2 = 0
    Echo& = Echo& + 1
LOOP
DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Audio2 AS INTEGER, Audio3 AS INTEGER, Audio4 AS INTEGER
REDIM PlayableFiles(0) AS STRING
 
 
'INPUT "Insert audio file name:"; a1$
 
DECLARE CUSTOMTYPE LIBRARY ".\direntry"
    FUNCTION load_dir& (s AS STRING)
    FUNCTION has_next_entry& ()
    SUB close_dir ()
    SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
END DECLARE
 
REDIM Dir(0) AS STRING, File(0) AS STRING
GetFileList _CWD$, Dir(), File()
 
 
FOR s = LBOUND(file) TO UBOUND(file)
    SELECT CASE UCASE$(RIGHT$(File(s), 3))
        CASE "MP3", "OGG", "WAV"
            PlayableFiles(i) = File(s)
            i = i + 1
            REDIM _PRESERVE PlayableFiles(i) AS STRING
    END SELECT
NEXT
 
PRINT "Files to play: "; i - 1
 
 
FOR playit = 0 TO i - 1
    a1$ = PlayableFiles(playit)
    PRINT "Opening file "; playit + 1; "/"; i - 1; " - "; PlayableFiles(playit)
    IF a THEN _SNDCLOSE a: a = 0
    a = _SNDOPEN(a1$)
    IF a THEN PRINT "Audio file opened" ELSE PRINT "Audio file 1 opening error.": END
    LENa = _CEIL(_SNDLEN(a)) + EchoLenght
    PRINT "Audio file lenght:"; LENa
    NewTrackTime = LENa
 
 
 
 
    Left = _MEMSOUND(a, 1)
    Right = _MEMSOUND(a, 2)
 
    NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
    NewSound = _MEMNEW(NewSoundSize&)
 
    PRINT "SndRate:"; _SNDRATE
    PRINT "Track memory len:"; Left.SIZE
    PRINT "Creating audio..."
 
    VolDown = 1 / OverSampling
    Create& = 0
    NewAudio& = 0
    DO UNTIL Create& >= Left.SIZE - 2
        _MEMGET Left, Left.OFFSET + Create&, Audio
        _MEMGET Right, Right.OFFSET + Create&, Audio2
 
        IF Create& > Echo& THEN
 
            E& = Create&
            Vol = 1
            DO UNTIL E& <= Create& - OverSampling
                Vol = Vol - VolDown
                _MEMGET Left, Left.OFFSET + Create& - Echo&, Audio3
                _MEMGET Left, Left.OFFSET + Create& - 2, Audio4
                Audio = (Audio + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
                E& = E& - 2
            LOOP
 
            E& = Create&
            Vol = 1
            DO UNTIL E& <= Create& - OverSampling
                Vol = Vol - VolDown
                _MEMGET Right, Right.OFFSET + Create& - Echo&, Audio3
                _MEMGET Right, Right.OFFSET + Create& - 2, Audio4
                Audio2 = (Audio2 + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
                E& = E& - 2
            LOOP
        END IF
 
        _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio 'left channel
        _MEMPUT NewSound, NewSound.OFFSET + NewAudio& + 2, Audio2 'right channel
        NewAudio& = NewAudio& + 4
        Create& = Create& + 2
    LOOP
 
    PRINT "New sound created. Saving as Tracks-mix4.wav..."
    SAVESOUND16S NewSound, "Tracks-mix4.wav"
    PRINT "Sound saved, erasing RAM..."
    _MEMFREE Left
    _MEMFREE Right
    _MEMFREE NewSound
 
    PRINT "Playing mixed sound"
    _SNDCLOSE a
    a = 0
    snd2 = _SNDOPEN("tracks-mix4.wav")
    PRINT _SNDLEN(snd2), snd2
    SLEEP
    _SNDPLAY snd2
    DO UNTIL _SNDPLAYING(snd2) = 0
        LOCATE 12
        PRINT _SNDGETPOS(snd2), _SNDLEN(snd2)
    LOOP
    CLS
    _SNDCLOSE snd2
    '    KILL "tracks-mix4.wav"
NEXT
 
END
 
 
FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    DIM o AS _INTEGER64, mo AS _MEM
    mo = _MEM(o)
    _MEMPUT mo, mo.OFFSET, OffsetVal
    _MEMFREE mo
    OFFSETasI64&& = o
END FUNCTION
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = OFFSETasI64(arr.SIZE) - 2 '  <---------------------- THIS IS THE PROBLEM. Without -2 works in 64 bit, with -2 works under 32 bit.
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 
SUB GetFileList (SearchDirectory AS STRING, DirList() AS STRING, FileList() AS STRING)
    CONST IS_DIR = 1
    CONST IS_FILE = 2
    DIM flags AS LONG, file_size AS LONG
 
    REDIM _PRESERVE DirList(100), FileList(100)
    DirCount = 0: FileCount = 0
 
    IF load_dir(SearchDirectory) THEN
        DO
            length = has_next_entry
            IF length > -1 THEN
                nam$ = SPACE$(length)
                get_next_entry nam$, flags, file_size
                IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
                    DirCount = DirCount + 1
                    IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
                    DirList(DirCount) = nam$
                ELSEIF (flags AND IS_FILE) OR _FILEEXISTS(SearchDirectory + nam$) THEN
                    FileCount = FileCount + 1
                    IF FileCount > UBOUND(filelist) THEN REDIM _PRESERVE FileList(UBOUND(filelist) + 100)
                    FileList(FileCount) = nam$
                END IF
            END IF
        LOOP UNTIL length = -1
        close_dir
    ELSE
    END IF
    REDIM _PRESERVE DirList(DirCount)
    REDIM _PRESERVE FileList(FileCount)
END SUB
 

now do the same bug in 64 bit version as in previous case previous code in 32 bit! So something in 32 bit ide is shifted by 2 bytes down in 32 bit ide or is something shifted by 2 byte up in 64 bit version?

FellippeHeitor · « **Reply #55 on:** January 04, 2021, 11:53:20 am »

Offset sizes are different depending on the platform. It could be that.

SMcNeill · « **Reply #56 on:** January 04, 2021, 01:15:52 pm »

Code: QB64: [Select]

DIM x AS INTEGER
DIM m AS _MEM
m = _MEM(x)
PRINT m.OFFSET
PRINT ConvertOffset(m.OFFSET)
 
 
FUNCTION ConvertOffset&& (value AS _OFFSET)
$CHECKING:OFF
DIM m AS _MEM 'Define a memblock
m = _MEM(value) 'Point it to use value
$IF 64BIT THEN
    'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
    _MEMGET m, m.OFFSET, ConvertOffset&& 'Get the contents of the memblock and put the values there directly into ConvertOffset&&
$ELSE
    'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
    _MEMGET m, m.OFFSET, temp& 'Like this
    ConvertOffset&& = temp& 'And then assign that long value to ConvertOffset&&
$END IF
_MEMFREE m 'Free the memblock
$CHECKING:ON
END FUNCTION
 
 

See the difference in the offset convertor above, and yours. I imagine there’s your issue (4 vs 8 bytes).

Petr · « **Reply #57 on:** January 04, 2021, 01:53:42 pm »

Thank you, Steve. This solved all. Now all works under all versions.

You can test it with this new effect, named as "When you shoot a turntable"

Code: QB64: [Select]

'program create speed - up track and then play it
INPUT "Insert sound file name:", snd$
DIM Left AS _MEM
DIM Right AS _MEM
DIM NewTrack AS _MEM
DIM S AS INTEGER
DIM SL AS LONG, SR AS LONG
 
snd = _SNDOPEN(snd$)
Left = _MEMSOUND(snd, 1)
Right = _MEMSOUND(snd, 2)
IF Right.SIZE = 0 THEN PRINT "Program need stereo track!": END
NewTrack = _MEMNEW(Left.SIZE * 2)
R = 0
DO UNTIL p& >= Left.SIZE - R
    IF p& MOD 88200 = 0 THEN R = R + 2
    IF p& + R > Left.SIZE THEN EXIT DO
    SL = 0
    SR = 0
    FOR SLUC = 1 TO R
        _MEMGET Left, Left.OFFSET + p& + R, S
        SL = SL + S
        _MEMGET Right, Right.OFFSET + p& + R, S
        SR = SR + S
    NEXT SLUC
 
    SL = SL \ R
    SR = SR \ R
    _MEMPUT NewTrack, NewTrack.OFFSET + i&, SL
    _MEMPUT NewTrack, NewTrack.OFFSET + i& + 2, SR
 
    p& = p& + R
    i& = i& + 4
LOOP
 
SAVESOUND16S NewTrack, "eff2.wav"
_SNDPLAYFILE ("eff2.wav")
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + ConvertOffset&&(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    '  $IF 32BIT THEN
    '      H16.lenght = ConvertOffset&&(arr.SIZE) - 2
    '  $ELSE
    H16.lenght = ConvertOffset&&(arr.SIZE)
    ' $END IF
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(ConvertOffset&&(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 
 
 
FUNCTION ConvertOffset&& (value AS _OFFSET)
    $CHECKING:OFF
    DIM m AS _MEM 'Define a memblock
    m = _MEM(value) 'Point it to use value
    $IF 64BIT THEN
        'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
        _MEMGET m, m.OFFSET, ConvertOffset&& 'Get the contents of the memblock and put the values there directly into ConvertOffset&&
    $ELSE
        'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
        _MEMGET m, m.OFFSET, temp& 'Like this
        ConvertOffset&& = temp& 'And then assign that long value to ConvertOffset&&
    $END IF
    _MEMFREE m 'Free the memblock
    $CHECKING:ON
END FUNCTION
 

a little better version:

Code: QB64: [Select]

'program create speed - up track and then play it
INPUT "Insert sound file name:", snd$
DIM Left AS _MEM
DIM Right AS _MEM
DIM NewTrack AS _MEM
DIM S AS INTEGER
DIM SL AS LONG, SR AS LONG
 
snd = _SNDOPEN(snd$)
Left = _MEMSOUND(snd, 1)
Right = _MEMSOUND(snd, 2)
IF Right.SIZE = 0 THEN PRINT "Program need stereo track!": END
NewTrack = _MEMNEW(Left.SIZE)
R = 0
DO UNTIL p& >= Left.SIZE - R
    IF i& \ 4 MOD 88200 = 0 THEN R = R + 2
    IF p& + R > Left.SIZE THEN EXIT DO
    SL = 0
    SR = 0
    FOR SLUC = 1 TO R
        _MEMGET Left, Left.OFFSET + p& + R, S
        SL = SL + S
        _MEMGET Right, Right.OFFSET + p& + R, S
        SR = SR + S
    NEXT SLUC
 
    SL = SL \ R
    SR = SR \ R
    _MEMPUT NewTrack, NewTrack.OFFSET + i&, SL
    _MEMPUT NewTrack, NewTrack.OFFSET + i& + 2, SR
 
    p& = p& + R
    i& = i& + 4
LOOP
 
'DO UNTIL S = 0
 
 
SAVESOUND16S NewTrack, "eff2.wav"
_SNDPLAYFILE ("eff2.wav")
PRINT i&
 
 
 
 
 
 
 
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + ConvertOffset&&(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    '  $IF 32BIT THEN
    '      H16.lenght = ConvertOffset&&(arr.SIZE) - 2
    '  $ELSE
    H16.lenght = ConvertOffset&&(arr.SIZE)
    ' $END IF
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(ConvertOffset&&(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 
 
 
FUNCTION ConvertOffset&& (value AS _OFFSET)
    $CHECKING:OFF
    DIM m AS _MEM 'Define a memblock
    m = _MEM(value) 'Point it to use value
    $IF 64BIT THEN
        'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
        _MEMGET m, m.OFFSET, ConvertOffset&& 'Get the contents of the memblock and put the values there directly into ConvertOffset&&
    $ELSE
        'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
        _MEMGET m, m.OFFSET, temp& 'Like this
        ConvertOffset&& = temp& 'And then assign that long value to ConvertOffset&&
    $END IF
    _MEMFREE m 'Free the memblock
    $CHECKING:ON
END FUNCTION
 
 
 
 
FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    DIM o AS _INTEGER64, mo AS _MEM
    mo = _MEM(o)
    _MEMPUT mo, mo.OFFSET, OffsetVal
    _MEMFREE mo
    OFFSETasI64&& = o
END FUNCTION
 
 

The reverse effect can be achieved by adding more samples between the existing samples (always the mathematical average of two adjacent samples), thus achieving a deceleration effect.

Petr · « **Reply #58 on:** January 04, 2021, 02:58:21 pm »

But the previous version is too rough. So, here's a way to do it better. The music will gradually speed up. This is done by omitting samples. To make this transition smoother, the transition is always supplemented by one sample to the place where the samples were omitted.
The more samples you insert, the more you slow down the acceleration and smooth the transition.

Code: QB64: [Select]

'speed - up track and then play it
INPUT "Insert sound file name:", snd$
DIM Left AS _MEM
DIM Right AS _MEM
DIM NewTrack AS _MEM
DIM S AS INTEGER
DIM SL AS INTEGER, SR AS INTEGER
 
snd = _SNDOPEN(snd$)
Left = _MEMSOUND(snd, 1)
Right = _MEMSOUND(snd, 2)
IF Right.SIZE = 0 THEN PRINT "Program need stereo track!": END
NewTrack = _MEMNEW(Left.SIZE * 2)
R = 0
DO UNTIL p& >= Left.SIZE
    IF p& MOD 22050 = 0 THEN
        skip& = skip& + 10: p& = p& + skip& 'speed up by 10 samples per half second.  This is linear, but it can be exponencial...
        OSL = SL
        OSR = SR
        IF p& > Left.SIZE - 2 THEN EXIT DO
        _MEMGET Left, Left.OFFSET + p&, SL
        _MEMGET Right, Right.OFFSET + p&, SR
        SL = (OSL + SL) \ 2
        SR = (OSR + SR) \ 2
        _MEMPUT NewTrack, NewTrack.OFFSET + i&, SL
        _MEMPUT NewTrack, NewTrack.OFFSET + i& + 2, SR
        i& = i& + 4
    ELSE p& = p& + 2 'all this values must be dividible by two (integer)
    END IF
    IF p& > Left.SIZE - 2 THEN EXIT DO
    _MEMGET Left, Left.OFFSET + p&, SL
    _MEMGET Right, Right.OFFSET + p&, SR
    _MEMPUT NewTrack, NewTrack.OFFSET + i&, SL
    _MEMPUT NewTrack, NewTrack.OFFSET + i& + 2, SR
    i& = i& + 4
LOOP
 
SAVESOUND16S NewTrack, "eff2.wav"
_SNDPLAYFILE ("eff2.wav")
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + ConvertOffset&&(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = ConvertOffset&&(arr.SIZE)
    IF _FILEEXISTS(file$) THEN KILL file$
    Audio$ = SPACE$(ConvertOffset&&(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
    CLOSE ch
END SUB
 
 
 
FUNCTION ConvertOffset&& (value AS _OFFSET)
    $CHECKING:OFF
    DIM m AS _MEM 'Define a memblock
    m = _MEM(value) 'Point it to use value
    $IF 64BIT THEN
        'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
        _MEMGET m, m.OFFSET, ConvertOffset&& 'Get the contents of the memblock and put the values there directly into ConvertOffset&&
    $ELSE
        'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
        _MEMGET m, m.OFFSET, temp& 'Like this
        ConvertOffset&& = temp& 'And then assign that long value to ConvertOffset&&
    $END IF
    _MEMFREE m 'Free the memblock
    $CHECKING:ON
END FUNCTION
 

Petr · « **Reply #59 on:** January 05, 2021, 01:37:14 pm »

Next example. Sound "ping - pong". Take two different songs (to make the effect stand out more) and have the sound sent from the right speaker to the left, with the second song going opposite. Sound position is changed continuously during playback. It's best to listening it on headphones.

Code: QB64: [Select]

DIM left AS _MEM
DIM Right AS _MEM
DIM AudioL AS INTEGER
DIM AudioR AS INTEGER
DIM L AS INTEGER
DIM R AS INTEGER
DIM NewSound AS _MEM
DIM Size AS _OFFSET
_TITLE "Sound ping - pong"
INPUT "Insert music file name"; snd$
INPUT "Insert music file name2"; snd2$
 
IF _FILEEXISTS(snd$) AND _FILEEXISTS(snd2$) THEN
    snd = _SNDOPEN(snd$)
    PRINT "File 1 opened"
    snd2 = _SNDOPEN(snd2$)
    PRINT "File 2 opened"
 
    left = _MEMSOUND(snd, 1)
    Right = _MEMSOUND(snd2, 1)
    IF Right.SIZE > left.SIZE THEN Size = left.SIZE ELSE Size = Right.SIZE
    PRINT "Size: "; Size
    NewSound = _MEMNEW(Size * 2)
    DO UNTIL s& = Size
        _MEMGET left, left.OFFSET + s&, AudioL
        _MEMGET Right, Right.OFFSET + s&, AudioR
        L = (AudioL * ABS(SIN(sinus)) + AudioR * ABS(COS(sinus2))) / 2
        R = (AudioR * ABS(SIN(sinus2)) + AudioL * ABS(COS(sinus))) / 2
        _MEMPUT NewSound, NewSound.OFFSET + t&, L
        _MEMPUT NewSound, NewSound.OFFSET + t& + 2, R
        sinus = sinus + .00001
        sinus2 = sinus + _PI
        s& = s& + 2
        t& = t& + 4
    LOOP
ELSE
    PRINT "Some file not exists."
    END
END IF
PRINT "Saving WAV"
SAVESOUND16S NewSound, "TestEff3.wav"
PRINT "Playing"
_SNDPLAYFILE "TestEff3.wav"
_SNDCLOSE snd
_SNDCLOSE snd2
_MEMFREE left
_MEMFREE Right
_MEMFREE NewSound
END
 
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + ConvertOffset&&(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = ConvertOffset&&(arr.SIZE)
    ' $END IF
    IF _FILEEXISTS(file$) THEN KILL file$
    Audio$ = SPACE$(ConvertOffset&&(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
    CLOSE ch
END SUB
 
 
 
FUNCTION ConvertOffset&& (value AS _OFFSET)
    $CHECKING:OFF
    DIM m AS _MEM 'Define a memblock
    m = _MEM(value) 'Point it to use value
    $IF 64BIT THEN
        'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
        _MEMGET m, m.OFFSET, ConvertOffset&& 'Get the contents of the memblock and put the values there directly into ConvertOffset&&
    $ELSE
        'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
        _MEMGET m, m.OFFSET, temp& 'Like this
        ConvertOffset&& = temp& 'And then assign that long value to ConvertOffset&&
    $END IF
    _MEMFREE m 'Free the memblock
    $CHECKING:ON
END FUNCTION
 
 

News:

Author Topic: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!) (Read 16422 times)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

SMcNeill

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)