Author Topic: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!) (Read 16411 times)

FellippeHeitor · « **Reply #15 on:** December 31, 2020, 05:42:10 pm »

Not in the works as of yet. Bear in mind we have _SNDRAW for sound generation.

Petr · « **Reply #16 on:** December 31, 2020, 06:03:54 pm »

WORKS AS EXPECTED!

[ You are not allowed to view this attachment ]

HAPPY NEW YEAR! NOW MIDNIGHT HERE!

FellippeHeitor · « **Reply #17 on:** December 31, 2020, 06:04:38 pm »

Happy New Year! Can't wait to see what you'll come up with this ❤️

Petr · « **Reply #18 on:** December 31, 2020, 06:14:28 pm »

I'll start with that in the morning. I will experiment a lot, the end of the restriction is amazing. A wonderful beginning of the new year. I like the way you made a option for shift in the music track in the window at the bottom. Even the pause mark is nice. Now testing, all pass.

FellippeHeitor · « **Reply #19 on:** December 31, 2020, 06:15:05 pm »

I just updated the code in the box above to make the tracker more visible when you move down the mouse.

Petr · « **Reply #20 on:** December 31, 2020, 06:38:56 pm »

Yes, now it's better see now. This music is a bit familiar to me :) Thank you again!

FellippeHeitor · « **Reply #21 on:** December 31, 2020, 06:40:49 pm »

Quote from: Petr on December 31, 2020, 06:38:56 pm

This music is a bit familiar to me :)

😉

Petr · « **Reply #22 on:** January 01, 2021, 06:11:41 am »

It's just an absolutely amazing thing. It's just something perfect. I made such an attempt. Take two different songs and create a one new from them - place the left channel of the first song in the left channel and place the left channel of the second song in the second channel. Previously? It was only possible with the WAV format and required a really large program. Now? It's really very simple! In addition, the program solves what QB64 cannot solve on its own yet, even though it is so easy! You can use the function in this program and you will never have a problem converting an OFFSET type to another numeric type.

Try it. Take two different songs (in order for the resulting mix to be heard well, you need to make sure that both have about the same volume) and go through it with this program. The result is a WAV file with mixed sound.

Of course, what can be done next? Sound effects, blending the left track to the right and vice versa, muting in the recording, inserting speech - and then saving it all. Of course, this is my first experiment of my own and it works great.

Code: QB64: [Select]

'Program create new WAV soundtrack, which mix left channel from audio 1 and right channel from audio 2
INPUT "Insert audio file name nr. 1:"; a1$
INPUT "Insert audio file name nr. 2:"; a2$
a = _SNDOPEN(a1$)
IF a THEN PRINT "Audio file 1 opened" ELSE PRINT "Audio file 1 opening error.": END
b = _SNDOPEN(a2$)
IF b THEN PRINT "Audio file 2 opened" ELSE PRINT "Audio file 2 opening error.": END
LENa = _CEIL(_SNDLEN(a))
LENb = _CEIL(_SNDLEN(b))
 
PRINT "Track 1 (Audio file 1) lenght:"; LENa
PRINT "Track 2 (Audio file 2) lenght:"; LENb
 
IF LENa > LENb THEN NewTrackTime = LENb ELSE NewTrackTime = LENa
PRINT "Mixed audio track lenght: "; NewTrackTime
 
DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Driver AS _OFFSET
Left = _MEMSOUND(a, 1)
Right = _MEMSOUND(b, 2)
IF Right.SIZE = 0 THEN Right = _MEMSOUND(b, 1) 'if track 2 is mono, use left channel from track 2
 
NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
NewSound = _MEMNEW(NewSoundSize&)
 
PRINT "SndRate:"; _SNDRATE
PRINT "Track 1 memory len:"; Left.SIZE
PRINT "Track 2 memory len:"; Right.SIZE
PRINT "New audio memory len:"; NewSound.SIZE
 
IF Left.SIZE < Right.SIZE THEN Driver = Left.SIZE ELSE Driver = Right.SIZE
 
DO UNTIL Create& = Driver
    _MEMGET Left, Left.OFFSET + Create&, Audio
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio
    NewAudio& = NewAudio& + 2 'because record lenght is 2 byte, use INTEGER
    _MEMGET Right, Right.OFFSET + Create&, Audio
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio
    NewAudio& = NewAudio& + 2 'because record lenght is 2 byte, use INTEGER
    Create& = Create& + 2
LOOP
 
PRINT "New sound created. Saving as Tracks-mix.wav..."
SAVESOUND16S NewSound, "Tracks-mix.wav"
PRINT "Playing mixed sound"
_SNDPLAYFILE ("tracks-mix.wav")
END
 
 
FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    DIM o AS _INTEGER64, mo AS _MEM
    mo = _MEM(o)
    _MEMPUT mo, mo.OFFSET, OffsetVal
    _MEMFREE mo
    OFFSETasI64&& = o
END FUNCTION
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = OFFSETasI64(arr.SIZE)
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 

Petr · « **Reply #23 on:** January 01, 2021, 08:15:57 am »

Hi @Fellippe, try listening your songs with echo effect:

Code: QB64: [Select]

'Program create new WAV soundtrack + add echo
 
EchoLenght = 0.25 '0.25 seconds is echo duration
Echo& = _SNDRATE * EchoLenght
 
DO UNTIL Echo& MOD 2 = 0
    Echo& = Echo& + 1
LOOP
 
 
INPUT "Insert audio file name:"; a1$
a = _SNDOPEN(a1$)
IF a THEN PRINT "Audio file 1 opened" ELSE PRINT "Audio file 1 opening error.": END
LENa = _CEIL(_SNDLEN(a)) + EchoLenght
PRINT "Audio file lenght:"; LENa
NewTrackTime = LENa
 
 
 
DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Audio2 AS INTEGER, Audio3 AS INTEGER, Audio4 AS INTEGER
Left = _MEMSOUND(a, 1)
Right = _MEMSOUND(a, 2)
 
NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
NewSound = _MEMNEW(NewSoundSize&)
 
PRINT "SndRate:"; _SNDRATE
PRINT "Track memory len:"; Left.SIZE
 
 
DO UNTIL Create& = Left.SIZE
    _MEMGET Left, Left.OFFSET + Create&, Audio
    _MEMGET Right, Right.OFFSET + Create&, Audio2
 
    IF Create& > Echo& THEN
        _MEMGET Left, Left.OFFSET + Create& - Echo&, Audio3
        Audio = (Audio + Audio3 * .75) \ 2
 
        _MEMGET Right, Right.OFFSET + Create& - Echo&, Audio3
        Audio2 = (Audio2 + Audio3 * .75) \ 2
    END IF
 
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio 'left channel
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio& + 2, Audio2 'right channel
    NewAudio& = NewAudio& + 4
    Create& = Create& + 2
LOOP
 
PRINT "New sound created. Saving as Tracks-mix.wav..."
SAVESOUND16S NewSound, "Tracks-mix.wav"
PRINT "Sound saved, erasing RAM..."
_MEMFREE Left
_MEMFREE Right
_MEMFREE NewSound
 
PRINT "Playing mixed sound"
_SNDPLAYFILE ("tracks-mix.wav")
END
 
 
FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    DIM o AS _INTEGER64, mo AS _MEM
    mo = _MEM(o)
    _MEMPUT mo, mo.OFFSET, OffsetVal
    _MEMFREE mo
    OFFSETasI64&& = o
END FUNCTION
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = OFFSETasI64(arr.SIZE)
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 

Petr · « **Reply #24 on:** January 01, 2021, 09:39:35 am »

This return better echo output:

Code: QB64: [Select]

'Program create new WAV soundtrack + add echo
 
EchoLenght = 0.06 '0.06 seconds is echo duration
OverSampling = 10 'number of echoes sample passes
 
Echo& = _SNDRATE * EchoLenght
 
DO UNTIL Echo& MOD 2 = 0
    Echo& = Echo& + 1
LOOP
 
INPUT "Insert audio file name:"; a1$
a = _SNDOPEN(a1$)
IF a THEN PRINT "Audio file 1 opened" ELSE PRINT "Audio file 1 opening error.": END
LENa = _CEIL(_SNDLEN(a)) + EchoLenght
PRINT "Audio file lenght:"; LENa
NewTrackTime = LENa
 
 
 
DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Audio2 AS INTEGER, Audio3 AS INTEGER, Audio4 AS INTEGER
Left = _MEMSOUND(a, 1)
Right = _MEMSOUND(a, 2)
 
NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
NewSound = _MEMNEW(NewSoundSize&)
 
PRINT "SndRate:"; _SNDRATE
PRINT "Track memory len:"; Left.SIZE
PRINT "Creating audio..."
 
VolDown = 1 / OverSampling
 
DO UNTIL Create& >= Left.SIZE - 2
    _MEMGET Left, Left.OFFSET + Create&, Audio
    _MEMGET Right, Right.OFFSET + Create&, Audio2
 
    IF Create& > Echo& THEN
 
        E& = Create&
        Vol = 1
        DO UNTIL E& <= Create& - OverSampling
            Vol = Vol - VolDown
            _MEMGET Left, Left.OFFSET + Create& - Echo&, Audio3
            _MEMGET Left, Left.OFFSET + Create& - 2, Audio4
            Audio = (Audio + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
            E& = E& - 2
        LOOP
 
        E& = Create&
        Vol = 1
        DO UNTIL E& <= Create& - OverSampling
            Vol = Vol - VolDown
            _MEMGET Right, Right.OFFSET + Create& - Echo&, Audio3
            _MEMGET Right, Right.OFFSET + Create& - 2, Audio4
            Audio2 = (Audio2 + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
            E& = E& - 2
        LOOP
    END IF
 
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio 'left channel
    _MEMPUT NewSound, NewSound.OFFSET + NewAudio& + 2, Audio2 'right channel
    NewAudio& = NewAudio& + 4
    Create& = Create& + 2
LOOP
 
PRINT "New sound created. Saving as Tracks-mix4.wav..."
SAVESOUND16S NewSound, "Tracks-mix4.wav"
PRINT "Sound saved, erasing RAM..."
_MEMFREE Left
_MEMFREE Right
_MEMFREE NewSound
 
PRINT "Playing mixed sound"
_SNDPLAYFILE ("tracks-mix4.wav")
END
 
 
FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    DIM o AS _INTEGER64, mo AS _MEM
    mo = _MEM(o)
    _MEMPUT mo, mo.OFFSET, OffsetVal
    _MEMFREE mo
    OFFSETasI64&& = o
END FUNCTION
 
 
SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
 
    TYPE head16
        chunk AS STRING * 4 '       4 bytes  (RIFF)
        size AS LONG '              4 bytes  (file size)
        fomat AS STRING * 4 '       4 bytes  (WAVE)
        sub1 AS STRING * 4 '        4 bytes  (fmt )
        subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
        format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
        channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
        rate AS LONG '              4 bytes  (sample rate, standard is 44100)
        ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
        Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
        Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
        subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
        lenght AS LONG '            4 bytes  Data block size
    END TYPE '                     44 bytes  total
    DIM H16 AS head16
    ch = FREEFILE
 
    H16.chunk = "RIFF"
    H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
 
    H16.fomat = "WAVE"
    H16.sub1 = "fmt "
    H16.subchunksize = 16
    H16.format = 1
    H16.channels = 2
    H16.rate = 44100
    H16.ByteRate = 44100 * 2 * 16 / 8
    H16.Block = 4
    H16.Bits = 16
    H16.subchunk2 = "data"
    H16.lenght = OFFSETasI64(arr.SIZE)
    IF _FILEEXISTS(file$) THEN KILL file$
 
    Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    _MEMGET arr, arr.OFFSET, Audio$
 
    OPEN file$ FOR BINARY AS #ch
    PUT #ch, , H16
    PUT #ch, , Audio$
    Audio$ = ""
 
    CLOSE ch
END SUB
 

FellippeHeitor · « **Reply #25 on:** January 01, 2021, 09:57:43 am »

Wow! One morning in your hands and we got sound processing! That's awesome, I'll be testing it right now!!

FellippeHeitor · « **Reply #26 on:** January 01, 2021, 10:42:39 am »

Great job, @Petr! On a side note, thanks for FUNCTION OFFSETasI64&& - that's really useful too.

Petr · « **Reply #27 on:** January 01, 2021, 10:56:32 am »

Thank you, Fellippe. There are already many new possibilities. And do you know what's funny? Remember the beginnings of QB64 with graphics? When was the first save format BMP? Now it's just WAV... the resemblance, isn't it wonderful? I'm going to keep experimenting because I really very enjoy it! Really nice function, this _MEMSOUND!

STxAxTIC · « **Reply #28 on:** January 01, 2021, 11:38:32 pm »

Here comes the first QB64 oscilloscope. Here I am "measuring" the frequency of a 500-hz sine wave:

Code: QB64: [Select]

OPTION _EXPLICIT
CONST true = -1, false = 0
 
DIM theSound AS LONG, x0 AS LONG, i AS _OFFSET, j AS _OFFSET
DIM a%, c~&, k&, trackerHeight AS INTEGER
DIM y0 AS LONG, y1 AS LONG
DIM mouseDown AS _BYTE, f$, mouseDownOn AS INTEGER
DIM sleft AS _MEM, sright AS _MEM
DIM stereo AS _BYTE
DIM stereoScreen AS LONG, monoScreen AS LONG
 
DIM BarFrequency AS INTEGER
DIM BarWavelength AS INTEGER
DIM BarPhase AS INTEGER
DIM SomeText AS STRING
BarFrequency = 441
BarPhase = 0
BarWavelength = INT(44100 / BarFrequency)
 
stereoScreen = _NEWIMAGE(882, 400, 32)
monoScreen = _NEWIMAGE(882, 200, 32)
SCREEN monoScreen
 
_TITLE "QB64 Sound Player + Oscilloscope"
 
IF _FILEEXISTS(COMMAND$) THEN
    f$ = COMMAND$
ELSE
    start:
    INPUT "File to load: ", f$
END IF
 
PRINT "Loading '"; f$; "'..."
theSound = _SNDOPEN(f$)
IF theSound = 0 THEN PRINT "Load failed.": END
 
loaded:
sleft = _MEMSOUND(theSound, 1)
sright = _MEMSOUND(theSound, 2)
 
IF sright.SIZE > 0 THEN
    SCREEN stereoScreen
    stereo = true
    y0 = _HEIGHT / 4
    y1 = _HEIGHT - _HEIGHT / 4
ELSE
    SCREEN monoScreen
    y0 = _HEIGHT / 2
END IF
_PRINTMODE _KEEPBACKGROUND
 
trackerHeight = 50
_SNDPLAY theSound
_SNDPAUSE theSound
 
DO
    WHILE _MOUSEINPUT
        IF (_KEYDOWN(100305) OR _KEYDOWN(100306)) THEN
            'BarPhase = BarPhase + SGN(_MOUSEWHEEL)
            BarFrequency = BarFrequency + SGN(_MOUSEWHEEL)
            BarWavelength = INT(44100 / BarFrequency)
        ELSE
            BarFrequency = BarFrequency + 20 * SGN(_MOUSEWHEEL)
            BarWavelength = INT(44100 / BarFrequency)
        END IF
    WEND
 
    IF _MOUSEBUTTON(1) THEN
        IF mouseDown = false THEN
            mouseDown = true
            IF _MOUSEY < _HEIGHT - trackerHeight THEN
                mouseDownOn = 1 'plot area
            ELSE
                mouseDownOn = 2 'track area
            END IF
        ELSE
            IF mouseDownOn = 2 AND _SNDPLAYING(theSound) = 0 THEN
                _SNDSETPOS theSound, map(_MOUSEX, 0, _WIDTH, 0, _SNDLEN(theSound))
            END IF
        END IF
    ELSEIF _MOUSEBUTTON(2) THEN
        IF mouseDown = false THEN
            mouseDown = true
            BarPhase = _MOUSEX
        ELSE
        END IF
    ELSE
        IF mouseDown THEN
            'toggle play
            IF mouseDownOn = 1 THEN
                toggleSoundState theSound
            ELSEIF mouseDownOn = 2 THEN
                _SNDSETPOS theSound, map(_MOUSEX, 0, _WIDTH, 0, _SNDLEN(theSound))
            END IF
            mouseDown = false
            mouseDownOn = 0
        END IF
    END IF
 
    k& = _KEYHIT
    IF k& = 32 THEN toggleSoundState theSound
 
    DIM alpha AS INTEGER
    alpha = 50 'IF _SNDPLAYING(theSound) THEN alpha = 40 ELSE alpha = 20
    LINE (0, 0)-(_WIDTH - 1, _HEIGHT - 1), _RGB32(0, alpha), BF
    GOSUB render
    IF _SNDPLAYING(theSound) = 0 THEN _PRINTSTRING (_WIDTH / 2 - 16, _HEIGHT / 2 - _FONTHEIGHT), CHR$(221) + CHR$(222)
 
    _DISPLAY
    _LIMIT 60
LOOP
 
render:
DIM o AS _OFFSET
o = INT((_SNDGETPOS(theSound)) * _SNDRATE)
WHILE o MOD 2 <> 0: o = o + 1: WEND
i = sleft.OFFSET + o
IF stereo THEN j = sright.OFFSET + o
FOR x0 = 0 TO _WIDTH
    _MEMGET sleft, i, a%
    IF a% < 0 THEN
        c~& = _RGB32(67, 150, 33, map(a%, 0, -32767, 80, 255))
    ELSE
        c~& = _RGB32(67, 150, 33, map(a%, 0, 32767, 80, 255))
    END IF
    LINE (x0, y0)-STEP(0, map(a%, -32768, 32767, -_HEIGHT / 4, _HEIGHT / 4)), c~&, B 'F
 
    IF stereo THEN
        _MEMGET sright, j, a%
        IF a% < 0 THEN
            c~& = _RGB32(67, 150, 33, map(a%, 0, -32767, 80, 255))
        ELSE
            c~& = _RGB32(67, 150, 33, map(a%, 0, 32767, 80, 255))
        END IF
        LINE (x0, y1)-STEP(0, map(a%, -32768, 32767, -_HEIGHT / 4, _HEIGHT / 4)), c~&, B 'F
    END IF
 
    IF (x0 MOD BarWavelength) = 0 THEN
        LINE (x0 + BarPhase, 0)-(x0 + BarPhase, _HEIGHT), _RGB32(0, 100, 100, 100)
    END IF
 
    i = i + 2
    IF stereo THEN j = j + 2
    IF i + 2 >= sleft.OFFSET + sleft.SIZE THEN EXIT FOR
NEXT
 
'tracker:
LINE (0, _HEIGHT - trackerHeight / 3)-STEP(map(_SNDGETPOS(theSound), 0, _SNDLEN(theSound), 0, _WIDTH), -trackerHeight / 3), _RGB32(255, 180), BF
IF _MOUSEY > _HEIGHT - trackerHeight THEN
    LINE (0, _HEIGHT - trackerHeight)-STEP(_WIDTH, trackerHeight), _RGB32(255, 30), BF
END IF
 
COLOR _RGB32(200, 200, 200, 255)
LOCATE 1, 1: PRINT "Measured frequency:"; BarFrequency
SomeText = "       MWheel = Coarse Freq.": LOCATE 1, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
SomeText = "CTRL + MWheel = Fine Freq.  ": LOCATE 2, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
SomeText = "  Right-Click = Phase       ": LOCATE 3, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
RETURN
 
FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
    map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
END FUNCTION
 
SUB toggleSoundState (theSound AS LONG)
    IF _SNDPLAYING(theSound) THEN
        _SNDPAUSE theSound
    ELSE
        DIM i AS INTEGER
        FOR i = -20 TO 20
            LINE (_WIDTH / 2 + 20, _HEIGHT / 2 - 5)-STEP(-40, i)
        NEXT
        _SNDLOOP theSound
    END IF
END SUB
 

Petr · « **Reply #29 on:** January 02, 2021, 04:48:28 am »

Hi @STxAxTIC I have a question about this. Let's say I want to measure the frequency of sound.

My theory is this: Suppose I choose the number of samples 441 to analyze. I count the number of zero crossings (or just decreasing and increasing in amplitude?) In these 441 samples. Because the sampling frequency for 1 second is 44100, this is a time interval of 100 milliseconds (in 441 samples). For example, if I count 12 changes in the amplitude direction, the resulting frequency is f = 12 / 0.01 = 1200 Hz. I will perform another frequency analysis on samples 442 - 883. Is it correct?

[ You are not allowed to view this attachment ]

News:

Author Topic: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!) (Read 16411 times)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

FellippeHeitor

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

STxAxTIC

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

Petr

Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)