« previous next »
Pages: 1 2 [3] 4 5 6   Go Down

Author Topic: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)  (Read 16407 times)

0 Members and 1 Guest are viewing this topic.

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
« Reply #30 on: January 02, 2021, 07:31:22 am »
  • Best Answer
    • Reply which find, must be in inversion to this program, i wrote:

    Code: QB64: [Select]
    1. SOUND 300, 18 '18 is 1 second of time
    3. SOUND2 300, 18
    4.  
    5. SUB SOUND2 (frequency AS INTEGER, Nlenght AS SINGLE)
    6.     lenght = Nlenght * 1 / 18
    7.     samples = _SNDRATE * lenght
    8.     s = _PI / (_SNDRATE / frequency) * 2
    9.  
    10.     DO UNTIL plsam >= samples
    11.         _SNDRAW SIN(u), COS(u)
    12.         u = u + s
    13.         IF ABS(s) = _SNDRATE / frequency THEN s = s * -1
    14.         plsam = plsam + 1
    15.     LOOP
    17.  
    « Last Edit: January 02, 2021, 07:32:37 am by Petr »
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #31 on: January 02, 2021, 07:58:02 am »
  • Best Answer
    • Damn, it's different. The frequency is determined by the zero crossing density - not how many times the wave passes through zero, but how far apart in time. The amplitude height determines the volume. I think. I have to verify this theory. Either it will be the density of the zero crossing, or the density of the change in the direction of the amplitude (how far apart the individual peaks are).
    Logged

    Offline STxAxTIC

    • Library Staff
    • Forum Resident
    • Posts: 1091
    • he lives
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #32 on: January 02, 2021, 12:16:57 pm »
  • Best Answer
    • Good morning Petr,

    An excellent question. It took me a few minutes to figure out how to get this working, but now I couldn't be happier. Hopefully this answers all of your questions...

    Starting with what's given by Fellippe, we have a "sample rate" of 44100 samples per second. That is: every 1/44100 seconds, we are handed the instantaneous volume of the sound being played. By plotting the sound data horizontally, there is precisely one "piece of data" per pixel. This means that the so-called "speed of sound" is exactly 44100 pixels per second in this scheme.

    Let me label the speed of sound on screen as C = 44100 pixels/sec.

    Now for some terms. Suppose we are handed a very simple sine curve. No weird squiggles, no squares or sawtooth waves yet, just a sine.

    The "period" ( T ) of the wave is the TIME taken, like in seconds, for the entire wave to repeat itself.
    The "frequency" ( F ) of the wave, is one divided by the period. This is why we measure frequency in Hz, which are just inverse seconds.
    The "wavelength" ( L ) of the wave, is the peak-to-peak span, measured in pixels.

    Now the cool part: What ties the variables all together, is the following wave equation:

    C = L * F

    So that means we can measure L and calculate F.

    Here is a full-blown example measurement of a 200-hz sine wave:

     [ You are not allowed to view this attachment ]  


    Alright, so what about more complicated patterns?

    Well, any complicated wave is actually the sum of simple waves, and each of those simple waves obeys the equation above. However, it's a little harder to discern what's happening by just looking at the sum of two of more waves. For an example, I chose to overlay a 400hz sine wave onto a 500hz sine wave, both having equal volumes. This gives rise to a "binaural beat" which you can actually hear at not 500hz or 400hz, but the difference of the two, aka. 100hz. I have measured the 100hz beat frequency in the image below.

     [ You are not allowed to view this attachment ]  


    In conclusion: frequency can only be reliably understood using the construction(s) above. It's misguiding to try counting it from the number of times the graph crosses the the x-axis, or anything like that. It will only turn out correct by accident, and only for pure sine curves.

    tldr:
    (i) know what the speed of sound on screen is
    (ii) measure the wavelength of the thing you're measuring
    (iii) let the equation tell you the frequency



    « Last Edit: January 02, 2021, 12:25:03 pm by STxAxTIC »
    Logged
    You're not done when it works, you're done when it's right.

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #33 on: January 02, 2021, 03:30:30 pm »
  • Best Answer
    • Thanks for reply, STxAxTIC.

    You don't even know (actually, you know, but I didn't know) how big you're right. Carve your words in stone. If I do it the way I intended, my bass frequency - the deep tones will completely overlap the tones of the higher frequencies. So the question is, but don't even bother to explain it to me, he's already tried it _Vince - but it came across my stupidity - how the hell to filter out the individual frequencies from each other. Each of the frequencies can start anywhere in time ... yeah, I know and some Furrier transforms, but as I wrote, I'm too stupid for that.

    So here I add a program - a demonstration of how not to do it. How my bad program works:

    You are somewhere in the audio position during playback, you get the position as INT (_SNGETPOS * _SNDRATE). From this point you go back in the _MEM field to the sample, which has the opposite polarity than the sample in the place where you started. You count the number of samples from your starting point. Then you do the same thing in opposite - again from the place in the field where the same starting position is, you go to the sample, which has the opposite polarity. During this, you also add the volumes (sizes) of these samples.
    When you encounter a sample with the opposite polarity, you calculate the total volume of that sample as the sum of the volumes / number of all samples.
    The numbers of samples are added (this will give you the duration of this sample - by calculating 1 / _SNDRATE * number of these samples)
    Finally, a modified formula is used to calculate the frequency, because the described process actually detects only one half-period of the frequency.

    Now I will deviate from frequency detection again and do something else again. :)

    Code: QB64: [Select]
    1. 'Example how it not works and how not writing this...
    2.  
    4. INPUT "Insert sound file name:"; s$
    5. PRINT "Opening file..."
    6.  
    7. s = _SNDOPEN(s$)
    8. IF s = 0 THEN PRINT "Invalid sound file.": END
    9. DIM left AS _MEM, right AS _MEM, SampleL AS _UNSIGNED INTEGER, SampleR AS _UNSIGNED INTEGER
    10. DIM VolL AS SINGLE, VolR AS SINGLE, BytePos AS LONG
    11. left = _MEMSOUND(s, 1)
    12. right = _MEMSOUND(s, 2)
    13.  
    14. SCREEN _NEWIMAGE(800, 600, 32)
    15. DIM LeftBox(7) AS INTEGER
    16. DIM RightBox(7) AS INTEGER
    17. DIM LeftVol(7) AS SINGLE
    18. DIM RightVol(7) AS SINGLE
    19. LeftVol(0) = 0
    20.  
    21. FOR an = 20 TO 244 STEP 32
    22.     LeftBox(i) = an + 1
    23.     LINE (an, 300)-(an + 29, 550), , B
    24.     RightBox(i) = an + 497
    25.     LINE (an + 496, 300)-(an + 525, 550), , B
    26.     i = i + 1
    29. i = 0
    32.     IF _SNDGETPOS(s) > .2 THEN
    33.         BytePos = INT(_SNDGETPOS(s) * _SNDRATE)
    34.         _MEMGET left, left.OFFSET + BytePos, SampleL
    35.         L = SGN(SampleL)
    36.         _MEMGET right, right.OFFSET + BytePos, SampleR
    37.         R = SGN(SampleR)
    38.  
    39.         i = 0
    40.         DO UNTIL SGN(SampleL) <> L
    41.             i = i - 2
    42.             IF i < left.OFFSET THEN EXIT DO
    43.             _MEMGET left, left.OFFSET + BytePos + i, SampleL
    44.             LeftVol = LeftVol + SampleL
    45.         LOOP
    46.         j = 0
    47.         _MEMGET left, left.OFFSET + BytePos, SampleL
    48.  
    49.         DO UNTIL SGN(SampleL) <> L
    50.             j = j + 2
    51.             IF j > left.SIZE THEN EXIT DO
    52.             _MEMGET left, left.OFFSET + BytePos + j, SampleL
    53.             LeftVol = LeftVol + SampleL
    54.         LOOP
    55.         DeltaL = ABS(i / 2) + j / 2
    56.  
    57.         i = 0
    58.         DO UNTIL SGN(SampleR) <> R
    59.             i = i - 2
    60.             IF i < right.OFFSET THEN EXIT DO
    61.             _MEMGET right, right.OFFSET + BytePos + i, SampleR
    62.             RightVol = RightVol + SampleR
    63.         LOOP
    64.         j = 0
    65.         _MEMGET right, right.OFFSET + BytePos, SampleR
    66.         DO UNTIL SGN(SampleR) <> R
    67.             IF j > right.SIZE THEN EXIT DO
    68.             j = j + 2
    69.             _MEMGET right, right.OFFSET + BytePos + j, SampleR
    70.             RightVol = RightVol + SampleR
    71.         LOOP
    72.         DeltaR = ABS(i / 2) + j / 2
    73.     END IF
    74.  
    75.  
    76.     FrequencyL = 1 / 44100 * DeltaL ' Time - amplitude duration between 2 samples - Left channel
    77.     FrequencyR = 1 / 44100 * DeltaR ' Time - amplitude duration between 2 samples - Right channel
    78.  
    79.     FL = FrequencyL * _SNDRATE / 2 / _PI(2) 'Frequency Left
    80.     FR = FrequencyR * _SNDRATE / 2 / _PI(2) 'Frequency Right
    81.  
    82.  
    83.     IF LeftVol THEN VolL = LeftVol / DeltaL / 32767: LeftVol = 0 ' This, current amplitude size (volume level) - Left
    84.     IF RightVol THEN VolR = RightVol / DeltaR / 32767: RightVol = 0 '                                             Right
    85.     '   PRINT FL; VolL; FR; VolR, FrequencyL; FrequencyR
    86.  
    87.     SELECT CASE FL
    88.         CASE 0 TO 150: BoxL = 0
    89.         CASE 151 TO 350: BoxL = 1
    90.         CASE 300 TO 500: BoxL = 2
    91.         CASE 501 TO 1000: BoxL = 3
    92.         CASE 1001 TO 2200: BoxL = 4
    93.         CASE 2201 TO 5000: BoxL = 5
    94.         CASE 5001 TO 6000: BoxL = 6
    95.         CASE IS > 6001: BoxL = 7
    96.  
    97.  
    98.     END SELECT
    99.  
    100.     SELECT CASE FR
    101.         CASE 0 TO 150: BoxR = 0
    102.         CASE 151 TO 350: BoxR = 1
    103.         CASE 300 TO 500: BoxR = 2
    104.         CASE 501 TO 1000: BoxR = 3
    105.         CASE 1001 TO 2200: BoxR = 4
    106.         CASE 2201 TO 5000: BoxR = 5
    107.         CASE 5001 TO 6000: BoxR = 6
    108.         CASE IS > 6001: BoxR = 7
    109.  
    110.     END SELECT
    111.  
    112.     PCOPY 1, _DISPLAY
    113.     LeftVol(BoxL) = LeftVol(BoxL) + VolL
    114.     IF LeftVol(BoxL) > 1 THEN LeftVol(BoxL) = 1
    115.  
    116.     RightVol(BoxR) = RightVol(BoxR) + VolR
    117.     IF RightVol(BoxR) > 1 THEN RightVol(BoxR) = 1
    118.  
    119.     FOR d = 0 TO 7
    120.         LINE (LeftBox(d), 549)-(LeftBox(d) + 27, 550 - (149 * LeftVol(d))), Red, BF
    121.         IF RightVol(d) <= 1 THEN LINE (RightBox(d), 549)-(RightBox(d) + 27, 550 - (149 * RightVol(d))), Red, BF
    122.         LeftVol(d) = LeftVol(d) - .003
    123.         IF LeftVol(d) < 0 THEN LeftVol(d) = 0
    124.         RightVol(d) = RightVol(d) - .003
    125.         IF RightVol(d) < 0 THEN RightVol(d) = 0
    126.     NEXT d
    127.     _DISPLAY
    129.  
    « Last Edit: January 02, 2021, 04:09:47 pm by Petr »
    Logged

    Offline STxAxTIC

    • Library Staff
    • Forum Resident
    • Posts: 1091
    • he lives
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #34 on: January 02, 2021, 05:51:36 pm »
  • Best Answer
    • Hello again Petr,

    I was successful in implementing a very crude, non-optimized, but correct discrete Fourier transform. It's very crude for now, as expected - but rather than deliver a highly polished result, I thought I would share the early stage of the whole thing working. Below are are few screenshots. The "measured" frequencies are plotted in red. For pure tones, we should expect to see only one bar at a time, which is indeed evident. For the last picture, I used the 400hz + 500hz binaural beat, which predicts TWO red bars. Luckily, they show up! So, the whole thing now works - it just needs optimization to look nice.

    Code: QB64: [Select]
    2. CONST true = -1, false = 0
    3.  
    5. pi = 4 * ATN(1)
    6.  
    7. DIM theSound AS LONG, x0 AS LONG, i AS _OFFSET, j AS _OFFSET
    8. DIM a%, c~&, k&, trackerHeight AS INTEGER
    9. DIM y0 AS LONG, y1 AS LONG
    10. DIM mouseDown AS _BYTE, f$, mouseDownOn AS INTEGER
    11. DIM sleft AS _MEM, sright AS _MEM
    12. DIM stereo AS _BYTE
    13. DIM stereoScreen AS LONG, monoScreen AS LONG
    14.  
    15. '''
    16. DIM BarFrequency AS INTEGER
    17. DIM BarWavelength AS INTEGER
    18. DIM BarPhase AS INTEGER
    19. DIM SomeText AS STRING
    20. BarFrequency = 441
    21. BarPhase = 0
    22. BarWavelength = INT(44100 / BarFrequency)
    23.  
    24.  
    25. stereoScreen = _NEWIMAGE(882, 400, 32)
    26. monoScreen = _NEWIMAGE(882, 200, 32)
    27. SCREEN monoScreen
    28.  
    29. '''
    30. DIM SHARED Amplitudes(_WIDTH) AS DOUBLE
    31. DIM SHARED Frequencies(_WIDTH) AS DOUBLE
    32. '''
    33.  
    34.  
    35. _TITLE "QB64 Sound Player + Analyzer"
    36.  
    38.     f$ = COMMAND$
    40.     start:
    41.     INPUT "File to load: ", f$
    43.  
    44. PRINT "Loading '"; f$; "'..."
    45. theSound = _SNDOPEN(f$)
    46. IF theSound = 0 THEN PRINT "Load failed.": END
    47.  
    48. loaded:
    49. sleft = _MEMSOUND(theSound, 1)
    50. sright = _MEMSOUND(theSound, 2)
    51.  
    52. IF sright.SIZE > 0 THEN
    53.     SCREEN stereoScreen
    54.     stereo = true
    55.     y0 = _HEIGHT / 4
    56.     y1 = _HEIGHT - _HEIGHT / 4
    58.     SCREEN monoScreen
    59.     y0 = _HEIGHT / 2
    62.  
    63. trackerHeight = 50
    64. _SNDPLAY theSound
    65. _SNDPAUSE theSound
    66.  
    69.         IF (_KEYDOWN(100305) OR _KEYDOWN(100306)) THEN
    70.             'BarPhase = BarPhase + SGN(_MOUSEWHEEL)
    71.             BarFrequency = BarFrequency + SGN(_MOUSEWHEEL)
    72.             BarWavelength = INT(44100 / BarFrequency)
    73.         ELSE
    74.             BarFrequency = BarFrequency + 20 * SGN(_MOUSEWHEEL)
    75.             BarWavelength = INT(44100 / BarFrequency)
    76.         END IF
    77.     WEND
    78.  
    80.         IF mouseDown = false THEN
    81.             mouseDown = true
    82.             IF _MOUSEY < _HEIGHT - trackerHeight THEN
    83.                 mouseDownOn = 1 'plot area
    84.             ELSE
    85.                 mouseDownOn = 2 'track area
    86.             END IF
    87.         ELSE
    88.             IF mouseDownOn = 2 AND _SNDPLAYING(theSound) = 0 THEN
    89.                 _SNDSETPOS theSound, map(_MOUSEX, 0, _WIDTH, 0, _SNDLEN(theSound))
    90.             END IF
    91.         END IF
    93.         IF mouseDown = false THEN
    94.             mouseDown = true
    95.             BarPhase = _MOUSEX
    96.         END IF
    97.     ELSE
    98.         IF mouseDown THEN
    99.             'toggle play
    100.             IF mouseDownOn = 1 THEN
    101.                 toggleSoundState theSound
    102.             ELSEIF mouseDownOn = 2 THEN
    103.                 _SNDSETPOS theSound, map(_MOUSEX, 0, _WIDTH, 0, _SNDLEN(theSound))
    104.             END IF
    105.             mouseDown = false
    106.             mouseDownOn = 0
    107.         END IF
    108.     END IF
    109.  
    110.     k& = _KEYHIT
    111.     IF k& = 32 THEN toggleSoundState theSound
    112.  
    113.     DIM alpha AS INTEGER
    114.     alpha = 50 'IF _SNDPLAYING(theSound) THEN alpha = 40 ELSE alpha = 20
    115.     LINE (0, 0)-(_WIDTH - 1, _HEIGHT - 1), _RGB32(0, alpha), BF
    116.     GOSUB render
    117.     IF _SNDPLAYING(theSound) = 0 THEN _PRINTSTRING (_WIDTH / 2 - 16, _HEIGHT / 2 - _FONTHEIGHT), CHR$(221) + CHR$(222)
    118.  
    119.     _DISPLAY
    120.     _LIMIT 60
    122.  
    123. render:
    124.  
    126. o = INT((_SNDGETPOS(theSound)) * _SNDRATE)
    127. WHILE o MOD 2 <> 0: o = o + 1: WEND
    128. i = sleft.OFFSET + o
    129. IF stereo THEN j = sright.OFFSET + o
    130. FOR x0 = 0 TO _WIDTH - 1
    131.     _MEMGET sleft, i, a%
    132.     IF a% < 0 THEN
    133.         c~& = _RGB32(67, 150, 33, map(a%, 0, -32767, 80, 255))
    134.     ELSE
    135.         c~& = _RGB32(67, 150, 33, map(a%, 0, 32767, 80, 255))
    136.     END IF
    137.     LINE (x0, y0)-STEP(0, map(a%, -32768, 32767, -_HEIGHT / 4, _HEIGHT / 4)), c~&, B 'F
    138.  
    139.     '''
    140.     Amplitudes(x0 + 1) = 100 * a% / 32767
    141.     '''
    142.  
    143.     IF stereo THEN
    144.         _MEMGET sright, j, a%
    145.         IF a% < 0 THEN
    146.             c~& = _RGB32(67, 150, 33, map(a%, 0, -32767, 80, 255))
    147.         ELSE
    148.             c~& = _RGB32(67, 150, 33, map(a%, 0, 32767, 80, 255))
    149.         END IF
    150.         LINE (x0, y1)-STEP(0, map(a%, -32768, 32767, -_HEIGHT / 4, _HEIGHT / 4)), c~&, B 'F
    151.     END IF
    152.  
    153.     IF (x0 MOD BarWavelength) = 0 THEN
    154.         LINE (x0 + BarPhase, 0)-(x0 + BarPhase, _HEIGHT), _RGB32(0, 100, 100, 100)
    155.     END IF
    156.  
    157.     i = i + 2
    158.     IF stereo THEN j = j + 2
    159.     IF i + 2 >= sleft.OFFSET + sleft.SIZE THEN EXIT FOR
    161.  
    162. '''
    165. FOR ii = 0 TO _WIDTH - 1
    166.     Frequencies(ii + 1) = 0
    167.     FOR jj = 0 TO _WIDTH - 1
    168.         Frequencies(ii + 1) = Frequencies(ii + 1) + Amplitudes(jj + 1) * COS(2 * pi * (ii + 1) * (jj + 1) / _WIDTH)
    169.     NEXT
    171. FOR ii = 0 TO _WIDTH / 2 - 1
    172.     LINE (2 * ii, _HEIGHT)-(2 * ii, _HEIGHT - ABS(Frequencies(ii))), _RGB32(200, 0, 0, 100)
    174. '''
    175.  
    176. 'tracker:
    177. LINE (0, _HEIGHT - trackerHeight / 3)-STEP(map(_SNDGETPOS(theSound), 0, _SNDLEN(theSound), 0, _WIDTH), -trackerHeight / 3), _RGB32(255, 180), BF
    178. IF _MOUSEY > _HEIGHT - trackerHeight THEN
    179.     LINE (0, _HEIGHT - trackerHeight)-STEP(_WIDTH, trackerHeight), _RGB32(255, 30), BF
    181.  
    182. COLOR _RGB32(200, 200, 200, 255)
    183. LOCATE 1, 1: PRINT "Measured frequency:"; BarFrequency; "Hz"
    184. SomeText = "       MWheel = Coarse Freq.": LOCATE 1, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
    185. SomeText = "CTRL + MWheel = Fine Freq.  ": LOCATE 2, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
    186. SomeText = "  Right-Click = Phase       ": LOCATE 3, _WIDTH / 8 - LEN(SomeText): PRINT SomeText
    188.  
    189. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
    190.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
    192.  
    193. SUB toggleSoundState (theSound AS LONG)
    194.     IF _SNDPLAYING(theSound) THEN
    195.         _SNDPAUSE theSound
    196.     ELSE
    197.         DIM i AS INTEGER
    198.         FOR i = -20 TO 20
    199.             LINE (_WIDTH / 2 + 20, _HEIGHT / 2 - 5)-STEP(-40, i)
    200.         NEXT
    201.         _SNDLOOP theSound
    202.     END IF
    204.  
    205.  
    206.  

      [ You are not allowed to view this attachment ]  
      [ You are not allowed to view this attachment ]  
      [ You are not allowed to view this attachment ]  
      [ You are not allowed to view this attachment ]  

    « Last Edit: January 02, 2021, 06:48:17 pm by STxAxTIC »
    Logged
    You're not done when it works, you're done when it's right.

    Offline Craz1000

    • Forum Regular
    • Posts: 111
    • I'm OK
      • View Profile
      • Craz1000.net
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #35 on: January 02, 2021, 09:39:47 pm »
  • Best Answer
    • I have a game project that has been on hold for over 2 years because I needed a way to get an oscilloscope working. Yes!
    « Last Edit: January 02, 2021, 09:41:30 pm by Craz1000 »
    Logged

    Offline Dav

    • Forum Resident
    • Posts: 792
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #36 on: January 02, 2021, 10:34:19 pm »
  • Best Answer
    • This all sounds very interesting!   Could something like this be used to analyze a played pitch and see if it's in tune?  Like frequency 440 Hz is the note A.    I tune pianos on the side, wonder if it would be possible to make a piano tuning app in QB64?

    - Dav 
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #37 on: January 03, 2021, 03:57:14 am »
  • Best Answer
    • Hi everyone.

    @STxAxTIC: I had to leave the forum yesterday, it was half past one in the morning when I finished and I don't think much of it at that time.
    Thanks for the new example, I'll take a look right away.

    @Dav : I think this option is already here, but you have to use the 32-bit version of the IDE in version 0.954 and the SFML library. I have verified that in this version it is really possible to use a microphone with the SFML library with the QB64. Of course, is there a possibility (and I haven't looked so far) that maybe @SpriggsySpriggs has developed a library that allows it in newer versions?

    Before adding post to this thread by @STxAxTIC, I wrote a simple - and sometimes I think practical - thing - when someone does a music editor, so here's a simple example of how to mute the sound at the end of an audio track. Of course, this can be done anywhere with a easy modification.

    Code: QB64: [Select]
    1. INPUT "Insert music file name:"; m$
    2. INPUT "How long retreat at the end of the track do you want to create? [sec]"; delay
    3.  
    5.     PRINT "Opening file..."
    6.     music = _SNDOPEN(m$)
    7.     DIM left AS _MEM
    8.     DIM right AS _MEM
    9.     DIM NewSound AS _MEM
    10.     DIM position AS _OFFSET, D AS DOUBLE
    11.     DIM Size AS _OFFSET, DT AS _OFFSET, audio AS INTEGER
    12.  
    13.     left = _MEMSOUND(music, 1)
    14.     right = _MEMSOUND(music, 2)
    15.  
    16.     position = left.SIZE - _SNDRATE * delay * 2 'INTEGER, so * 2
    17.     downturn = 1 / (_SNDRATE * delay)
    18.  
    19.     IF right.SIZE > 0 THEN Size = left.SIZE * 2 ELSE Size = left.SIZE
    20.     NewSound = _MEMNEW(Size)
    21.  
    22.     'create downturn on both tracks...
    23.     PRINT "Building downturn..."
    24.  
    25.     DT = left.SIZE - 2
    26.  
    27.     DO UNTIL DT <= position
    28.         _MEMGET left, left.OFFSET + DT, audio
    29.         audio = audio * D
    30.         _MEMPUT left, left.OFFSET + DT, audio
    31.         IF right.SIZE > 0 THEN
    32.             _MEMGET right, right.OFFSET + DT, audio
    33.             audio = audio * D
    34.             _MEMPUT right, right.OFFSET + DT, audio
    35.         END IF
    36.         D = D + downturn
    37.         DT = DT - 2
    38.     LOOP
    39.     PRINT "Creating new track..."
    40.     'create one stereo track
    41.     DT = 0
    42.     i = 0
    43.     DO UNTIL i = left.SIZE
    44.         _MEMGET left, left.OFFSET + i, audio
    45.         _MEMPUT NewSound, NewSound.OFFSET + DT, audio
    46.         IF right.SIZE > 0 THEN
    47.             DT = DT + 2
    48.             _MEMGET right, right.OFFSET + i, audio
    49.             _MEMPUT NewSound, NewSound.OFFSET + DT, audio
    50.         END IF
    51.         DT = DT + 2
    52.         i = i + 2
    53.     LOOP
    54.  
    55.     'save work
    56.     f$ = "downturn_test.wav"
    57.     SAVESOUND16S NewSound, f$
    58.     PRINT "New audio file saved as "; f$
    59.     PRINT "Skipping 5 seconds before applyed downturn and playing..."
    60.     _SNDCLOSE music
    61.     music = _SNDOPEN(f$)
    62.     _SNDSETPOS music, _SNDLEN(music) - delay - 5
    63.     _SNDPLAY music
    65.     PRINT "File "; m$; "not exist."
    66.     END
    68.  
    69. DO UNTIL _SNDPLAYING(music) = 0
    71. PRINT "Done"
    72. _SNDCLOSE music
    74. _MEMFREE right
    75. _MEMFREE NewSound
    77.  
    78.  
    79. FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    80.     DIM o AS _INTEGER64, mo AS _MEM
    81.     mo = _MEM(o)
    82.     _MEMPUT mo, mo.OFFSET, OffsetVal
    83.     _MEMFREE mo
    84.     OFFSETasI64&& = o
    86.  
    87.  
    88. SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
    89.  
    90.     TYPE head16
    91.         chunk AS STRING * 4 '       4 bytes  (RIFF)
    92.         size AS LONG '              4 bytes  (file size)
    93.         fomat AS STRING * 4 '       4 bytes  (WAVE)
    94.         sub1 AS STRING * 4 '        4 bytes  (fmt )
    95.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
    96.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
    97.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
    98.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
    99.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
    100.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
    101.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
    102.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
    103.         lenght AS LONG '            4 bytes  Data block size
    104.     END TYPE '                     44 bytes  total
    105.     DIM H16 AS head16
    106.     ch = FREEFILE
    107.  
    108.     H16.chunk = "RIFF"
    109.     H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
    110.  
    111.     H16.fomat = "WAVE"
    112.     H16.sub1 = "fmt "
    113.     H16.subchunksize = 16
    114.     H16.format = 1
    115.     H16.channels = 2
    116.     H16.rate = 44100
    117.     H16.ByteRate = 44100 * 2 * 16 / 8
    118.     H16.Block = 4
    119.     H16.Bits = 16
    120.     H16.subchunk2 = "data"
    121.     H16.lenght = OFFSETasI64(arr.SIZE)
    122.     IF _FILEEXISTS(file$) THEN KILL file$
    123.  
    124.     Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    125.     _MEMGET arr, arr.OFFSET, Audio$
    126.  
    127.     OPEN file$ FOR BINARY AS #ch
    128.     PUT #ch, , H16
    129.     PUT #ch, , Audio$
    130.     Audio$ = ""
    131.  
    132.     CLOSE ch
    134.  
    135.  
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #38 on: January 03, 2021, 06:11:35 am »
  • Best Answer
    • @STxAxTIC  Thank you again for your example. Extra thanks for ''' separators, its very useful for me for better orientation in source code.

    I have a few questions. In the source code, line 140. Why is the Amplitudes (x0 + 1) = 100 * a% / 32767 sample a% multiplied by one hundred? I have found that this affects the height of the amplitude. Is it an increase in sensitivity because the Amplitudes field is of type DOUBLE?

    On line 168, do I understand that correctly? Do you calculate the frequency for each amplitude on the screen? Definitely yes, well yeah!

    Oh yeah! And because in line 140 you calculate the amplitude depending on the width of the screen, the width of the screen is used everywhere for the calculation. So if I determine from how many samples in the _MEM field I want to count, I will do the same, but I will use the number of samples instead of the screen width.

    This rendering on line 171 - 173 is  always draw by one column, that's probably just for graphic effect, right?

    The BarFrequency, BarWaveLenght are not used for calculation, they are just for visualization, as It look.
    « Last Edit: January 03, 2021, 06:15:51 am by Petr »
    Logged

    FellippeHeitor

    • Guest
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #39 on: January 03, 2021, 08:18:00 pm »
  • Best Answer
    • _MEMSOUND has now made it to the development build, and there have been a few fixes since the alpha testing you guys started. @Petr make sure you get the latest update (_SNDCLOSE has been fixed, also reading the new .SOUND element of the _MEM udt has been fixed).

    Anyone willing to test the cool samples above in this thread can now get the development build from https://www.qb64.org/portal/development-build/ and just compile them - keep us updated if all goes as expected.
    « Last Edit: January 03, 2021, 08:19:32 pm by FellippeHeitor »
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #40 on: January 04, 2021, 10:09:06 am »
  • Best Answer
    • @FellippeHeitor   Hi, I came home from work a while ago, I'll get to it right away!
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #41 on: January 04, 2021, 10:33:21 am »
  • Best Answer
    • First test and problem occur: Downloaded version is 32 bit, 488c4a1. Try this source code in attachment. In previous version, in which i test it, it do new audio track and then play it. BUT NOW, in this version it do new audio track as expected, return valid handle for sound (it open created wav audio file and handle for it is 2) but nothing is playing. If i try play this file with windows media player, it plays correctly. Because valid handle is returned, i try _SNDLEN, if track time is writed correctly and - it is. But play not.

    eee :) source code...

    Code: QB64: [Select]
    1. 'Program create new WAV soundtrack + add echo
    2.  
    3. EchoLenght = 0.12 '0.06 seconds is echo duration
    4. OverSampling = 10 'number of echoes sample passes
    5.  
    6. Echo& = _SNDRATE * EchoLenght
    7.  
    8. DO UNTIL Echo& MOD 2 = 0
    9.     Echo& = Echo& + 1
    11. DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Audio2 AS INTEGER, Audio3 AS INTEGER, Audio4 AS INTEGER
    12. REDIM PlayableFiles(0) AS STRING
    13.  
    14.  
    15. 'INPUT "Insert audio file name:"; a1$
    16.  
    18.     FUNCTION load_dir& (s AS STRING)
    19.     FUNCTION has_next_entry& ()
    20.     SUB close_dir ()
    21.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
    23.  
    24. REDIM Dir(0) AS STRING, File(0) AS STRING
    25. GetFileList _CWD$, Dir(), File()
    26.  
    27.  
    28. FOR s = LBOUND(file) TO UBOUND(file)
    29.     SELECT CASE UCASE$(RIGHT$(File(s), 3))
    30.         CASE "MP3", "OGG", "WAV"
    31.             PlayableFiles(i) = File(s)
    32.             i = i + 1
    33.             REDIM _PRESERVE PlayableFiles(i) AS STRING
    34.     END SELECT
    36.  
    37. PRINT "Files to play: "; i - 1
    38.  
    39.  
    40. FOR playit = 0 TO i - 1
    41.     a1$ = PlayableFiles(playit)
    42.     PRINT "Opening file "; playit + 1; "/"; i - 1; " - "; PlayableFiles(playit)
    43.     IF a THEN _SNDCLOSE a
    44.     a = _SNDOPEN(a1$)
    45.     IF a THEN PRINT "Audio file opened" ELSE PRINT "Audio file 1 opening error.": END
    46.     LENa = _CEIL(_SNDLEN(a)) + EchoLenght
    47.     PRINT "Audio file lenght:"; LENa
    48.     NewTrackTime = LENa
    49.  
    50.  
    51.  
    52.  
    53.     Left = _MEMSOUND(a, 1)
    54.     Right = _MEMSOUND(a, 2)
    55.  
    56.     NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
    57.     NewSound = _MEMNEW(NewSoundSize&)
    58.  
    59.     PRINT "SndRate:"; _SNDRATE
    60.     PRINT "Track memory len:"; Left.SIZE
    61.     PRINT "Creating audio..."
    62.  
    63.     VolDown = 1 / OverSampling
    64.     Create& = 0
    65.     NewAudio& = 0
    66.     DO UNTIL Create& >= Left.SIZE - 2
    67.         _MEMGET Left, Left.OFFSET + Create&, Audio
    68.         _MEMGET Right, Right.OFFSET + Create&, Audio2
    69.  
    70.         IF Create& > Echo& THEN
    71.  
    72.             E& = Create&
    73.             Vol = 1
    74.             DO UNTIL E& <= Create& - OverSampling
    75.                 Vol = Vol - VolDown
    76.                 _MEMGET Left, Left.OFFSET + Create& - Echo&, Audio3
    77.                 _MEMGET Left, Left.OFFSET + Create& - 2, Audio4
    78.                 Audio = (Audio + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
    79.                 E& = E& - 2
    80.             LOOP
    81.  
    82.             E& = Create&
    83.             Vol = 1
    84.             DO UNTIL E& <= Create& - OverSampling
    85.                 Vol = Vol - VolDown
    86.                 _MEMGET Right, Right.OFFSET + Create& - Echo&, Audio3
    87.                 _MEMGET Right, Right.OFFSET + Create& - 2, Audio4
    88.                 Audio2 = (Audio2 + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
    89.                 E& = E& - 2
    90.             LOOP
    91.         END IF
    92.  
    93.         _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio 'left channel
    94.         _MEMPUT NewSound, NewSound.OFFSET + NewAudio& + 2, Audio2 'right channel
    95.         NewAudio& = NewAudio& + 4
    96.         Create& = Create& + 2
    97.     LOOP
    98.  
    99.     PRINT "New sound created. Saving as Tracks-mix4.wav..."
    100.     SAVESOUND16S NewSound, "Tracks-mix4.wav"
    101.     PRINT "Sound saved, erasing RAM..."
    102.     _MEMFREE Left
    103.     _MEMFREE Right
    104.     _MEMFREE NewSound
    105.  
    106.     PRINT "Playing mixed sound"
    107.     snd = _SNDOPEN("tracks-mix4.wav")
    108.     _SNDPLAY snd
    109.     DO UNTIL _SNDPLAYING(snd) = 0
    110.         LOCATE 12
    111.         PRINT _SNDGETPOS(snd)
    112.     LOOP
    113.     CLS
    114.     _SNDCLOSE snd
    115.     KILL "tracks-mix4.wav"
    117.  
    119.  
    120.  
    121. FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    122.     DIM o AS _INTEGER64, mo AS _MEM
    123.     mo = _MEM(o)
    124.     _MEMPUT mo, mo.OFFSET, OffsetVal
    125.     _MEMFREE mo
    126.     OFFSETasI64&& = o
    128.  
    129.  
    130. SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
    131.  
    132.     TYPE head16
    133.         chunk AS STRING * 4 '       4 bytes  (RIFF)
    134.         size AS LONG '              4 bytes  (file size)
    135.         fomat AS STRING * 4 '       4 bytes  (WAVE)
    136.         sub1 AS STRING * 4 '        4 bytes  (fmt )
    137.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
    138.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
    139.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
    140.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
    141.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
    142.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
    143.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
    144.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
    145.         lenght AS LONG '            4 bytes  Data block size
    146.     END TYPE '                     44 bytes  total
    147.     DIM H16 AS head16
    148.     ch = FREEFILE
    149.  
    150.     H16.chunk = "RIFF"
    151.     H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
    152.  
    153.     H16.fomat = "WAVE"
    154.     H16.sub1 = "fmt "
    155.     H16.subchunksize = 16
    156.     H16.format = 1
    157.     H16.channels = 2
    158.     H16.rate = 44100
    159.     H16.ByteRate = 44100 * 2 * 16 / 8
    160.     H16.Block = 4
    161.     H16.Bits = 16
    162.     H16.subchunk2 = "data"
    163.     H16.lenght = OFFSETasI64(arr.SIZE)
    164.     IF _FILEEXISTS(file$) THEN KILL file$
    165.  
    166.     Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    167.     _MEMGET arr, arr.OFFSET, Audio$
    168.  
    169.     OPEN file$ FOR BINARY AS #ch
    170.     PUT #ch, , H16
    171.     PUT #ch, , Audio$
    172.     Audio$ = ""
    173.  
    174.     CLOSE ch
    176.  
    177. SUB GetFileList (SearchDirectory AS STRING, DirList() AS STRING, FileList() AS STRING)
    178.     CONST IS_DIR = 1
    179.     CONST IS_FILE = 2
    180.     DIM flags AS LONG, file_size AS LONG
    181.  
    182.     REDIM _PRESERVE DirList(100), FileList(100)
    183.     DirCount = 0: FileCount = 0
    184.  
    185.     IF load_dir(SearchDirectory) THEN
    186.         DO
    187.             length = has_next_entry
    188.             IF length > -1 THEN
    189.                 nam$ = SPACE$(length)
    190.                 get_next_entry nam$, flags, file_size
    191.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
    192.                     DirCount = DirCount + 1
    193.                     IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
    194.                     DirList(DirCount) = nam$
    195.                 ELSEIF (flags AND IS_FILE) OR _FILEEXISTS(SearchDirectory + nam$) THEN
    196.                     FileCount = FileCount + 1
    197.                     IF FileCount > UBOUND(filelist) THEN REDIM _PRESERVE FileList(UBOUND(filelist) + 100)
    198.                     FileList(FileCount) = nam$
    199.                 END IF
    200.             END IF
    201.         LOOP UNTIL length = -1
    202.         close_dir
    203.     ELSE
    204.     END IF
    205.     REDIM _PRESERVE DirList(DirCount)
    206.     REDIM _PRESERVE FileList(FileCount)
    208.  
    209.  
    210.  


      [ You are not allowed to view this attachment ]  
    « Last Edit: January 04, 2021, 10:38:27 am by Petr »
    Logged

    FellippeHeitor

    • Guest
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #42 on: January 04, 2021, 10:38:48 am »
  • Best Answer
    • Because you are opening sound files in sequence, and using the same variable to hold the handle, it's important to reset it to 0 before attempting to _SNDOPEN again. See if this fixes it:

    Code: QB64: [Select]
    1. 'Program create new WAV soundtrack + add echo
    2.  
    3. EchoLenght = 0.12 '0.06 seconds is echo duration
    4. OverSampling = 10 'number of echoes sample passes
    5.  
    6. Echo& = _SNDRATE * EchoLenght
    7.  
    8. DO UNTIL Echo& MOD 2 = 0
    9.     Echo& = Echo& + 1
    11. DIM Left AS _MEM, Right AS _MEM, NewSound AS _MEM, Audio AS INTEGER, Audio2 AS INTEGER, Audio3 AS INTEGER, Audio4 AS INTEGER
    12. REDIM PlayableFiles(0) AS STRING
    13.  
    14.  
    15. 'INPUT "Insert audio file name:"; a1$
    16.  
    18.     FUNCTION load_dir& (s AS STRING)
    19.     FUNCTION has_next_entry& ()
    20.     SUB close_dir ()
    21.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
    23.  
    24. REDIM Dir(0) AS STRING, File(0) AS STRING
    25. GetFileList _CWD$, Dir(), File()
    26.  
    27.  
    28. FOR s = LBOUND(file) TO UBOUND(file)
    29.     SELECT CASE UCASE$(RIGHT$(File(s), 3))
    30.         CASE "MP3", "OGG", "WAV"
    31.             PlayableFiles(i) = File(s)
    32.             i = i + 1
    33.             REDIM _PRESERVE PlayableFiles(i) AS STRING
    34.     END SELECT
    36.  
    37. PRINT "Files to play: "; i - 1
    38.  
    39.  
    40. FOR playit = 0 TO i - 1
    41.     a1$ = PlayableFiles(playit)
    42.     PRINT "Opening file "; playit + 1; "/"; i - 1; " - "; PlayableFiles(playit)
    43.     IF a THEN _SNDCLOSE a: a = 0
    44.     a = _SNDOPEN(a1$)
    45.     IF a THEN PRINT "Audio file opened" ELSE PRINT "Audio file 1 opening error.": END
    46.     LENa = _CEIL(_SNDLEN(a)) + EchoLenght
    47.     PRINT "Audio file lenght:"; LENa
    48.     NewTrackTime = LENa
    49.  
    50.  
    51.  
    52.  
    53.     Left = _MEMSOUND(a, 1)
    54.     Right = _MEMSOUND(a, 2)
    55.  
    56.     NewSoundSize& = _SNDRATE * NewTrackTime * 2 * 2 'use stereo  + use INTEGER
    57.     NewSound = _MEMNEW(NewSoundSize&)
    58.  
    59.     PRINT "SndRate:"; _SNDRATE
    60.     PRINT "Track memory len:"; Left.SIZE
    61.     PRINT "Creating audio..."
    62.  
    63.     VolDown = 1 / OverSampling
    64.     Create& = 0
    65.     NewAudio& = 0
    66.     DO UNTIL Create& >= Left.SIZE - 2
    67.         _MEMGET Left, Left.OFFSET + Create&, Audio
    68.         _MEMGET Right, Right.OFFSET + Create&, Audio2
    69.  
    70.         IF Create& > Echo& THEN
    71.  
    72.             E& = Create&
    73.             Vol = 1
    74.             DO UNTIL E& <= Create& - OverSampling
    75.                 Vol = Vol - VolDown
    76.                 _MEMGET Left, Left.OFFSET + Create& - Echo&, Audio3
    77.                 _MEMGET Left, Left.OFFSET + Create& - 2, Audio4
    78.                 Audio = (Audio + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
    79.                 E& = E& - 2
    80.             LOOP
    81.  
    82.             E& = Create&
    83.             Vol = 1
    84.             DO UNTIL E& <= Create& - OverSampling
    85.                 Vol = Vol - VolDown
    86.                 _MEMGET Right, Right.OFFSET + Create& - Echo&, Audio3
    87.                 _MEMGET Right, Right.OFFSET + Create& - 2, Audio4
    88.                 Audio2 = (Audio2 + Audio3 * (Vol + .01) + Audio4 * Vol) \ 3
    89.                 E& = E& - 2
    90.             LOOP
    91.         END IF
    92.  
    93.         _MEMPUT NewSound, NewSound.OFFSET + NewAudio&, Audio 'left channel
    94.         _MEMPUT NewSound, NewSound.OFFSET + NewAudio& + 2, Audio2 'right channel
    95.         NewAudio& = NewAudio& + 4
    96.         Create& = Create& + 2
    97.     LOOP
    98.  
    99.     PRINT "New sound created. Saving as Tracks-mix4.wav..."
    100.     SAVESOUND16S NewSound, "Tracks-mix4.wav"
    101.     PRINT "Sound saved, erasing RAM..."
    102.     _MEMFREE Left
    103.     _MEMFREE Right
    104.     _MEMFREE NewSound
    105.  
    106.     PRINT "Playing mixed sound"
    107.     snd = _SNDOPEN("tracks-mix4.wav")
    108.     _SNDPLAY snd
    109.     DO UNTIL _SNDPLAYING(snd) = 0
    110.         LOCATE 12
    111.         PRINT _SNDGETPOS(snd)
    112.     LOOP
    113.     CLS
    114.     _SNDCLOSE snd
    115.     KILL "tracks-mix4.wav"
    117.  
    119.  
    120.  
    121. FUNCTION OFFSETasI64&& (OffsetVal AS _OFFSET) 'convert OFFSET value to _INTEGER64 value -> 8 byte lenght to 8 byte lenght
    122.     DIM o AS _INTEGER64, mo AS _MEM
    123.     mo = _MEM(o)
    124.     _MEMPUT mo, mo.OFFSET, OffsetVal
    125.     _MEMFREE mo
    126.     OFFSETasI64&& = o
    128.  
    129.  
    130. SUB SAVESOUND16S (arr AS _MEM, file AS STRING)
    131.  
    132.     TYPE head16
    133.         chunk AS STRING * 4 '       4 bytes  (RIFF)
    134.         size AS LONG '              4 bytes  (file size)
    135.         fomat AS STRING * 4 '       4 bytes  (WAVE)
    136.         sub1 AS STRING * 4 '        4 bytes  (fmt )
    137.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
    138.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
    139.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
    140.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
    141.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
    142.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
    143.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
    144.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
    145.         lenght AS LONG '            4 bytes  Data block size
    146.     END TYPE '                     44 bytes  total
    147.     DIM H16 AS head16
    148.     ch = FREEFILE
    149.  
    150.     H16.chunk = "RIFF"
    151.     H16.size = 44 + OFFSETasI64(arr.SIZE) / _SNDRATE / 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
    152.  
    153.     H16.fomat = "WAVE"
    154.     H16.sub1 = "fmt "
    155.     H16.subchunksize = 16
    156.     H16.format = 1
    157.     H16.channels = 2
    158.     H16.rate = 44100
    159.     H16.ByteRate = 44100 * 2 * 16 / 8
    160.     H16.Block = 4
    161.     H16.Bits = 16
    162.     H16.subchunk2 = "data"
    163.     H16.lenght = OFFSETasI64(arr.SIZE)
    164.     IF _FILEEXISTS(file$) THEN KILL file$
    165.  
    166.     Audio$ = SPACE$(OFFSETasI64(arr.SIZE))
    167.     _MEMGET arr, arr.OFFSET, Audio$
    168.  
    169.     OPEN file$ FOR BINARY AS #ch
    170.     PUT #ch, , H16
    171.     PUT #ch, , Audio$
    172.     Audio$ = ""
    173.  
    174.     CLOSE ch
    176.  
    177. SUB GetFileList (SearchDirectory AS STRING, DirList() AS STRING, FileList() AS STRING)
    178.     CONST IS_DIR = 1
    179.     CONST IS_FILE = 2
    180.     DIM flags AS LONG, file_size AS LONG
    181.  
    182.     REDIM _PRESERVE DirList(100), FileList(100)
    183.     DirCount = 0: FileCount = 0
    184.  
    185.     IF load_dir(SearchDirectory) THEN
    186.         DO
    187.             length = has_next_entry
    188.             IF length > -1 THEN
    189.                 nam$ = SPACE$(length)
    190.                 get_next_entry nam$, flags, file_size
    191.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
    192.                     DirCount = DirCount + 1
    193.                     IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
    194.                     DirList(DirCount) = nam$
    195.                 ELSEIF (flags AND IS_FILE) OR _FILEEXISTS(SearchDirectory + nam$) THEN
    196.                     FileCount = FileCount + 1
    197.                     IF FileCount > UBOUND(filelist) THEN REDIM _PRESERVE FileList(UBOUND(filelist) + 100)
    198.                     FileList(FileCount) = nam$
    199.                 END IF
    200.             END IF
    201.         LOOP UNTIL length = -1
    202.         close_dir
    203.     ELSE
    204.     END IF
    205.     REDIM _PRESERVE DirList(DirCount)
    206.     REDIM _PRESERVE FileList(FileCount)
    208.  
    209.  
    210.  
    Logged

    Offline Petr

    • Forum Resident
    • Posts: 1720
    • The best code is the DNA of the hops.
      • View Profile
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #43 on: January 04, 2021, 10:43:55 am »
  • Best Answer
    • NOT. I test also your new 64bit version now and there all works without any upgrades in my source code as expected. So bug is in 32 bit version only.
    Logged

    FellippeHeitor

    • Guest
    Re: Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)
    « Reply #44 on: January 04, 2021, 10:45:27 am »
  • Best Answer
    • I'll try to reproduce it on my end. Mind sending me the offending audio file?

    Keep in mind I've been developing _MEMSOUND in a 32bit environment, btw.

    Also, keep in mind the need to reset the handle variable before loading new data.
    Logged
    Pages: 1 2 [3] 4 5 6   Go Up
    « previous next »