How to leave an input line.

[bartok]

I have a problem. My program (I have attached an image as example) is almost finished, but at the moment is a flow. I have to introduce the possibility to navigate through it and then write the results to files.

The problem is this.
The program at the start asks some input:

1) Enter input 1:      B
2) Enter input 2:      B
3) Enter input 3:      C
4) Enter input 4:      _


Suppose that the program is now asking input 4 and that we have just realized that input 1 is wrong, because is not B, but A.

I want to do this: just pressing up arrow (without enter), the program must leaves the input line corresponding to input 4 and go up, to line asking input 3, and so on (possibly preserving input 2 and 3).

[euklides]

Not very elegant, but for example you could imagine something like that:


1000 Input "blabla A (or -1 to cancel)", a1$: If a1$ = "-1" Then Stop
1001 Input "blabla B (or -1 -> asking A)", b1$: If b1$ = "-1" Then GoTo 1000
1002 Input "blabla C (or -1 -> asking B)", c1$: If c1$ = "-1" Then GoTo 1001
1003 Input "blabla D (or -1 -> asking C)", d1$: If d1$ = "-1" Then GoTo 1002

[bplus]

EDIT missed this part:

I want to do this: just pressing up arrow (without enter), the program must leaves the input line corresponding to input 4 and go up, to line asking input 3, and so on (possibly preserving input 2 and 3).

[bplus]

EDIT missed this part:

I want to do this: just pressing up arrow (without enter), the program must leaves the input line corresponding to input 4 and go up, to line asking input 3, and so on (possibly preserving input 2 and 3).

[bplus]

EDIT missed this part:

I want to do this: just pressing up arrow (without enter), the program must leaves the input line corresponding to input 4 and go up, to line asking input 3, and so on (possibly preserving input 2 and 3).

[SMcNeill]

Terry Ritchie’s GLInput Library does what you’re looking for, and is well documented, if you have a copy of it.

[NOVARSEG]

@bartok


Here is a basic program that shows what you want. It takes a lot more coding to make it work properly.

Code: QB64: [Select]

1. DIM msg(1) AS STRING
2. DIM S(1) AS STRING
3. DIM X AS INTEGER
4.  
5. msg(0) = "Enter name "
6. msg(1) = "Enter date "
7.  
8. LL1:
9. FOR X = 0 TO 1
10.     IF INKEY$ = CHR$(27) THEN END
11.     LOCATE 10 + X, 2 + LEN(msg(X)): PRINT SPACE$(10)
12.     LOCATE 10 + X, 2: PRINT msg(X);: INPUT S(X)
13.  
14. NEXT X
15.  
16. DO
17.     i$ = INKEY$
18.     IF i$ = CHR$(27) THEN END
19.     IF i$ = CHR$(13) THEN GOTO LL1
20. LOOP
21.  

[Cobalt]

A custom input routine would probably be your best bet for that kind of flexibility.
Based around a DO:LOOP structure without GOTO. It will take me a bit to write you up an example but if your willing to wait.....

[Cobalt]

Not super refined but is something like this what you want?

Code: QB64: [Select]

1. 'Editable input example
2. 'lets start with some base constants
3. CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
4. CONST TRUE = -1, FALSE = NOT TRUE
5.  
6. DIM Inputs(10) AS STRING 'for this example we will allow up to 10 inputs
7.  
8. 'some prep work
9. Opt%% = 1 'start on the first input line
10.  
11. 'start our loop up
12. DO
13.  KBD& = _KEYHIT 'keyboard input
14.  IF KBD& < 0 THEN KBD& = 0 'negate any negative keyhit values
15.  FOR I%% = 1 TO 10 'loop through all our input options
16.   'double space the input lines for readability
17.   LOCATE I%% * 2, 1: PRINT "INPUT VALUE #"; I%%; "  -"; Inputs(I%%);
18.   'print a "cursor" to show which input user is on, use space$ to clear other lines
19.   IF I%% = Opt%% THEN PRINT CHR$(176) ELSE PRINT SPACE$(2)
20.  NEXT I%%
21.  
22.  'let us process which line the user is inputing
23.  SELECT CASE KBD&
24.   CASE 13 'enter to accept inputs
25.    ExitFlag%% = TRUE
26.   CASE 8 'backspace to clear this input
27.    Inputs(Opt%%) = ""
28.   CASE Key_Up
29.    Opt%% = Opt%% - 1
30.    'for this example we will stop on 1, we could always cycle to 10 though
31.    IF Opt%% = 0 THEN Opt%% = 1
32.   CASE Key_Down
33.    Opt%% = Opt%% + 1
34.    'we will cap off at 10, though we could cycle back to 1
35.    IF Opt%% = 11 THEN Opt%% = 10
36.   CASE 32 TO 122
37.    'now we are only going to allow 1 character inputs for this example
38.    Inputs(Opt%%) = CHR$(KBD&)
39.   CASE NOT 0 ' any other input(0 is no input)
40.    BEEP 'invalid input
41.  END SELECT
42.  '-----------------------------------------------
43.  
44.  _LIMIT 30 'up date 30times a sec to save CPU use
45.  IF KBD& = 27 THEN ExitFlag%% = TRUE 'exit this example
46. LOOP UNTIL ExitFlag%%

[NOVARSEG]

@Cobalt
I like the way you combined  a FOR NEXT  inside a DO LOOP

Here are a few mods.  Can enter text . Backspace works

up / down keys rotate now.

Code: QB64: [Select]

1. 'Editable input example
2. 'lets start with some base constants
3. CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
4. CONST TRUE = -1, FALSE = NOT TRUE
5.  
6. DIM Inputs(9) AS STRING 'for this example we will allow up to 10 inputs
7. DIM KH AS LONG
8. DIM I AS INTEGER
9. DIM OPT AS INTEGER
10.  
11.  
12. 'some prep work
13. OPT = 0 'start on the first input line
14.  
15. 'start our loop up
16. DO
17.     KH = _KEYHIT 'keyboard input
18.     IF KH < 0 THEN KH = 0 'negate any negative keyhit values
19.  
20.     FOR I = 0 TO 9 'loop through all our input options
21.  
22.         'double space the input lines for readability
23.         LOCATE 1 + (I * 2), 1: PRINT "INPUT VALUE #"; I; "  -"; Inputs(I);
24.  
25.         'print a "cursor" to show which input user is on, use space$ to clear other lines
26.         IF I = OPT THEN PRINT CHR$(176) + " " ELSE PRINT SPACE$(2)
27.  
28.     NEXT I
29.  
30.     'let us process which line the user is inputing
31.     SELECT CASE KH
32.         CASE 13 'enter to accept inputs
33.             ExitFlag%% = TRUE
34.         CASE 8 'backspace to clear this input
35.  
36.             Inputs(OPT) = LEFT$(Inputs(OPT), LEN(Inputs(OPT)) - 1)
37.  
38.         CASE Key_Up
39.             IF OPT = 0 THEN OPT = 10
40.             IF OPT > 0 THEN OPT = OPT - 1
41.  
42.         CASE Key_Down
43.  
44.             IF OPT < 10 THEN OPT = OPT + 1
45.             IF OPT = 10 THEN OPT = 0
46.  
47.         CASE 32 TO 122
48.             'now we are only going to allow 1 character inputs for this example
49.             Inputs(OPT) = Inputs(OPT) + CHR$(KH)
50.         CASE NOT 0 ' any other input(0 is no input)
51.             BEEP 'invalid input
52.     END SELECT
53.     '-----------------------------------------------
54.  
55.     _LIMIT 30 'up date 30times a sec to save CPU use
56.     IF KH = 27 THEN ExitFlag%% = TRUE 'exit this example
57. LOOP UNTIL ExitFlag%%
58.  

Added blinking cursor

Code: QB64: [Select]

1. 'Editable input example
2. 'lets start with some base constants
3. CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
4. CONST TRUE = -1, FALSE = NOT TRUE
5.  
6. DIM Inputs(9) AS STRING 'for this example we will allow up to 10 inputs
7. DIM KH AS LONG
8. DIM I AS INTEGER
9. DIM OPT AS INTEGER
10. DIM cp(30)
11. _FULLSCREEN
12.  
13.  
14. 'some prep work
15. OPT = 0 'start on the first input line
16.  
17. 'start our loop up
18. DO
19.     KH = _KEYHIT 'keyboard input
20.     IF KH < 0 THEN KH = 0 'negate any negative keyhit values
21.  
22.     FOR I = 0 TO 9 'loop through all our input options
23.  
24.         'double space the input lines for readability
25.         LOCATE 1 + (I * 2), 1: PRINT "INPUT VALUE #"; I; Inputs(I)
26.  
27.         IF I = OPT THEN
28.             LOCATE 1 + (OPT * 2), cp(OPT) + 17: PRINT " "
29.         END IF
30.  
31.     NEXT I
32.     LOCATE 1 + (OPT * 2), cp(OPT) + 17, 1, 31, 31
33.  
34.  
35.     'let us process which line the user is inputing
36.     SELECT CASE KH
37.  
38.         CASE 13 'enter to accept inputs
39.             ExitFlag%% = TRUE
40.  
41.         CASE 8 'backspace to clear this input
42.             IF cp(OPT) > 0 THEN
43.                 Inputs(OPT) = LEFT$(Inputs(OPT), LEN(Inputs(OPT)) - 1)
44.                 cp(OPT) = cp(OPT) - 1
45.             END IF
46.  
47.         CASE Key_Up
48.             IF OPT = 0 THEN OPT = 10
49.             IF OPT > 0 THEN OPT = OPT - 1
50.  
51.         CASE Key_Down
52.  
53.             IF OPT < 10 THEN OPT = OPT + 1
54.             IF OPT = 10 THEN OPT = 0
55.  
56.         CASE 32 TO 122
57.             'now we are only going to allow 1 character inputs for this example
58.             Inputs(OPT) = Inputs(OPT) + CHR$(KH)
59.             cp(OPT) = cp(OPT) + 1
60.         CASE NOT 0 ' any other input(0 is no input)
61.             BEEP 'invalid input
62.     END SELECT
63.     '-----------------------------------------------
64.  
65.     _LIMIT 30 'up date 30times a sec to save CPU use
66.     IF KH = 27 THEN ExitFlag%% = TRUE 'exit this example
67. LOOP UNTIL ExitFlag%%
68.  

[bartok]

Cobalt and NOVARSEG,
thank you very much to both! It almost seems what I am searching. The idea to create a custom input routine is sharp. I have to study it in ordet to apply it to the program. Why I has a bouble %%? I know as variable definition $, %, &, !, but %%?

[Richard]

@bartok

From the QB64  IDE Help > Alphabetical  (a few "pages" back from the very end)




    Variable Name Type Suffixes
þ $ STRING text character type: 1 byte
þ ! SINGLE floating decimal point numerical type (4 bytes)
þ # DOUBLE floating decimal point numerical type (8 bytes)
þ ## _FLOAT QB64 decimal point numerical type (32 bytes)
þ ~ _UNSIGNED QB64 whole positive numerical type when it precedes the 6 numerical
  suffixes below:
þ % INTEGER whole numerical type (2 bytes)
þ & LONG whole numerical type (4 bytes}
þ && _INTEGER64 QB64 whole numerical type (8 bytes)
þ ` _BIT QB64 whole numerical type (1 bit) (Key below tilde (~) or CHR$(96))
þ %% _BYTE QB64 whole numerical type (1 byte)
þ %& _OFFSET QB64 whole numerical pointer address type (any byte size required)

Hope this helps

[bplus]

Nice @Cobalt and @NOVARSEG

I made some mods for how I would like to use:

Code: QB64: [Select]

1. Option _Explicit ' to remind what I haven't dim'd
2. Dim As Long cursor, nInputs, i
3. Dim k$
4. 'setups
5. nInputs = 6 'for this example we will allow up to nInputs inputs
6. Dim Inputs$(1 To nInputs)
7. Dim prompts$(1 To nInputs)
8. prompts$(1) = "First Name: "
9. prompts$(2) = " Last Name: "
10. prompts$(3) = "Home Phone: "
11. prompts$(4) = "Cell Phone: "
12. prompts$(5) = "Birth date: "
13. prompts$(6) = "     State: "
14. cursor = 1 'start on the first input line
15. 'start our loop up
16. Do
17.     k$ = InKey$ 'keyboard input
18.     For i = 1 To nInputs 'loop through all our input options
19.         Locate i, 1: Print prompts$(i); Inputs$(i);
20.         'print a "cursor" to show which input user is on, use space$ to clear other lines
21.         If i = cursor Then Print "_" + " " Else Print Space$(2)
22.     Next
23.     If Len(k$) Then 'let us process which line the user is inputing
24.         Select Case Asc(Right$(k$, 1))
25.             Case 13: If cursor = nInputs Then Exit Do Else cursor = cursor + 1 ' no exit unless on last line
26.             Case 8: Inputs$(cursor) = Left$(Inputs$(cursor), Len(Inputs$(cursor)) - 1) 'backspace to clear this input
27.             Case 27: Exit Do
28.             Case 72: If cursor > 1 Then cursor = cursor - 1 ' up
29.             Case 80: If cursor < nInputs Then cursor = cursor + 1 'down
30.             Case 32 TO 122: Inputs$(cursor) = Inputs$(cursor) + k$
31.         End Select
32.     End If
33.     _Limit 30 'up date 30 times a sec to save CPU use
34. Loop
35. 'show results of inputs
36. For i = 1 To nInputs
37.     Print i, prompts$(i); "= "; Inputs$(i)
38. Next
39.  
40.  

[Dav]

Nice little snippet, @bplus.  Saving it for future use.  I added CASE 73, 75, 77, 81: 'don't print these to the SELECT CASE ASC(RIGHT$(k$, 1)) area to not show those keys.

- Dav

[bplus]

Hi @Dav

Yeah, the working in of the cursor was simple but genius, NOVARSEG or Cobalt?, in the display update loop,

75, 77 left and right arrow? more up and down? or are we really getting into editing :)

73, 81 pgUp and pgDn make sense, you could start thinking of over a screen full of inputs!

Update:

Code: QB64: [Select]

1. Option _Explicit ' to remind what I haven't dim'd  B+ mod Cobalt and NOVARSEG and Dav 2021-06-15
2. Dim As Long cursor, nInputs, i
3. Dim k$
4. 'setups
5. nInputs = 6 'for this example we will allow up to nInputs inputs
6. Dim Inputs$(1 To nInputs)
7. Dim prompts$(1 To nInputs)
8. prompts$(1) = "First Name: "
9. prompts$(2) = " Last Name: "
10. prompts$(3) = "Home Phone: "
11. prompts$(4) = "Cell Phone: "
12. prompts$(5) = "Birth date: "
13. prompts$(6) = "     State: "
14. cursor = 1 'start on the first input line
15. 'start our loop up
16. Do
17.     k$ = InKey$ 'keyboard input
18.     For i = 1 To nInputs 'loop through all our input options
19.         Locate i, 1: Print prompts$(i); Inputs$(i);
20.         'print a "cursor" to show which input user is on, use space$ to clear other lines
21.         If i = cursor Then Print "_" + " " Else Print Space$(2)
22.     Next
23.     If Len(k$) Then 'let us process which line the user is inputing
24.         Select Case Asc(Right$(k$, 1))
25.             Case 13: If cursor = nInputs Then Exit Do Else cursor = cursor + 1 ' no exit unless on last line
26.             Case 8: Inputs$(cursor) = Left$(Inputs$(cursor), Len(Inputs$(cursor)) - 1) 'backspace to clear this input
27.             Case 27: Exit Do
28.             Case 72, 75: If cursor > 1 Then cursor = cursor - 1 ' up
29.             Case 73: cursor = 1 'pgUp
30.             Case 80, 77: If cursor < nInputs Then cursor = cursor + 1 'down
31.             Case 81: cursor = nInputs ' pgDn
32.             Case 32 TO 122: Inputs$(cursor) = Inputs$(cursor) + k$
33.         End Select
34.     End If
35.     _Limit 30 'up date 30times a sec to save CPU use
36. Loop
37. 'show results of inputs
38. For i = 1 To nInputs
39.     Print i, prompts$(i); "= "; Inputs$(i)
40. Next
41.  
42.