How to leave an input line.

[TempodiBasic]

Hi
it is so fine to see how different and similar approaches have been showed here for a customized input routine.

@bartok
as our friends have said it is no possible navigation trough the input lines if you use old standard INPUT/ LINE INPUT / INPUT$()  keywords. Please forgot them because you will not want a DOS  interface with black screen.

[bartok]

@Cobalt
I like the way you combined  a FOR NEXT  inside a DO LOOP

Here are a few mods.  Can enter text . Backspace works

up / down keys rotate now.

Code: QB64: [Select]

1. 'Editable input example
2. 'lets start with some base constants
3. CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
4. CONST TRUE = -1, FALSE = NOT TRUE
5.  
6. DIM Inputs(9) AS STRING 'for this example we will allow up to 10 inputs
7. DIM KH AS LONG
8. DIM I AS INTEGER
9. DIM OPT AS INTEGER
10.  
11.  
12. 'some prep work
13. OPT = 0 'start on the first input line
14.  
15. 'start our loop up
16. DO
17.     KH = _KEYHIT 'keyboard input
18.     IF KH < 0 THEN KH = 0 'negate any negative keyhit values
19.  
20.     FOR I = 0 TO 9 'loop through all our input options
21.  
22.         'double space the input lines for readability
23.         LOCATE 1 + (I * 2), 1: PRINT "INPUT VALUE #"; I; "  -"; Inputs(I);
24.  
25.         'print a "cursor" to show which input user is on, use space$ to clear other lines
26.         IF I = OPT THEN PRINT CHR$(176) + " " ELSE PRINT SPACE$(2)
27.  
28.     NEXT I
29.  
30.     'let us process which line the user is inputing
31.     SELECT CASE KH
32.         CASE 13 'enter to accept inputs
33.             ExitFlag%% = TRUE
34.         CASE 8 'backspace to clear this input
35.  
36.             Inputs(OPT) = LEFT$(Inputs(OPT), LEN(Inputs(OPT)) - 1)
37.  
38.         CASE Key_Up
39.             IF OPT = 0 THEN OPT = 10
40.             IF OPT > 0 THEN OPT = OPT - 1
41.  
42.         CASE Key_Down
43.  
44.             IF OPT < 10 THEN OPT = OPT + 1
45.             IF OPT = 10 THEN OPT = 0
46.  
47.         CASE 32 TO 122
48.             'now we are only going to allow 1 character inputs for this example
49.             Inputs(OPT) = Inputs(OPT) + CHR$(KH)
50.         CASE NOT 0 ' any other input(0 is no input)
51.             BEEP 'invalid input
52.     END SELECT
53.     '-----------------------------------------------
54.  
55.     _LIMIT 30 'up date 30times a sec to save CPU use
56.     IF KH = 27 THEN ExitFlag%% = TRUE 'exit this example
57. LOOP UNTIL ExitFlag%%
58.  

Added blinking cursor

Code: QB64: [Select]

1. 'Editable input example
2. 'lets start with some base constants
3. CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
4. CONST TRUE = -1, FALSE = NOT TRUE
5.  
6. DIM Inputs(9) AS STRING 'for this example we will allow up to 10 inputs
7. DIM KH AS LONG
8. DIM I AS INTEGER
9. DIM OPT AS INTEGER
10. DIM cp(30)
11. _FULLSCREEN
12.  
13.  
14. 'some prep work
15. OPT = 0 'start on the first input line
16.  
17. 'start our loop up
18. DO
19.     KH = _KEYHIT 'keyboard input
20.     IF KH < 0 THEN KH = 0 'negate any negative keyhit values
21.  
22.     FOR I = 0 TO 9 'loop through all our input options
23.  
24.         'double space the input lines for readability
25.         LOCATE 1 + (I * 2), 1: PRINT "INPUT VALUE #"; I; Inputs(I)
26.  
27.         IF I = OPT THEN
28.             LOCATE 1 + (OPT * 2), cp(OPT) + 17: PRINT " "
29.         END IF
30.  
31.     NEXT I
32.     LOCATE 1 + (OPT * 2), cp(OPT) + 17, 1, 31, 31
33.  
34.  
35.     'let us process which line the user is inputing
36.     SELECT CASE KH
37.  
38.         CASE 13 'enter to accept inputs
39.             ExitFlag%% = TRUE
40.  
41.         CASE 8 'backspace to clear this input
42.             IF cp(OPT) > 0 THEN
43.                 Inputs(OPT) = LEFT$(Inputs(OPT), LEN(Inputs(OPT)) - 1)
44.                 cp(OPT) = cp(OPT) - 1
45.             END IF
46.  
47.         CASE Key_Up
48.             IF OPT = 0 THEN OPT = 10
49.             IF OPT > 0 THEN OPT = OPT - 1
50.  
51.         CASE Key_Down
52.  
53.             IF OPT < 10 THEN OPT = OPT + 1
54.             IF OPT = 10 THEN OPT = 0
55.  
56.         CASE 32 TO 122
57.             'now we are only going to allow 1 character inputs for this example
58.             Inputs(OPT) = Inputs(OPT) + CHR$(KH)
59.             cp(OPT) = cp(OPT) + 1
60.         CASE NOT 0 ' any other input(0 is no input)
61.             BEEP 'invalid input
62.     END SELECT
63.     '-----------------------------------------------
64.  
65.     _LIMIT 30 'up date 30times a sec to save CPU use
66.     IF KH = 27 THEN ExitFlag%% = TRUE 'exit this example
67. LOOP UNTIL ExitFlag%%
68.  

Why, if I add on the top of your code,

test& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
_DEST test&
SCREEN test&

the cursor is not blincking? A part from that, with _NEWIMAGE graphic screen, LOCATE in your program continues to work fine without changes. So it seems that cursorstart and cursorstop may have problems.

[bplus]

So it seems that cursorstart and cursorstop may have problems.

In graphics screens.

[bartok]

In graphics screens.

yes, but adding \16 and \8 nothing changes. In my program, SCREEN test& (that is called SCREEN schermo&), is the screen where all the images are put, after they have been collected between them.
For example, the attached image of the first post, is the result of an image put 2 times (the 2 graphs) inside a larger image (with datas) finally put in turn on schermo&. I use schermo& to ask inputs to the user or to write some information, but it has to contain also images.

So, is there a way in order to have blinking cursor on test&(schermo&)?

I thounght that implementing navigability was easier and that the worst was over!

However, thanks you all, I have understood the examples and I have done what I wanted. A part from blinking cursor...

Hi
it is so fine to see how different and similar approaches have been showed here for a customized input routine.

@bartok
as our friends have said it is no possible navigation trough the input lines if you use old standard INPUT/ LINE INPUT / INPUT$()  keywords. Please forgot them because you will not want a DOS  interface with black screen.

apart from the fact that I adore DOS inferface with black screen...:D
apart from the fact that, even having implemented this new standar of input, my interface still seems a DOS interface with back screen...

but: implementing this flexible kind of input, is absolutely not a joke, above all if the real case requires well defined kind of inputs! So, if it is not necessary such a flexibility, I think "normal" INPUT is preferable.

[bplus]

Well, when you have a graphics screen you can replace a blinking cursor with a B&W blinking BF box option for Line.
If cursor box is not in a cls screen loop that updates in fractions of seconds then use a timer to blink the box.

[SMcNeill]

This concept isn't that complex.  Let me strip it down to the very basics for you guys:

Code: QB64: [Select]

1. Dim result(1 To 3) As String
2.  
3. V = 1: T! = Timer
4. Do
5.     If V < 1 Then V = 3 Else If V > 3 Then V = 1 'stay in bounds of our array
6.     If Timer > T! + 0.5 Then blink = Not blink: T! = Timer 'blink on and off timer
7.     Cls
8.     Print "Enter your name: "; result(1);: If V = 1 And blink Then Print "Û" Else Print
9.     Print "Enter your age : "; result(2);: If V = 2 And blink Then Print "Û" Else Print
10.     Print "Enter your sex : "; result(3);: If V = 3 And blink Then Print "Û" Else Print
11.     Print "Esc to Accept Data and exit"
12.     k = _KeyHit
13.     Select Case k
14.         Case 18432: V = V - 1 'up
15.         Case 20480: V = V + 1 'down
16.         Case 13: V = V + 1 'enter
17.         Case 8: result(V) = Left$(result(V), Len(result(V)) - 1) 'backspace
18.         Case 32 TO 255: result(V) = result(V) + Chr$(k) 'add character
19.     End Select
20.     _Limit 30
21.     _Display
22. Loop Until k = 27
23. Print: Print "Your final data was:", result(1), result(2), result(3)
24.  

[bartok]

This concept isn't that complex.  Let me strip it down to the very basics for you guys:

Code: QB64: [Select]

1. Dim result(1 To 3) As String
2.  
3. V = 1: T! = Timer
4. Do
5.     If V < 1 Then V = 3 Else If V > 3 Then V = 1 'stay in bounds of our array
6.     If Timer > T! + 0.5 Then blink = Not blink: T! = Timer 'blink on and off timer
7.     Cls
8.     Print "Enter your name: "; result(1);: If V = 1 And blink Then Print "Û" Else Print
9.     Print "Enter your age : "; result(2);: If V = 2 And blink Then Print "Û" Else Print
10.     Print "Enter your sex : "; result(3);: If V = 3 And blink Then Print "Û" Else Print
11.     Print "Esc to Accept Data and exit"
12.     k = _KeyHit
13.     Select Case k
14.         Case 18432: V = V - 1 'up
15.         Case 20480: V = V + 1 'down
16.         Case 13: V = V + 1 'enter
17.         Case 8: result(V) = Left$(result(V), Len(result(V)) - 1) 'backspace
18.         Case 32 TO 255: result(V) = result(V) + Chr$(k) 'add character
19.     End Select
20.     _Limit 30
21.     _Display
22. Loop Until k = 27
23. Print: Print "Your final data was:", result(1), result(2), result(3)
24.  

done! thank's!

Code: QB64: [Select]

1. '[...]
2. schermo& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
3. esci$ = "I dati forniti non determinao pioggia efficace, quindi non vi Š portata. Premere un tasto per uscire."
4. SCREEN schermo&
5. _SCREENMOVE 0, 0
6. PRINT "Questo programma serve a calcolare l'idrogramma di progetto (e relativa portata di picco) per"
7. PRINT "un  dato  tempo  di  ritorno,  utilizzando  l'idrogramma  unitario  adimensionale di Mockus e"
8. PRINT "ietrogrammi tipo "; CHR$(34); "Chicago"; CHR$(34); " o "; CHR$(34); "costanti"; CHR$(34); "."
9. PRINT
10. PRINT "Di seguito si dovranno inserire i valori della curva di possibilit… climatica "; CHR$(34); "h = Ktúaúd^n"; CHR$(34); "."
11. PRINT "Se  si dispone  dei valori  del Centro  Funzionale, digitare il valore "; CHR$(34); "Kt"; CHR$(34); " relativo al tempo"
12. PRINT "di ritorno "; CHR$(34); "T"; CHR$(34); " d'interesse, con i relativi valori "; CHR$(34); "a"; CHR$(34); " e "; CHR$(34); "n"; CHR$(34); "."
13. PRINT "Se invece si ha una  propria curva di possibilit… climatica, quando verr… chiesto di inserire"
14. PRINT CHR$(34); "Kt"; CHR$(34); ", digitare "; CHR$(34); "INVIO"; CHR$(34); ", o "; CHR$(34); "1"; CHR$(34); "."
15. PRINT "In tal caso "; CHR$(34); "Kt"; CHR$(34); " sar… considerato pari a "; CHR$(34); "1"; CHR$(34); " e "; CHR$(34); "T"; CHR$(34); " come "; CHR$(34); "definito dall'utente"; CHR$(34); "."
16. PRINT
17. PRINT "- Kt [-] (INVIO per 1)                                           = "
18. PRINT "- a [mm/d^n]                                                     = "
19. PRINT "- n [-] (0ö1)                                                    = "
20. PRINT "- Area del bacino idrografico [mý]                               = "
21. PRINT "- Lunghezza dell'asta principale del bacino idrografico [m]      = "
22. PRINT "- Altitudine s.l.m. del punto pi— alto dell'asta principale [m]  = "
23. PRINT "- Altitudine s.l.m. del punto pi— basso dell'asta principale [m] = "
24. PRINT "- Pendenza media del bacino idrografico [%] (1ö100)              = "
25. PRINT "- CN(II) [-] (1ö100)                                             = "
26. PRINT "- Coefficiente delle perdite inziali [-] (0ö0.2 - INVIO per 0.1) = "
27. CALL InserimentoDati(k!, a1!, n1, A2!, L!, HmaxL!, HminL!, s1!, CNII!, CoeffPerditeIniziali!)
28. LOCATE PosizioneCursore% + 10, 1
29. PRINT "- Visualizzare i risultati utilizzando lo ietogramma Chicago [1] o costante [2]?"
30. PRINT
31. '[...]
32. SUB InserimentoDati (k!, a1!, n1, A2!, L!, HmaxL!, HminL!, s1!, CNII!, CoeffPerditeIniziali!)
33.  
34.     SHARED PosizioneCursore%
35.  
36.     DIM inputs$(10)
37.     DIM richiesta%
38.     DIM test%(10)
39.     DIM debug%
40.     DIM carattere$
41.     DIM punti%
42.     DIM T!
43.     DIM cursore%
44.     DIM esci%
45.  
46.     PosizioneCursore% = CSRLIN - 10
47.     richiesta% = 1
48.     T! = TIMER
49.     DO
50.         _LIMIT 30
51.         KeyPress$ = INKEY$
52.         IF TIMER > T! + 0.5 THEN
53.             cursore% = NOT cursore%
54.             T! = TIMER
55.         END IF
56.         FOR i% = 1 TO 10
57.             LOCATE PosizioneCursore% - 1 + i%, 68: PRINT inputs$(i%) + SPACE$(30)
58.         NEXT i%
59.         IF esci% = 1 THEN EXIT DO
60.         LOCATE PosizioneCursore% - 1 + richiesta%, 68 + LEN(inputs$(richiesta%))
61.         IF cursore% THEN PRINT "_"
62.         SELECT CASE KeyPress$
63.             CASE CHR$(44), CHR$(46) ',e.
64.                 punti% = 0
65.                 IF KeyPress$ = CHR$(44) THEN KeyPress$ = CHR$(46)
66.                 FOR n% = 1 TO LEN(inputs$(richiesta%))
67.                     carattere$ = MID$(inputs$(richiesta%), n%, 1)
68.                     IF carattere$ = CHR$(46) THEN punti% = 1
69.                 NEXT n%
70.                 SELECT CASE punti%
71.                     CASE IS = 0
72.                         inputs$(richiesta%) = inputs$(richiesta%) + KeyPress$
73.                     CASE IS = 1
74.                         inputs$(richiesta%) = inputs$(richiesta%)
75.                 END SELECT
76.             CASE CHR$(48) TO CHR$(57) '0-9
77.                 inputs$(richiesta%) = inputs$(richiesta%) + KeyPress$
78.             CASE CHR$(8) 'del
79.                 SELECT CASE LEN(inputs$(richiesta%))
80.                     CASE IS = 0
81.                         EXIT SELECT
82.                     CASE IS = 1
83.                         inputs$(richiesta%) = ""
84.                         LOCATE , 68: PRINT " "
85.                     CASE ELSE
86.                         inputs$(richiesta%) = LEFT$(inputs$(richiesta%), LEN(inputs$(richiesta%)) - 1)
87.                         LOCATE , 68 + LEN(inputs$(richiesta%)): PRINT " "
88.                 END SELECT
89.             CASE CHR$(0) + "H" 'su
90.                 GOSUB Valutavalore
91.                 SELECT CASE test%(richiesta%)
92.                     CASE IS = 0
93.                         inputs$(richiesta%) = ""
94.                     CASE IS = 1
95.                         IF richiesta% = 1 THEN
96.                             EXIT SELECT
97.                         ELSEIF richiesta <= 10 THEN
98.                             richiesta% = richiesta% - 1
99.                         END IF
100.                 END SELECT
101.             CASE CHR$(0) + "P" 'giu'
102.                 GOSUB Valutavalore
103.                 SELECT CASE test%(richiesta%)
104.                     CASE IS = 0
105.                         inputs$(richiesta%) = ""
106.                     CASE IS = 1
107.                         IF richiesta% < 10 THEN
108.                             IF inputs$(richiesta% + 1) <> "" THEN richiesta% = richiesta% + 1
109.                         ELSE
110.                             EXIT SELECT
111.                         END IF
112.                 END SELECT
113.             CASE CHR$(13) 'invio
114.                 GOSUB Valutavalore
115.                 IF debug% = 1 THEN
116.                     _AUTODISPLAY
117.                     EXIT SUB
118.                 END IF
119.                 IF richiesta% <> 1 THEN
120.                     IF LEN(inputs$(richiesta%)) = 0 THEN test%(richiesta%) = 0
121.                 END IF
122.                 SELECT CASE test%(richiesta%)
123.                     CASE IS = 0
124.                         richiesta% = richiesta%
125.                         inputs$(richiesta%) = ""
126.                     CASE IS = 1
127.                         IF richiesta% = 10 THEN
128.                             esci% = 1
129.                         ELSE
130.                             richiesta% = richiesta% + 1
131.                         END IF
132.                 END SELECT
133.         END SELECT
134.         _DISPLAY
135.     LOOP
136.     k! = VAL(inputs$(1))
137.     a1! = VAL(inputs$(2))
138.     n1! = VAL(inputs$(3))
139.     A2! = VAL(inputs$(4))
140.     L! = VAL(inputs$(5))
141.     HmaxL! = VAL(inputs$(6))
142.     HminL! = VAL(inputs$(7))
143.     s1! = VAL(inputs$(8))
144.     CNII! = VAL(inputs$(9))
145.     CoeffPerditeIniziali! = VAL(inputs$(10))
146.     IF k! = 1 THEN
147.         T$ = "Definito dall'utente."
148.     ELSE
149.         GOSUB TrovaT
150.     END IF
151.     _AUTODISPLAY
152.     EXIT SUB
153.     '-----------------------------------------------------------------------------------------------------------------------------------------------------------
154.     Valutavalore:
155.     test%(richiesta%) = 0 ' se 0 rimane nella richiesta in corso, se 1, cambia.
156.  
157.     SELECT CASE richiesta%
158.         CASE 1
159.             IF inputs$(1) = "123" THEN 'avvia debug
160.                 'Cillian:
161.                 'k! = 1: a1! = 1: n1! = 0.45596: A2! = 2641902: L! = 3300: HmaxL! = 1981: HminL! = 1062: s1! = 41.5: CNII! = 70:CoeffPerditeIniziali!=0.1
162.                 k! = 2.34: a1! = 14.6653: n1! = 0.45596: A2! = 2641902: L! = 3300: HmaxL! = 1981: HminL! = 1062: s1! = 41.5: CNII! = 70: CoeffPerditeIniziali! = 0.1
163.                 'pialong:
164.                 'k! = 2.34:'a1! = 17.097811:'n1! = 0.497753:'A2! = 2509318:'L! = 2919:'HmaxL! = 1654:'HminL! = 388:'s1! = 0.663:'CNII! = 66:CoeffPerditeIniziali!=0.1
165.                 GOSUB TrovaT
166.                 debug% = 1
167.                 RETURN
168.             END IF
169.             IF LEN(inputs$(richiesta%)) = 0 THEN
170.                 IF KeyPress$ = CHR$(13) THEN inputs$(richiesta%) = "1"
171.             END IF
172.             test%(richiesta%) = 1
173.         CASE 2, 4, 5, 6, 7
174.             test%(richiesta%) = 1
175.         CASE 3
176.             IF VAL(inputs$(richiesta%)) <= 1 THEN
177.                 test%(richiesta%) = 1
178.             ELSE
179.                 test%(richiesta%) = 0
180.             END IF
181.         CASE 8, 9
182.             IF VAL(inputs$(richiesta%)) >= 1 THEN
183.                 IF VAL(inputs$(richiesta%)) <= 100 THEN test%(richiesta%) = 1
184.             ELSEIF inputs$(richiesta%) = "" THEN test%(richiesta%) = 1
185.             ELSE
186.                 test%(richiesta%) = 0
187.             END IF
188.         CASE IS = 10
189.             IF LEN(inputs$(richiesta%)) = 0 THEN
190.                 IF KeyPress$ = CHR$(13) THEN inputs$(richiesta%) = "0.1"
191.                 test%(richiesta%) = 1
192.             ELSE
193.                 IF VAL(inputs$(richiesta%)) >= 0 THEN
194.                     IF VAL(inputs$(richiesta%)) <= 0.2 THEN test%(richiesta%) = 1
195.                 ELSE
196.                     test%(richiesta%) = 0
197.                 END IF
198.             END IF
199.     END SELECT
200.     '-----------------------------------------------------------------------------------------------------------------------------------------------------------
201.     TrovaT:
202.     i% = 1
203.     '[...]
204.     RETURN
205. END SUB
206. '-----------------------------------------------------------------------------------------------------------------------------------------------------------
207.  

I have implemented also the blinking cursor. But all of that is a very complecated stuff, in oder to do things likes these:
- transforms "," in "."
- not allow double "."
- not go DOWN if down the field is empty
- automatic cancel not allowed data
- etc

to do that, more then 200 lines of code!

[SMcNeill]

Here's a little something which I tossed together in about 20 minutes this afternoon, which you might be able to use:

Code: QB64: [Select]

1. Screen _NewImage(1280, 720, 32)
2. Dim As String prompt(3), results(3)
3. prompt(0) = "Name": prompt(1) = "Age": prompt(2) = "Sex": prompt(3) = "Phone Number"
4. For i = 1 To 100 'Draw some stuff on the screen for a background
5.     Line (Rnd * 1280, Rnd * 720)-(Rnd * 1280, Rnd * 720), _RGB32(Rnd * 255, Rnd * 255, Rnd * 255), BF
6. Next
7. Print "SLEEPING SO YOU CAN SEE OUR BACKGROUND"
8. Sleep
9. MultiInput 100, 100, prompt(), results(), 20
10. Print: Print "As you can see, when finished, our pop up restored our background..."
11. Print "And your answers were the following:"
12. For i = 0 To UBound(results): Print results(i): Next
13. Sub MultiInput (xPos, yPos, prompt() As String, results() As String, maxLength As Integer)
14.     backupImage = _CopyImage(0) 'copy our screen
15.     B = _Blend: _DontBlend: A = _AutoDisplay: u = UBound(prompt)
16.     For i = 0 To u 'get box size
17.         p = _PrintWidth(prompt(i)): If p > maxWidth Then maxWidth = p
18.     Next
19.     boxWidth = maxWidth + maxLength * _FontWidth + 10: boxheight = (u + 1) * (_FontHeight + 3)
20.     Do
21.         If Timer > t# + .5 Then blink = Not blink: t# = Timer
22.         k = _KeyHit 'get input
23.         Select Case k
24.             Case 18432: selection = selection - 1: If selection < 0 Then selection = u 'up
25.             Case 20480, 13: selection = selection + 1: If selection > u Then selection = 0 'down
26.             Case 27: Exit Do 'esc is the exit/finish code
27.             Case 8: results(selection) = Left$(results(selection), Len(results(selection)) - 1) 'backspace
28.             Case 32 TO 255: results(selection) = results(selection) + Chr$(k) 'all else
29.         End Select
30.  
31.         _PutImage , backupImage 'restore background
32.         Line (xPos, yPos)-Step(boxWidth, boxheight), 0, BF: Line (x + xPos + maxWidth + 1, y + yPos)-Step(0, boxheight), -1 'draw box
33.         For i = 0 To u
34.             Line (x + xPos, y + i * (_FontHeight + 3) + yPos)-Step(boxWidth, _FontHeight + 3), -1, B
35.             _PrintString (x + xPos + 2, y + i * (_FontHeight + 3) + yPos + 2), prompt(i)
36.             If i = selection And blink Then out$ = results(i) + Chr$(219) Else out$ = results(i)
37.             _PrintString (x + xPos + maxWidth + 3, y + i * (_FontHeight + 3) + yPos + 2), out$
38.         Next
39.         _Limit 30: _Display
40.     Loop
41.     _PutImage , backupImage
42.     If B Then _Blend
43.     If A Then _AutoDisplay
44.     _FreeImage backupImage
45. End Sub

45 lines total, and  only 33 lines for our SUB, which does all the real work for us.

And what's this do, you ask?

It creates a simple, stand-alone, multi-line, POP-UP input box which we can use the arrow keys to move up and down between. 

Usage is rather simple:
1) Dim 2 arrays to hold your prompts and the results.
2) Set your prompts.
3) Call the function, get the results.

Can't be much simpler than that!