Blackjack

[bplus]

Simple game without card images and doesn't bother with suits. X is Roman for 10 when looking at the hands. Dealer wins all ties, except Blackjack for Player immediately pays double the bet.

Code: QB64: [Select]

1. OPTION _EXPLICIT ' No suits shown for cards A is Ace, J, Q, K are Jack, Queen, King, X is for 10
2. DEFINT A-Z '       Player's Blackjack pays double the bet set at the beginning of the game
3. RANDOMIZE TIMER
4.  
5. _TITLE "Blackjack Best B+ mod" ' started 2019-06-06
6.  
7. CONST rank$ = "A23456789XJQK"
8. CONST player = 1
9. CONST dealer = 2
10.  
11. TYPE playerType
12.     ID AS STRING
13.     Hand AS STRING
14.     Ace AS INTEGER
15.     Total AS INTEGER
16. END TYPE
17. DIM SHARED deck$(1 TO 52), players(1 TO 2) AS playerType, deckIndex
18.  
19. DIM i, r, card$, chips, bet, setbet
20. players(player).ID = "Player"
21. players(dealer).ID = "Dealer"
22. FOR i = 1 TO 52
23.     deck$(i) = MID$(rank$ + rank$ + rank$ + rank$, i, 1)
24. NEXT
25. chips = 100
26. cp 8, "For this Blackjack Game, you start with 100 chips"
27. cp 9, "and can bet any amount of them for each game."
28. cp 10, "If you'd like to set your bet for each game now"
29. cp 11, "enter that amount otherwise enter 0 "
30. LOCATE 12, 38: INPUT ""; setbet
31. DO
32.     IF setbet = 0 THEN
33.         CLS
34.         cp 10, "You have" + STR$(chips) + " chips to bet."
35.         LOCATE 11, 25: INPUT "(0 quits) Enter your bet > ", bet
36.         IF bet = 0 THEN EXIT DO
37.         IF bet > chips THEN bet = chips
38.     ELSE
39.         bet = setbet
40.     END IF
41.     clearPlayers 'clears screen too
42.     cp 4, "BLACKJACK    chips:" + STR$(chips) + "   betting:" + STR$(bet) + " chips."
43.     FOR i = 52 TO 2 STEP -1 'shuffle
44.         r = INT(RND * i) + 1
45.         SWAP deck$(r), deck$(i)
46.     NEXT
47.     deckIndex = 0
48.     FOR i = 1 TO 2 'each Player is dealt 2 cards
49.         PlayerAddCard player
50.         PlayerAddCard dealer
51.     NEXT
52.     cp 7, players(dealer).ID + " ? " + MID$(players(dealer).Hand, 2, 1)
53.     cp 10, playerShow$(player)
54.     IF players(player).Total = 21 THEN
55.         chips = chips + 2 * bet
56.         cp 11, "BlackJack! You added" + STR$(2 * bet) + " to your chips."
57.         _DELAY 2
58.         GOTO BJskip
59.     END IF
60.     WHILE players(player).Total < 21
61.         cp 11, "Press h for Hit, any other to stay..."
62.         card$ = INKEY$
63.         WHILE LEN(card$) = 0: card$ = INKEY$: _LIMIT 60: WEND
64.         IF card$ = "h" THEN
65.             PlayerAddCard player
66.             cp 11, SPACE$(50)
67.             cp 10, playerShow$(player)
68.         ELSE
69.             cp 11, SPACE$(50)
70.             EXIT WHILE
71.         END IF
72.     WEND
73.     cp 7, playerShow$(dealer)
74.     _DELAY 1
75.     WHILE players(player).Total < 22 AND (players(dealer).Total < 21 AND players(dealer).Total < players(player).Total)
76.         cp 8, "Dealer takes a card."
77.         _DELAY 1
78.         PlayerAddCard dealer
79.         cp 7, playerShow$(dealer)
80.         cp 8, SPACE$(50)
81.         _DELAY 2
82.     WEND
83.     IF players(player).Total > 21 OR (players(player).Total <= players(dealer).Total AND players(dealer).Total < 22) THEN
84.         cp 13, "You lose."
85.         chips = chips - bet
86.     ELSE
87.         cp 13, "You win!"
88.         chips = chips + bet
89.     END IF
90.     BJskip:
91.     IF chips = 0 THEN cp 15, "Out of chips!"
92.     _DELAY 4
93. LOOP UNTIL chips = 0
94. cp 17, "Goodbye"
95.  
96. SUB clearPlayers
97.     DIM i
98.     CLS
99.     FOR i = 1 TO 2
100.         players(i).Hand = ""
101.         players(i).Ace = 0
102.         players(i).Total = 0
103.     NEXT
104. END SUB
105.  
106. SUB PlayerAddCard (receiver)
107.     DIM i AS INTEGER, cv AS INTEGER
108.     deckIndex = deckIndex + 1
109.     players(receiver).Hand = players(receiver).Hand + deck$(deckIndex)
110.     IF deck$(deckIndex) = "A" THEN players(receiver).Ace = -1
111.     players(receiver).Total = 0
112.     FOR i = 1 TO LEN(players(receiver).Hand)
113.         IF INSTR(rank, MID$(players(receiver).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank, MID$(players(receiver).Hand, i, 1))
114.         players(receiver).Total = players(receiver).Total + cv
115.     NEXT
116.     IF players(receiver).Total < 12 AND players(receiver).Ace THEN players(receiver).Total = players(receiver).Total + 10
117. END SUB
118.  
119. FUNCTION playerShow$ (shower)
120.     DIM i AS INTEGER, S$
121.     S$ = players(shower).ID + " "
122.     FOR i = 1 TO LEN(players(shower).Hand)
123.         S$ = S$ + MID$(players(shower).Hand, i, 1) + " "
124.     NEXT
125.     S$ = S$ + "Total =" + STR$(players(shower).Total)
126.     IF players(shower).Total > 21 THEN S$ = S$ + " Busted!"
127.     playerShow$ = S$
128. END FUNCTION
129.  
130. SUB cp (row, s AS STRING)
131.     LOCATE row, (80 - LEN(s)) / 2: PRINT s
132. END SUB
133.  

I am thinking of setting up a number of dummy players so Dealer wouldn't be looking to beat any one player in particular, ie it would have to stay more often than it does here, playing one-on-one.

[johnno56]

Cut and paste into IDE. Run... Then this....

[bplus]

Hi Johnno,

Yeah time to update to QB64 v1.3 where Type allows variable length strings. :)

This version of Blackjack will save you bundles of money lost at casinos. ;D

Besides, you might have card images and noises for a real app. ;-))

[johnno56]

Well spotted. I indeed was 'still' using version 1.2. New version installed. No more error. Many thanks.

J

ps: Your 'dealer' cleaned me out!! :(

[bplus]

Well spotted. I indeed was 'still' using version 1.2. New version installed. No more error. Many thanks.

J

ps: Your 'dealer' cleaned me out!! :(

Yeah! That's why I need to add more dummy players, so it has to "stay" more conservative, instead of drawing cards until it matches or beats or busts the only player it goes against.

[Pete]

One on my first programs after I graduated colors was Black Jack, played Las Vegas style, out of a shoe. Instead of a two player game, I made it an analysis program, to test different well documented playing strategies. I can credit that project with keeping out of casinos. In order to win anything of any significance, you have to make large bets, and play all day. You also literally cannot afford to make mistakes. You risk being banned for card counting if you actually do well, and, as one interesting book I read stated, "If you think people who built these casinos on drug money and prostitution wouldn't cheat you are cards, there is no helping you." All the casino has to do is take out a ace, pop in a couple of extra 5's or 2's, and you're totally screwed, no matter how well you play the system. I wish I could credit that program to QBasic, but at that time, I was using an Atari.

Pete

[bplus]

Hi Pete,

You know, adding aces to the deck might make my little Blackjack game more interesting and be another way to overcome the dealer's advantage of winning ties. I would have to change the neat way to total a hand and create the deck but I am no longer interested in minimum lines of code.


Preliminary plans with dummy players:
The shoe in my game is only 1 deck and is shuffled before each round. I like the simplicity of that.

So I think 3 dummies plus me and dealer is ideal, just enough cards used that card counting might work, if you want to try a hand at that. Let the 3 dummies go first get a feel of cards played.

So far my dummy players have a choice of playing a set bet amount all the time or altering the bet. But what conditions could possible be used to alter the bet intelligently?

As I have been coding the game, all the betting occurs before any cards are shown. I know in real games after 2 cards dealt (dealer shows 1 face up), you can double down or split or buy insurance... however that goes, that too might make game more enjoyable against dealer and house rules.

Main rule at casinos: The Odds must be in favor of the house! Which is no fun!

My main rule: Have fun playing (and coding). Which means a probable chance of payoff for diligence and skill employed.

Well I guess I am just thinking out loud here... coding rarely ever goes as I had thought in preliminary plans.
But the aces idea with dummy players seem a good experiment.

[bplus]

12 Aces and 4 bots including the dealer:

Code: QB64: [Select]

1. OPTION _EXPLICIT '     No suits for cards A is Ace, J, Q, K are Jack, Queen, King, X is Roman for 10
2. DEFINT A-Z '              Dealer wins all ties except a Player's Blackjack which pays double the bet
3. RANDOMIZE TIMER '
4. _TITLE "Blackjack with Bots" ' started 2019-06-07 Players 1 through 3 are bots you play bottom right
5.  
6. TYPE XY 'graphic or cell location on screen or in array
7.     X AS INTEGER
8.     Y AS INTEGER
9. END TYPE
10.  
11. TYPE Box
12.     TopLeft AS XY
13.     W AS INTEGER
14.     H AS INTEGER
15.     BC AS _UNSIGNED LONG
16.     FC AS _UNSIGNED LONG
17. END TYPE
18.  
19. TYPE PlayerType 'a container for all program data!
20.     Win AS Box 'for screening the players data
21.     ID AS STRING
22.     Chips AS INTEGER
23.     SetBet AS INTEGER
24.     Bet AS INTEGER
25.     Hand AS STRING
26.     Ace AS INTEGER
27.     Total AS INTEGER
28.     Blackjack AS INTEGER
29. END TYPE
30.  
31. CONST xmax = 640
32. CONST ymax = 432
33. CONST nPlayers = 5 '       the 5th is the Dealer, the 4th is You and 1 - 3 are the bots who go first
34. CONST You = 4
35. CONST Dealer = 5
36. CONST dk = "A2345A6789AXJQKA2345A6789AXJQKA2345A6789AXJQKA2345A6789AXJQK"
37. CONST white = &HFFFDDFDD
38. CONST black = &HFF000000
39. CONST green = &HFF004515
40. CONST orange = &HFFFF3300
41. CONST brown = &HFF3C1D06
42. CONST cyan = &HFF3774C0
43. CONST ltCyan = &HFF99BBFF
44. CONST drkRed = &HFF220102
45. CONST mRed = &HFF7F0000
46. CONST yellow = &HFFFFFF00
47. CONST blue = &HFF00008D
48.  
49. DIM SHARED deck$(1 TO LEN(dk)), player(1 TO nPlayers) AS PlayerType, deckIndex
50. DIM i, j, r, in, is$, stillPlayer
51. SCREEN _NEWIMAGE(xmax, ymax, 32)
52. COLOR yellow, green
53. FOR i = 1 TO LEN(dk)
54.     deck$(i) = MID$(dk, i, 1)
55. NEXT
56. initPlayers
57. DO
58.     clearPlayers 'clears screen too                                                    start a round
59.     stillPlayer = 0 ' to check at end of round if there is still a player playing
60.  
61.     IF player(3).Chips > 0 THEN '                                                        handle bets
62.         player(3).Bet = INT(player(3).Chips / 2 + .5)
63.     END IF
64.     IF player(You).Chips > 0 THEN
65.         IF player(You).SetBet = 0 THEN
66.             CLS
67.             cp 0, 10, "You have" + STR$(player(4).Chips) + " chips to bet."
68.             LOCATE 11, 25: INPUT "Enter your bet > ", in
69.             IF in = 0 THEN EXIT DO
70.             IF in > player(You).Chips THEN player(You).Bet = player(You).Chips ELSE player(You).Bet = in
71.             CLS
72.         ELSE
73.             player(You).Bet = player(You).SetBet
74.         END IF
75.     END IF
76.     FOR i = 1 TO 4 'make sure everyone is not betting more than amount of chips they have
77.         IF player(i).Bet > player(i).Chips THEN player(i).Bet = player(i).Chips
78.     NEXT
79.  
80.     FOR i = LEN(dk) TO 2 STEP -1 '                                                                shuffle
81.         r = INT(RND * i) + 1
82.         SWAP deck$(r), deck$(i)
83.     NEXT
84.     deckIndex = 0
85.  
86.     FOR j = 1 TO 2 '                                 everybody gets 2 cards if they still have chips
87.         FOR i = 1 TO nPlayers 'each Player is dealt 2 cards
88.             IF ((player(i).Chips > 0) AND (i <> Dealer)) OR (i = Dealer) THEN
89.                 addCard i
90.                 showPlayer i
91.                 IF i = Dealer THEN
92.                     cp Dealer, 7, SPACE$(18)
93.                     cp Dealer, 8, SPACE$(18)
94.                     IF j = 1 THEN
95.                         cp Dealer, 7, "? "
96.                         cp Dealer, 8, "Total: ?"
97.                     ELSE
98.                         cp Dealer, 7, SPACE$(18)
99.                         cp Dealer, 7, "Hand: ? " + MID$(player(Dealer).Hand, 2, 1)
100.                         cp Dealer, 8, "Total: ?"
101.                     END IF
102.                 END IF
103.                 _DELAY 1
104.                 IF i <> Dealer AND j = 2 AND player(i).Total = 21 THEN
105.                     cp i, 9, "Blackjack!"
106.                     player(i).Blackjack = -1
107.                     _DELAY 1
108.                 END IF
109.             ELSE
110.                 clsPlayer i
111.             END IF
112.         NEXT
113.     NEXT
114.  
115.     FOR i = 1 TO nPlayers - 1 '                    OK now handle the players until they stay or bust
116.         IF player(i).Chips > 0 THEN
117.             WHILE player(i).Total < 21
118.                 IF i = You THEN
119.                     cp i, 11, "<h>it <s>tay"
120.                     is$ = INKEY$
121.                     WHILE LEN(is$) = 0: is$ = INKEY$: _LIMIT 60: WEND
122.                     IF is$ = "h" THEN
123.                         addCard You
124.                         cp i, 11, SPACE$(18)
125.                         showPlayer i
126.                     ELSE
127.                         cp i, 11, SPACE$(18)
128.                         EXIT WHILE
129.                     END IF
130.                 ELSE
131.                     IF player(i).Total < 16 THEN '                               bots to hit on < 16
132.                         cp i, 11, "Hit me."
133.                         _DELAY 1
134.                         addCard i
135.                         showPlayer i
136.                         _DELAY 2
137.                     ELSE
138.                         EXIT WHILE 'stay
139.                     END IF
140.                 END IF
141.             WEND
142.         END IF
143.     NEXT
144.  
145.     showPlayer Dealer '                                                                dealer's turn
146.     _DELAY 1
147.     WHILE player(Dealer).Total < 17
148.         cp Dealer, 10, "(Takes a card)"
149.         _DELAY 1
150.         addCard Dealer
151.         showPlayer Dealer
152.         cp Dealer, 10, SPACE$(18)
153.         _DELAY 2
154.     WEND
155.  
156.     FOR i = 1 TO nPlayers - 1 '                                   name the winners and losers, payup
157.         IF player(i).Chips > 0 THEN
158.             IF player(i).Blackjack = 0 THEN
159.                 IF player(i).Total > 21 OR (player(i).Total <= player(Dealer).Total AND player(Dealer).Total < 22) THEN
160.                     cp i, 11, player(i).ID + " lost."
161.                     player(i).Chips = player(i).Chips - player(i).Bet
162.                     player(Dealer).Chips = player(Dealer).Chips + player(i).Bet
163.                 ELSE
164.                     cp i, 11, player(i).ID + " won!"
165.                     player(i).Chips = player(i).Chips + player(i).Bet
166.                     player(Dealer).Chips = player(Dealer).Chips - player(i).Bet
167.                 END IF
168.             ELSE
169.                 cp i, 11, player(i).ID + " won!"
170.                 player(i).Chips = player(i).Chips + 2 * player(i).Bet
171.                 player(Dealer).Chips = player(Dealer).Chips - 2 * player(i).Bet
172.             END IF
173.             IF player(i).Chips = 0 THEN cp i, 12, "Out of chips!" ELSE stillPlayer = -1
174.         END IF
175.         _DELAY .5
176.     NEXT
177.     _DELAY 3
178. LOOP UNTIL stillPlayer = 0
179. cp 0, 12, "Goodbye"
180.  
181. SUB clearPlayers 'clear player data for new game
182.     DIM i
183.     CLS
184.     FOR i = 1 TO nPlayers
185.         player(i).Hand = ""
186.         player(i).Ace = 0
187.         player(i).Total = 0
188.         player(i).Blackjack = 0
189.     NEXT
190. END SUB
191.  
192. SUB addCard (nPlayer) 'add a card to reciever's hand and retotal points according to aces present
193.     DIM i AS INTEGER
194.     deckIndex = deckIndex + 1
195.     player(nPlayer).Hand = player(nPlayer).Hand + deck$(deckIndex)
196.     IF deck$(deckIndex) = "A" THEN player(nPlayer).Ace = -1
197.     player(nPlayer).Total = 0
198.     FOR i = 1 TO LEN(player(nPlayer).Hand)
199.         'IF INSTR(rank, MID$(player(nPlayer).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank, MID$(player(nPlayer).Hand, i, 1))
200.         player(nPlayer).Total = player(nPlayer).Total + CardValue(MID$(player(nPlayer).Hand, i, 1))
201.     NEXT
202.     IF player(nPlayer).Total < 12 AND player(nPlayer).Ace THEN player(nPlayer).Total = player(nPlayer).Total + 10
203. END SUB
204.  
205. SUB showPlayer (nPlayer)
206.     DIM i AS INTEGER, S$
207.     clsPlayer nPlayer
208.     cp nPlayer, 1, player(nPlayer).ID
209.     cp nPlayer, 3, "Chips:" + STR$(player(nPlayer).Chips)
210.     IF nPlayer <> Dealer THEN
211.         cp nPlayer, 4, "Bet:" + STR$(player(nPlayer).Bet)
212.     END IF
213.     FOR i = 1 TO LEN(player(nPlayer).Hand) 'with 12 aces could get very long hands
214.         IF LEN(player(nPlayer).Hand) * 2 < player(nPlayer).Win.W THEN
215.             S$ = S$ + MID$(player(nPlayer).Hand, i, 1) + " "
216.         ELSE
217.             S$ = S$ + MID$(player(nPlayer).Hand, i, 1)
218.         END IF
219.     NEXT
220.     cp nPlayer, 6, "___Hand___"
221.     cp nPlayer, 7, S$
222.     cp nPlayer, 8, "Total:" + STR$(player(nPlayer).Total)
223.     IF player(nPlayer).Total > 21 THEN
224.         cp nPlayer, 9, "Busted!"
225.     END IF
226. END FUNCTION
227.  
228. SUB clsPlayer (nPlayer)
229.     DIM i, lastR
230.     COLOR player(nPlayer).Win.FC, player(nPlayer).Win.BC
231.     IF nPlayer = Dealer THEN
232.         lastR = player(nPlayer).Win.TopLeft.Y + player(nPlayer).Win.H - 1
233.     ELSE
234.         lastR = player(nPlayer).Win.TopLeft.Y + player(nPlayer).Win.H
235.     END IF
236.     FOR i = player(nPlayer).Win.TopLeft.Y TO lastR
237.         LOCATE i, player(nPlayer).Win.TopLeft.X: PRINT SPACE$(player(nPlayer).Win.W);
238.     NEXT
239.     COLOR yellow, green
240. END SUB
241.  
242. SUB cp (nPlayer, row, s AS STRING) 'center print a string on the given row
243.     IF nPlayer THEN
244.         COLOR player(nPlayer).Win.FC, player(nPlayer).Win.BC
245.         LOCATE player(nPlayer).Win.TopLeft.Y + row, player(nPlayer).Win.TopLeft.X + (player(nPlayer).Win.W - LEN(s)) / 2: PRINT s;
246.         COLOR yellow, green
247.     ELSE
248.         COLOR yellow, green
249.         LOCATE row, (80 - LEN(s)) / 2: PRINT s;
250.     END IF
251. END SUB
252.  
253. SUB initPlayers 'the stuff that never changes
254.     DIM i, widt, height
255.  
256.     'for printing in each players window area of screen = blackjack table
257.     widt = _WIDTH / (4 * 8)
258.     height = _HEIGHT / (2 * 16)
259.     FOR i = 1 TO nPlayers - 1
260.         player(i).Win.TopLeft.X = widt * (i - 1) + 2
261.         player(i).Win.TopLeft.Y = height - 1
262.         player(i).Win.W = widt - 2
263.         player(i).Win.H = height - 1
264.         player(i).Chips = 100
265.     NEXT
266.     player(Dealer).Win.TopLeft.X = (_WIDTH / 8 - widt) / 2 + 1
267.     player(Dealer).Win.TopLeft.Y = 1
268.     player(Dealer).Win.W = widt
269.     player(Dealer).Win.H = height - 2
270.     player(Dealer).Chips = -400 'the dealer has "lent" 100 chips to each player
271.  
272.     player(1).Win.FC = brown: player(1).Win.BC = orange: player(1).ID = "Pete": player(1).SetBet = 5: player(1).Bet = 5
273.     player(2).Win.FC = drkRed: player(2).Win.BC = cyan: player(2).ID = "Qwerkey": player(2).SetBet = 15: player(2).Bet = 15
274.     player(3).Win.FC = white: player(3).Win.BC = mRed: player(3).ID = "Johnno": player(3).SetBet = 0
275.     player(4).Win.FC = ltCyan: player(4).Win.BC = blue: player(4).ID = "You"
276.     player(5).Win.FC = yellow: player(5).Win.BC = green: player(5).ID = "Dealer"
277.  
278.     'ask the user / YOU what e prefers for betting
279.     CLS
280.     cp 0, 8, "For this Blackjack Game, you start with 100 chips"
281.     cp 0, 9, "and can bet any amount of them for each game."
282.     cp 0, 10, "If you'd like to set your bet for each game now"
283.     cp 0, 11, "enter that amount otherwise enter 0 and get asked"
284.     cp 0, 12, "before each round at the table."
285.     LOCATE 13, 38: INPUT ""; i
286.     IF i < 0 THEN i = 0 'lets not do allot of checking and reasking
287.     IF i > 100 THEN i = 100
288.     player(You).SetBet = i
289. END SUB
290.  
291. FUNCTION CardValue (s$)
292.     IF s$ = "A" THEN
293.         CardValue = 1
294.     ELSEIF INSTR("23456789", s$) > 0 THEN
295.         CardValue = VAL(s$)
296.     ELSEIF INSTR("XJQK", s$) > 0 THEN
297.         CardValue = 10
298.     END IF
299. END FUNCTION
300.  

[QBExile]

Very nice program!
One spelling error i encountered is "You loose." should be "You lose."

[bplus]

Very nice program!
One spelling error i encountered is "You loose." should be "You lose."

Oh, 'loose" was in first program... OK fixed, Thanks

A couple of things I like in second program is using Types within Types that creates a window for each player, and a perfect accounting system: Dealer's Total Chips + all the Player's Chips = 0 (and the Player's chips are always positive or 0).

[bplus]

Thanks to [banned user] and his deck image png file, I have more visual representation of cards.

I also eased up on the House Rules st the Dealer only draws until the total > 16 PLUS this game allows more ties eg when both players bust or match totals.

Code: QB64: [Select]

1. OPTION _EXPLICIT ' Easier House Rules: Dealer must draw if card total < 17.
2. DEFINT A-Z '       Player's Blackjack pays double the bet set at the beginning of the game.
3. RANDOMIZE TIMER '  If both Dealer and Player match totals or bust, it is a tie.
4. _TITLE "BJ 1on1 wImages" ' started 2019-06-09 B+ thanks to [banned user] Card Image file.
5. CONST xmax = 800, ymax = 640 '40 lines
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 300, 20
8.  
9. TYPE CardType
10.     ID AS INTEGER
11.     cname AS STRING
12.     value AS INTEGER '1 to 13
13.     suit AS INTEGER
14.     points AS INTEGER '1 to 10
15. END TYPE
16.  
17. TYPE PlayerType
18.     ID AS STRING
19.     hand AS STRING
20.     cardY AS INTEGER
21.     Ace AS INTEGER
22.     Total AS INTEGER
23. END TYPE
24.  
25. CONST player = 1
26. CONST dealer = 2
27.  
28. DIM SHARED Deck(1 TO 52) AS CardType, Players(1 TO 2) AS PlayerType, deckIndex
29. DIM SHARED CardDeck AS LONG, round
30. Players(player).ID = "Player": Players(player).cardY = 420
31. Players(dealer).ID = "Dealer": Players(dealer).cardY = 100
32. DIM SHARED bet, chips
33. DIM i, card$, setbet, loaded
34.  
35. loaded = loadCardImages
36. IF loaded = 0 THEN PRINT "PlayingCards.png failed to load, bye!": END
37.  
38. initDeck
39.  
40. chips = 100
41. cp 8, "For this Blackjack Game, you start with 100 chips"
42. cp 9, "and can bet any amount of them for each game."
43. cp 10, "If you'd like to set your bet for each game now"
44. cp 11, "enter that amount otherwise enter 0 "
45. cp 12, ""
46. INPUT ""; setbet
47. DO
48.     IF setbet = 0 THEN
49.         CLS
50.         cp 10, "You have" + STR$(chips) + " chips to bet."
51.         LOCATE 11, 25: INPUT "(0 quits) Enter your bet > ", bet
52.         IF bet = 0 THEN EXIT DO
53.         IF bet > chips THEN bet = chips
54.     ELSE
55.         bet = setbet
56.     END IF
57.     clearPlayers 'clears screen too
58.     shuffle
59.     deckIndex = 0
60.     FOR i = 1 TO 2 'each Player is dealt 2 cards
61.         PlayerAddCard player
62.         PlayerAddCard dealer
63.         round = round + 1
64.     NEXT
65.     'cp 7, Players(dealer).ID + " ? " + MID$(Players(dealer).hand, 2, 1)
66.     playerShow dealer
67.     playerShow player
68.     IF Players(player).Total = 21 THEN
69.         chips = chips + 2 * bet
70.         cp 36, "BlackJack! You added" + STR$(2 * bet) + " to your chips."
71.         _DELAY 2
72.         GOTO BJskip
73.     END IF
74.     WHILE Players(player).Total < 21
75.         cp 36, "Press h for Hit, any other to stay..."
76.         card$ = INKEY$
77.         WHILE LEN(card$) = 0: card$ = INKEY$: _LIMIT 60: WEND
78.         IF card$ = "h" THEN
79.             PlayerAddCard player
80.             playerShow player
81.         ELSE
82.             cp 38, SPACE$(50)
83.             EXIT WHILE
84.         END IF
85.     WEND
86.     round = round + 1 'now round > 2 so first card won't be hidden
87.     playerShow dealer
88.     _DELAY 1
89.     WHILE Players(dealer).Total < 17
90.         cp 16, "Dealer takes a card."
91.         _DELAY 1
92.         PlayerAddCard dealer
93.         playerShow dealer
94.         _DELAY 2
95.     WEND
96.     IF (Players(player).Total > 21 AND Players(dealer).Total < 22) OR (Players(player).Total < Players(dealer).Total AND Players(dealer).Total < 22) THEN
97.         cp 38, "You lost."
98.         chips = chips - bet
99.     ELSEIF (Players(player).Total > Players(dealer).Total AND Players(player).Total < 22) OR (Players(player).Total < 22 AND Players(dealer).Total > 21) THEN
100.         cp 38, "You won!"
101.         chips = chips + bet
102.     ELSEIF (Players(player).Total = Players(dealer).Total) OR (Players(player).Total > 21 AND Players(dealer).Total > 21) THEN
103.         cp 38, "We tied..."
104.     END IF
105.     BJskip:
106.     IF chips = 0 THEN cp 40, "Out of chips!"
107.     _DELAY 4
108. LOOP UNTIL chips = 0
109. cp 5, "Goodbye"
110.  
111. SUB clearPlayers
112.     DIM i
113.     CLS
114.     FOR i = 1 TO 2
115.         Players(i).hand = ""
116.         Players(i).Ace = 0
117.         Players(i).Total = 0
118.     NEXT
119.     round = 0
120. END SUB
121.  
122. SUB PlayerAddCard (receiver)
123.     DIM i, di
124.     deckIndex = deckIndex + 1
125.     Players(receiver).hand = Players(receiver).hand + d2$(deckIndex)
126.     IF Deck(deckIndex).value = 1 THEN Players(receiver).Ace = -1
127.     Players(receiver).Total = 0
128.     FOR i = 1 TO LEN(Players(receiver).hand) STEP 2
129.         di = VAL(MID$(Players(receiver).hand, i, 2))
130.         Players(receiver).Total = Players(receiver).Total + Deck(di).points
131.     NEXT
132.     IF Players(receiver).Total < 12 AND Players(receiver).Ace THEN Players(receiver).Total = Players(receiver).Total + 10
133. END SUB
134.  
135. FUNCTION d2$ (num) 'we have to store 1 or 2 digit numbers in a string to represent hand that is buch of card indexes
136.     d2$ = LEFT$(_TRIM$(STR$(num)) + "  ", 2)
137. END FUNCTION
138.  
139. SUB playerShow (shower)
140.     DIM i, xoff, di
141.  
142.     IF shower = dealer THEN
143.         LINE (0, 0)-STEP(xmax, 319), &HFF000000, BF
144.         cp 2, "B+ BLACKJACK: If Dealer total < 16 then must hit else stays."
145.         cp 5, Players(shower).ID
146.         cp 15, "Total =" + STR$(Players(shower).Total)
147.         IF Players(shower).Total > 21 THEN cp 16, "Busted!"
148.     ELSE
149.         LINE (0, 320)-STEP(xmax, 320), &HFF000000, BF
150.         cp 25, "Chips:" + STR$(chips) + "   Betting:" + STR$(bet) + " chips."
151.         cp 23, Players(shower).ID
152.         cp 35, "Total =" + STR$(Players(shower).Total)
153.         IF Players(shower).Total > 21 THEN cp 36, "Busted!"
154.     END IF
155.     xoff = (xmax - 43 * LEN(Players(shower).hand)) / 2
156.     FOR i = 1 TO LEN(Players(shower).hand) STEP 2
157.         di = VAL(MID$(Players(shower).hand, i, 2))
158.         showCardDI xoff, Players(shower).cardY, di
159.         xoff = xoff + 86
160.     NEXT
161.     IF shower = dealer AND round <= 2 THEN 'hide first card
162.         xoff = (xmax - 43 * LEN(Players(shower).hand)) / 2
163.         ShowCard xoff, Players(dealer).cardY, 0, 4
164.         cp 15, " Total = ?? "
165.     END IF
166. END SUB
167.  
168. SUB cp (row, s AS STRING)
169.     LOCATE row, (xmax / 8 - LEN(s)) / 2: PRINT s;
170. END SUB
171.  
172. SUB initDeck
173.     DIM i, s, v
174.     DIM suit$(3)
175.     suit$(0) = "Hearts": suit$(1) = "Clubs": suit$(2) = "Diamonds": suit$(3) = "Spades"
176.     DIM v$(1 TO 13)
177.     v$(1) = "Ace": v$(11) = "Jack": v$(12) = "Queen": v$(13) = "King"
178.     FOR i = 2 TO 10
179.         v$(i) = _TRIM$(STR$(i))
180.     NEXT
181.     i = 0
182.     FOR s = 0 TO 3
183.         FOR v = 1 TO 13
184.             i = i + 1
185.             Deck(i).ID = i
186.             Deck(i).cname = v$(v) + " of " + suit$(s)
187.             Deck(i).value = v
188.             Deck(i).suit = s
189.             IF v < 11 THEN Deck(i).points = v ELSE Deck(i).points = 10
190.         NEXT
191.     NEXT
192. END SUB
193.  
194. SUB shuffle
195.     DIM i, r
196.     FOR i = 52 TO 2 STEP -1
197.         r = INT(i * RND) + 1
198.         SWAP Deck(i), Deck(r)
199.     NEXT
200. END SUB
201.  
202. SUB showCardDI (x AS INTEGER, y AS INTEGER, deckI AS INTEGER)
203.     ShowCard x, y, Deck(deckI).value - 1, Deck(deckI).suit
204. END SUB
205.  
206. 'at scale = 2 need screen space of 76 x 100 for one card
207. SUB ShowCard (ScrnX, ScrnY, imageCol, imageRow) 'screen x, y  h= horizontal  , v =vertical  image h, v
208.     DIM ch, cv, scale
209.     ch = 38 * imageCol + 1: cv = 51 * imageRow + 1: scale = 2 ' <  might want to change?
210.     _PUTIMAGE (ScrnX, ScrnY)-STEP(38 * scale, 50 * scale), CardDeck, 0, (ch, cv)-(ch + 37, cv + 50)
211. END SUB
212.  
213. FUNCTION loadCardImages%
214.     CardDeck = _LOADIMAGE("PlayingCards.png")
215.     IF CardDeck = -1 THEN EXIT FUNCTION
216.     _SOURCE CardDeck
217.     _CLEARCOLOR POINT(0, 0), CardDeck
218.     _SOURCE 0
219.     loadCardImages% = -1
220. END FUNCTION
221.  
222.  

 

[Pete]

You owe me 500 chips. I like the ones with ruffles.

Any thoughts to add a way to change the betting amount?

Pete

[bplus]

You owe me 500 chips. I like the ones with ruffles.

Any thoughts to add a way to change the betting amount?

Pete

You can bet any amount up to the amount of chips you have each round by entering 0 or just enter on very first screen.

cp 8, "For this Blackjack Game, you start with 100 chips"
cp 9, "and can bet any amount of them for each game."
cp 10, "If you'd like to set your bet for each game now"
cp 11, "enter that amount otherwise enter 0 "

I am planning more options for the player at Hit or Stay time so if you've won so much money it's burning holes in your pocket you will have option to change the SetBet amount and maybe change your room to the Penthouse Suite.

[johnno56]

Nicely done! But, not so much, the $600 your dealer took from me!!  lol

[bplus]

Nicely done! But, not so much, the $600 your dealer took from me!!  lol

See the bundle I am saving you by keeping you out of casinos! :-))