Need help with trying to draw a circle with the mouse

[robpugh0829]

Hey all,
I am stuck and can't figure something out. If any of you could help me I would appreciate it. I'm trying to draw a circle with the mouse just like MS Paint does, how it chooses location and size using the mouse, etc... I can draw a circle with the mouse, but the sizing doesn't work and it just never is right for some reason, can somebody help me please?

Thanks!

[FellippeHeitor]

Please post your current attempt.

PS: Welcome to the Forum.

[bplus]

Well this draws ellipse like Paint but I wouldn't use either for important drawings. I would use QB64 to get the center and radii exactly how I want.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _SCREENMOVE 300, 60
3. bk& = _NEWIMAGE(800, 600, 32)
4. _PUTIMAGE , 0, bk&
5. WHILE _KEYDOWN(27) = 0
6.     CLS
7.     _PUTIMAGE , bk&, 0
8.     WHILE _MOUSEINPUT: WEND
9.     mb = _MOUSEBUTTON(1)
10.     IF mb AND corner1F = 0 THEN
11.         x1 = _MOUSEX: y1 = _MOUSEY: corner1F = 1
12.         mb = 0
13.     ELSEIF mb AND corner1F = 1 THEN '2nd corner
14.         x2 = _MOUSEX: y2 = _MOUSEY
15.         IF max(x1, x2) = x1 THEN lowx = x2: hix = x1 ELSE lowx = x1: hix = x2
16.         IF max(y1, y2) = y1 THEN lowy = y2: hiy = y1 ELSE lowy = y1: hiy = y2
17.         cx = (hix + lowx) / 2: cy = (hiy + lowy) / 2
18.         xr = cx - lowx: yr = cy - lowy
19.         ellipse cx, cy, xr, yr
20.     ELSEIF mb = 0 AND corner1F = 1 THEN
21.         x2 = _MOUSEX: y2 = _MOUSEY
22.         IF max(x1, x2) = x1 THEN lowx = x2: hix = x1 ELSE lowx = x1: hix = x2
23.         IF max(y1, y2) = y1 THEN lowy = y2: hiy = y1 ELSE lowy = y1: hiy = y2
24.         cx = (hix + lowx) / 2: cy = (hiy + lowy) / 2
25.         xr = cx - lowx: yr = cy - lowy
26.         ellipse cx, cy, xr, yr
27.         IF ABS(x1 - x2) > 3 OR ABS(y1 - y2) > 3 THEN _PUTIMAGE , 0, bk&
28.         corner1F = 0
29.         x1 = 0: x2 = 0: y1 = 0: y2 = 0
30.     END IF
31.     _DISPLAY
32.     _LIMIT 60
33. WEND
34.  
35. SUB ellipse (CX AS LONG, CY AS LONG, xRadius AS LONG, yRadius AS LONG)
36.     DIM scale AS SINGLE, xs AS LONG, x AS LONG, y AS LONG
37.     DIM lastx AS LONG, lasty AS LONG
38.     scale = yRadius / xRadius: xs = xRadius * xRadius
39.     PSET (CX, CY - yRadius): PSET (CX, CY + yRadius)
40.     lastx = 0: lasty = yRadius
41.     FOR x = 1 TO xRadius
42.         y = scale * SQR(xs - x * x)
43.         LINE (CX + lastx, CY - lasty)-(CX + x, CY - y)
44.         LINE (CX + lastx, CY + lasty)-(CX + x, CY + y)
45.         LINE (CX - lastx, CY - lasty)-(CX - x, CY - y)
46.         LINE (CX - lastx, CY + lasty)-(CX - x, CY + y)
47.         lastx = x: lasty = y
48.     NEXT
49. END SUB
50.  
51. FUNCTION max (a, b)
52.     IF b > a THEN max = b ELSE max = a
53. END FUNCTION
54.  

[SMcNeill]

SCREEN _NEWIMAGE(640.480,32)
Radius = 25
DO
    _LIMIT 60
    WHILE _MOUSEINPUT: Radius = Radius + _MOUSEWHEEL:WEND
    IF _MOUSEBUTTON(1) THEN
        CIRCLE (_MOUSEX, _MOUSEY), Radius, _RGB32(255,255,255)
     END IF
LOOP UNTIL _KEYHIT = 27

**************

Done via memory, on my iPad, so may require a little tweaking to correct syntax 100%.

Use left button to draw the circle, wheel to make size larger or smaller.

[TerryRitchie]

School's back in session guys. Be careful, we might be getting homework requests. Always better to see what work has been done first and help them through their issues.  I had to watch my students like a hawk to make sure they weren't getting their work done 100% for them.

[FellippeHeitor]

School's back in session guys. Be careful, we might be getting homework requests. Always better to see what work has been done first and help them through their issues.  I had to watch my students like a hawk to make sure they weren't getting their work done 100% for them.

I *always* try to check that first.

Please post your current attempt.

PS: Welcome to the Forum.

Bplus is *always* quick to give it ready first.

[robpugh0829]

screen 12
do
   do while _MOUSEINPUT
      x = _mousex
      y = _mousey
      locate 1,1
      print x, y
      
      if _mousebutton(1) then
         circle(x,y),x + y / 2
      end if
   loop
loop

[robpugh0829]

Thanks for all the answers, I will work through this. I'm coming back to QB after a long time doing other things such as Web Development with PHP and other languages. Sorry I didn't post my code first, I will remember that for next time. I'm too old to be getting my homework done ;-).

Thanks again guys!

[SMcNeill]

Two main issues I see here:

1) You're running inside the mouse loop, which can cause excessive program lag.  Your OS can poll the mouse thousands of times a second; PRINT generally won't keep up with it, and you'll get a bottleneck of events where it'll take the program several long seconds to catch up to mouse events even after you've quit interacting with it.

I'd suggest the following style changes:

DO WHILE _MOUSEINPUT: LOOP
X = _MOUSEX
Y = _MOUSEY
LOCATE 1,1
PRINT X, Y

2) The radius on your circle is inconsistent.  At the top left of the screen (X = 0, Y = 0), you're going to have a zero radius circle.  At the bottom of the screen, the radius is going to be larger than your whole screen, drawing off the map completely.  I'd suggest a fixed size radius, alterable by some other means.  (+/- keys for example to increase/decrease circle size).

[robpugh0829]

SMcNeill,
Thanks! I was going to take the print away, I was just using that as a reference for where the pointer was at. I also do that when I'm building something with buttons and I need to know where the cursor is at to set the button press parameters in my if statement. I will also try what you said with the radius, that makes sense. Thanks a million!

Have a great day!

[bplus]

This didn't look like a homework assignment.

It is fun challenge to be first, hard to beat "Ninja fingers".

Steve there is typo in code you posted and IDE points not to cause of problem.

robpugh0829, your code didn't look like it came from QB64 IDE? What are you running from?

Try this: click down at your circle center, then drag out your radius, when just right, release mouse button and it becomes part of the permanent record.

Extra Bonus: Undo up to last 10 circles.

[SMcNeill]

This didn't look like a homework assignment.

It is fun challenge to be first, hard to beat "Ninja fingers".

Steve there is typo in code you posted and IDE points not to cause of problem.

robpugh0829, your code didn't look like it came from QB64 IDE? What are you running from?

Try this: click down at your circle center, then drag out your radius, when just right, release mouse button and it becomes part of the permanent record.

Extra Bonus: Undo up to last 10 circles.

SCREEN _NEWIMAGE(640.480,32)

It's the period there, instead of a comma.  Oddly enough, it still runs and compiles just fine for me -- though the screensize is so large it runs completely off my monitor!  I guess it's making a 640x32 SCREEN 0 screen?

Just change that period to a comma and all is good.   ;)

[bplus]

;-)) runs fine until you click the mouse!

[FellippeHeitor]

This didn't look like a homework assignment.

It is fun challenge to be first, hard to beat "Ninja fingers".

Not sure if naive or playing naive.

Better pay closer attention either way. Someone fishing for ninja fingers is someone who's likely being forced to go through a language course he/she hates and is not giving a shit about your skills. You'd be helping a cheater. Not encouraged.

Luckily it doesn't seem like it was robpug's case.

Here's my ninja code I had written last night after the initial post in this thread (my github repository "Snippets" as proof of time). I didn't post it immediately trying to figure OP's good intentions first.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2.  
3. TYPE circles
4.     x AS SINGLE
5.     y AS SINGLE
6.     radius AS SINGLE
7.     ratio AS SINGLE
8.     color AS _UNSIGNED LONG
9. END TYPE
10.  
11. DIM circles(1 TO 1000) AS circles
12.  
13. _TITLE "Circle drawing"
14. RANDOMIZE TIMER
15.  
16. DO
17.     WHILE _MOUSEINPUT: WEND
18.  
19.     IF _MOUSEBUTTON(1) THEN
20.         IF NOT mouseDown THEN
21.             mouseDown = -1
22.             totalCircles = totalCircles + 1
23.             IF totalCircles > 1000 THEN totalCircles = 1
24.             mx1 = _MOUSEX
25.             my1 = _MOUSEY
26.             mx2 = mx1
27.             my2 = my1
28.             circles(totalCircles).color = _RGB32(RND * 255, RND * 255, RND * 255)
29.         ELSE
30.             mx2 = _MOUSEX
31.             my2 = _MOUSEY
32.         END IF
33.     ELSE
34.         mouseDown = false
35.     END IF
36.  
37.     CLS
38.  
39.     IF mouseDown THEN
40.         x1 = mx1
41.         x2 = mx2
42.         IF x1 > x2 THEN SWAP x1, x2
43.  
44.         y1 = my1
45.         y2 = my2
46.         IF y1 > y2 THEN SWAP y1, y2
47.  
48.         circles(totalCircles).x = x1 + (x2 - x1) / 2
49.         circles(totalCircles).y = y1 + (y2 - y1) / 2
50.         IF (x2 - x1) > (y2 - y1) THEN
51.             circles(totalCircles).radius = (x2 - x1) / 2
52.         ELSE
53.             circles(totalCircles).radius = (y2 - y1) / 2
54.         END IF
55.         circles(totalCircles).ratio = (y2 - y1) / (x2 - x1)
56.     END IF
57.  
58.     FOR i = 1 TO totalCircles
59.         CIRCLE (circles(i).x, circles(i).y), circles(i).radius, circles(i).color, , , circles(i).ratio
60.     NEXT
61.  
62.     _DISPLAY
63.     _LIMIT 60
64. LOOP

[robpugh0829]

BPlus,
I'm using Dav's IDE.

Everybody,
Thanks again for all the help and answers!