Need help with trying to draw a circle with the mouse

[bplus]

As usual, everyone is done as B+ just getting warmed up. ;-))

Here is perfect circle drawing I was talking about PLUS unlimited Undo and Redo! PLUS if the circle formed is too close to the origin will assume user changed mind about drawing circle.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _SCREENMOVE 300, 60
3. bk& = _NEWIMAGE(800, 600, 32) 'back ground screen
4. _PUTIMAGE , 0, bk& 'practice ;-))
5. TYPE circleType 'for circle (x, y), r (black and white exercise)
6.     x AS SINGLE
7.     y AS SINGLE
8.     r AS SINGLE
9. END TYPE
10. REDIM cs(0) AS circleType 'circles array
11. ci = 0 'stay ahead one of what has been recorded  for circle index
12. WHILE _KEYDOWN(27) = 0
13.     CLS
14.     _PUTIMAGE , bk&, 0
15.     k$ = INKEY$
16.     IF k$ = "u" THEN 'undo
17.         IF ci > 0 THEN ci = ci - 1
18.         CLS
19.         FOR i = 0 TO ci - 1
20.             CIRCLE (cs(i).x, cs(i).y), cs(i).r
21.         NEXT
22.         _PUTIMAGE , 0, bk&
23.     END IF
24.     IF k$ = "r" THEN 'redo
25.         IF ci < UBOUND(cs) THEN
26.             ci = ci + 1
27.             FOR i = 0 TO ci - 1
28.                 CIRCLE (cs(i).x, cs(i).y), cs(i).r
29.             NEXT
30.             _PUTIMAGE , 0, bk&
31.         END IF
32.     END IF
33.     WHILE _MOUSEINPUT: WEND
34.     mb = _MOUSEBUTTON(1)
35.     IF mb AND md = 0 THEN
36.         x1 = _MOUSEX: y1 = _MOUSEY: md = -1: mb = 0
37.     ELSEIF mb AND md THEN 'draw sample circle
38.         x2 = _MOUSEX: y2 = _MOUSEY
39.         r = _HYPOT(x1 - x2, y1 - y2)
40.         CIRCLE (x1, y1), r
41.     ELSEIF mb = 0 AND md THEN
42.         x2 = _MOUSEX: y2 = _MOUSEY
43.         r = _HYPOT(x1 - x2, y1 - y2)
44.         CIRCLE (x1, y1), r
45.         IF ABS(x1 - x2) > 3 OR ABS(y1 - y2) > 3 THEN 'user may not want a circle here and goes back to x1, y1
46.             _PUTIMAGE , 0, bk&
47.             cs(ci).x = x1
48.             cs(ci).y = y1
49.             cs(ci).r = r
50.             ci = ci + 1
51.             REDIM _PRESERVE cs(ci) AS circleType
52.         END IF
53.         md = 0: x1 = 0: x2 = 0: y1 = 0: y2 = 0
54.     END IF
55.     _DISPLAY
56.     _LIMIT 60
57. WEND
58.  

I was very pleasantly surprised to find that _HYPOT could be looked up on-line from inside the IDE.

Hey this looks like the beginnings of a Paint program, mouse locations could help perfect drawings as well as displaying current radius.

[robpugh0829]

BPlus,
You are amazing! Thanks! I am working on making a paint program for my kids. They are growing up fast and I want them to have something that interests them and ms paint is boring, so I'm making them a themed paint program. It's going to be Avengers Themed, so obviously I would never be able to release it because of copyright and all, but it will be cool when it's done. Thanks again so much!

[bplus]

Good! You are seeing how to change CircleType to DrawType and doing lines and boxes... along with circles and color?

[robpugh0829]

I am, your code is very clean and easy to understand. Thanks again!