Double Pendulum Studies

[STxAxTIC]

REDACTED

[MasterGy]

it seems interesting, simple, but there are very complicated calculations behind it. Do you think it would be easy to connect additional wrists? or does it all have to be approached differently? I don't understand the "random" part, between mouse and random values. What does that do?

[bplus]

Do you think it would be easy to connect additional wrists?

Yes we did this already with clocks each arm extended off the the arm before and even a 10th's of a sec arm extended off the sec arm extended off the minute arm extended off the hours hand. New times!

[MasterGy]

oh !! where can i see ?

[bplus]

Apologies to STx if this is hi-jacking but it was your idea to begin with so... I don't feel too bad :-))
Damned if I can remember the topic or useful keyword for search... oh parametric clock might have dun it, too late!

Code: QB64: [Select]

1. Option _Explicit
2. _Title "Jointed 4 arms clock #6: Any changes color, digits change hours: 0 = 12 or click mouse at 1, 2, 3... o'clock" 'b+ started 2020-11-22
3. ' inspsired by STx Parametric clock specially the faces  https://www.qb64.org/forum/index.php?topic=3277.msg125579#msg125579
4. ' I wish to see what a large circle joint at center would look like, first can I get similar face? yes sorta
5. ' 2020-11-23 More work on clock face, less LOC for drawPully, add modes and color changes
6. ' 2020-11-24 add stuff to make different arms
7. ' 2020-11-25  OK 4 armed clocks
8.  
9. Randomize Timer
10. Const xmax = 710, ymax = 710, CX = xmax / 2, CY = ymax / 2, hhr0 = 20, hhr1 = 10, mhr1 = 5, shr1 = 3, thr = 0, hh = 180, mh = 110, sh = 36, th = 12
11. Dim Shared face As Long, mode As Long, colr As _Unsigned Long, hourHand&, minHand&, secHand&, tenthsHand&
12.  
13. Screen _NewImage(xmax, ymax, 32)
14. _Delay .25
15. _ScreenMove _Middle
16.  
17. Dim k$, a, t As Double, h, m, s, tenths, hha, mha, sha, tha, hhx, hhy, mhx, mhy, shx, shy, thx, thy
18. face = _NewImage(_Width, _Height, 32)
19. makeAFace
20. Do
21.     k$ = InKey$
22.     If Len(k$) Then
23.         If InStr("0123456789", k$) Then mode = Val(k$)
24.         makeAFace
25.     End If
26.     While _MouseInput: Wend
27.     If _MouseButton(1) Then
28.         a = _R2D(_Atan2(_MouseY - CY, _MouseX - CX)) + 90 + 15
29.         If a < 0 Then a = a + 360
30.         If a > 360 Then a = a - 360
31.         a = Int(a / 30)
32.         If a >= 0 And a <= 12 Then mode = a: makeAFace
33.     End If
34.     _PutImage , face&, 0
35.     t = Timer(.001)
36.     h = t / 3600 ' fix this for mode
37.     If h > 12 Then h = h - 12
38.     m = (h - Int(h)) * 60
39.     s = t Mod 60
40.     tenths = Int((t - Int(t)) * 10)
41.     hha = h / mode * _Pi(2) - _Pi(.5)
42.     mha = m / 60 * _Pi(2) - _Pi(.5)
43.     sha = s / 60 * _Pi(2) - _Pi(.5)
44.     tha = tenths / 10 * _Pi(2) - _Pi(.5)
45.     hhx = CX + hh * Cos(hha): hhy = CY + hh * Sin(hha)
46.     mhx = hhx + mh * Cos(mha): mhy = hhy + mh * Sin(mha)
47.     shx = mhx + sh * Cos(sha): shy = mhy + sh * Sin(sha)
48.     thx = shx + .35 * th * Cos(tha): thy = shy + .35 * th * Sin(tha) ' why so far away? move in .4 ???
49.     RotoZoom3 CX, CY, hourHand&, 1, 1, hha
50.     RotoZoom3 hhx, hhy, minHand&, 1, 1, mha
51.     RotoZoom3 mhx, mhy, secHand&, 1, 1, sha
52.     RotoZoom3 thx, thy, tenthsHand&, 1, 1, tha
53.     _Display
54.     _Limit 30
55. Loop Until _KeyDown(27)
56.  
57. Sub drawPully (x1, y1, r1, x2, y2, r2, c As _Unsigned Long)
58.     Dim a
59.     a = _Atan2(y2 - y1, x2 - x1) + _Pi(.5)
60.     Line (x1 + r1 * Cos(a), y1 + r1 * Sin(a))-(x2 + r2 * Cos(a), y2 + r2 * Sin(a)), c
61.     Line (x1 + r1 * Cos(a - _Pi), y1 + r1 * Sin(a - _Pi))-(x2 + r2 * Cos(a - _Pi), y2 + r2 * Sin(a - _Pi)), c
62.     Circle (x1, y1), r1, c
63.     Circle (x2, y2), r2, c
64. End Sub
65.  
66. Sub makeAFace
67.     Dim cColr As _Unsigned Long, r, g, b, a, vi, h, hha, mha, sha, hhx, hhy, mhx, mhy, shx, shy, t, tha, thx, thy
68.     colr = _RGB32((Rnd < .5) * -1 * (Rnd * 128 + 127), Rnd * 128 + 127, (Rnd < .5) * -1 * (Rnd * 128 + 127), &H23)
69.     cAnalysis colr, r, g, b, a
70.     cColr = _RGB32(255 - r, 255 - g, 255 - b, 2)
71.     If mode = 0 Then mode = 12
72.     Cls
73.     For vi = 1 To mode * 3600
74.         h = vi / 3600
75.         hha = h / mode * _Pi(2) - _Pi(.5)
76.         mha = (h - Int(h)) * _Pi(2) - _Pi(.5)
77.         sha = (vi Mod 60) / 60 * _Pi(2) - _Pi(.5)
78.         hhx = CX + hh * Cos(hha): hhy = CY + hh * Sin(hha)
79.         mhx = hhx + mh * Cos(mha): mhy = hhy + mh * Sin(mha)
80.         shx = mhx + sh * Cos(sha): shy = mhy + sh * Sin(sha)
81.         drawPully mhx, mhy, mhr1, shx, shy, shr1, colr
82.         For t = 0 To 9
83.             tha = t / 10 * _Pi(2) - _Pi(.5)
84.             thx = shx + th * Cos(tha): thy = shy + th * Sin(tha)
85.             drawPully shx, shy, shr1, thx, thy, thr, cColr
86.         Next
87.     Next
88.     _PutImage , 0, face
89.     'arms look better with the draw color for the face on the edges, it hides raggity border edges.
90.     ' otherwise we could just draw these once at the beginning of program.
91.     makeArmImage hourHand&, hh, hhr0, hhr1, &HFFFFFFFF, &H88000000
92.     makeArmImage minHand&, mh, hhr1, mhr1, &HFFFFFFFF, &H88000000
93.     makeArmImage secHand&, sh, mhr1, shr1, &HFFFFFFFF, &H88000000
94.     makeArmImage tenthsHand&, th, shr1, thr, &HFFFFFFFF, &H88000000
95. End Sub
96.  
97. Sub makeArmImage (hdl&, length, r1, r2, c1 As _Unsigned Long, c2 As _Unsigned Long)
98.     ' intend to use this with rotozoom so have to make image rotate-able in middle
99.     ' arm image starts big in middle and points right to smaller radius r2
100.     ' hdl& image handle to use
101.     ' length  run of origins of half circles
102.     ' c1 is color on left in middle = bigger joint , c2 is color on right
103.     Dim width, height, wd2, hd2, x1, y1, x2, y2, a
104.     width = 2 * (r2 + length) + 2: height = 2 * r1 + 2: wd2 = width / 2: hd2 = height / 2
105.     hdl& = _NewImage(width + 2, height + 2, 32)
106.     _Dest hdl&
107.     _Source hdl&
108.     x1 = wd2: y1 = hd2: x2 = wd2 + length: y2 = hd2: a = _Pi(.5)
109.     Line (x1 + r1 * Cos(a), y1 + r1 * Sin(a))-(x2 + r2 * Cos(a), y2 + r2 * Sin(a)), colr
110.     Line (x1 + r1 * Cos(a - _Pi), y1 + r1 * Sin(a - _Pi))-(x2 + r2 * Cos(a - _Pi), y2 + r2 * Sin(a - _Pi)), colr
111.     arc x1, y1, r1, _Pi(.5), _Pi(1.5), colr
112.     arc x2, y2, r2, _Pi(1.5), _Pi(.5), colr
113.     paint4 x1, y1, c1, c2
114.     _Dest 0
115.     _Source 0
116. End Sub
117.  
118. 'use radians
119. Sub arc (x, y, r, raBegin, raEnd, c As _Unsigned Long) ' updated 2020-11-24
120.     ' raStart is first angle clockwise from due East = 0 degrees
121.     ' arc will start drawing there and clockwise until raStop angle reached
122.     'x, y origin, r = radius, c = color
123.     Dim raStart, raStop, dStart, dStop, al, a, lastx, lasty
124.  
125.     ' Last time I tried to use this SUB it hung the program, possible causes:
126.     ' Make sure raStart and raStop are between 0 and 2pi.
127.     ' This sub does not have to be recursive, use GOSUB to do drawing to execute arc in one call.
128.  
129.     'make copies before changing
130.     raStart = raBegin: raStop = raEnd
131.     While raStart < 0: raStart = raStart + _Pi(2): Wend
132.     While raStart >= _Pi(2): raStart = raStart - _Pi(2): Wend
133.     While raStop < 0: raStop = raStop + _Pi(2): Wend
134.     While raStop >= _Pi(2): raStop = raStop - _Pi(2): Wend
135.  
136.     If raStop < raStart Then
137.         dStart = raStart: dStop = _Pi(2) - .00001
138.         GoSub drawArc
139.         dStart = 0: dStop = raStop
140.         GoSub drawArc
141.     Else
142.         dStart = raStart: dStop = raStop
143.         GoSub drawArc
144.     End If
145.     Exit Sub
146.     drawArc: ' I am going back to lines instead of pset
147.     al = 2 * _Pi * r * (dStop - dStart) / _Pi(2)
148.     For a = dStart To dStop Step 1 / al
149.         If a > dStart Then Line (lastx, lasty)-(x + r * Cos(a), y + r * Sin(a)), c
150.         lastx = x + r * Cos(a): lasty = y + r * Sin(a)
151.     Next
152.     Return
153. End Sub
154.  
155. Sub cAnalysis (c As _Unsigned Long, outRed, outGrn, outBlu, outAlp)
156.     outRed = _Red32(c): outGrn = _Green32(c): outBlu = _Blue32(c): outAlp = _Alpha32(c)
157. End Sub
158.  
159. Function Ink~& (c1 As _Unsigned Long, c2 As _Unsigned Long, fr##)
160.     Dim R1, G1, B1, A1, R2, G2, B2, A2
161.     cAnalysis c1, R1, G1, B1, A1
162.     cAnalysis c2, R2, G2, B2, A2
163.     Ink~& = _RGB32(R1 + (R2 - R1) * fr##, G1 + (G2 - G1) * fr##, B1 + (B2 - B1) * fr##, A1 + (A2 - A1) * fr##)
164. End Function
165.  
166. Sub paint4 (x0, y0, c1 As _Unsigned Long, c2 As _Unsigned Long) ' needs max, min functions
167.     Dim fillColor As _Unsigned Long, W, H, parentF, tick, ystart, ystop, xstart, xstop, x, y
168.     fillColor = Point(x0, y0)
169.     'PRINT fillColor
170.     W = _Width - 1: H = _Height - 1
171.     Dim temp(W, H)
172.     temp(x0, y0) = 1: parentF = 1
173.     PSet (x0, y0), Ink~&(c1, c2, Abs((y0 - _Height / 2) / (_Height / 2)))
174.     While parentF = 1
175.         parentF = 0: tick = tick + 1
176.         ystart = max(y0 - tick, 0): ystop = min(y0 + tick, H)
177.         y = ystart
178.         While y <= ystop
179.             xstart = max(x0 - tick, 0): xstop = min(x0 + tick, W)
180.             x = xstart
181.             While x <= xstop
182.                 If Point(x, y) = fillColor And temp(x, y) = 0 Then
183.                     If temp(max(0, x - 1), y) Then
184.                         temp(x, y) = 1: parentF = 1: PSet (x, y), Ink~&(c1, c2, Abs((y - _Height / 2) / (_Height / 2)))
185.                     ElseIf temp(min(x + 1, W), y) Then
186.                         temp(x, y) = 1: parentF = 1: PSet (x, y), Ink~&(c1, c2, Abs((y - _Height / 2) / (_Height / 2)))
187.                     ElseIf temp(x, max(y - 1, 0)) Then
188.                         temp(x, y) = 1: parentF = 1: PSet (x, y), Ink~&(c1, c2, Abs((y - _Height / 2) / (_Height / 2)))
189.                     ElseIf temp(x, min(y + 1, H)) Then
190.                         temp(x, y) = 1: parentF = 1: PSet (x, y), Ink~&(c1, c2, Abs((y - _Height / 2) / (_Height / 2)))
191.                     End If
192.                 End If
193.                 x = x + 1
194.             Wend
195.             y = y + 1
196.         Wend
197.     Wend
198. End Sub
199.  
200. Function min (n1, n2)
201.     If n1 > n2 Then min = n2 Else min = n1
202. End Function
203.  
204. Function max (n1, n2)
205.     If n1 < n2 Then max = n2 Else max = n1
206. End Function
207.  
208. ' Description:
209. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
210. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
211. ' making this tightly coded routine a very powerful and versatile image tool.
212. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single)
213.     ' This assumes you have set your drawing location with _DEST or default to screen.
214.     ' X, Y - is where you want to put the middle of the image
215.     ' Image - is the handle assigned with _LOADIMAGE
216.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
217.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
218.     ' radianRotation is the Angle in Radian units to rotate the image
219.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
220.     '       and saves a little time converting from degree.
221.     '       Use the _D2R() function if you prefer to work in degree units for angles.
222.  
223.     Dim px(3) As Single: Dim py(3) As Single ' simple arrays for x, y to hold the 4 corners of image
224.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
225.     W& = _Width(Image&): H& = _Height(Image&)
226.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
227.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
228.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
229.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
230.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation) ' rotation helpers
231.     For i& = 0 To 3 ' calc new point locations with rotation and zoom
232.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
233.         px(i&) = x2&: py(i&) = y2&
234.     Next
235.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
236.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
237. End Sub
238.  
239.  

Oh I have reference links right in code, how thoughtful of me!

[MasterGy]

I see, it's spectacular! But he doesn't really use physics. The above program, in turn, models the pendulum-like relationship of two masses. I don't see a connection between the two programs.

[bplus]

I see, it's spectacular! But he doesn't really use physics. The above program, in turn, models the pendulum-like relationship of two masses. I don't see a connection between the two programs.

I don't know, do you want to see with your eyes, connected arms or see connection between application concepts, with your mind? sheesh! :)

Well the connection is the arm thing, the way they are connected. One arm or length or pendulum extends off the end of the last. I see the connection clear as that bell ringing, someone answer the phone.

[MasterGy]

I'm sorry, you're right. I expressed myself badly. I was thinking about the math behind the two programs. The watch has "A", it can be calculated from "B", from it it can be calculated from C .... more. But the pendulum also has backward calculations, and it can’t be so easily deduced. I was just wondering if additional arms could be added to the pendulum with a simple modification. You're right, I'm sorry again! There are connecting arms in both programs!

[STxAxTIC]

REDACTED

[bplus]

Sure time has no relation to the viscosity of liquids unless we consider time in the mass viscosity of space.

[MasterGy]

It can be complicated. I will be curious to continue. And also that if you manage to write the equations, it will work with any number of arms?

[STxAxTIC]

REDACTED

[MasterGy]

I really like what you're experimenting with! Unfortunately, I didn't delve much into what you showed (I complicate the spider game) I like it because you can see the effect of 2 points back and forth on the screen. There is no problem moving a point. It could be its direction, its velocity vector. But if there are already at least two points between which there is some kind of connection that is flexible or rigid, new parameters are immediately created. angular velocity, rotation. The car game didn't really start as a game, but I wanted to model the collision, rotation and overturning of a body. Like yours. The combination of several points. However !! As the wheel damping followed, a real relationship between the car and the wheel was not actually achieved. So it doesn’t go beyond 90 degrees, so it’s good, but if it rolled over, the system I built on would be completely inoperable. I admire what you did because any number of arms would be good. since then it could already be combined with rigid-body physics and real, real physical modeling could be seen on the screen. All you have to do is define N bodies and define what the relationship is between them. How good it would be! For example, we connect two cubes with string and discard them. And it’s also interesting because a change of 1 point has an effect on the other 15 points as well. I see in yours that it works great.

just a thought:
You have 3 points in your program. ABC. working perfectly. If we included a 4th point or a fifth and grouped it in such a way that there were only 3 points in 1 group, you could work AB-C and you would have already calculated CD in front of it ... and so on. But it's a shame I can't put it right. If that weren't understandable, I'll try to make my question more understandable.

[STxAxTIC]

Hey MasterGy

Just wanted to let you know I read your response thoroughly - thanks for your interest in all this. Ya know, I was going to study something altogether different next, but I think you've convinced me to stay on the pendulum case, and generalize the work to handle N arms instead of 2. If opportunity permits, I'll try to let the masses and pendulum lengths be variable rather than homogeneous.

On a completely separate note, there is another approach using the "method of constraints", which may end up being better, but our present tools are too blunt to do this nicely. That is, I would prefer to have a finely-polished package for inverting matrices and doing other maneuvers in linear algebra.

For now though, I'll see if I can extend what I've already done for N links. Stay tuned.

[STxAxTIC]

REDACTED