Mover Bricks 2D and 3D

[MasterGy]

Hello !

The game is complete, it does not use external files. At start-up, the difficulty level can be adjusted (1-5).
I could still increase the design, but it wasn’t my goal with all this to make a design game, so I won’t deal with it anymore.
I was wondering how many of you make games. You make very good 2D games. I especially like walking games.A small change can be made from these games into a 3D game.

The program would ultimately be a demonstration. At the end of the source code, those few lines perform the 3D calculations.
You need a 3D coordinate system, you need to include many points (many points form textures), and you need a point in this space who is an "observer." This is the most important ! The observer! Who looks at the other points. The observer has 5 data. X, Y, Z coordinates and direction to look. This is the angle of 2 planes perpendicular to each other. So X, Y, Z, ALPHA, BETA Knowing this, you can calculate the projected position of all the points on the screen, and _maptriangle can come.
I was thinking of a 3d engine that anyone could easily try based on their own ideas, but since the whole thing would be about 5 lines, I figured out instead that I would try to describe it as simply as possible to make it understandable.
A short, perfectly understandable writing about this. Put 2d theory and 3D projection on one level! It's a lot simpler than it looks.
Next time, I’ll check to see if a lot of people get to deal with it.

Code: QB64: [Select]

1. DIM SHARED size_block, size_wall, me(9), cam(9), monx, mony, mb_c, map_x, map_y, crash_test_disable, shdw_c, speed_min, speed_max, draw_2d_map, zoom_3d
2. '----------------- settings ---------------------------------------------------------------------------------------------
3.  
4.  
5. PRINT "MOVER BRICK game  (MasterGy 2022)"
6. PRINT "Choise level !  Press key 1,2,3,4,5"
7. PRINT "(1-no move bricks 2-easy 3-medium 4-high 5-extreme)"
8. DO: _LIMIT 10: x = ASC(RIGHT$(" " + INKEY$, 1)): IF x = 27 THEN SYSTEM
9. LEVEL = x - 49: LOOP WHILE LEVEL < 0 OR LEVEL > 4
10. 'LEVEL = 3
11.  
12. map_x = 30 'size map X
13. map_y = 30 'size map Y
14. money_c = 10 'money number what you find
15. mb_c = 90 'maximum mover bricks in the map
16. me_speed = .12 'my speed
17. mouse_sens = 1
18.  
19.  
20.  
21. '------------------------------------------------------ advanced settings -------------------------------------------------------------
22. add_wall_c = 4 'cross road-walls inside map
23. walk_limit = 8 'walk limit outside map
24. tile_marg = 5 'tiles outside near wall
25. me(5) = .5 'the size of my extent relative to a brick (1=standard size)
26. cheat_keys = 0 'enable cheat keys
27. monx = 800: mony = INT(monx / _DESKTOPWIDTH * _DESKTOPHEIGHT)
28. size_wall = .9 'size percent size_block (1=standard)
29. b_colors = 12 'brick colors
30. shdw_c = 50 'mipmap
31. speed_max = .11 * LEVEL / 4 'bricks maximum speed
32. speed_min = speed_max * .7 'bricks minimum speed
33. zoom_2d = .8
34. '----------------------------------------------------------------------------------------
35.  
36. 'ARRAYS
37. 'MB array 0-ena/disa 1,2-XYlocation 3-direction 4-stopcounter 5-colorindex 6-relativespeed 7-levelratiospeed
38. 'MAP array 0-empty 1-wall 2-wall-crossroad 3-money
39. 'ME/CAM array  '0,1,2-X,Y,Z   3=angXY 4=angXZ    5'XY dimension
40.  
41. DIM SHARED temp_color(9) AS _INTEGER64
42. CONST pip180 = 3.141592 / 180
43. RANDOMIZE TIMER: _AUTODISPLAY
44.  
45. 'ME install
46. me(0) = -1: me(1) = -1 'my start locate
47. size = 100: temp = _NEWIMAGE(size, size, 32): _DEST temp: CLS 0, _RGB32(10, 10, 10): CIRCLE (size / 2, size / 2), size / 2 * size_wall, _RGB32(200, 200, 200)
48. PAINT (size / 2, size / 2), _RGB32(200, 200, 200): _CLEARCOLOR _RGB32(10, 10, 10): me_text = _COPYIMAGE(temp, 33): _FREEIMAGE temp
49.  
50. 'shadows
51. DIM SHARED shdw(16383) AS _BYTE: FOR t = 0 TO 16383
52.     ashdw = INT((shdw_c - 1) * 0.0006 * t): IF ashdw > shdw_c - 1 THEN ashdw = shdw_c - 1
53.     shdw(t) = ashdw
54. NEXT t
55.  
56.  
57. 'directions
58. DIM d(3, 1) AS _BYTE: d(3, 1) = -1: d(0, 0) = 1: d(1, 1) = 1: d(2, 0) = -1: d(3, 1) = -1
59.  
60. DIM SHARED map(map_x - 1, map_y - 1) AS _UNSIGNED _BYTE, mb(mb_c - 1, 9)
61.  
62. 'make colors
63. DIM SHARED b_colors(b_colors - 1) AS _INTEGER64: FOR t = 1 TO b_colors - 1: b_colors(t) = _RGB32(30 + 180 * RND(1), 30 + 180 * RND(1), 30 + 180 * RND(1)): NEXT t
64. b_colors(0) = _RGB32(150, 20, 20) 'wall color
65.  
66. 'make textures
67. marg = .12: tmax = 40: tmin = 40
68. DIM SHARED text_mb(mb_c - 1, shdw_c - 1), text_wall(shdw_c - 1)
69. FOR t = 0 TO shdw_c - 1: size = INT(tmax - (tmax - tmin) / (shdw_c - 1) * t): dark = 1 - 1 / (shdw_c - 1) * t
70.     stand_temp = _NEWIMAGE(size, size, 32): _DEST stand_temp: CLS , _RGB32(50, 50, 50) 'frame color
71.     LINE (size * marg, size * marg)-(size - size * marg, size - size * marg), _RGB32(180, 180, 180), BF: _SOURCE stand_temp
72.     noise = 5 + 5 * (1 / (shdw_c - 1) * t) ^ 1.2 'add noise far tiles
73.     FOR tx = 0 TO size - 1: FOR ty = 0 TO size - 1: temp_color(0) = POINT(tx, ty)
74.             PSET (tx, ty), _RGB32(_RED32(temp_color(0)) - noise / 2 + RND(1) * noise, _GREEN32(temp_color(0)) - noise / 2 * RND(1) * noise, _BLUE32(temp_color(0)) - noise / 2 + RND(1) * noise)
75.     NEXT ty, tx
76.  
77.     'make wall
78.     FOR t2 = 0 TO b_colors - 1: temp = _COPYIMAGE(stand_temp, 32): _DEST temp
79.         IF t2 = 0 THEN LINE (0, 0)-(size, size), _RGB32(50, 50, 50): LINE (size, 0)-(0, size), _RGB32(50, 50, 50) 'no mover wall
80.         trans = _NEWIMAGE(5, 5, 32): _DEST trans: CLS , _RGBA32(_RED32(b_colors(t2)) * dark, _GREEN32(b_colors(t2)) * dark, _BLUE32(b_colors(t2)) * dark, 150)
81.         _SOURCE trans: _DEST temp: _BLEND temp: _PUTIMAGE: _FREEIMAGE trans 'tile coloring
82.         trans = _NEWIMAGE(5, 5, 32): _DEST trans: CLS , _RGBA32(0, 0, 0, (1 - dark) * 255)
83.         _SOURCE trans: _DEST temp: _PUTIMAGE: _FREEIMAGE trans 'tile darking
84.     text_mb(t2, t) = _COPYIMAGE(temp, 33): _FREEIMAGE temp: NEXT t2: _FREEIMAGE stand_temp
85. NEXT t
86.  
87.  
88. 'skys_color
89. DIM text_sky(999)
90. FOR t = 0 TO 499
91.     temp = _NEWIMAGE(3, 3, 32): _DEST temp: CLS , _RGB32(20, 20, 255 / 499 * t): text_sky(t) = _COPYIMAGE(temp, 33): _FREEIMAGE temp
92. NEXT t
93.  
94.  
95. 'make walls
96. FOR tx = 0 TO map_x - 1: FOR ty = 0 TO map_y - 1: map(tx, ty) = ABS(tx = 0 OR ty = 0 OR tx = map_x - 1 OR ty = map_y - 1): NEXT ty, tx
97.  
98. 'add walls within the framework
99. add_wall_p(0) = .8: add_wall_p(1) = .8: FOR t = 1 TO add_wall_c
100.     DO: FOR t2 = 0 TO 3: p(t2) = map_x * add_wall_p(t2 MOD 2) * RND(1) + map_x * (1 - add_wall_p(t2 MOD 2)) / 2: NEXT t2
101.     dis = SQR((p(0) - p(2)) ^ 2 + (p(1) - p(3)) ^ 2): LOOP WHILE dis < 5: dis = dis * .7
102. FOR t2 = 0 TO dis: map(INT(p(0) + (p(2) - p(0)) / dis * t2), INT(p(1) + (p(3) - p(1)) / dis * t2)) = 2: NEXT t2, t
103.  
104. 'money install
105. DIM SHARED text_money(9)
106. FOR t = 0 TO 9: temp = _NEWIMAGE(8, 16, 32): _DEST temp: COLOR _RGB32(256 * RND(1), 256 * RND(1), 256 * RND(1)): PRINT "$";
107. _CLEARCOLOR _RGB32(0, 0, 0): text_money(t) = _COPYIMAGE(temp, 33): _FREEIMAGE temp: NEXT t
108. DIM money(money_c - 1, 9)
109. FOR t = 0 TO money_c - 1: DO: money(t, 0) = INT(1 + (map_x - 2) * RND(1)): money(t, 1) = INT(1 + (map_y - 2) * RND(1))
110. LOOP WHILE map(money(t, 0), money(t, 1)): map(money(t, 0), money(t, 1)) = 3: NEXT t
111.  
112. 'make mover bricks
113. FOR t = 0 TO mb_c - 1: agent_timer = TIMER
114.     DO: mb(t, 1) = INT(1 + (map_x - 2) * RND(1)): mb(t, 2) = INT(1 + (map_y - 2) * RND(1)): mb(t, 3) = INT(4 * RND(1)): busy = 0
115.         FOR tx = -1 TO 1: FOR ty = -1 TO 1: what = map(tx + mb(t, 1), ty + mb(t, 2)): busy = busy OR ABS(what = 2 OR what = 3): NEXT ty, tx
116.         FOR t2 = 0 TO mb_c - 1: IF mb(t2, 0) = 0 OR busy THEN _CONTINUE
117.         busy = busy OR (SQR((mb(t2, 1) - mb(t, 1)) ^ 2 + (mb(t2, 2) - mb(t, 2)) ^ 2) < 2): NEXT t2: IF ABS(agent_timer - TIMER) > 2 THEN EXIT FOR
118.     LOOP WHILE busy: mb(t, 0) = 1: mb(t, 5) = 1 + INT((b_colors - 1) * RND(1))
119.     mb(t, 7) = RND(1)
120. NEXT t
121.  
122. 'entri brick to the area
123. DO: t = INT(2 * RND(1)): posx = INT((1 + (map_x - 2) * RND(1)) * t) + INT(2 * RND(1)) * (map_x - 1) * ABS(t = 0)
124.     posy = INT((1 + (map_y - 2) * RND(1)) * (t XOR 1)) + INT(2 * RND(1)) * (map_x - 1) * ABS((t XOR 1) = 0)
125.     busy = 0: FOR t = 0 TO mb_c - 1: busy = busy OR SQR((posx - mb(t, 1)) ^ 2 + (posy - mb(t, 2)) ^ 2) < 1.5: NEXT t
126. LOOP WHILE busy: map(posx, posy) = 0
127.  
128.  
129.  
130. mon = _NEWIMAGE(monx, mony, 32): SCREEN mon: _DEST mon: _DISPLAYORDER _HARDWARE , _SOFTWARE: _FULLSCREEN: _MOUSEHIDE
131. COLOR , _RGBA32(0, 0, 0, 0)
132.  
133.  
134.  
135.  
136. limit_cycle = 1
137.  
138. '------------------------------------------- BOSS CYCLE
139. DO: IF limit_cycle THEN _LIMIT 30
140.  
141.     'draw non mover blocks
142.     FOR tx = -tile_marg TO map_x - 1 + tile_marg: FOR ty = -tile_marg TO map_y - 1 + tile_marg
143.             IF (tx < 0 OR tx > map_x - 1 OR ty < 0 OR ty > map_y - 1) = 0 THEN IF map(tx, ty) = 1 OR map(tx, ty) = 2 THEN draw_brick_3d tx, ty, 0, 1
144.             tile_3d tx, ty
145.     NEXT ty, tx
146.  
147.     'draw mover blocks
148.     FOR amb = 0 TO mb_c - 1: IF mb(amb, 0) THEN draw_brick_3d mb(amb, 1), mb(amb, 2), mb(amb, 5), 1
149.     NEXT amb
150.  
151.     'draw me
152.     IF (dead = 0 OR (dead AND INT(2 * RND(1)))) AND draw_2d_map THEN draw_brick_3d me(0), me(1), mb(0, 0), me(5)
153.  
154.     'draw money
155.     IF storyline = 0 THEN
156.         FOR t = 0 TO money_c - 1: IF money(t, 2) = 0 THEN money_3d money(t, 0), money(t, 1)
157.         NEXT t
158.     END IF
159.  
160.     'moving mover bricks
161.     FOR amb = 0 TO mb_c - 1: IF mb(amb, 0) = 0 THEN _CONTINUE
162.         p(0) = CINT(mb(amb, 1) + d(mb(amb, 3), 0) * (mb(amb, 6) + .5))
163.         p(1) = CINT(mb(amb, 2) + d(mb(amb, 3), 1) * (mb(amb, 6) + .5)): dontgo = 0: letsneg = 0
164.  
165.         FOR t = 0 TO mb_c - 1: IF mb(t, 0) = 0 OR t = amb OR dontgo THEN _CONTINUE
166.             vr = mb(t, 3) MOD 2: vr2 = vr = (mb(amb, 3) MOD 2)
167.             letsneg = letsneg OR (((ABS(mb(t, 1 + vr) - mb(amb, 1 + vr)) < 1) AND (mb(t, 1 + (vr XOR 1))) = (mb(amb, 1 + (vr XOR 1)))) AND vr2)
168.         dontgo = dontgo OR ((ABS(p(0) - mb(t, 1)) < 1 AND ABS(p(1) - mb(t, 2)) < 1) AND (vr2 = 0)): NEXT t
169.  
170.         mb(amb, 3) = (mb(amb, 3) + ABS(((letsneg) OR map(p(0), p(1)) = 2 OR map(p(0), p(1)) = 3) OR (p(0) = 0 OR p(0) = map_x - 1 OR p(1) = 0 OR p(1) = map_y - 1)) * 2) MOD 4
171.         mb(amb, 4) = (mb(amb, 4) + ABS(dontgo)) * ABS(dontgo)
172.         mb(amb, 3) = (mb(amb, 3) + 2 * ABS((mb(amb, 4) > 5 / mb(amb, 6)) AND dontgo)) MOD 4
173.         mb(amb, 1) = mb(amb, 1) + d(mb(amb, 3), 0) * mb(amb, 6) * ABS(dontgo = 0)
174.         mb(amb, 2) = mb(amb, 2) + d(mb(amb, 3), 1) * mb(amb, 6) * ABS(dontgo = 0)
175.     NEXT amb
176.  
177.  
178.     'control me
179.     mousex = 0: mousey = 0: mw = 0: WHILE _MOUSEINPUT: mousex = mousex + _MOUSEMOVEMENTX: mousey = mousey + _MOUSEMOVEMENTY: mw = mw + _MOUSEWHEEL: WEND
180.     k_left = _KEYDOWN(19200) OR _KEYDOWN(ASC("a")): k_right = _KEYDOWN(19712) OR _KEYDOWN(ASC("d"))
181.     k_up = _KEYDOWN(18432) OR _KEYDOWN(ASC("w")) OR _MOUSEBUTTON(1): k_down = _KEYDOWN(20480) OR _KEYDOWN(ASC("s"))
182.     mouse_act_sens = mouse_sens * (1 - (zoom_3d * .9) * ABS(draw_2d_map = 0))
183.     me(3) = me(3) + mousex * mouse_act_sens - INT(me(3) / 360) * 360
184.     me(4) = me(4) + mousey * mouse_act_sens
185.     IF ABS(me(4)) > 80 THEN me(4) = 80 * SGN(me(4))
186.     d2m_ang = INT((me(3) + 45) / 90) * 90
187.     zoom_change = (mw / 30 + (-_KEYDOWN(ASC("-")) + _KEYDOWN(ASC("+"))) / 50)
188.     zoom_2d = zoom_2d + zoom_change * draw_2d_map
189.     IF zoom_2d < 0 THEN zoom_2d = 0 ELSE IF zoom_2d > 1 THEN zoom_2d = 1
190.     zoom_3d = zoom_3d + zoom_change * (draw_2d_map = 0)
191.     IF zoom_3d < 0 THEN zoom_3d = 0 ELSE IF zoom_3d > 1 THEN zoom_3d = 1
192.  
193.     IF dead = 0 THEN
194.         IF crash_test(me(0), me(1)) THEN
195.             try_speed = speed_max * 1.1
196.             try = -1: FOR atry = 0 TO 3
197.                 IF crash_test(me(0) + d(atry, 0) * try_speed, me(1) + d(atry, 1) * try_speed) = 0 THEN try = atry: EXIT FOR
198.             NEXT atry: IF try = -1 THEN dead = 1
199.             IF dead = 0 THEN me(0) = me(0) + d(atry, 0) * try_speed: me(1) = me(1) + d(atry, 1) * try_speed
200.         END IF
201.         try_ang_sc = 85
202.         FOR try_ang = 0 TO try_ang_sc STEP 6: FOR try_ang_dir = 0 TO 1
203.                 go = me_speed * ABS((k_left + k_right + k_up + k_down) = -1) * (1 / try_ang_sc * (try_ang_sc - try_ang)) ^ .7
204.                 go_ang = k_down * 180 + 90 * (k_left - k_right) + (me(3) + (try_ang_dir * 2 - 1) * try_ang) * ABS(draw_2d_map = 0) + draw_2d_map * d2m_ang
205.                 go_x = SIN(go_ang * pip180) * go + me(0): go_y = -COS(go_ang * pip180) * go + me(1)
206.                 walk_limit_ok = (go_x < -walk_limit OR go_y < -walk_limit OR go_x > map_x - 1 + walk_limit OR go_y > map_y - 1 + walk_limit) = 0
207.                 IF crash_test(go_x, go_y) = 0 AND walk_limit_ok THEN me(0) = go_x: me(1) = go_y: GOTO ok
208.         NEXT try_ang_dir, try_ang
209.         ok:
210.     END IF
211.  
212.  
213.     'cheats
214.     inkey2$ = INKEY$: IF inkey2$ = CHR$(27) THEN SYSTEM
215.     IF cheat_keys THEN
216.         IF inkey2$ = "r" THEN RUN
217.         IF inkey2$ = "l" THEN limit_cycle = limit_cycle XOR 1
218.         IF inkey2$ = "c" THEN crash_test_disable = crash_test_disable XOR 1
219.         IF inkey2$ = "o" THEN dead = 1 'reborn
220.         IF inkey2$ = "p" THEN dead = 0 'dead
221.     END IF
222.  
223.     'sky draw
224.     IF draw_2d_map = 0 THEN
225.         sky_flash = sky_flash - 0.02: IF sky_flash < 0 THEN sky_flash = 0
226.         IF sky_flash > 1 THEN sky_flash = 1
227.         IF dead THEN sky_ind = 490 * SGN(INT(TIMER * 50) AND 1) ELSE sky_ind = INT(490 * sky_flash)
228.         asky = text_sky(sky_ind)
229.         _MAPTRIANGLE (0, 0)-(0, 5)-(5, 0), asky TO(-16000, -16000, -10000)-(16000, -16000, -10000)-(-16000, 16000, -10000)
230.         _MAPTRIANGLE (0, 0)-(0, 5)-(5, 0), asky TO(16000, 16000, -10000)-(16000, -16000, -10000)-(-16000, 16000, -10000)
231.     END IF
232.  
233.     _DISPLAY: CLS
234.  
235.     'STORYLINE
236.     IF storyline = 0 THEN
237.         FOR t = 0 TO money_c - 1
238.             find_money = SQR((me(0) - money(t, 0)) ^ 2 + (me(1) - money(t, 1)) ^ 2) < 1.1 AND (money(t, 2) = 0)
239.             IF find_money THEN money_sum = money_sum + 1: map(money(t, 0), money(t, 1)) = 0: money(t, 2) = 1: sky_flash = 1: set_speed_bricks 1 / money_c * money_sum
240.         NEXT t
241.         storyline = storyline + ABS(money_sum = money_c)
242.     END IF
243.     IF storyline = 1 AND (me(0) > 0 AND me(0) < map_x - 1 AND me(1) > 0 AND me(1) < map_y - 1) = 0 THEN storyline = 2
244.  
245.     SELECT CASE storyline
246.         CASE 0: s$ = "GET THE MONEY !   " + STR$(money_c) + " /" + STR$(money_sum)
247.         CASE 1: s$ = "ESCAPE OUTSIDE THE WALL !"
248.         CASE 2: s$ = "Mission compeleted ! "
249.     END SELECT
250.     IF dead THEN s$ = "you dead ,mission incompleted !"
251.     COLOR _RGB32(255 * RND(1), 255 * RND(1), 255 * RND(1)): LOCATE 3, (monx / 8 - LEN(s$)) / 2: PRINT s$
252.     COLOR _RGB32(255, 255, 255): LOCATE mony / 16 - 2, 2
253.  
254.     IF draw_2d_map THEN
255.         PRINT "Switch 2D to 3D- space-key      control: arrows            2D zoom: mouse wheel ("; INT(zoom_2d * 100); "%)"
256.     ELSE
257.         PRINT "Switch 3D to 2D- space-key      control: WASD + mouse      3D zoom: mouse wheel ("; INT(zoom_3d * 100); "%)"
258.     END IF
259.  
260.  
261.     'camera fresh
262.     IF inkey2$ = " " THEN draw_2d_map = draw_2d_map XOR 1: IF draw_2d_map = 0 THEN me(3) = d2m_ang: me(4) = 0: zoom_3d = 0
263.  
264.     IF draw_2d_map THEN
265.         cam(0) = cam(0) + (me(0) - cam(0)) * 0.1
266.         cam(1) = cam(1) + (me(1) - cam(1)) * 0.1
267.         cam(2) = cam(2) + ((1.1 + (1 - zoom_2d) * 40) - cam(2)) * 0.1
268.         cam(3) = cam(3) + (d2m_ang - cam(3)) * 0.5
269.         cam(4) = cam(4) + (90 - cam(4)) * 0.1
270.     ELSE
271.         cam(0) = me(0)
272.         cam(1) = me(1)
273.         cam(3) = me(3)
274.         cam(4) = cam(4) + (me(4) - cam(4)) * (0.05 + 0.45 * ABS(ABS(me(2) - cam(2)) < .5))
275.         cam(2) = cam(2) + (0.3 - cam(2)) * 0.1
276.     END IF
277.  
278. LOOP
279.  
280. SUB rotate_2d (x, y, ang): x1 = -(x * COS(ang) - y * SIN(ang)): y1 = -(x * SIN(ang) + y * COS(ang)): x = x1: y = y1: END SUB
281.  
282. FUNCTION crash_test (x, y): IF crash_test_disable THEN EXIT FUNCTION
283.     FOR myp = 0 TO 3: mx = x + me(5) * .5 * (SGN(myp AND 1) * 2 - 1): my = y + me(5) * .5 * (SGN(myp AND 2) * 2 - 1)
284.         FOR amb = 0 TO mb_c - 1: IF mb(amb, 0) = 0 THEN _CONTINUE
285.             IF mx > mb(amb, 1) - .5 AND mx < mb(amb, 1) + .5 AND my > mb(amb, 2) - .5 AND my < mb(amb, 2) + .5 THEN crash_test = 1: EXIT FUNCTION
286.         NEXT amb
287.         FOR tx = 0 TO map_x - 1: FOR ty = 0 TO map_y - 1: IF map(tx, ty) = 0 THEN _CONTINUE
288.                 IF mx > tx - .5 AND mx < tx + .5 AND my > ty - .5 AND my < ty + .5 THEN crash_test = 1: EXIT FUNCTION
289.     NEXT ty, tx, myp
290. END FUNCTION
291.  
292. SUB point_3d (x, y, z)
293.     x = x - cam(0): y = y - cam(2): z = z - cam(1): rotate_2d x, z, -(cam(3) + 180) * pip180: rotate_2d y, z, (cam(4) + 180) * pip180
294.     x = x * 100: y = y * 100: z = z * (120 - ABS(draw_2d_map = 0) * zoom_3d * 115)
295. END SUB
296.  
297. SUB draw_brick_3d (x, y, text, relsize)
298.     DIM p(3, 2), pc(7, 2), sq(3) AS _UNSIGNED _BYTE
299.     size = size_wall * .5 * relsize
300.     FOR t = 0 TO 7
301.         pc(t, 0) = size * (SGN(t AND 1) * 2 - 1) + x: pc(t, 2) = size * (SGN(t AND 2) * 2 - 1) + y: pc(t, 1) = size * SGN(t AND 4) * 2
302.         point_3d pc(t, 0), pc(t, 1), pc(t, 2)
303.     NEXT t
304.  
305.     FOR t = 0 TO 4
306.         FOR t2 = 0 TO 3: side = VAL(MID$("-0246-2367-3175-1054-4567", 2 + t * 5 + t2, 1))
307.         FOR t3 = 0 TO 2: p(t2, t3) = pc(side, t3): NEXT t3, t2
308.         draw_square p(), text_mb(text, shdw(ABS(INT((p(0, 2) + p(1, 2) + p(2, 2) + p(3, 2)) / 4)) * (draw_2d_map XOR 1)))
309.     NEXT t
310. END SUB
311.  
312. SUB tile_3d (x, y)
313.     DIM p(3, 2)
314.     FOR t = 0 TO 3
315.         p(t, 0) = x + (SGN(t AND 1) * 2 - 1) * .5: p(t, 2) = y + (SGN(t AND 2) * 2 - 1) * .5: p(t, 1) = 0
316.         point_3d p(t, 0), p(t, 1), p(t, 2)
317.     NEXT t
318.     IF draw_2d_map THEN shdw = 1000 ELSE shdw = ABS(INT((p(0, 2) + p(1, 2) + p(2, 2) + p(3, 2)) / 4))
319.     draw_square p(), text_mb(0, shdw(shdw))
320.  
321. END SUB
322.  
323. SUB money_3d (x, y)
324.     DIM p(3, 2)
325.     FOR t = 0 TO 3
326.         ang = (TIMER * 2 + _PI * (t AND 1) + x + y) * (((x + y) AND 1) * 2 - 1)
327.         p(t, 0) = SIN(ang) * .5: p(t, 2) = COS(ang) * .5: p(t, 1) = SGN(t AND 2)
328.         IF draw_2d_map THEN SWAP p(t, 1), p(t, 2): p(t, 1) = p(t, 1) + .5: p(t, 2) = p(t, 2) - .5
329.         p(t, 0) = p(t, 0) + x: p(t, 2) = p(t, 2) + y
330.         point_3d p(t, 0), p(t, 1), p(t, 2)
331.     NEXT t
332.     draw_square p(), text_money(INT(10 * RND(1)))
333. END SUB
334.  
335. SUB draw_square (p(), text)
336.     wtext = _WIDTH(text) - 1: htext = _HEIGHT(text) - 1
337.     _MAPTRIANGLE (0, 0)-(wtext, 0)-(0, htext), text TO(p(0, 0), p(0, 1), p(0, 2))-(p(1, 0), p(1, 1), p(1, 2))-(p(2, 0), p(2, 1), p(2, 2)), , _SMOOTH
338.     _MAPTRIANGLE (wtext, htext)-(wtext, 0)-(0, htext), text TO(p(3, 0), p(3, 1), p(3, 2))-(p(1, 0), p(1, 1), p(1, 2))-(p(2, 0), p(2, 1), p(2, 2)), , _SMOOTH
339. END SUB
340.  
341. SUB set_speed_bricks (set_speed)
342.     FOR amb = 0 TO mb_c - 1: mb(amb, 6) = (speed_min + (speed_max - speed_min) * mb(amb, 7)) * set_speed * ABS(mb(amb, 0)): NEXT amb
343. END SUB
344.  
345.  

[STxAxTIC]

This is brilliant. You're in a class of your own, Master. Your works are loved by many, FEARED by many more.

[dbox]

I got the money!  @MasterGy this is extremely impressive.  It's pretty remarkable the projects you've been able to do just using _MapTriangle.

[johnno56]

Fascinating. Even the Vulcan Science Academy is interested in your work!

[Dav]

Awesome work, @MasterGy!

- Dav

[MasterGy]

Thanks for trying it!

Thanks STxAxTIC and Dav, good praise!

Dbox. That's interesting. Extremely I didn't even succeed. I deliberately made it hard for no one to succeed!

Johnno56 "Vulcan Science Academy". What's that  ? :)

[dbox]

Well, I did play with option 2 - Easy.  Mostly in top-down mode.

[johnno56]

@MasterGy "What's that?"

I am obviously in error for not stating my point more clearly. My apologies.

To keep it short... It's a Star Trek thing... Follow https://startrekdesignproject.com/symbols/vulcan-science-academy-vsa/ then the link to "Memory Alpha". If you have any further questions, feel free to ask...

Regards

J

[madscijr]

Hello !

The game is complete, it does not use external files. At start-up, the difficulty level can be adjusted (1-5).
I could still increase the design, but it wasn’t my goal with all this to make a design game, so I won’t deal with it anymore.
I was wondering how many of you make games. You make very good 2D games. I especially like walking games.A small change can be made from these games into a 3D game.

I love the idea of giving the user the option to play a game in 2-D, 2.5D or 3-D or switching between these views while they play. I'll definitely give this a look!