What are the limits for _DesktopWidth and _DesktopHeight?

[hanness]

My laptop has a display resolution of 3840 x 2160, but when I run the code below it returns a display width of 1920 and a display height of 1080:

Option _Explicit
Dim As Integer x, y
' image& = _ScreenImage
x = _DesktopWidth
y = _DesktopHeight
Print x; y

Tested on Win 10, 20H2 with QB64 1.5

[SMcNeill]

It’s because you have windows scaling at 200%.

Set scale to 100% and you’ll get the full resolution.

[SpriggsySpriggs]

@hanness This is because QB64 programs are not DPI aware. I made a pull request on GitHub to fix a different issue that still is tied to yours that allows QB64 programs to be DPI aware. This should allow you to have full 3840 x 2160 even when at 200% resolution.

[SpriggsySpriggs]

Try running the below code with your scaling at 200% and see if you get the right results:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. Type RECT
4.     As Long left, top, right, bottom
5. End Type
6.  
7. Declare Dynamic Library "User32"
8.     Function SetProcessDPIAware%% ()
9. End Declare
10.  
11. Declare Dynamic Library "Shcore"
12.     Function SetProcessDpiAwareness%& (ByVal value As Long)
13. End Declare
14.  
15. Declare CustomType Library
16.     Function GetDesktopWindow%& ()
17.     Function GetWindowRect%% (ByVal hWnd As _Offset, Byval lpRect As _Offset)
18.     Function GetClientRect%% (ByVal hWnd As _Offset, Byval lpRect As _Offset)
19. End Declare
20.  
21. 'Print SetProcessDPIAware 'You can uncomment this one and comment out the other if you want. Both do the same thing.
22. Print SetProcessDpiAwareness(1)
23.  
24. Dim As _Offset desktop
25. Dim As RECT rect, rect2
26. desktop = GetDesktopWindow
27. Print _DesktopWidth, _DesktopHeight
28. If desktop Then
29.     If GetWindowRect(desktop, _Offset(rect)) Then
30.         Print rect.left, rect.top, rect.right, rect.bottom
31.         If GetClientRect(desktop, _Offset(rect2)) Then
32.             Print rect2.left, rect2.top, rect2.right, rect2.bottom
33.         End If
34.     End If
35. End If

[hanness]

Thanks much. That makes sense, and the code provided did indeed work.

As always, the help was very appreciated.

[SpriggsySpriggs]

@hanness Awesome! Glad it worked for you. Your problem and LM's are both good examples to show that DPI awareness is needed in QB64.

[SpriggsySpriggs]

@hanness The latest dev build has the bug fix and automatically makes the program DPI aware. Download at your convenience and let us know how it goes for you.