Program code to simulate removing and inserting USB stick

[Richard]

Is it possible to code in QB64 the

"Eject USB stick"  AND also (later on)  "Simulating that same USB stick as having been just inserted"

in that order, actions - without having to physically remove and insert the USB stick?

[euklides]

Well, it is not exactly your problem, but perhaps look here: https://www.qb64.org/forum/index.php?topic=1507.msg107057#msg107057 (Working with files located on USB devices)

[Pete]

Ah, I miss the good ol' days when you could eject the CD tray with a simple PEEK/POKE command.

To "safely" eject a usb device would probably require a Windows API call.

Now to check to see if a drive is active, hmmm, the good ol' days again... I used to check to see if a drive was active on my QuickBASIC computer programs by polling drives a-z using an error trap to resume if no drive was found. In QB64, you could use the same method. CHDIR, for instance. Use it to map all your current drives a-z. Let's say the routine errors out all but 3 times, meaning it found 3 drives. Now insert a USB stick, and run the routine again. Now it will error out all but 4 times, meaning a new drive was detected.

Something like this, for a portion of what would be required. Note: I did not run this code, so there may be some errors. It's just to give you an idea to consider...

Code: QB64: [Select]

1. ON ERROR GOTO handler
2. FOR i% = 1 TO 26
3.     CHDIR LTRIM$(STR$(i% + 64)) + ":\" ' A - Z
4.     IF er1% THEN
5.         er1% = 0
6.     ELSE
7.         numberofdrives = numberofdrives + 1
8.         PRINT "Drive Found: "; LTRIM$(STR$(i% + 95))
9.     END IF
10. NEXT
11. CHDIR mydir$
12. END
13.  
14. handler:
15. er1% = -1
16. RESUME NEXT

Pete

[SpriggsySpriggs]

I'm pretty busy nowadays but I can look at this. Like Pete said, you'd need a Windows API call. I have found a function that is designed to do that. It doesn't seem simple to set up. I'll have to do some testing at home and then write a wrapper for it.

https://docs.microsoft.com/en-us/windows/win32/api/cfgmgr32/nf-cfgmgr32-cm_request_device_ejectw

or this, which looks much simpler:
https://social.msdn.microsoft.com/Forums/vstudio/en-US/22790e90-d923-4069-a32c-caaf96f7d0f6/whats-eject-usb-drive-api-?forum=csharpgeneral

[SpriggsySpriggs]

@Richard

Believe it or not, I don't have a USB handy to test this with. I based this code off the second link in my last reply. All this does is cause an ejection of a drive when you call the sub EjectDrive with the drive letter that you are wanting to eject. I don't have code ready for trying to mount the drive again if it is still in the port. Feel free to test this with some USB that you have laying around.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST OPEN_EXISTING = 3
4. CONST GENERIC_READ = &H80000000
5. CONST GENERIC_WRITE = &H40000000
6. CONST IOCTL_STORAGE_EJECT_MEDIA = &H2D4808
7.  
8. DECLARE DYNAMIC LIBRARY "Kernel32"
9.     FUNCTION CloseHandle% (BYVAL hObject AS LONG)
10.     FUNCTION DeviceIoControl% (BYVAL hDevice AS LONG, BYVAL dwIoControlCode AS LONG, BYVAL lpInBuffer AS _OFFSET, BYVAL nInBufferSize AS LONG, BYVAL lpOutBuffer AS _OFFSET, BYVAL nOutBufferSize AS LONG, BYVAL lpBytesReturned AS _OFFSET, BYVAL lpOverlapped AS _OFFSET)
11.     FUNCTION CreateFile& ALIAS CreateFileA (BYVAL lpFileName AS _OFFSET, BYVAL dwDesiredAccess AS LONG, BYVAL dwShareMode AS LONG, BYVAL lpSecurityAttributes AS _OFFSET, BYVAL dwCreationDisposition AS LONG, BYVAL dwFlagsAndAttributes AS LONG, BYVAL hTemplateFile AS LONG)
12. END DECLARE
13.  
14. SUB EjectDrive (driveLetter AS STRING)
15.     DIM path AS STRING
16.     path = "\\.\" + driveLetter + ":"
17.     DIM handle AS LONG
18.     handle = CreateFile(_OFFSET(path), GENERIC_READ OR GENERIC_WRITE, 0, 0, OPEN_EXISTING, 0, 0)
19.     IF handle = -1 THEN
20.         PRINT "Unable to open drive " + driveLetter
21.         EXIT SUB
22.     END IF
23.     DIM dummy AS INTEGER
24.     DIM dev AS INTEGER
25.     dev = DeviceIoControl(handle, IOCTL_STORAGE_EJECT_MEDIA, 0, 0, 0, 0, _OFFSET(dummy), 0)
26.     dev = CloseHandle(handle)
27.     PRINT "OK to remove drive."
28. END SUB

[Richard]

@SpriggsySpriggs

Thanks - it worked with a usb stick in drive "J" - look forward to the mounting of same.

[SpriggsySpriggs]

Here is the reference I will use for making code to mount the unmounted drive:

https://stackoverflow.com/questions/16295774/winapi-calls-to-access-usb-storage-which-has-no-drive-letter

[SpriggsySpriggs]

@Richard

I have some code made up that I based on that Stack Overflow answer. I haven't verified if it remounts an ejected drive (I don't have anything to eject right now). It is supposed to do that, though. This might require some fine finishing later as I haven't broken it down into a function. Run that first code I gave you to eject that USB drive you had and then run this code (leaving the drive plugged in) and see if it remounts it to a free letter. Again, it should but I can't test it for real just yet.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. $CONSOLE:ONLY
3. _DEST _CONSOLE
4.  
5. DECLARE DYNAMIC LIBRARY "Kernel32"
6.     FUNCTION FindFirstVolume& ALIAS FindFirstVolumeA (BYVAL lpszVolumeName AS _OFFSET, BYVAL cchBufferLength AS LONG)
7.     FUNCTION FindNextVolume% ALIAS FindNextVolumeA (BYVAL hFindVolume AS LONG, BYVAL lpszVolumeName AS _OFFSET, BYVAL cchBufferLength AS LONG)
8.     FUNCTION GetVolumePathNamesForVolumeName% ALIAS GetVolumePathNamesForVolumeNameA (BYVAL lpszVolumeName AS _OFFSET, BYVAL lpszVolumePathNames AS _OFFSET, BYVAL cchBufferLength AS LONG, BYVAL lpcchReturnLength AS _OFFSET)
9.     FUNCTION GetLogicalDrives& ()
10.     FUNCTION SetVolumeMountPoint% ALIAS SetVolumeMountPointA (BYVAL lpszVolumeMountPoint AS _OFFSET, BYVAL lpszVolumeName AS _OFFSET)
11.     FUNCTION GetVolumeInformation% ALIAS GetVolumeInformationA (BYVAL lpRootPathName AS _OFFSET, BYVAL lpVolumeNameBuffer AS _OFFSET, BYVAL nVolumeNameSize AS LONG, BYVAL lpVolumeSerialNumber AS _OFFSET, BYVAL lpMaximumComponentLength AS _OFFSET, BYVAL lpFileSystemFlags AS _OFFSET, BYVAL lpFileSystemNameBuffer AS _OFFSET, BYVAL nFileSystemNameSize AS LONG)
12.     FUNCTION FindVolumeClose% (BYVAL hFindVolume AS LONG)
13.     FUNCTION GetLastError& ()
14. END DECLARE
15.  
16. DIM volumeID AS STRING * 256, volumePathName AS STRING * 256, volumeName AS STRING * 256, volumeFS AS STRING * 256
17. DIM newMountPoint AS STRING
18. DIM volumeSerialNumber AS _UNSIGNED LONG
19. DIM size AS _UNSIGNED LONG
20. DIM handle AS LONG
21. DIM bool AS INTEGER
22.  
23. handle = FindFirstVolume(_OFFSET(volumeID), 256)
24.  
25. DO
26.     PRINT "Volume GUID = " + volumeID
27.     bool = GetVolumePathNamesForVolumeName(_OFFSET(volumeID), _OFFSET(volumePathName), 256, _OFFSET(size))
28.     IF LEN(MID$(volumePathName, 1, INSTR(volumePathName, CHR$(0)) - 1)) = 0 THEN
29.         PRINT "Not mounted"
30.         newMountPoint = firstFreeLetter + ":\"
31.         IF SetVolumeMountPoint(_OFFSET(newMountPoint), _OFFSET(volumeID)) <> 0 THEN
32.             bool = GetVolumePathNamesForVolumeName(_OFFSET(volumeID), _OFFSET(volumePathName), 256, _OFFSET(size))
33.             PRINT "Now mounted on " + volumePathName
34.         ELSE
35.             PRINT "Couldn't mount to " + newMountPoint, GetLastError
36.         END IF
37.     ELSE
38.         PRINT "Mounted on " + volumePathName
39.     END IF
40.     bool = GetVolumeInformation(_OFFSET(volumePathName), _OFFSET(volumeName), 256, _OFFSET(volumeSerialNumber), 0, 0, _OFFSET(volumeFS), 256)
41.     PRINT "Volume name "; volumeName; " FS = "; volumeFS; " Serial = "; LTRIM$(STR$(volumeSerialNumber))
42.     PRINT
43.     volumePathName = "" + CHR$(0): volumeFS = "" + CHR$(0): volumeName = "" + CHR$(0): volumeSerialNumber = 0
44. LOOP WHILE FindNextVolume(handle, _OFFSET(volumeID), 256)
45.  
46. bool = FindVolumeClose(handle)
47. SLEEP
48.  
49. FUNCTION firstFreeLetter$
50.     DIM freeLetters AS _UNSIGNED LONG
51.     freeLetters = GetLogicalDrives
52.     IF freeLetters < 4 THEN EXIT FUNCTION
53.     DIM letter AS INTEGER
54.     letter = ASC("C")
55.     DIM i AS _UNSIGNED LONG
56.     i = 4
57.     DO
58.         letter = letter + 1
59.         i = _SHL(i, 1)
60.     LOOP WHILE (freeLetters AND i) <> 0
61.     firstFreeLetter = CHR$(letter)
62. END FUNCTION

[Richard]

@SpriggsySpriggs

Just to let you know on how your program is working so far...

I unmounted usb stick (J:\) as per first program - result seems to be OK

then tried second program to mount - did not work as expected




CMD>dir j:\  reports   "The device is not ready"



the usb stick (J:\) does have a lot of files on it.

[SpriggsySpriggs]

You must run the code as administrator and you cannot have File Explorer open while doing either code. I'm looking at more code right now that works a little better but still having problems with it.

[SpriggsySpriggs]

@Richard

Here is my newest code. You need to run it as administrator but you can leave File Explorer open with this one. The downside: Removing a USB using this code will not allow you to just unplug it and plug it back in to remount it. It just won't mount. You have to run the MountDrives sub to mount all the unmounted drives (or just run mountvol <driveletter>: <volumeGUID> in an elevated command prompt).

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DIM driveLetter AS STRING
4. DO
5.     CLS
6.     INPUT "Enter drive letter: ", driveLetter
7. LOOP UNTIL driveLetter <> ""
8. EjectDrive driveLetter
9.  
10. SLEEP
11.  
12. MountDrives
13.  
14. SUB EjectDrive (driveLetter AS STRING)
15.     SHELL _HIDE "mountvol " + driveLetter + ": /P"
16. END SUB
17.  
18. SUB MountDrives
19.     DECLARE DYNAMIC LIBRARY "Kernel32"
20.         FUNCTION FindFirstVolume& ALIAS FindFirstVolumeA (BYVAL lpszVolumeName AS _OFFSET, BYVAL cchBufferLength AS LONG)
21.         FUNCTION FindNextVolume% ALIAS FindNextVolumeA (BYVAL hFindVolume AS LONG, BYVAL lpszVolumeName AS _OFFSET, BYVAL cchBufferLength AS LONG)
22.         FUNCTION GetVolumePathNamesForVolumeName% ALIAS GetVolumePathNamesForVolumeNameA (BYVAL lpszVolumeName AS _OFFSET, BYVAL lpszVolumePathNames AS _OFFSET, BYVAL cchBufferLength AS LONG, BYVAL lpcchReturnLength AS _OFFSET)
23.         FUNCTION GetLogicalDrives& ()
24.         FUNCTION SetVolumeMountPoint% ALIAS SetVolumeMountPointA (BYVAL lpszVolumeMountPoint AS _OFFSET, BYVAL lpszVolumeName AS _OFFSET)
25.         FUNCTION FindVolumeClose% (BYVAL hFindVolume AS LONG)
26.         FUNCTION GetLastError& ()
27.     END DECLARE
28.  
29.     DIM volumeID AS STRING * 256, volumePathName AS STRING * 256, volumeName AS STRING * 256, volumeFS AS STRING * 256
30.     DIM newMountPoint AS STRING * 4
31.     DIM volumeSerialNumber AS _UNSIGNED LONG
32.     DIM size AS _UNSIGNED LONG
33.     DIM handle AS LONG
34.     DIM bool AS INTEGER
35.  
36.     handle = FindFirstVolume(_OFFSET(volumeID), 256)
37.  
38.     DO
39.         bool = GetVolumePathNamesForVolumeName(_OFFSET(volumeID), _OFFSET(volumePathName), 256, _OFFSET(size))
40.         IF LEN(MID$(volumePathName, 1, INSTR(volumePathName, CHR$(0)) - 1)) = 0 THEN
41.             newMountPoint = firstFreeLetter + ":"
42.             SHELL _HIDE "mountvol " + newMountPoint + " " + MID$(volumeID, 1, INSTR(volumeID, CHR$(0)) - 1)
43.         END IF
44.     LOOP WHILE FindNextVolume(handle, _OFFSET(volumeID), 256)
45.     bool = FindVolumeClose(handle)
46. END SUB
47.  
48. FUNCTION firstFreeLetter$
49.     DIM freeLetters AS _UNSIGNED LONG
50.     freeLetters = GetLogicalDrives
51.     IF freeLetters < 4 THEN EXIT FUNCTION
52.     DIM letter AS INTEGER
53.     letter = ASC("C")
54.     DIM i AS _UNSIGNED LONG
55.     i = 4
56.     DO
57.         letter = letter + 1
58.         i = _SHL(i, 1)
59.     LOOP WHILE (freeLetters AND i) <> 0
60.     firstFreeLetter = CHR$(letter)
61. END FUNCTION

[Richard]

@SpriggsySpriggs

I think I may have misunderstood what you just replied...

I copied your first program (to eject drive)  - called it USBeject.exe
I copied the latest second program   - called it USBmount.exe

both of these exe were copied to A:\

Ran CMD as ADMINISTRATOR

a:\USBeject
A:\USBmount
dir J:\

THEN USED File Explorer to verify results.  J:\    not there

******** IT APPEARS that the usb stick is "Dead" now - it cannot be seen when physically placed in another usb slot (meaning it would become K:\) **************

if I get another usb stick (but not running your programs at all with it) - the other usb stick shows up as J:\ when inserted into the usb slot as to where the original J:\ stick was placed.

The data on the now "dead" usb stick was not really important (just the reboot Windows 10 x64 for build 20H2).

  [ You are not allowed to view this attachment ]  

[SpriggsySpriggs]

You've made your USB unmountable. Like I said, you need to run mountvol. You can open command prompt as administrator and run mountvol. It will tell you the drive that isn't mounted. Copy the full drive path and then follow the usage syntax for mounting it to a letter.

My latest code was for both functions as one source. The SLEEP command was to separate out the two things and to give you a pause for you to verify that the drive is unmounted. After you press enter it tries to mount whatever it finds that isn't mounted. First, run mountvol and follow my instructions for that since you've ran something out of order which is causing you to not get the drive back. You should be good after that.

[Richard]

@SpriggsySpriggs

As per your advice - my usb stick is now "alive" again

  [ You are not allowed to view this attachment ]  

I ran your combined program and the first part unmounted j:\ but still "listed" in file explorer but of course not "accessible" to view files (previously your first program did not "list" J:\ in file explorer)

  [ You are not allowed to view this attachment ]  

NOW (with usb stick not physically moved) allowed your combined program to continue

  [ You are not allowed to view this attachment ]  

BUT the device is STILL NOT READY.

NOW manually recovered J:\ to put J:\ back to normal

  [ You are not allowed to view this attachment ]  

Am I still missing something in the process?

[SpriggsySpriggs]

I don't know, @Richard .

Unless it is a versioning difference in Windows 10 (my version is Windows 10 64 bit 20H2, compiled in QB64 x64) I can't know for sure what is causing your run to be different than mine. It worked fine (for what it is) on my machine. What's your reason for wanting to eject and mount USB in QB64?

Are you running my code with simply the letter itself? No colon, no slash? You should only be having EjectDrive "J". Also, for remounting with mountvol, you only need it as mountvol J: \\?\Volume{whateveryourguidis}\