A quick program for folks to test

[SMcNeill]

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. ip$ = GetPublicIP$
5. PRINT "Your IP Address is:"; ip$
6. PRINT
7. Lat_Long ip$, lat, lon
8. PRINT "Your Latitude and Longitude is: "; lat, lon
9. PRINT
10. PRINT "For your location, the following is true for Xmas day:"
11. SunStuff lat, lon, 12, 25, 2020
12.  
13.  
14. FUNCTION GetPublicIP$
15.     f = FREEFILE
16.     OPEN "tempPIP.txt" FOR OUTPUT AS #f: CLOSE f
17.     SHELL _HIDE "cmd /c nslookup myip.opendns.com resolver1.opendns.com>tempPIP.txt"
18.  
19.     OPEN "tempPIP.txt" FOR INPUT AS #f
20.     IF LOF(f) THEN
21.         DO
22.             LINE INPUT #f, temp$
23.             IF temp$ <> "" THEN last$ = temp$ 'there's a blank line after the data we need.
24.             '                                 Ignore it.  What we want is the last line of info generated here.
25.         LOOP UNTIL EOF(1)
26.     END IF
27.     CLOSE f
28.     l = _INSTRREV(last$, "Address:")
29.     IF l THEN GetPublicIP$ = MID$(last$, l + 10)
30.     KILL "tempPIP.txt"
31. END FUNCTION
32.  
33. SUB Lat_Long (ip$, lat, lon)
34.     out$ = "powershell.exe -c " + CHR$(34) + "Invoke-Webrequest 'ip-api.com/line/"
35.     out$ = out$ + ip$
36.     out$ = out$ + "?fields=lat,lon' -OutFile '.\temp.txt'" + CHR$(34)
37.     SHELL _HIDE out$
38.     OPEN "temp.txt" FOR INPUT AS #1
39.     INPUT #1, lat
40.     INPUT #1, lon
41.     CLOSE 1
42. END SUB
43.  
44. SUB SunStuff (lat, lon, month, day, year)
45.     out$ = "powershell.exe -c " + CHR$(34) + "Invoke-Webrequest 'https://api.sunrise-sunset.org/json?lat="
46.     out$ = out$ + _TRIM$(STR$(lat)) + "&lng="
47.     out$ = out$ + _TRIM$(STR$(lon)) + "&date="
48.     d$ = _TRIM$(STR$(year)) + _TRIM$(STR$(month)) + _TRIM$(STR$(day))
49.     out$ = out$ + d$ + "'   -OutFile '.\temp.txt'"
50.     SHELL out$
51.     OPEN "temp.txt" FOR BINARY AS #1
52.     t$ = SPACE$(LOF(1))
53.     GET #1, 1, t$
54.     'strip off unwanted stuff
55.     l = INSTR(t$, ":{"): t$ = MID$(t$, l + 2)
56.     DO
57.         l = INSTR(t$, CHR$(34))
58.         t$ = LEFT$(t$, l - 1) + MID$(t$, l + 1)
59.     LOOP UNTIL l = 0
60.     DO
61.         l = INSTR(t$, "_")
62.         t$ = LEFT$(t$, l - 1) + " " + MID$(t$, l + 1)
63.     LOOP UNTIL l = 0
64.     t$ = _TRIM$(t$)
65.     t$ = LEFT$(t$, LEN(t$) - 1)
66.  
67.     DO
68.         l = INSTR(t$, ",")
69.         IF l = 0 THEN EXIT DO
70.         whole$ = LEFT$(t$, l)
71.         l$ = LEFT$(whole$, INSTR(whole$, ":") - 1)
72.         r$ = MID$(whole$, INSTR(whole$, ":") + 1)
73.         r$ = LEFT$(r$, LEN(r$) - 1)
74.         PRINT l$; " is "; r$
75.         t$ = MID$(t$, l + 1)
76.     LOOP
77.     CLOSE 1
78. END SUB
79.  

Output should look like the below (more, or less, changed by your location):

  [ You are not allowed to view this attachment ]  

Let me know if this fails to work for any of you Windows folk, and let me know what it does do (if anything at all), so I can work on this.  I'm hoping to add this into my little calendar program so that it'll always be able to give me sunrise and sunset times for my location in the world.  :D

[STxAxTIC]

Works awesome!

I was thinking about two things for the calendar, too. Might as well state them here.

1) Names of the days of the week across the top. I'm sure you kinda get used to the days not being there, but it would be a little more complete that way.

2) Externalizing holiday data as an external file. This opens up a big world, in the sense that if you let certain RSS feeds add to that data file, this calendar can archive or predict all kinds of stuff.

[SMcNeill]

NOTE: All times are in UTC and summer time adjustments are not included in the returned data.

[STxAxTIC]

Oh and - if you completely generalize the routine that undresses t$, you will have a JSON parser.

[SMcNeill]

Oh and - if you completely generalize the routine that undresses t$, you will have a JSON parser.

That's a job for another day.  ;)

As for days, that's easy enough to insert.  I'll add a CONST as a toggle for folks who want them, or not.

For the external holidays, I'm still sorting out the format I want to add for future versions.  I'm thinking something like:

Exact, 12,25, Christmas
Last, 12, 5, Foo_day
First, 12, 2, Fee_day

12/25 is Christmas
Last Thursday (5) in December (12) is Foo_day
First Monday (2) in December is Fee_day

Flexible enough for mouse holidays, and not so complex as to be indecipherable.

[Bert22306]

In my attempt, it said that it could not find the file in line 38. That's where you tell it to open temp.txt for input. And it's supposed to contain lat and long? Weird. I'll bet my enterprise net is blocking whatever you're trying to do here.

But, it did print out my IP address. Of course, that's an address behind the NAT, so it doesn't really help pinpoint my location. Wha' happened?

[SMcNeill]

In my attempt, it said that it could not find the file in line 38. That's where you tell it to input temp.txt.

But, it did print out my IP address. Of course, that's an address behind the NAT, so it doesn't really help pinpoint my location. Wha' happened?

Remove the _HIDE on line 37 and see what the output in the console looks like. 

Did it generate a lat/long value for you?

And you need permissions to run powershell scripts on your PC, as well, if that's an issue.

[Bert22306]

No. It says something about authentication required to reach the site, but it did show a public IP address, at least, as opposed to the one behind my NAT. I'm doing this test from my corporate enterprise net, which is almost certainly why these problems exist.

[Richard]

@Steve
🎄
  [ You are not allowed to view this attachment ]  

So in Australia we have longer Xmas days than you.

[SpriggsySpriggs]

I shall give this a try and use my pipecom library to get rid of the file operations.

[SMcNeill]

I shall give this a try and use my pipecom library to get rid of the file operations.

Personally, I prefer the file operations.  With them, I can check to see if the file exists, and if so, don't need to call the functions again.  ;)

[johnno56]

Hi Steve,

Mine didn't run. Linux Mint 20. "Line: 38 (in main module). File not found". "temp.txt"

J

[SMcNeill]

Hi Steve,

Mine didn't run. Linux Mint 20. "Line: 38 (in main module). File not found". "temp.txt"

J

Yours won't run, as it relies on window's Powershell to download info from the web.  I'll need to add a Linux method to do the same, and then it'll work for you.

[johnno56]

Thanks Steve... No rush... Just curious to see if it would work....

[SMcNeill]

Thanks Steve... No rush... Just curious to see if it would work....

Linux would probably just need to use wget instead.

SHELL "wget http://example.com/file.tar -O /path/to/dir/file.tar"

With the syntax above, used with the links from the powershell code, you should be able to download the same results on Linux as on windows.  I'll see about putting up some code for you to try later, so you can be my test monkey with it.  I don't usually try and code much for Linux, as all my personal stuff is windows, but this is easy enough to account for that I don't mind trying it blindfolded.  ;)