Emerging game: FluidCraft

[STxAxTIC]

Hello all,

Continuing the work started in https://www.qb64.org/forum/index.php?topic=2967.0, it's time to give this thing a name, and perhaps, a purpose. The so-called "particle engine" is now called FluidCraft, a 2D sandbox/pseudo-simulation tool for dealing with compressible fluids (a kind of thick gas you can play with). Left on their own, the gas particles will naturally repel each other, but not strictly - with enough "weight" involved, the particles compress and want to burst apart. Particles also bear a notion of hotness - the hot ones will rise, the cold ones will fall - and particles conduct or steal energy from their neighbors.

Apart from gravity, there are three fundamental "control" structures you can draw with the mouse (use mouse1 to draw, mousewheel to choose color).

1) Red lines are sources of heat and serve as a boundary for particles.
2) Blue lines are a source of cooling and are also a boundary.
3) Green lines move the particles strictly upward, no matter what.

So those are the fundamentals... Then, with no real effort at all, we get new effects by mixing colors. So far I've only hardcoded yellow, which is a mixture of red and green. Averaging the effects of red and green, yellow lines are "hot capillaries". Right mouse button deletes level elements.

There is also an export button, "e", for saving levels... which must imply a "load" feature. Indeed, drag+drop a level onto Untitled.exe (or FluidCraft.exe if you actually save it). I've included a sample level as a download. It never plays exactly the same twice. Of course, if you load no level, you get a blank slate, more or less. No screenshot this time, you have to run it.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _DELAY .25
3. _TITLE "FluidCraft"
4. SCREEN _NEWIMAGE(1024, 768, 32)
5. RANDOMIZE TIMER
6.  
7.  
8. TYPE Vector
9.     x AS DOUBLE
10.     y AS DOUBLE
11. END TYPE
12.  
13. TYPE ShadeVector
14.     shadered AS DOUBLE
15.     shadegreen AS DOUBLE
16.     shadeblue AS DOUBLE
17.     shadealpha AS DOUBLE
18. END TYPE
19.  
20. TYPE ShadeElement
21.     TheName AS STRING
22.     TheShade AS ShadeVector
23. END TYPE
24.  
25. TYPE Pixel
26.     active AS INTEGER
27.     position AS Vector
28.     velocity AS Vector
29.     acceleration AS Vector
30.     size AS DOUBLE
31.     TheShade AS ShadeVector
32. END TYPE
33.  
34. DIM SHARED ShadeData(4) AS ShadeElement
35. DIM SHARED ActiveShade AS INTEGER
36. DIM SHARED PixelCloud(3000) AS Pixel
37. DIM SHARED ObjectSize AS DOUBLE
38. DIM SHARED GridSize AS Vector
39. ObjectSize = 6
40. GridSize.x = 1 + INT(_WIDTH / ObjectSize)
41. GridSize.y = 1 + INT(_HEIGHT / ObjectSize)
42. DIM SHARED Level(GridSize.x, GridSize.y) AS ShadeVector
43.  
44. CALL InitializeAll
45. CALL LoadFile
46.  
47. DO
48.     CALL UserInput
49.     CLS
50.     CALL DrawBorder
51.     CALL DrawPixels
52.     CALL DrawLevel
53.     CALL Dynamics
54.     LINE (ObjectSize * INT(_MOUSEX / ObjectSize) - ObjectSize / 2, ObjectSize * INT(_MOUSEY / ObjectSize) - ObjectSize / 2)-(ObjectSize * INT(_MOUSEX / ObjectSize) + ObjectSize / 2 - 1, ObjectSize * INT(_MOUSEY / ObjectSize) + ObjectSize / 2 - 1), _RGBA(ShadeData(ActiveShade).TheShade.shadered, ShadeData(ActiveShade).TheShade.shadegreen, ShadeData(ActiveShade).TheShade.shadeblue, ShadeData(ActiveShade).TheShade.shadealpha), BF
55.     _DISPLAY
56.     _LIMIT 30
57. LOOP
58.  
59. END
60.  
61. SUB DrawBorder
62.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGB32(255, 0, 0, 255), BF
63.     LINE (10, 10)-(_WIDTH - 10, _HEIGHT - 10), _RGB32(0, 0, 0, 255), BF
64. END SUB
65.  
66. SUB DrawPixels
67.     DIM k AS INTEGER
68.     DIM x AS DOUBLE
69.     DIM y AS DOUBLE
70.     DIM s AS DOUBLE
71.     FOR k = 1 TO UBOUND(PixelCloud)
72.         IF (PixelCloud(k).active = 1) THEN
73.             x = PixelCloud(k).position.x
74.             y = PixelCloud(k).position.y
75.             s = PixelCloud(k).size
76.             CALL clinebf(x - s, y - s, x + s, y + s, _RGBA(PixelCloud(k).TheShade.shadered, PixelCloud(k).TheShade.shadegreen, PixelCloud(k).TheShade.shadeblue, PixelCloud(k).TheShade.shadealpha))
77.         END IF
78.     NEXT
79. END SUB
80.  
81. SUB DrawLevel
82.     DIM i AS INTEGER
83.     DIM j AS INTEGER
84.     DIM x AS DOUBLE
85.     DIM y AS DOUBLE
86.     DIM s AS DOUBLE
87.     s = ObjectSize
88.     FOR i = 1 TO GridSize.x
89.         FOR j = 1 TO GridSize.y
90.             x = (i - 1) * s
91.             y = (j - 1) * s
92.             CALL slinebf(x - s / 2, y - s / 2, x + s / 2 - 1, y + s / 2 - 1, _RGBA(Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha))
93.         NEXT
94.     NEXT
95. END SUB
96.  
97. SUB InitializeAll
98.     DIM k AS INTEGER
99.     ShadeData(1).TheName = "red"
100.     ShadeData(1).TheShade.shadered = 255
101.     ShadeData(1).TheShade.shadegreen = 0
102.     ShadeData(1).TheShade.shadeblue = 0
103.     ShadeData(1).TheShade.shadealpha = 255
104.     ShadeData(2).TheName = "green"
105.     ShadeData(2).TheShade.shadered = 0
106.     ShadeData(2).TheShade.shadegreen = 255
107.     ShadeData(2).TheShade.shadeblue = 0
108.     ShadeData(2).TheShade.shadealpha = 255
109.     ShadeData(3).TheName = "blue"
110.     ShadeData(3).TheShade.shadered = 0
111.     ShadeData(3).TheShade.shadegreen = 0
112.     ShadeData(3).TheShade.shadeblue = 255
113.     ShadeData(3).TheShade.shadealpha = 255
114.     ShadeData(4).TheName = "yellow"
115.     ShadeData(4).TheShade.shadered = 255
116.     ShadeData(4).TheShade.shadegreen = 255
117.     ShadeData(4).TheShade.shadeblue = 0
118.     ShadeData(4).TheShade.shadealpha = 255
119.     ActiveShade = 1
120.     FOR k = 1 TO UBOUND(PixelCloud)
121.         PixelCloud(k).active = 1
122.         PixelCloud(k).size = 3
123.         PixelCloud(k).acceleration.x = 0
124.         PixelCloud(k).acceleration.y = 0
125.         PixelCloud(k).velocity.x = 0
126.         PixelCloud(k).velocity.y = 0
127.         PixelCloud(k).position.x = (RND - .5) * _WIDTH * .9
128.         PixelCloud(k).position.y = (RND - .5) * _HEIGHT * .9
129.         CALL SetPixelShade(k, 0, 0, 255, 150)
130.     NEXT
131. END SUB
132.  
133. SUB SetPixelShade (i AS INTEGER, r AS INTEGER, g AS INTEGER, b AS INTEGER, a AS INTEGER)
134.     PixelCloud(i).TheShade.shadered = r
135.     PixelCloud(i).TheShade.shadegreen = g
136.     PixelCloud(i).TheShade.shadeblue = b
137.     PixelCloud(i).TheShade.shadealpha = a
138. END SUB
139.  
140. SUB UserInput
141.     DIM mb1 AS INTEGER
142.     DIM mb2 AS INTEGER
143.     DIM mb3 AS INTEGER
144.     DIM i AS INTEGER
145.     DIM j AS INTEGER
146.     mb1 = 0
147.     mb2 = 0
148.     mb3 = 0
149.     DO WHILE _MOUSEINPUT
150.         IF (_MOUSEBUTTON(1) = -1) AND (mb1 <> -1) THEN
151.             mb1 = -1
152.             i = 1 + INT(_MOUSEX / ObjectSize)
153.             j = 1 + INT(_MOUSEY / ObjectSize)
154.             Level(i, j).shadered = ShadeData(ActiveShade).TheShade.shadered
155.             Level(i, j).shadegreen = ShadeData(ActiveShade).TheShade.shadegreen
156.             Level(i, j).shadeblue = ShadeData(ActiveShade).TheShade.shadeblue
157.             Level(i, j).shadealpha = ShadeData(ActiveShade).TheShade.shadealpha
158.         END IF
159.         IF ((_MOUSEBUTTON(2) = -1) AND (mb2 <> -1)) THEN
160.             mb2 = -1
161.             i = 1 + INT(_MOUSEX / ObjectSize)
162.             j = 1 + INT(_MOUSEY / ObjectSize)
163.             Level(i, j).shadered = 0
164.             Level(i, j).shadegreen = 0
165.             Level(i, j).shadeblue = 0
166.             Level(i, j).shadealpha = 0
167.         END IF
168.         IF (_MOUSEWHEEL = -1) THEN
169.             ActiveShade = ActiveShade + 1
170.             IF (ActiveShade > UBOUND(ShadeData)) THEN
171.                 ActiveShade = 1
172.             END IF
173.         END IF
174.         IF (_MOUSEWHEEL = 1) THEN
175.             ActiveShade = ActiveShade - 1
176.             IF (ActiveShade < 1) THEN
177.                 ActiveShade = UBOUND(ShadeData)
178.             END IF
179.         END IF
180.     LOOP
181.     SELECT CASE _KEYHIT
182.         CASE ASC("e"), ASC("E")
183.             CALL Export
184.         CASE 27
185.             FOR i = 1 TO GridSize.x
186.                 FOR j = 1 TO GridSize.y
187.                     Level(i, j).shadered = 0
188.                     Level(i, j).shadegreen = 0
189.                     Level(i, j).shadeblue = 0
190.                     Level(i, j).shadealpha = 0
191.                 NEXT
192.             NEXT
193.     END SELECT
194.     DO WHILE _MOUSEINPUT: LOOP
195. END SUB
196.  
197. SUB Export
198.     DIM i AS INTEGER
199.     DIM j AS INTEGER
200.     OPEN "LiquidCraft" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt" FOR OUTPUT AS #1
201.     FOR i = 1 TO UBOUND(Level, 1)
202.         FOR j = 1 TO UBOUND(Level, 2)
203.             PRINT #1, i, j, Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha
204.         NEXT
205.     NEXT
206.     CLOSE #1
207. END SUB
208.  
209. SUB Dynamics
210.     DIM k AS INTEGER
211.     FOR k = 1 TO UBOUND(PixelCloud)
212.         CALL CalculateInfluence(k)
213.         CALL UpdatePosition(k)
214.     NEXT
215. END SUB
216.  
217. SUB UpdatePosition (i AS INTEGER)
218.     DIM dt AS DOUBLE
219.     DIM damp AS DOUBLE
220.     DIM brownian AS DOUBLE
221.     dt = 2
222.     damp = .25
223.     brownian = .525
224.     PixelCloud(i).velocity.x = damp * PixelCloud(i).velocity.x + dt * PixelCloud(i).acceleration.x
225.     PixelCloud(i).velocity.y = damp * PixelCloud(i).velocity.y + dt * PixelCloud(i).acceleration.y
226.     PixelCloud(i).position.x = PixelCloud(i).position.x + dt * PixelCloud(i).velocity.x + (RND - .5) * brownian
227.     PixelCloud(i).position.y = PixelCloud(i).position.y + dt * PixelCloud(i).velocity.y + (RND - .5) * brownian
228.     IF (PixelCloud(i).position.y <= -_HEIGHT / 2 + 2 * PixelCloud(i).size + 1) THEN
229.         PixelCloud(i).position.y = _HEIGHT / 2 - 2 * PixelCloud(i).size
230.     END IF
231. END SUB
232.  
233. SUB CalculateInfluence (i AS INTEGER)
234.     DIM x AS DOUBLE
235.     DIM y AS DOUBLE
236.     DIM dx AS DOUBLE
237.     DIM dy AS DOUBLE
238.     DIM xr AS DOUBLE
239.     DIM yr AS DOUBLE
240.     DIM xg AS DOUBLE
241.     DIM yg AS DOUBLE
242.     DIM xb AS DOUBLE
243.     DIM yb AS DOUBLE
244.     DIM WPoint(9) AS _UNSIGNED LONG
245.     DIM WRed(9) AS INTEGER
246.     DIM WGreen(9) AS INTEGER
247.     DIM WBlue(9) AS INTEGER
248.     x = PixelCloud(i).position.x
249.     y = PixelCloud(i).position.y
250.     dx = 2 * PixelCloud(i).size
251.     dy = 2 * PixelCloud(i).size
252.     WPoint(7) = cpoint(x - dx, y + dy)
253.     WPoint(8) = cpoint(x, y + dy)
254.     WPoint(9) = cpoint(x + dx, y + dy)
255.     WPoint(4) = cpoint(x - dx, y)
256.     WPoint(6) = cpoint(x + dx, y)
257.     WPoint(1) = cpoint(x - dx, y - dy)
258.     WPoint(2) = cpoint(x, y - dy)
259.     WPoint(3) = cpoint(x + dx, y - dy)
260.     WRed(7) = _RED32(WPoint(7))
261.     WRed(8) = _RED32(WPoint(8))
262.     WRed(9) = _RED32(WPoint(9))
263.     WRed(4) = _RED32(WPoint(4))
264.     WRed(6) = _RED32(WPoint(6))
265.     WRed(1) = _RED32(WPoint(1))
266.     WRed(2) = _RED32(WPoint(2))
267.     WRed(3) = _RED32(WPoint(3))
268.     WGreen(7) = _GREEN32(WPoint(7))
269.     WGreen(8) = _GREEN32(WPoint(8))
270.     WGreen(9) = _GREEN32(WPoint(9))
271.     WGreen(4) = _GREEN32(WPoint(4))
272.     WGreen(6) = _GREEN32(WPoint(6))
273.     WGreen(1) = _GREEN32(WPoint(1))
274.     WGreen(2) = _GREEN32(WPoint(2))
275.     WGreen(3) = _GREEN32(WPoint(3))
276.     WBlue(7) = _BLUE32(WPoint(7))
277.     WBlue(8) = _BLUE32(WPoint(8))
278.     WBlue(9) = _BLUE32(WPoint(9))
279.     WBlue(4) = _BLUE32(WPoint(4))
280.     WBlue(6) = _BLUE32(WPoint(6))
281.     WBlue(1) = _BLUE32(WPoint(1))
282.     WBlue(2) = _BLUE32(WPoint(2))
283.     WBlue(3) = _BLUE32(WPoint(3))
284.  
285.     xr = (WRed(6) - WRed(4) + (WRed(9) + WRed(3)) / SQR(2) - (WRed(7) + WRed(1)) / SQR(2))
286.     yr = (WRed(8) - WRed(2) + (WRed(7) + WRed(9)) / SQR(2) - (WRed(1) + WRed(3)) / SQR(2))
287.     xg = -(WGreen(6) - WGreen(4) + (WGreen(9) + WGreen(3)) / SQR(2) - (WGreen(7) + WGreen(1)) / SQR(2))
288.     yg = 10 * (0 - WGreen(2) + (0 + 0) / SQR(2) - (WGreen(1) + WGreen(3)) / SQR(2))
289.     xb = (WBlue(6) - WBlue(4) + (WBlue(9) + WBlue(3)) / SQR(2) - (WBlue(7) + WBlue(1)) / SQR(2))
290.     yb = (WBlue(8) - WBlue(2) + (WBlue(7) + WBlue(9)) / SQR(2) - (WBlue(1) + WBlue(3)) / SQR(2))
291.  
292.     x = xr + xg + xb
293.     y = yr + yg + yb
294.  
295.     IF (xr ^ 2 + yr ^ 2 > xb ^ 2 + yb ^ 2) AND (xr ^ 2 + yr ^ 2 > 16) THEN
296.         PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered + 64
297.         IF (PixelCloud(i).TheShade.shadered >= 255) THEN PixelCloud(i).TheShade.shadered = 255
298.         PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue - 64
299.         IF (PixelCloud(i).TheShade.shadeblue <= 0) THEN PixelCloud(i).TheShade.shadeblue = 0
300.     END IF
301.  
302.     IF (xb ^ 2 + yb ^ 2 > xr ^ 2 + yr ^ 2) THEN
303.         PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 64
304.         IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
305.         PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 64
306.         IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
307.     END IF
308.  
309.     y = y - 2 * (PixelCloud(i).TheShade.shadered - PixelCloud(i).TheShade.shadeblue) / 255
310.  
311.     IF (ABS(x) < .001) THEN
312.         PixelCloud(i).acceleration.x = 0
313.     ELSE
314.         PixelCloud(i).acceleration.x = -x / SQR(x * x + y * y)
315.     END IF
316.     IF (ABS(y) < .001) THEN
317.         PixelCloud(i).acceleration.y = 0
318.     ELSE
319.         PixelCloud(i).acceleration.y = -y / SQR(x * x + y * y)
320.     END IF
321.  
322.     PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 2 '5
323.     IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
324.     PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 2 '5
325.     IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
326. END SUB
327.  
328. FUNCTION cpoint& (x1 AS DOUBLE, y1 AS DOUBLE)
329.     DIM TheReturn AS _UNSIGNED LONG
330.     TheReturn = POINT(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)
331.     cpoint = TheReturn
332. END FUNCTION
333.  
334. SUB clinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
335.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2 - 0, -y2 + _HEIGHT / 2 + 0), col, BF
336. END SUB
337.  
338. SUB slinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
339.     LINE (x1, y1)-(x2, y2), col, BF
340. END SUB
341.  
342. SUB LoadFile
343.     DIM i AS INTEGER
344.     DIM j AS INTEGER
345.     DIM r AS INTEGER
346.     DIM g AS INTEGER
347.     DIM b AS INTEGER
348.     DIM a AS INTEGER
349.     IF (COMMAND$ <> "") THEN
350.         PRINT "Loading..."
351.         OPEN COMMAND$ FOR INPUT AS #1
352.         DO WHILE NOT EOF(1)
353.             INPUT #1, i, j, r, g, b, a
354.             Level(i, j).shadered = r
355.             Level(i, j).shadegreen = g
356.             Level(i, j).shadeblue = b
357.             Level(i, j).shadealpha = a
358.         LOOP
359.         CLOSE #1
360.     END IF
361. END SUB
362.  

[Juan Tamarit]

Code: QB64: [Select]

1. TYPE ShadeVector
2.     shadered AS DOUBLE
3.     shadegreen AS DOUBLE
4.     shadeblue AS DOUBLE
5.     shadealpha AS DOUBLE
6. END TYPE
7.  
8. TYPE ShadeElement
9.     TheName AS STRING
10.     TheShade AS ShadeVector
11. END TYPE
12.  

I'm very interested about this. In line 22 of your code you got a TYPE inside a TYPE? How do you access it? say... How can you access the string and the doubles?

[STxAxTIC]

Good morning Juan,

Types within types are a dream aren't they? To access embedded stuff, we have the "dot" operator ( . ), which you can use more than once per line, like so:

Code: QB64: [Select]

1. PixelCloud(i).acceleration.x = -x / SQR(x * x + y * y)

Looks like I came to the particle fountain party too late because you have the first legit question about any of this! Whats the matter boys, everything in here too trivial for you?

[bplus]

As per usual very interesting "game"? red goes right through green as if not there but green stops blue. Blue may contain red a bit...

I immediately wish for black eraser.

 

[STxAxTIC]

Right click to erase (sorry on road no verbosity)

[bplus]

Right click to erase (sorry on road no verbosity)

Ah OK, thanks :)

[Juan Tamarit]

Good morning Juan,

Types within types are a dream aren't they? To access embedded stuff, we have the "dot" operator ( . ), which you can use more than once per line, like so:

Code: QB64: [Select]

1. PixelCloud(i).acceleration.x = -x / SQR(x * x + y * y)

Looks like I came to the particle fountain party too late because you have the first legit question about any of this! Whats the matter boys, everything in here too trivial for you?

Bro, thank you for your reply. Very interesting what you comment on TYPEs inside TYPEs... i can't mentally DIM it yet (feels like from another planet more than another dimension), but i will think about it. I honestly don´t know what particles are, didn't get to that point of Terrie's course yet, but sounds like a bit of pieces blowing away from an explosion hehehe

[Ashish]

Wow! This is great! I spend 30 mins playing with this. I could also create a loop! It will be great if we could draw the obstacles as well. :D

[STxAxTIC]

Thanks Ashish and everyone - bplus, loudar, Juan and whoever else - for trying this.

So this latest version has updated mechanics. We still have the same rules as before (except new behavior for yellow), plus some new ones...

1) Red lines are sources of heat and serve as a boundary for particles.
2) Blue lines are a source of cooling and are also a boundary.
3) Green lines move the particles strictly upward.
4) Aqua lines move particles strictly to the right.
5) Yellow lines move particles strictly to the left.
6) White lines move particles strictly downward.

The mouse control is way way better too. (Thanks for tolerating the crappy first take...) You'll find that colors can be stacked all the way to white. Right click to delete, use mousewheel to select between them.

Updated code, test level, and screenshot below. You can see this one is all about getting all the primitive behavior correct. By now we can represent most of the plumbing and hvac apparatus found in north america. The next update will prolly be less about mechanics and more about UI.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "FluidCraft"
3. _DELAY .25
4. SCREEN _NEWIMAGE(1024, 768, 32)
5. RANDOMIZE TIMER
6.  
7. TYPE Vector
8.     x AS DOUBLE
9.     y AS DOUBLE
10. END TYPE
11.  
12. TYPE ShadeVector
13.     shadered AS DOUBLE
14.     shadegreen AS DOUBLE
15.     shadeblue AS DOUBLE
16.     shadealpha AS DOUBLE
17. END TYPE
18.  
19. TYPE ShadeElement
20.     TheName AS STRING
21.     TheShade AS ShadeVector
22. END TYPE
23.  
24. TYPE Pixel
25.     active AS INTEGER
26.     position AS Vector
27.     velocity AS Vector
28.     acceleration AS Vector
29.     size AS DOUBLE
30.     TheShade AS ShadeVector
31. END TYPE
32.  
33. DIM SHARED ShadeData(7) AS ShadeElement
34. DIM SHARED ActiveShade AS INTEGER
35. DIM SHARED PixelCloud(3000) AS Pixel
36. DIM SHARED ObjectSize AS DOUBLE
37. DIM SHARED GridSize AS Vector
38. ObjectSize = 6
39. GridSize.x = 1 + INT(_WIDTH / ObjectSize)
40. GridSize.y = 1 + INT(_HEIGHT / ObjectSize)
41. DIM SHARED Level(GridSize.x, GridSize.y) AS ShadeVector
42.  
43. CALL InitializeAll
44. CALL LoadFile
45.  
46. DO
47.     CALL UserInput
48.     CLS
49.     CALL DrawBorder
50.     CALL DrawPixels
51.     CALL DrawLevel
52.     CALL Dynamics
53.     LINE (ObjectSize * INT(_MOUSEX / ObjectSize) - ObjectSize / 2, ObjectSize * INT(_MOUSEY / ObjectSize) - ObjectSize / 2)-(ObjectSize * INT(_MOUSEX / ObjectSize) + ObjectSize / 2 - 1, ObjectSize * INT(_MOUSEY / ObjectSize) + ObjectSize / 2 - 1), _RGBA(ShadeData(ActiveShade).TheShade.shadered, ShadeData(ActiveShade).TheShade.shadegreen, ShadeData(ActiveShade).TheShade.shadeblue, ShadeData(ActiveShade).TheShade.shadealpha), BF
54.     _DISPLAY
55.     _LIMIT 30
56. LOOP
57.  
58. END
59.  
60. SUB DrawBorder
61.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGB32(255, 0, 0, 255), BF
62.     LINE (10, 10)-(_WIDTH - 10, _HEIGHT - 10), _RGB32(0, 0, 0, 255), BF
63. END SUB
64.  
65. SUB DrawPixels
66.     DIM k AS INTEGER
67.     DIM x AS DOUBLE
68.     DIM y AS DOUBLE
69.     DIM s AS DOUBLE
70.     FOR k = 1 TO UBOUND(PixelCloud)
71.         IF (PixelCloud(k).active = 1) THEN
72.             x = PixelCloud(k).position.x
73.             y = PixelCloud(k).position.y
74.             s = PixelCloud(k).size
75.             CALL clinebf(x - s, y - s, x + s, y + s, _RGBA(PixelCloud(k).TheShade.shadered, PixelCloud(k).TheShade.shadegreen, PixelCloud(k).TheShade.shadeblue, PixelCloud(k).TheShade.shadealpha))
76.         END IF
77.     NEXT
78. END SUB
79.  
80. SUB DrawLevel
81.     DIM i AS INTEGER
82.     DIM j AS INTEGER
83.     DIM x AS DOUBLE
84.     DIM y AS DOUBLE
85.     DIM s AS DOUBLE
86.     s = ObjectSize
87.     FOR i = 1 TO GridSize.x
88.         FOR j = 1 TO GridSize.y
89.             x = (i - 1) * s
90.             y = (j - 1) * s
91.             CALL slinebf(x - s / 2, y - s / 2, x + s / 2 - 1, y + s / 2 - 1, _RGBA(Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha))
92.         NEXT
93.     NEXT
94. END SUB
95.  
96. SUB InitializeAll
97.     DIM k AS INTEGER
98.     ShadeData(1).TheName = "red"
99.     ShadeData(1).TheShade.shadered = 255
100.     ShadeData(1).TheShade.shadegreen = 0
101.     ShadeData(1).TheShade.shadeblue = 0
102.     ShadeData(1).TheShade.shadealpha = 255
103.     ShadeData(2).TheName = "green"
104.     ShadeData(2).TheShade.shadered = 0
105.     ShadeData(2).TheShade.shadegreen = 255
106.     ShadeData(2).TheShade.shadeblue = 0
107.     ShadeData(2).TheShade.shadealpha = 255
108.     ShadeData(3).TheName = "blue"
109.     ShadeData(3).TheShade.shadered = 0
110.     ShadeData(3).TheShade.shadegreen = 0
111.     ShadeData(3).TheShade.shadeblue = 255
112.     ShadeData(3).TheShade.shadealpha = 255
113.     ShadeData(4).TheName = "yellow"
114.     ShadeData(4).TheShade.shadered = 255
115.     ShadeData(4).TheShade.shadegreen = 255
116.     ShadeData(4).TheShade.shadeblue = 0
117.     ShadeData(4).TheShade.shadealpha = 255
118.     ShadeData(5).TheName = "aqua"
119.     ShadeData(5).TheShade.shadered = 0
120.     ShadeData(5).TheShade.shadegreen = 255
121.     ShadeData(5).TheShade.shadeblue = 255
122.     ShadeData(5).TheShade.shadealpha = 255
123.     ShadeData(6).TheName = "violet"
124.     ShadeData(6).TheShade.shadered = 255
125.     ShadeData(6).TheShade.shadegreen = 0
126.     ShadeData(6).TheShade.shadeblue = 255
127.     ShadeData(6).TheShade.shadealpha = 255
128.     ShadeData(7).TheName = "white"
129.     ShadeData(7).TheShade.shadered = 255
130.     ShadeData(7).TheShade.shadegreen = 255
131.     ShadeData(7).TheShade.shadeblue = 255
132.     ShadeData(7).TheShade.shadealpha = 255
133.  
134.  
135.     ActiveShade = 1
136.     FOR k = 1 TO UBOUND(PixelCloud)
137.         PixelCloud(k).active = 1
138.         PixelCloud(k).size = 3
139.         PixelCloud(k).acceleration.x = 0
140.         PixelCloud(k).acceleration.y = 0
141.         PixelCloud(k).velocity.x = 0
142.         PixelCloud(k).velocity.y = 0
143.         PixelCloud(k).position.x = (RND - .5) * _WIDTH * .9
144.         PixelCloud(k).position.y = (RND - .5) * _HEIGHT * .9
145.         CALL SetPixelShade(k, 0, 0, 255, 150)
146.     NEXT
147. END SUB
148.  
149. SUB SetPixelShade (i AS INTEGER, r AS INTEGER, g AS INTEGER, b AS INTEGER, a AS INTEGER)
150.     PixelCloud(i).TheShade.shadered = r
151.     PixelCloud(i).TheShade.shadegreen = g
152.     PixelCloud(i).TheShade.shadeblue = b
153.     PixelCloud(i).TheShade.shadealpha = a
154. END SUB
155.  
156. SUB UserInput
157.     DIM mb1 AS INTEGER
158.     DIM mb2 AS INTEGER
159.     DIM mb3 AS INTEGER
160.     DIM i AS INTEGER
161.     DIM j AS INTEGER
162.     mb1 = 0
163.     mb2 = 0
164.     mb3 = 0
165.     DO WHILE _MOUSEINPUT
166.         IF (_MOUSEBUTTON(1) = -1) AND (mb1 <> 1) THEN
167.             mb1 = -1
168.             i = 1 + INT(_MOUSEX / ObjectSize)
169.             j = 1 + INT(_MOUSEY / ObjectSize)
170.             Level(i, j).shadered = Level(i, j).shadered + ShadeData(ActiveShade).TheShade.shadered
171.             Level(i, j).shadegreen = Level(i, j).shadegreen + ShadeData(ActiveShade).TheShade.shadegreen
172.             Level(i, j).shadeblue = Level(i, j).shadeblue + ShadeData(ActiveShade).TheShade.shadeblue
173.             Level(i, j).shadealpha = Level(i, j).shadealpha + ShadeData(ActiveShade).TheShade.shadealpha
174.         END IF
175.         IF ((_MOUSEBUTTON(2) = -1) AND (mb2 <> -1)) THEN
176.             mb2 = -1
177.             i = 1 + INT(_MOUSEX / ObjectSize)
178.             j = 1 + INT(_MOUSEY / ObjectSize)
179.             Level(i, j).shadered = 0
180.             Level(i, j).shadegreen = 0
181.             Level(i, j).shadeblue = 0
182.             Level(i, j).shadealpha = 0
183.         END IF
184.         IF (_MOUSEWHEEL = -1) THEN
185.             ActiveShade = ActiveShade + 1
186.             IF (ActiveShade > UBOUND(ShadeData)) THEN
187.                 ActiveShade = 1
188.             END IF
189.         END IF
190.         IF (_MOUSEWHEEL = 1) THEN
191.             ActiveShade = ActiveShade - 1
192.             IF (ActiveShade < 1) THEN
193.                 ActiveShade = UBOUND(ShadeData)
194.             END IF
195.         END IF
196.     LOOP
197.     SELECT CASE _KEYHIT
198.         CASE ASC("e"), ASC("E")
199.             CALL Export
200.         CASE 27
201.             FOR i = 1 TO GridSize.x
202.                 FOR j = 1 TO GridSize.y
203.                     Level(i, j).shadered = 0
204.                     Level(i, j).shadegreen = 0
205.                     Level(i, j).shadeblue = 0
206.                     Level(i, j).shadealpha = 0
207.                 NEXT
208.             NEXT
209.     END SELECT
210.     DO WHILE _MOUSEINPUT: LOOP
211. END SUB
212.  
213. SUB Export
214.     DIM i AS INTEGER
215.     DIM j AS INTEGER
216.     OPEN "FluidCraft" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt" FOR OUTPUT AS #1
217.     FOR i = 1 TO UBOUND(Level, 1)
218.         FOR j = 1 TO UBOUND(Level, 2)
219.             PRINT #1, i, j, Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha
220.         NEXT
221.     NEXT
222.     CLOSE #1
223. END SUB
224.  
225. SUB Dynamics
226.     DIM k AS INTEGER
227.     FOR k = 1 TO UBOUND(PixelCloud)
228.         CALL CalculateInfluence(k)
229.         CALL UpdatePosition(k)
230.     NEXT
231. END SUB
232.  
233. SUB UpdatePosition (i AS INTEGER)
234.     DIM dt AS DOUBLE
235.     DIM damp AS DOUBLE
236.     DIM brownian AS DOUBLE
237.     dt = 1
238.     damp = 0.8 '.1 '0.5 '.25
239.     brownian = .5 '1 'PixelCloud(i).size / 4 '1 '.525
240.     PixelCloud(i).velocity.x = damp * PixelCloud(i).velocity.x + dt * PixelCloud(i).acceleration.x
241.     PixelCloud(i).velocity.y = damp * PixelCloud(i).velocity.y + dt * PixelCloud(i).acceleration.y
242.     PixelCloud(i).position.x = PixelCloud(i).position.x + dt * PixelCloud(i).velocity.x + (RND - .5) * brownian
243.     PixelCloud(i).position.y = PixelCloud(i).position.y + dt * PixelCloud(i).velocity.y + (RND - .5) * brownian
244.     IF (PixelCloud(i).position.y <= -_HEIGHT / 2 + 2 * PixelCloud(i).size + 1) THEN
245.         PixelCloud(i).position.y = _HEIGHT / 2 - 2 * PixelCloud(i).size
246.     END IF
247. END SUB
248.  
249. SUB CalculateInfluence (i AS INTEGER)
250.     DIM x AS DOUBLE
251.     DIM y AS DOUBLE
252.     DIM dx AS DOUBLE
253.     DIM dy AS DOUBLE
254.     DIM xr AS DOUBLE
255.     DIM yr AS DOUBLE
256.     DIM xg AS DOUBLE
257.     DIM yg AS DOUBLE
258.     DIM xb AS DOUBLE
259.     DIM yb AS DOUBLE
260.     DIM WPoint(9) AS _UNSIGNED LONG
261.     DIM WRed(9) AS DOUBLE
262.     DIM WGreen(9) AS DOUBLE
263.     DIM WBlue(9) AS DOUBLE
264.     x = PixelCloud(i).position.x
265.     y = PixelCloud(i).position.y
266.     dx = 2 * PixelCloud(i).size
267.     dy = 2 * PixelCloud(i).size
268.     WPoint(7) = cpoint(x - dx, y + dy)
269.     WPoint(8) = cpoint(x, y + dy)
270.     WPoint(9) = cpoint(x + dx, y + dy)
271.     WPoint(4) = cpoint(x - dx, y)
272.     WPoint(6) = cpoint(x + dx, y)
273.     WPoint(1) = cpoint(x - dx, y - dy)
274.     WPoint(2) = cpoint(x, y - dy)
275.     WPoint(3) = cpoint(x + dx, y - dy)
276.     WRed(7) = _RED32(WPoint(7)) * _ALPHA32(WPoint(7))
277.     WRed(8) = _RED32(WPoint(8)) * _ALPHA32(WPoint(8))
278.     WRed(9) = _RED32(WPoint(9)) * _ALPHA32(WPoint(9))
279.     WRed(4) = _RED32(WPoint(4)) * _ALPHA32(WPoint(4))
280.     'WRed(5) = 0
281.     WRed(6) = _RED32(WPoint(6)) * _ALPHA32(WPoint(6))
282.     WRed(1) = _RED32(WPoint(1)) * _ALPHA32(WPoint(1))
283.     WRed(2) = _RED32(WPoint(2)) * _ALPHA32(WPoint(2))
284.     WRed(3) = _RED32(WPoint(3)) * _ALPHA32(WPoint(3))
285.     WGreen(7) = _GREEN32(WPoint(7)) * _ALPHA32(WPoint(7))
286.     WGreen(8) = _GREEN32(WPoint(8)) * _ALPHA32(WPoint(8))
287.     WGreen(9) = _GREEN32(WPoint(9)) * _ALPHA32(WPoint(9))
288.     WGreen(4) = _GREEN32(WPoint(4)) * _ALPHA32(WPoint(4))
289.     'WGreen(5) = 0
290.     WGreen(6) = _GREEN32(WPoint(6)) * _ALPHA32(WPoint(6))
291.     WGreen(1) = _GREEN32(WPoint(1)) * _ALPHA32(WPoint(1))
292.     WGreen(2) = _GREEN32(WPoint(2)) * _ALPHA32(WPoint(2))
293.     WGreen(3) = _GREEN32(WPoint(3)) * _ALPHA32(WPoint(3))
294.     WBlue(7) = _BLUE32(WPoint(7)) * _ALPHA32(WPoint(7))
295.     WBlue(8) = _BLUE32(WPoint(8)) * _ALPHA32(WPoint(8))
296.     WBlue(9) = _BLUE32(WPoint(9)) * _ALPHA32(WPoint(9))
297.     WBlue(4) = _BLUE32(WPoint(4)) * _ALPHA32(WPoint(4))
298.     'WBlue(5) = 0
299.     WBlue(6) = _BLUE32(WPoint(6)) * _ALPHA32(WPoint(6))
300.     WBlue(1) = _BLUE32(WPoint(1)) * _ALPHA32(WPoint(1))
301.     WBlue(2) = _BLUE32(WPoint(2)) * _ALPHA32(WPoint(2))
302.     WBlue(3) = _BLUE32(WPoint(3)) * _ALPHA32(WPoint(3))
303.  
304.     xr = (WRed(6) - WRed(4) + (WRed(9) + WRed(3)) / SQR(2) - (WRed(7) + WRed(1)) / SQR(2))
305.     yr = (WRed(8) - WRed(2) + (WRed(7) + WRed(9)) / SQR(2) - (WRed(1) + WRed(3)) / SQR(2))
306.     xg = -(WGreen(6) - WGreen(4) + (WGreen(9) + WGreen(3)) / SQR(2) - (WGreen(7) + WGreen(1)) / SQR(2))
307.     yg = (0 - WGreen(2) + (0 + 0) / SQR(2) - (WGreen(1) + WGreen(3)) / SQR(2))
308.     xb = (WBlue(6) - WBlue(4) + (WBlue(9) + WBlue(3)) / SQR(2) - (WBlue(7) + WBlue(1)) / SQR(2))
309.     yb = (WBlue(8) - WBlue(2) + (WBlue(7) + WBlue(9)) / SQR(2) - (WBlue(1) + WBlue(3)) / SQR(2))
310.  
311.     x = xr + xg + xb
312.     y = yr + yg + yb
313.  
314.     '''
315.     DIM k AS INTEGER
316.     DIM WMixed(9) AS DOUBLE
317.     DIM xc AS DOUBLE
318.     DIM yc AS DOUBLE
319.     DIM cs AS INTEGER
320.     cs = 0
321.  
322.     ' yellow
323.     xc = 0
324.     yc = 0
325.     FOR k = 1 TO 9
326.         IF WRed(k) > 250 AND WGreen(k) > 250 AND WBlue(k) < 50 AND k <> 5 THEN
327.             WMixed(k) = 255
328.         ELSE
329.             WMixed(k) = 0
330.         END IF
331.     NEXT
332.     xc = (WMixed(6) - 0 + (WMixed(9) + WMixed(3)) / SQR(2) - (0 + 0) / SQR(2))
333.     yc = -(WMixed(8) - WMixed(2) + (WMixed(7) + WMixed(9)) / SQR(2) - (WMixed(1) + WMixed(3)) / SQR(2))
334.     IF xc <> 0 OR yc <> 0 THEN
335.         cs = 1
336.         x = xc
337.         y = yc
338.     END IF
339.  
340.     ' aqua
341.     xc = 0
342.     yc = 0
343.     FOR k = 1 TO 9
344.         IF WRed(k) < 50 AND WGreen(k) > 250 AND WBlue(k) > 250 AND k <> 5 THEN
345.             WMixed(k) = 255
346.         ELSE
347.             WMixed(k) = 0
348.         END IF
349.     NEXT
350.     xc = -(WMixed(6) - 0 + (WMixed(9) + WMixed(3)) / SQR(2) - (0 + 0) / SQR(2))
351.     yc = -(WMixed(8) - WMixed(2) + (WMixed(7) + WMixed(9)) / SQR(2) - (WMixed(1) + WMixed(3)) / SQR(2))
352.     IF xc <> 0 OR yc <> 0 THEN
353.         cs = 1
354.         x = xc
355.         y = yc
356.     END IF
357.  
358.     ' white
359.     xc = 0
360.     yc = 0
361.     FOR k = 1 TO 9
362.         IF WRed(k) >= 254 AND WGreen(k) >= 254 AND WBlue(k) >= 254 AND k <> 5 THEN
363.             WMixed(k) = 255
364.         ELSE
365.             WMixed(k) = 0
366.         END IF
367.     NEXT
368.     xc = -(WMixed(6) - WMixed(4) + (WMixed(9) + WMixed(3)) / SQR(2) - (WMixed(7) + WMixed(1)) / SQR(2))
369.     yc = -(0 - WMixed(2) + (0 + 0) / SQR(2) - (WMixed(1) + WMixed(3)) / SQR(2))
370.     IF xc <> 0 OR yc <> 0 THEN
371.         cs = 1
372.         x = xc
373.         y = yc
374.     END IF
375.  
376.  
377.  
378.  
379.  
380.     '''
381.  
382.     ' Particle conductivity
383.     IF cs = 0 THEN
384.         IF (((xr * xr + yr * yr) > (xb * xb + yb * yb)) AND (xr * xr + yr * yr > 16) AND (xg * xg + yg * yg < 16)) THEN
385.             PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered + 64
386.             IF (PixelCloud(i).TheShade.shadered >= 255) THEN PixelCloud(i).TheShade.shadered = 255
387.             PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue - 64
388.             IF (PixelCloud(i).TheShade.shadeblue <= 0) THEN PixelCloud(i).TheShade.shadeblue = 0
389.         END IF
390.  
391.         IF ((xb * xb + yb * yb) > (xr * xr + yr * yr) AND (xg * xg + yg * yg < 16)) THEN
392.             PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 64
393.             IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
394.             PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 64
395.             IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
396.         END IF
397.     END IF
398.  
399.     ' Gravity or levity
400.     y = y - (PixelCloud(i).TheShade.shadered - PixelCloud(i).TheShade.shadeblue) / 255
401.  
402.     ' Normalize acceleration
403.     IF (ABS(x) < .001) THEN
404.         PixelCloud(i).acceleration.x = 0
405.     ELSE
406.         PixelCloud(i).acceleration.x = -x / SQR(x * x + y * y)
407.     END IF
408.     IF (ABS(y) < .001) THEN
409.         PixelCloud(i).acceleration.y = 0
410.     ELSE
411.         PixelCloud(i).acceleration.y = -y / SQR(x * x + y * y)
412.     END IF
413.  
414.     ' Auto-cooling
415.     PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 2
416.     IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
417.     PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 2
418.     IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
419.  
420. END SUB
421.  
422. FUNCTION cpoint& (x1 AS DOUBLE, y1 AS DOUBLE)
423.     DIM TheReturn AS _UNSIGNED LONG
424.     TheReturn = POINT(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)
425.     cpoint = TheReturn
426. END FUNCTION
427.  
428. SUB clinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
429.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2 - 0, -y2 + _HEIGHT / 2 + 0), col, BF
430. END SUB
431.  
432. SUB slinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
433.     LINE (x1, y1)-(x2, y2), col, BF
434. END SUB
435.  
436. SUB LoadFile
437.     DIM i AS INTEGER
438.     DIM j AS INTEGER
439.     DIM r AS INTEGER
440.     DIM g AS INTEGER
441.     DIM b AS INTEGER
442.     DIM a AS INTEGER
443.     IF (COMMAND$ <> "") THEN
444.         PRINT "Loading..."
445.         OPEN COMMAND$ FOR INPUT AS #1
446.         DO WHILE NOT EOF(1)
447.             INPUT #1, i, j, r, g, b, a
448.             Level(i, j).shadered = r
449.             Level(i, j).shadegreen = g
450.             Level(i, j).shadeblue = b
451.             Level(i, j).shadealpha = a
452.         LOOP
453.         CLOSE #1
454.     END IF
455. END SUB
456.  

[STxAxTIC]

Another mechanics overhaul - I have much better control over things now... And holy crap, the result was better than expected. I call this the plasma update. This one's for you @loudar - you were right about the red not being conductive enough.

Now the UI is different. The mouse pointer tells you which color is selected; right click to draw with that color. Right clicking will change the selected color to whatever was under the mouse. See top corner of the screen for available swatches. Mousewheel and mouse3 do nothing. Press ESC to clear all hand-drawn lines.

Color guide:
Red = heat source / barrier
Blue = cold source / barrier
Violet = (red + blue) = neutral barrier
Green = up only
Yellow = left only
Aqua = right only
White = down only

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "FluidCraft"
3. _DELAY .25
4. SCREEN _NEWIMAGE(1024, 768, 32)
5. RANDOMIZE TIMER
6.  
7. TYPE Vector
8.     x AS DOUBLE
9.     y AS DOUBLE
10. END TYPE
11.  
12. TYPE ShadeVector
13.     shadered AS DOUBLE
14.     shadegreen AS DOUBLE
15.     shadeblue AS DOUBLE
16.     shadealpha AS DOUBLE
17. END TYPE
18.  
19. TYPE ShadeElement
20.     TheName AS STRING
21.     TheShade AS ShadeVector
22. END TYPE
23.  
24. TYPE Pixel
25.     position AS Vector
26.     velocity AS Vector
27.     acceleration AS Vector
28.     size AS DOUBLE
29.     TheShade AS ShadeVector
30. END TYPE
31.  
32. DIM SHARED ShadeData(8) AS ShadeElement
33. DIM SHARED ActiveShade AS ShadeVector
34. DIM SHARED PixelCloud(3000) AS Pixel
35. DIM SHARED ObjectSize AS DOUBLE
36. DIM SHARED GridSize AS Vector
37. ObjectSize = 6
38. GridSize.x = 1 + INT(_WIDTH / ObjectSize)
39. GridSize.y = 1 + INT(_HEIGHT / ObjectSize)
40. DIM SHARED Level(GridSize.x, GridSize.y) AS ShadeVector
41.  
42. CALL InitializeAll
43. CALL LoadFile
44. DO
45.     CALL UserInput
46.     CLS
47.     CALL DrawBorder
48.     CALL DrawPixels
49.     CALL DrawLevel
50.     CALL Dynamics
51.     CALL DrawOverlay
52.     _DISPLAY
53.     _LIMIT 30
54. LOOP
55.  
56. END
57.  
58. SUB DrawBorder
59.     DIM k AS INTEGER
60.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGB32(255, 0, 255, 255), BF
61.     FOR k = 6 TO _HEIGHT - 1 - 6
62.         LINE (6, k)-(_WIDTH - 6, k), _RGB32(255 * k / _HEIGHT, 0, 255 * (1 - k / _HEIGHT), 255)
63.     NEXT
64.     LINE (12, 12)-(_WIDTH - 12, _HEIGHT - 12), _RGB32(0, 0, 0, 255), BF
65.     LINE (12, 12)-(18 * (UBOUND(ShadeData) + 1) - 1 + 6 + 12, 38 + 12), _RGB32(0, 0, 255, 255), BF
66.     LINE (12, 12)-(18 * (UBOUND(ShadeData) + 1) - 1 + 6 + 6, 38 + 6), _RGB32(255, 0, 255, 255), BF
67.     LINE (12, 12)-(18 * (UBOUND(ShadeData) + 1) - 1 + 6, 38), _RGB32(0, 0, 0, 255), BF
68. END SUB
69.  
70. SUB DrawPixels
71.     DIM k AS INTEGER
72.     DIM x AS DOUBLE
73.     DIM y AS DOUBLE
74.     DIM s AS DOUBLE
75.     FOR k = 1 TO UBOUND(PixelCloud)
76.         x = PixelCloud(k).position.x
77.         y = PixelCloud(k).position.y
78.         s = PixelCloud(k).size
79.         CALL clinebf(x - s, y - s, x + s, y + s, _RGBA(PixelCloud(k).TheShade.shadered, PixelCloud(k).TheShade.shadegreen, PixelCloud(k).TheShade.shadeblue, PixelCloud(k).TheShade.shadealpha))
80.     NEXT
81. END SUB
82.  
83. SUB DrawLevel
84.     DIM i AS INTEGER
85.     DIM j AS INTEGER
86.     DIM x AS DOUBLE
87.     DIM y AS DOUBLE
88.     DIM s AS DOUBLE
89.     s = ObjectSize
90.     FOR i = 1 TO GridSize.x
91.         FOR j = 1 TO GridSize.y
92.             x = (i - 1) * s
93.             y = (j - 1) * s
94.             IF (Level(i, j).shadered > 5) OR (Level(i, j).shadegreen > 5) OR (Level(i, j).shadeblue > 5) THEN
95.                 CALL slinebf(x - s / 2, y - s / 2, x + s / 2 - 1, y + s / 2 - 1, _RGBA(Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha))
96.             END IF
97.         NEXT
98.     NEXT
99. END SUB
100.  
101. SUB DrawOverlay
102.     DIM k AS INTEGER
103.     LINE (ObjectSize * INT(_MOUSEX / ObjectSize) - ObjectSize / 2 - 1, ObjectSize * INT(_MOUSEY / ObjectSize) - ObjectSize / 2 - 1)-(ObjectSize * INT(_MOUSEX / ObjectSize) + ObjectSize / 2 - 1 + 1, ObjectSize * INT(_MOUSEY / ObjectSize) + ObjectSize / 2 - 1 + 1), _RGBA(255, 255, 255, 255), B
104.     LINE (ObjectSize * INT(_MOUSEX / ObjectSize) - ObjectSize / 2, ObjectSize * INT(_MOUSEY / ObjectSize) - ObjectSize / 2)-(ObjectSize * INT(_MOUSEX / ObjectSize) + ObjectSize / 2 - 1, ObjectSize * INT(_MOUSEY / ObjectSize) + ObjectSize / 2 - 1), _RGBA(ActiveShade.shadered, ActiveShade.shadegreen, ActiveShade.shadeblue, ActiveShade.shadealpha), BF
105.     FOR k = 1 TO UBOUND(ShadeData)
106.         LINE (18 * k + 1, 18)-(18 * (k + 1) - 1, 32), _RGB32(ShadeData(k).TheShade.shadered, ShadeData(k).TheShade.shadegreen, ShadeData(k).TheShade.shadeblue, ShadeData(k).TheShade.shadealpha), BF
107.         LINE (18 * k + 1, 18)-(18 * (k + 1) - 1, 32), _RGB32(255, 255, 255, 255), B
108.     NEXT
109. END SUB
110.  
111. SUB InitializeAll
112.     DIM k AS INTEGER
113.     ShadeData(1).TheName = "Red"
114.     ShadeData(1).TheShade.shadered = 255
115.     ShadeData(1).TheShade.shadegreen = 0
116.     ShadeData(1).TheShade.shadeblue = 0
117.     ShadeData(1).TheShade.shadealpha = 255
118.     ShadeData(2).TheName = "Blue"
119.     ShadeData(2).TheShade.shadered = 0
120.     ShadeData(2).TheShade.shadegreen = 0
121.     ShadeData(2).TheShade.shadeblue = 255
122.     ShadeData(2).TheShade.shadealpha = 255
123.     ShadeData(3).TheName = "Green"
124.     ShadeData(3).TheShade.shadered = 0
125.     ShadeData(3).TheShade.shadegreen = 255
126.     ShadeData(3).TheShade.shadeblue = 0
127.     ShadeData(3).TheShade.shadealpha = 255
128.     ShadeData(4).TheName = "White"
129.     ShadeData(4).TheShade.shadered = 255
130.     ShadeData(4).TheShade.shadegreen = 255
131.     ShadeData(4).TheShade.shadeblue = 255
132.     ShadeData(4).TheShade.shadealpha = 255
133.     ShadeData(5).TheName = "Yellow"
134.     ShadeData(5).TheShade.shadered = 255
135.     ShadeData(5).TheShade.shadegreen = 255
136.     ShadeData(5).TheShade.shadeblue = 0
137.     ShadeData(5).TheShade.shadealpha = 255
138.     ShadeData(6).TheName = "Aqua"
139.     ShadeData(6).TheShade.shadered = 0
140.     ShadeData(6).TheShade.shadegreen = 255
141.     ShadeData(6).TheShade.shadeblue = 255
142.     ShadeData(6).TheShade.shadealpha = 255
143.     ShadeData(7).TheName = "Violet"
144.     ShadeData(7).TheShade.shadered = 255
145.     ShadeData(7).TheShade.shadegreen = 0
146.     ShadeData(7).TheShade.shadeblue = 255
147.     ShadeData(7).TheShade.shadealpha = 255
148.     ShadeData(8).TheName = "Black"
149.     ShadeData(8).TheShade.shadered = 0
150.     ShadeData(8).TheShade.shadegreen = 0
151.     ShadeData(8).TheShade.shadeblue = 0
152.     ShadeData(8).TheShade.shadealpha = 255
153.  
154.     FOR k = 1 TO UBOUND(PixelCloud)
155.         PixelCloud(k).size = 3
156.         PixelCloud(k).acceleration.x = 0
157.         PixelCloud(k).acceleration.y = 0
158.         PixelCloud(k).velocity.x = 0
159.         PixelCloud(k).velocity.y = 0
160.         PixelCloud(k).position.x = (RND - .5) * _WIDTH * .8
161.         PixelCloud(k).position.y = (RND - .5) * _HEIGHT * .8
162.         CALL SetPixelShade(k, 0, 0, 255, 150)
163.     NEXT
164.  
165.     ActiveShade.shadered = 255
166.     ActiveShade.shadegreen = 0
167.     ActiveShade.shadeblue = 0
168.     ActiveShade.shadealpha = 255
169.  
170. END SUB
171.  
172. SUB SetPixelShade (i AS INTEGER, r AS INTEGER, g AS INTEGER, b AS INTEGER, a AS INTEGER)
173.     PixelCloud(i).TheShade.shadered = r
174.     PixelCloud(i).TheShade.shadegreen = g
175.     PixelCloud(i).TheShade.shadeblue = b
176.     PixelCloud(i).TheShade.shadealpha = a
177. END SUB
178.  
179. SUB UserInput
180.     DIM mb1 AS INTEGER
181.     DIM mb2 AS INTEGER
182.     DIM mb3 AS INTEGER
183.     DIM i AS INTEGER
184.     DIM j AS INTEGER
185.     DIM k AS INTEGER
186.     mb1 = 0
187.     mb2 = 0
188.     mb3 = 0
189.     DO WHILE _MOUSEINPUT
190.         IF (_MOUSEBUTTON(1) = -1) AND (mb1 <> 1) THEN
191.             mb1 = -1
192.             i = 1 + INT(_MOUSEX / ObjectSize)
193.             j = 1 + INT(_MOUSEY / ObjectSize)
194.             Level(i, j).shadered = ActiveShade.shadered
195.             Level(i, j).shadegreen = ActiveShade.shadegreen
196.             Level(i, j).shadeblue = ActiveShade.shadeblue
197.             Level(i, j).shadealpha = ActiveShade.shadealpha
198.         END IF
199.         IF ((_MOUSEBUTTON(2) = -1) AND (mb2 <> -1)) THEN
200.             mb2 = -1
201.             i = ObjectSize * INT(_MOUSEX / ObjectSize)
202.             j = ObjectSize * INT(_MOUSEY / ObjectSize)
203.             ActiveShade.shadered = _RED32(POINT(i, j))
204.             ActiveShade.shadegreen = _GREEN32(POINT(i, j))
205.             ActiveShade.shadeblue = _BLUE32(POINT(i, j))
206.             ActiveShade.shadealpha = _ALPHA32(POINT(i, j))
207.         END IF
208.     LOOP
209.     SELECT CASE _KEYHIT
210.         CASE ASC("e"), ASC("E")
211.             CALL Export
212.         CASE ASC("r"), ASC("R")
213.             FOR k = 1 TO UBOUND(PixelCloud)
214.                 PixelCloud(k).TheShade.shadered = 255
215.                 PixelCloud(k).TheShade.shadegreen = 0
216.                 PixelCloud(k).TheShade.shadeblue = 0
217.             NEXT
218.         CASE ASC("b"), ASC("B")
219.             FOR k = 1 TO UBOUND(PixelCloud)
220.                 PixelCloud(k).TheShade.shadered = 0
221.                 PixelCloud(k).TheShade.shadegreen = 0
222.                 PixelCloud(k).TheShade.shadeblue = 255
223.             NEXT
224.         CASE ASC("0")
225.             FOR k = 1 TO UBOUND(PixelCloud)
226.                 PixelCloud(k).position.x = (RND - .5) * _WIDTH * .8
227.                 PixelCloud(k).position.y = (RND - .5) * _HEIGHT * .8
228.             NEXT
229.         CASE 27
230.             FOR i = 1 TO GridSize.x
231.                 FOR j = 1 TO GridSize.y
232.                     Level(i, j).shadered = 0
233.                     Level(i, j).shadegreen = 0
234.                     Level(i, j).shadeblue = 0
235.                     Level(i, j).shadealpha = 0
236.                 NEXT
237.             NEXT
238.     END SELECT
239.     'DO WHILE _MOUSEINPUT: LOOP
240. END SUB
241.  
242. SUB Export
243.     DIM i AS INTEGER
244.     DIM j AS INTEGER
245.     OPEN "FluidCraft" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt" FOR OUTPUT AS #1
246.     FOR i = 1 TO UBOUND(Level, 1)
247.         FOR j = 1 TO UBOUND(Level, 2)
248.             PRINT #1, i, j, Level(i, j).shadered, Level(i, j).shadegreen, Level(i, j).shadeblue, Level(i, j).shadealpha
249.         NEXT
250.     NEXT
251.     CLOSE #1
252. END SUB
253.  
254. SUB Dynamics
255.     DIM k AS INTEGER
256.     FOR k = 1 TO UBOUND(PixelCloud)
257.         CALL CalculateInfluence(k)
258.         CALL UpdatePosition(k)
259.     NEXT
260. END SUB
261.  
262. SUB UpdatePosition (i AS INTEGER)
263.     DIM dt AS DOUBLE
264.     DIM damp AS DOUBLE
265.     DIM brownian AS DOUBLE
266.     dt = 1
267.     damp = 0.8 '.1 '0.5 '.25
268.     brownian = .65 '1 'PixelCloud(i).size / 4 '1 '.525
269.     PixelCloud(i).velocity.x = damp * PixelCloud(i).velocity.x + dt * PixelCloud(i).acceleration.x
270.     PixelCloud(i).velocity.y = damp * PixelCloud(i).velocity.y + dt * PixelCloud(i).acceleration.y
271.     PixelCloud(i).position.x = PixelCloud(i).position.x + dt * PixelCloud(i).velocity.x + (RND - .5) * brownian
272.     PixelCloud(i).position.y = PixelCloud(i).position.y + dt * PixelCloud(i).velocity.y + (RND - .5) * brownian
273.     IF (PixelCloud(i).position.y <= -_HEIGHT / 2 + 2 * PixelCloud(i).size + 1) THEN
274.         PixelCloud(i).position.y = _HEIGHT / 2 - 2 * PixelCloud(i).size
275.     END IF
276. END SUB
277.  
278. SUB CalculateInfluence (i AS INTEGER)
279.     DIM x AS DOUBLE
280.     DIM y AS DOUBLE
281.     DIM dx AS DOUBLE
282.     DIM dy AS DOUBLE
283.     DIM xr AS DOUBLE
284.     DIM yr AS DOUBLE
285.     DIM xg AS DOUBLE
286.     DIM yg AS DOUBLE
287.     DIM xb AS DOUBLE
288.     DIM yb AS DOUBLE
289.     DIM WPoint(9) AS _UNSIGNED LONG
290.     x = PixelCloud(i).position.x
291.     y = PixelCloud(i).position.y
292.     dx = 2 * PixelCloud(i).size
293.     dy = 2 * PixelCloud(i).size
294.     WPoint(7) = cpoint(x - dx, y + dy)
295.     WPoint(8) = cpoint(x, y + dy)
296.     WPoint(9) = cpoint(x + dx, y + dy)
297.     WPoint(4) = cpoint(x - dx, y)
298.     WPoint(6) = cpoint(x + dx, y)
299.     WPoint(1) = cpoint(x - dx, y - dy)
300.     WPoint(2) = cpoint(x, y - dy)
301.     WPoint(3) = cpoint(x + dx, y - dy)
302.  
303.     '''
304.     DIM k AS INTEGER
305.     DIM WShade(9) AS DOUBLE
306.     DIM xc AS DOUBLE
307.     DIM yc AS DOUBLE
308.     DIM cs AS INTEGER
309.     cs = 0
310.     x = 0
311.     y = 0
312.  
313.     ' red
314.     FOR k = 1 TO 9
315.         IF (k <> 5) THEN
316.             IF ((_RED32(WPoint(k)) > 25) AND (_GREEN32(WPoint(k)) < 5) AND (_BLUE32(WPoint(k)) < 25)) THEN
317.                 WShade(k) = _RED32(WPoint(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
318.             ELSE
319.                 WShade(k) = 0
320.             END IF
321.         END IF
322.     NEXT
323.     xr = (WShade(6) - WShade(4) + (WShade(9) + WShade(3)) / SQR(2) - (WShade(7) + WShade(1)) / SQR(2))
324.     yr = (WShade(8) - WShade(2) + (WShade(7) + WShade(9)) / SQR(2) - (WShade(1) + WShade(3)) / SQR(2))
325.     x = x + xr
326.     y = y + yr
327.  
328.     ' blue
329.     FOR k = 1 TO 9
330.         IF (k <> 5) THEN
331.             IF ((_RED32(WPoint(k)) < 25) AND (_GREEN32(WPoint(k)) < 5) AND (_BLUE32(WPoint(k)) > 25)) THEN
332.                 WShade(k) = _RED32(WPoint(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
333.             ELSE
334.                 WShade(k) = 0
335.             END IF
336.         END IF
337.     NEXT
338.     xb = (WShade(6) - WShade(4) + (WShade(9) + WShade(3)) / SQR(2) - (WShade(7) + WShade(1)) / SQR(2))
339.     yb = (WShade(8) - WShade(2) + (WShade(7) + WShade(9)) / SQR(2) - (WShade(1) + WShade(3)) / SQR(2))
340.     x = x + xb
341.     y = y + yb
342.  
343.     ' green
344.     FOR k = 1 TO 9
345.         IF (k <> 5) THEN
346.             IF ((_RED32(WPoint(k)) < 5) AND (_GREEN32(WPoint(k)) > 250) AND (_BLUE32(WPoint(k)) < 5)) THEN
347.                 WShade(k) = _RED32(WShade(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
348.                 cs = 1
349.             ELSE
350.                 WShade(k) = 0
351.             END IF
352.         END IF
353.     NEXT
354.     xg = -(WShade(6) - WShade(4) + (WShade(9) + WShade(3)) / SQR(2) - (WShade(7) + WShade(1)) / SQR(2))
355.     yg = (0 - WShade(2) + (0 + 0) / SQR(2) - (WShade(1) + WShade(3)) / SQR(2))
356.     x = x + xg
357.     y = y + yg
358.  
359.     ' custom yellow
360.     FOR k = 1 TO 9
361.         IF (k <> 5) THEN
362.             IF ((_RED32(WPoint(k)) > 250) AND (_GREEN32(WPoint(k)) > 250) AND (_BLUE32(WPoint(k)) < 5)) THEN
363.                 WShade(k) = _RED32(WShade(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
364.                 cs = 1
365.             ELSE
366.                 WShade(k) = 0
367.             END IF
368.         END IF
369.     NEXT
370.     xc = (WShade(6) - 0 + (WShade(9) + WShade(3)) / SQR(2) - (0 + 0) / SQR(2))
371.     yc = 0
372.     x = x + xc
373.     y = y + yc
374.  
375.     ' custom aqua
376.     FOR k = 1 TO 9
377.         IF (k <> 5) THEN
378.             IF ((_RED32(WPoint(k)) < 5) AND (_GREEN32(WPoint(k)) > 250) AND (_BLUE32(WPoint(k)) > 250)) THEN
379.                 WShade(k) = _RED32(WShade(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
380.                 cs = 1
381.             ELSE
382.                 WShade(k) = 0
383.             END IF
384.         END IF
385.     NEXT
386.     xc = -(WShade(6) - 0 + (WShade(9) + WShade(3)) / SQR(2) - (0 + 0) / SQR(2))
387.     yc = 0
388.     x = x + xc
389.     y = y + yc
390.  
391.     ' custom white
392.     FOR k = 1 TO 9
393.         IF (k <> 5) THEN
394.             IF ((_RED32(WPoint(k)) > 250) AND (_GREEN32(WPoint(k)) > 250) AND (_BLUE32(WPoint(k)) > 250)) THEN
395.                 WShade(k) = _RED32(WShade(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
396.                 cs = 1
397.             ELSE
398.                 WShade(k) = 0
399.             END IF
400.         END IF
401.     NEXT
402.     xc = -(WShade(6) - WShade(4) + (WShade(9) + WShade(3)) / SQR(2) - (WShade(7) + WShade(1)) / SQR(2))
403.     yc = -(0 - WShade(2) + (0 + 0) / SQR(2) - (WShade(1) + WShade(3)) / SQR(2))
404.     x = x + xc
405.     y = y + yc
406.  
407.     ' custom violet
408.     FOR k = 1 TO 9
409.         IF (k <> 5) THEN
410.             IF ((_RED32(WPoint(k)) > 250) AND (_GREEN32(WPoint(k)) < 5) AND (_BLUE32(WPoint(k)) > 250)) THEN
411.                 WShade(k) = _RED32(WShade(k)) + _GREEN32(WPoint(k)) + _BLUE32(WPoint(k))
412.                 cs = 1
413.             ELSE
414.                 WShade(k) = 0
415.             END IF
416.         END IF
417.     NEXT
418.     xc = (WShade(6) - WShade(4) + (WShade(9) + WShade(3)) / SQR(2) - (WShade(7) + WShade(1)) / SQR(2))
419.     yc = (WShade(8) - WShade(2) + (WShade(7) + WShade(9)) / SQR(2) - (WShade(1) + WShade(3)) / SQR(2))
420.     x = x + xc
421.     y = y + yc
422.  
423.  
424.     ' Conductivity
425.     IF (cs = 0) THEN
426.         IF ((xr * xr + yr * yr) > (xb * xb + yb * yb)) THEN
427.             PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered + 64
428.             IF (PixelCloud(i).TheShade.shadered >= 255) THEN PixelCloud(i).TheShade.shadered = 255
429.             PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue - 64
430.             IF (PixelCloud(i).TheShade.shadeblue <= 0) THEN PixelCloud(i).TheShade.shadeblue = 0
431.         END IF
432.         IF ((xb * xb + yb * yb) > (xr * xr + yr * yr)) THEN
433.             PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 64
434.             IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
435.             PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 64
436.             IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
437.         END IF
438.     END IF
439.  
440.     ' Gravity or levity
441.     IF (cs = 0) THEN
442.         y = y - (PixelCloud(i).TheShade.shadered - PixelCloud(i).TheShade.shadeblue) / 255
443.     END IF
444.  
445.     ' Normalize acceleration
446.     IF (ABS(x) < .001) THEN
447.         PixelCloud(i).acceleration.x = 0
448.     ELSE
449.         PixelCloud(i).acceleration.x = -x / SQR(x * x + y * y)
450.     END IF
451.     IF (ABS(y) < .001) THEN
452.         PixelCloud(i).acceleration.y = 0
453.     ELSE
454.         PixelCloud(i).acceleration.y = -y / SQR(x * x + y * y)
455.     END IF
456.  
457.     ' Auto-cooling
458.     IF (cs = 0) THEN
459.         PixelCloud(i).TheShade.shadered = PixelCloud(i).TheShade.shadered - 2
460.         IF (PixelCloud(i).TheShade.shadered <= 0) THEN PixelCloud(i).TheShade.shadered = 0
461.         PixelCloud(i).TheShade.shadeblue = PixelCloud(i).TheShade.shadeblue + 2
462.         IF (PixelCloud(i).TheShade.shadeblue >= 255) THEN PixelCloud(i).TheShade.shadeblue = 255
463.     END IF
464. END SUB
465.  
466. FUNCTION cpoint& (x1 AS DOUBLE, y1 AS DOUBLE)
467.     DIM TheReturn AS _UNSIGNED LONG
468.     TheReturn = POINT(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)
469.     cpoint = TheReturn
470. END FUNCTION
471.  
472. SUB clinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
473.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2 - 0, -y2 + _HEIGHT / 2 + 0), col, BF
474. END SUB
475.  
476. SUB slinebf (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
477.     LINE (x1, y1)-(x2, y2), col, BF
478. END SUB
479.  
480. SUB cprintstring (y1 AS DOUBLE, a AS STRING)
481.     _PRINTSTRING (_WIDTH / 2 - (LEN(a) * 8) / 2, -y1 + _HEIGHT / 2), a
482. END SUB
483.  
484.  
485. SUB LoadFile
486.     DIM i AS INTEGER
487.     DIM j AS INTEGER
488.     DIM r AS INTEGER
489.     DIM g AS INTEGER
490.     DIM b AS INTEGER
491.     DIM a AS INTEGER
492.     IF (COMMAND$ <> "") THEN
493.         PRINT "Loading..."
494.         OPEN COMMAND$ FOR INPUT AS #1
495.         DO WHILE NOT EOF(1)
496.             INPUT #1, i, j, r, g, b, a
497.             Level(i, j).shadered = r
498.             Level(i, j).shadegreen = g
499.             Level(i, j).shadeblue = b
500.             Level(i, j).shadealpha = a
501.         LOOP
502.         CLOSE #1
503.     END IF
504. END SUB
505.  

[Dav]

I finally got around to trying this.  Wow - that's some top notch coding there!

- Dav

[TempodiBasic]

Hi STxAxTIC

thanks to share this FluidCraft!
I find it very fine and impressive. Running on my Toshiba i3 4 GB ram I have just an issue on selecting color both using internal mousepad of notebook both using a wireless USB mouse. Rarely it changes color also if I point the color with mouse cursor in the panel of colors and I click right button of mouse.
Moreover I can draw on panel of colors...

Great app.

[STxAxTIC]

Thanks for your useful feedback TempodiBasic - the mouse stuff is still clunky and unfinished for sure. For now, I don't mind that we can draw over the borders, because sometimes we want to control what the border does instead rely on the default. What I would want to tackle during the `polishing' stage is the alignment of the border edges with the grid for drawing.

As for performance -  I knew this would be a thing eventually - I'm testing this on my new system, which in all probability is faster than any other machine testing this code, so I get the best view (a first for me). I tried it out on my old rig and it wasn't as impressive. Either knocking the particle number down from 3000 to like 2000 works, or also shrinking the overall window...

[TempodiBasic]

Hi STxAxTIC
I have found the glitch for my experience.
Your game starts with a specific dimensions screen that are not fitted into my notebook

adding this line of code before TYPE section I can catch the glitch

Code: QB64: [Select]

1. _FULLSCREEN , _SMOOTH

so now I can change the color of mouse if the little floating square in front of cursor of mouse is under the wanted color and I click with right button of mouse.

Moreover it is still possible for me to draw on borders of  Color change tool.

Also on my old notebook it runs quickly.
Thanks to share!

[loudar]

Hey @STxAxTIC! Thank you for the update, it's truly amazing...

One little thing again: The directional barriers seem to partly block the direction they should be letting through. If I have a white barrier and a mass on top and below, the particles above don't really push the ones below aside - so more gravity/mass might be interesting? I also thought about having heat particles not specifically move up, but just move faster than cold ones, eventually like molecules. If they would additionally have slight attraction to each other (like water) this could get really interesting. At the moment it's more simulating a gas/fluid state between hot/cold :D Just add air as invisible particles and add mass and density and you're good to go basically (I say "just"; I know this is a lot but if done right, what a simulation that would be!)