Math help with puck/paddle bounce

[STxAxTIC]

Right, now that we're pulling on this thread, the "hidden circle" can be of any radius with a lower limit of twice the paddle height. The upper limit is infinity, in which case the paddle acts the way it looks.

Here is all you have to do, it solves the whole problem:

Decide on a radius of curvature as sketched above.
Create a function that translates a point of contact on the paddle to a point on the imagined circle. This will literally be an arc-trig function.
The normal vector to the paddle, which is usually horizontal, becomes (cos a, sin a), where a is the angle from horizontal.
Reflect the ball velocity about that vector.
Done.

Oh and this is my 777th post.

EDIT: I'm on call and may have to leave at any time but if there is no solution in 24 hours I'm going to do it myself.

[bplus]

OH wait, you can vary the angle of return according to how far from center of the paddle the ball is when it hits the paddle. Compare difference between ball y and center of paddle y, the greater the distance the more angle is towards the upper or lower paddle half.

[codeguy]

pro tip: sin(2theta) will be your friend and the reflected angle will be the same as the incident angle relative to the tangent line along the circle or ellipse.

[TerryRitchie]

So to be clear - the paddle needs to look like a paddle and move like a paddle, but reflect the ball as if curved. (This is a one-liner solution with vectors but it seems like bplus has something close to cooked already.)

Yes, exactly. Sorry for the delay, wife came home and had to leave the computer for a while.

[TerryRitchie]

A more subtle arc like from an ellipse?

I have a Breakout Game that uses a "loaf-of-bread" paddle, LOL. I have to check the math I used for that.

Yes, in my drawing I envisioned the ellipse to go from upper left to lower left passing through the center of the paddle. Not sure if that is accurate but what I envisioned.

[_vince]

Another tip, don't forget to convert to radians when doing trig in QB64, radians = degrees*pi/180 will be critical

[bplus]

Air Hockey
https://www.qb64.org/forum/index.php?topic=2326.0

Uses round paddles and the paddles are not restricted to up and down but anywhere on the players side of the table or center line which is more like a regular game of pong.

The math for handling collision is simple circle intersect circle ie the circle centers are less in distance than the sum of their radii.

The math a little more than simple wall collision but not as bad as ellipse collision will be, which is likely to get terrible and I don't think newbies to QB64 will appreciate unless they are math or physics majors in college. Maybe I could figure out the rebound from an ellipse paddle if I really, really, had too, but yuck!

So I have to ask Terry, are you sure you want to go that far?

In meantime, I will try to explain math for circle versus circle collision and rebound:

Here is code from AirHockey to handle contact with paddle,
it's probably over simplified for STx standards, but does the job fairly well:

Code: QB64: [Select]

1.     IF SQR((px - psx) ^ 2 + (py - psy) ^ 2) < (pr + pr2) THEN 'puck has penetrated player's striker = collision plus!
2.         pa = _ATAN2(py - psy, px - psx)  'calc the new direction for puck to go
3.         'boost puck away
4.         px = px + .5 * speed * COS(pa) 'calc new position for puck, back it out of paddle
5.         py = py + .5 * speed * SIN(pa)
6.         snd 2200, 4
7.     END IF
8.  

Not too scary is it?

Here is collision detection line: IF SQR((px - psx) ^ 2 + (py - psy) ^ 2) < (pr + pr2) THEN
px, py the puck location
psx, psy the player striker location

This line determines the angle of the puck center to the player striker center:
pa = _ATAN2(py - psy, px - psx)
Important: this also resets pa, the puck angle, which is the direction in radians the puck is traveling. With round paddles the angle the puck hits the striker is the angle the puck rebounds! simple beauty math-wise.

This resets the puck location (anywhere in code eg starting drawPuck sub):
        px = px + .5 * speed * COS(pa)
        py = py + .5 * speed * SIN(pa)

The x component of the speed and heading of the puck,
My dx or Terry's xv = .5 * speed * COS(pa) or new location for x component = old x + the speed times COS of the puck angle
My dy or Terry's yv = .5 * speed * SIN(pa)  or new location for y component = old y + the speed times SIN of the puck angle


PS where I used an ellipse paddle, the loaf of bread thing in Breakout game, I used random rebounding, which is not bad way to go specially if the randomness is increased the more off center the ball strikes the paddle. You might get ellipse like rebounding without allot of math, IF you can make the random rebound increase in the direction of the reflection.

Update #1: The .5 in xv = .5 * speed * COS(pa)
.5 is the average distance the ball will have sunk into the paddle ie somewhere between (0 and  1) * COS(pa) likewise for the y component of the change in position. (Not having studied my code for awhile, I had to figure out again WTH the .5 was for?! LOL)

[STxAxTIC]

Ellipses are not needed. See my post 777 otherwise I'm stuck on the road a while

[TempodiBasic]

@TerryRitchie
can be this useful?
  [ You are not allowed to view this attachment ]  
....elastic collision in physic

[STxAxTIC]

Okay I've cracked the main problem carrying out the steps I laid out above. I did this by writing the following code in the MovePuck sub:

Code: QB64: [Select]

1.             '''
2.             ' Velocity vector using ordinary orientation.
3.             vx = Puck.xv
4.             vy = Puck.yv
5.  
6.             ' Find place on paddle where puck is hitting as fraction from midpoint. Result in interval [-1,1]
7.             hy = 2 * (Puck.y - P1Paddle.y) / (P1Paddle.rect.y1 - P1Paddle.rect.y2)
8.  
9.             ' Convert fractional height to an angle. Result in interval [-pi/2,pi/2]
10.             ang = _ASIN(hy)
11.  
12.             ' Create unit vectors based on imaginary circle.
13.             rux = COS(ang)
14.             ruy = SIN(ang)
15.             tux = -SIN(ang)
16.             tuy = COS(ang)
17.  
18.             ' Re-calculate velocity vector in new basis.
19.             wr = vx * rux + vy * ruy
20.             wt = vx * tux + vy * tuy
21.  
22.             ' Reflect the velocity about the normal vector
23.             wt = -wt
24.  
25.             ' Re-calculate veloctiy in old basis.
26.             vx = wr * COS(ang) - wt * SIN(ang)
27.             vy = wr * SIN(ang) + wt * COS(ang)
28.  
29.             ' Restore original variables
30.             Puck.xv = vx
31.             Puck.yv = vy
32.             '''

For maximal clarity, this is the exact implementation Terry was trying to draw in the top post. The paddle is still a rectangle, but reflects the ball exactly as if it were a circle. I modified the main code to get rid of the random y-velocity and to toss the ball at player 1, as this code is only implemented for player 1.

Near the edges, the ball reflects wildly. Of course, this is what you get for a circle. As I was saying above, this effect can be made less drastic by making the invisible circle bigger.

Anyway, here's the whole thing:

Code: QB64: [Select]

1. 'OPTION _EXPLICIT
2.  
3. '-------------------------------------------------------------------------------------------------------------
4. '** Declare constants
5. '-------------------------------------------------------------------------------------------------------------
6.  
7. CONST FALSE = 0, TRUE = NOT FALSE '               truth detectors
8. CONST BRIGHTWHITE = _RGB32(255, 255, 255) '       define colors
9. CONST WHITE = _RGB32(192, 192, 192)
10. CONST GRAY = _RGB32(128, 128, 128) '
11. CONST SCREENWIDTH = 768 '                         screen width
12. CONST SCREENHEIGHT = 576 '                        screen height
13. CONST PUCKSIZE = 10 '                             puck square size
14. CONST PADDLEWIDTH = 10 '                          paddle width
15. CONST PADDLEHEIGHT = 60 '                         paddle height
16. CONST PADDLESPEED = 2 '                           paddle Y speed
17. CONST PADDLEOFFSET = 20 '                         paddle offset from side of screen
18. CONST P1MISSED = PUCKSIZE \ 2 '                   puck on left side edge of screen
19. CONST P2MISSED = SCREENWIDTH - 1 - PUCKSIZE \ 2 ' puck on right side edge of screen
20. CONST PADDLEYMIN = PADDLEHEIGHT \ 2 + 30 '                                     min Y coordinate for paddles
21. CONST PADDLEYMAX = SCREENHEIGHT - 30 - PADDLEHEIGHT \ 2 '                      max Y coordinate for paddles
22. CONST PUCKXMIN = PADDLEOFFSET + PADDLEWIDTH + PUCKSIZE \ 2 '                   min X coordinate for puck
23. CONST PUCKXMAX = SCREENWIDTH - 1 - PADDLEOFFSET - PADDLEWIDTH - PUCKSIZE \ 2 ' max X coordinate for puck
24. CONST PUCKYMIN = 30 + PUCKSIZE \ 2 '                                           min Y coordinate for puck
25. CONST PUCKYMAX = SCREENHEIGHT - 30 - PUCKSIZE \ 2 '                            max Y coordinate for puck
26. CONST FPS = 300 '                                                              game frames per second
27.  
28. '-------------------------------------------------------------------------------------------------------------
29. '** Declare TYPE definitions
30. '-------------------------------------------------------------------------------------------------------------
31.  
32. TYPE RECTTYPE '        rectangle definition for collision detection
33.     x1 AS INTEGER '    upper left X coordinate
34.     y1 AS INTEGER '    upper left Y coordinate
35.     x2 AS INTEGER '    lower right X coordinate
36.     y2 AS INTEGER '    lower right Y coordinate
37. END TYPE
38.  
39. TYPE MOVINGOBJECT '    moving object definition
40.     x AS SINGLE '      center X coordinate
41.     y AS SINGLE '      center Y coordinate
42.     xv AS SINGLE '     X vector component
43.     yv AS SINGLE '     Y vector component
44.     rect AS RECTTYPE ' rectangle coordinates for collision detection
45. END TYPE
46.  
47. '-------------------------------------------------------------------------------------------------------------
48. '** Declare global variables
49. '-------------------------------------------------------------------------------------------------------------
50.  
51. DIM PlayField AS LONG '        playing field image
52. DIM PlayFieldCopy AS LONG '    playing field image copy (without scores)
53. DIM P1Paddle AS MOVINGOBJECT ' player 1 paddle
54. DIM P2Paddle AS MOVINGOBJECT ' player 2 paddle
55. DIM Puck AS MOVINGOBJECT '     puck properties
56. DIM Computer AS INTEGER '      TRUE if computer playing
57. DIM Score(9) AS STRING * 15 '  encoded font data
58. DIM Pscore(1) AS INTEGER '     player scores (0=player1, 1=player2
59. DIM Missed AS INTEGER '        TRUE when a player misses the puck
60. DIM GameOver AS INTEGER '      TRUE when a player reaches a score of 9
61.  
62. '-------------------------------------------------------------------------------------------------------------
63. '** Begin main program
64. '-------------------------------------------------------------------------------------------------------------
65.  
66. SCREEN _NEWIMAGE(SCREENWIDTH, SCREENHEIGHT, 32) ' enter graphics screen
67. _TITLE "QB64 PONG!" '                             give window a title
68. _DELAY .5 '                                       slight delay
69. _SCREENMOVE _MIDDLE '                             move window to center of desktop
70. Initialize '                                      initialize game settings
71. DO '                                              begin main program loop
72.     NewGame '                                     start a new game
73.     DO '                                          begin game loop
74.         PlayGame '                                play the game
75.     LOOP UNTIL GameOver OR _KEYDOWN(27) '         leave when game over or player exits
76. LOOP UNTIL _KEYDOWN(27) '                         leave when player exits
77. Cleanup '                                         clean player's computer memory and exit to operating system
78.  
79. '-------------------------------------------------------------------------------------------------------------
80. '** end main program
81. '-------------------------------------------------------------------------------------------------------------
82.  
83. '-------------------------------------------------------------------------------------------------------------
84. '** Declare subroutines and functions
85. '-------------------------------------------------------------------------------------------------------------
86.  
87. '-------------------------------------------------------------------------------------------------------------
88. SUB ResetRound ()
89.     '---------------------------------------------------------------------------------------------------------
90.  
91.     SHARED Missed AS INTEGER '    need access to puck miss indicator
92.     SHARED Puck AS MOVINGOBJECT ' need access to puck
93.  
94.     IF SGN(Puck.xv) = 1 THEN '                          puck was heading right?
95.         Puck.x = SCREENWIDTH * .25 '                    yes, serve from player 1 side
96.         Puck.xv = .5 '                                  puck will travel right
97.     ELSE '                                              no, puck was travleing left
98.         Puck.x = SCREENWIDTH * .75 '                    serve from player 2 side
99.         Puck.xv = -.5 '                                 puck will travel left
100.     END IF
101.     Puck.y = INT(RND(1) * (SCREENHEIGHT - 100)) + 50 '  random puck Y coordinate
102.     Puck.yv = 0 '(RND(1) - RND(1)) / 2 '                   random puck Y vector component
103.     Missed = FALSE '                                    reset puck missed indicator
104.  
105. END SUB
106.  
107. '-------------------------------------------------------------------------------------------------------------
108. SUB PlayGame ()
109.     '---------------------------------------------------------------------------------------------------------
110.  
111.     SHARED PlayField AS LONG '    need access to playing field image
112.     SHARED Missed AS INTEGER '    need access to puck miss indicator
113.     SHARED Puck AS MOVINGOBJECT ' need access to puck
114.     SHARED Pscore() AS INTEGER '  need access to player scores
115.     SHARED GameOver AS INTEGER '  need access to game over indicator
116.  
117.     ResetRound '                                             set up next game round
118.     DO '                                                     begin round loop
119.         _LIMIT FPS '                                         limit game speed
120.         _PUTIMAGE , PlayField '                              reset playing field
121.         MovePaddles '                                        update player paddles
122.         MovePuck '                                           update puck
123.         _DISPLAY '                                           update screen with changes
124.     LOOP UNTIL Missed OR _KEYDOWN(27) '                      leave when puck missed or a player presses ESC
125.     IF SGN(Puck.xv) = -1 THEN '                              was puck heading left?
126.         Pscore(1) = Pscore(1) + 1 '                          yes, increase player 2 score
127.     ELSE '                                                   no, puck was heading right
128.         Pscore(0) = Pscore(0) + 1 '                          increase player 1 score
129.     END IF
130.     IF Pscore(0) = 9 OR Pscore(1) = 9 THEN GameOver = TRUE ' set game over indicator when player reaches 9
131.     UpdateScores '                                           update player scores
132.  
133. END SUB
134.  
135. '-------------------------------------------------------------------------------------------------------------
136. SUB UpdateScores ()
137.     '---------------------------------------------------------------------------------------------------------
138.  
139.     SHARED PlayField AS LONG '     need access to playing field image
140.     SHARED PlayFieldCopy AS LONG ' need access to playing field image copy
141.     SHARED Pscore() AS INTEGER '   need access to player scores
142.     DIM Clr AS _UNSIGNED LONG '    font color
143.  
144.     _PUTIMAGE , PlayFieldCopy, PlayField '                      restore playing field
145.     _DEST PlayField '                                           make playing field image the destination
146.     IF Pscore(0) = 9 THEN Clr = BRIGHTWHITE ELSE Clr = WHITE '  set color of font
147.     DrawScore SCREENWIDTH \ 2 - 100, 50, Pscore(0), Clr '       draw player 1's score
148.     IF Pscore(1) = 9 THEN Clr = BRIGHTWHITE ELSE Clr = WHITE '  set color of font
149.     DrawScore SCREENWIDTH \ 2 + 55, 50, Pscore(1), Clr '        draw player 2's score
150.     _DEST 0 '                                                   set destination back to screen
151.  
152. END SUB
153.  
154. '-------------------------------------------------------------------------------------------------------------
155. SUB DrawScore (dx AS INTEGER, dy AS INTEGER, n AS INTEGER, clr AS _UNSIGNED LONG)
156.     '---------------------------------------------------------------------------------------------------------
157.  
158.     SHARED Score() AS STRING * 15 ' need access to encoded font data
159.     DIM x AS INTEGER '              font column counter
160.     DIM y AS INTEGER '              font row counter
161.     DIM p AS INTEGER '              string position counter
162.  
163.     p = 0 '                                       reset string position counter
164.     FOR y = 0 TO 4 '                              cycle through 5 rows
165.         FOR x = 0 TO 2 '                          cycle through 3 columns
166.             p = p + 1 '                           increment string position counter
167.             IF MID$(Score(n), p, 1) <> " " THEN ' character in this position?
168.                 LINE (dx + x * 15, dy + y * 15)-(dx + x * 15 + 15, dy + y * 15 + 15), clr, BF ' yes, draw cube
169.             END IF
170.     NEXT x, y '                                   leave when all rows and columns processed
171.  
172. END SUB
173.  
174. '-------------------------------------------------------------------------------------------------------------
175. SUB MovePuck ()
176.     '---------------------------------------------------------------------------------------------------------
177.  
178.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
179.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
180.     SHARED Puck AS MOVINGOBJECT '     need access to puck
181.     SHARED Missed AS INTEGER '        need access to puck miss indicator
182.     SHARED Pscore() AS INTEGER '      need access to player scores
183.  
184.     Puck.x = Puck.x + Puck.xv '            add X vector component to X coordinate
185.     Puck.y = Puck.y + Puck.yv '            add Y vector component to Y coordinate
186.     Puck.rect.x1 = Puck.x - PUCKSIZE \ 2 ' calculate puck rectangle coordinates
187.     Puck.rect.y1 = Puck.y - PUCKSIZE \ 2
188.     Puck.rect.x2 = Puck.x + PUCKSIZE \ 2
189.     Puck.rect.y2 = Puck.y + PUCKSIZE \ 2
190.     IF Puck.x < PUCKXMIN OR Puck.x > PUCKXMAX THEN '                             is puck within a paddle area?
191.         IF SGN(Puck.xv) = -1 AND RectCollide(Puck.rect, P1Paddle.rect) THEN '    going left and hit paddle?
192.  
193.             '''
194.             ' Velocity vector using ordinary orientation.
195.             vx = Puck.xv
196.             vy = Puck.yv
197.  
198.             ' Find place on paddle where puck is hitting as fraction from midpoint. Result in interval [-1,1]
199.             hy = 2 * (Puck.y - P1Paddle.y) / (P1Paddle.rect.y1 - P1Paddle.rect.y2)
200.  
201.             ' Convert fractional height to an angle. Result in interval [-pi/2,pi/2]
202.             ang = _ASIN(hy)
203.  
204.             ' Create unit vectors based on imaginary circle.
205.             rux = COS(ang)
206.             ruy = SIN(ang)
207.             tux = -SIN(ang)
208.             tuy = COS(ang)
209.  
210.             ' Re-calculate velocity vector in new basis.
211.             wr = vx * rux + vy * ruy
212.             wt = vx * tux + vy * tuy
213.  
214.             ' Reflect the velocity about the normal vector
215.             wt = -wt
216.  
217.             ' Re-calculate veloctiy in old basis.
218.             vx = wr * COS(ang) - wt * SIN(ang)
219.             vy = wr * SIN(ang) + wt * COS(ang)
220.  
221.             ' Restore original variables
222.             Puck.xv = vx
223.             Puck.yv = vy
224.             '''
225.  
226.             Puck.xv = -Puck.xv + .025 '                                          yes, reverse X vector
227.             Puck.x = PUCKXMIN '                                                  place puck to right of paddle
228.  
229.             '** change in Y vector component here
230.  
231.             SOUND 440, 1 '                                                       audio report
232.         ELSEIF SGN(Puck.xv) = 1 AND RectCollide(Puck.rect, P2Paddle.rect) THEN ' going right and hit paddle?
233.             Puck.xv = -Puck.xv - .025 '                                          yes, reverse X vector
234.             Puck.x = PUCKXMAX '                                                  place puck to left of paddle
235.  
236.             '** change in Y vector component here
237.  
238.             SOUND 440, 1 '                                                       audio report
239.         END IF
240.     END IF
241.     IF Puck.y < PUCKYMIN OR Puck.y > PUCKYMAX THEN '                             is puck hitting a side line?
242.         IF SGN(Puck.yv) = -1 THEN Puck.y = PUCKYMIN ELSE Puck.y = PUCKYMAX '     yes, place puck above/below
243.         Puck.yv = -Puck.yv '                                                     reverse Y vector
244.         SOUND 880, 1 '                                                           audio report
245.     END IF
246.     IF Puck.x < P1MISSED OR Puck.x > P2MISSED THEN '                             did puck hit edge of screen?
247.         Missed = TRUE '                                                          yes, set missed indicator
248.         SOUND 220, 1 '                                                           audio report
249.     END IF
250.     LINE (Puck.rect.x1, Puck.rect.y1)-(Puck.rect.x2, Puck.rect.y2), BRIGHTWHITE, BF ' draw puck
251.  
252. END SUB
253.  
254. '-------------------------------------------------------------------------------------------------------------
255. SUB MovePaddles ()
256.     '---------------------------------------------------------------------------------------------------------
257.  
258.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
259.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
260.     SHARED Puck AS MOVINGOBJECT '     need access to puck
261.     SHARED Computer AS INTEGER '      need access to computer opponent
262.  
263.     IF _KEYDOWN(87) OR _KEYDOWN(119) THEN '                       player 1 pressing W or w keys?
264.         P1Paddle.y = P1Paddle.y - PADDLESPEED '                   yes, move paddle up
265.         IF P1Paddle.y < PADDLEYMIN THEN P1Paddle.y = PADDLEYMIN ' keep paddle in playing field
266.     ELSEIF _KEYDOWN(83) OR _KEYDOWN(115) THEN '                   player 1 pressing S or s keys?
267.         P1Paddle.y = P1Paddle.y + PADDLESPEED '                   yes, move paddle down
268.         IF P1Paddle.y > PADDLEYMAX THEN P1Paddle.y = PADDLEYMAX ' keep paddle in playing field
269.     END IF
270.     IF Computer THEN '                                            is player 1 playing computer?
271.         IF SGN(Puck.xv) = 1 THEN '                                yes, is puck heading for computer?
272.             IF Puck.y - P2Paddle.y < 0 THEN '                     yes, is puck higher than center of paddle?
273.                 P2Paddle.y = P2Paddle.y - .5 - RND(1) / 3 '       yes, move computer paddle up
274.                 IF P2Paddle.y < PADDLEYMIN THEN P2Paddle.y = PADDLEYMIN ' keep paddle in playing field
275.             ELSE '                                                no, puck is below center of paddle
276.                 P2Paddle.y = P2Paddle.y + .5 + RND(1) / 3 '       move computer paddle down
277.                 IF P2Paddle.y > PADDLEYMAX THEN P2Paddle.y = PADDLEYMAX ' keep paddle in playing field
278.             END IF
279.         END IF
280.     ELSEIF _KEYDOWN(18432) THEN '                                 player 2 pressing up arrow key?
281.         P2Paddle.y = P2Paddle.y - PADDLESPEED '                   yes, move paddle up
282.         IF P2Paddle.y < PADDLEYMIN THEN P2Paddle.y = PADDLEYMIN ' keep paddle in playing field
283.     ELSEIF _KEYDOWN(20480) THEN '                                 player 2 pressing down arrow key?
284.         P2Paddle.y = P2Paddle.y + PADDLESPEED '                   yes, move paddle down
285.         IF P2Paddle.y > PADDLEYMAX THEN P2Paddle.y = PADDLEYMAX ' keep paddle in playing field
286.     END IF
287.     P1Paddle.rect.y1 = P1Paddle.y - PADDLEHEIGHT \ 2 '            calc player 1 paddle rectangle
288.     P1Paddle.rect.y2 = P1Paddle.y + PADDLEHEIGHT \ 2
289.     P2Paddle.rect.y1 = P2Paddle.y - PADDLEHEIGHT \ 2 '            calc player 2 paddle rectangle
290.     P2Paddle.rect.y2 = P2Paddle.y + PADDLEHEIGHT \ 2
291.     LINE (P1Paddle.rect.x1, P1Paddle.rect.y1)-(P1Paddle.rect.x2, P1Paddle.rect.y2), BRIGHTWHITE, BF ' draw
292.     LINE (P2Paddle.rect.x1, P2Paddle.rect.y1)-(P2Paddle.rect.x2, P2Paddle.rect.y2), BRIGHTWHITE, BF ' paddles
293.  
294. END SUB
295.  
296. '-------------------------------------------------------------------------------------------------------------
297. SUB NewGame ()
298.     '---------------------------------------------------------------------------------------------------------
299.  
300.     SHARED P1Paddle AS MOVINGOBJECT ' need access toplayer 1 paddle
301.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
302.     SHARED Puck AS MOVINGOBJECT '     need access to puck
303.     SHARED PlayField AS LONG '        need access to playing field image
304.     SHARED Pscore() AS INTEGER '      need access to player scores
305.     SHARED Missed AS INTEGER '        need access to puck miss indicator
306.     SHARED GameOver AS INTEGER '      need access to game over indicator
307.     SHARED Computer AS INTEGER '      need access to computer opponent
308.     DIM Blink AS INTEGER '            blink bit
309.     DIM NumPlayers AS INTEGER '       number of players selected
310.     DIM Frames AS INTEGER '           frame counter
311.  
312.     P1Paddle.y = SCREENHEIGHT \ 2 '                                                reset paddle locations
313.     P2Paddle.y = P1Paddle.y
314.     Puck.xv = -1 '.5 '                                                                 reset puck X speed
315.     Puck.y = SCREENHEIGHT \ 2
316.     Missed = FALSE '                                                               reset missed indicator
317.     GameOver = FALSE '                                                             reset game over indicator
318.     Computer = FALSE '                                                             player 2 is human
319.     SOUND 440, 1 '                                                                 new game audio
320.     SOUND 880, 1
321.     DO '                                                                           begin setup loop
322.         _LIMIT FPS '                                                               limit frame speed
323.         _PUTIMAGE , PlayField '                                                    restore playing field
324.         MovePaddles '                                                              allow paddle movement
325.         Frames = Frames + 1 '                                                      increment frame counter
326.         IF Frames = FPS THEN '                                                     max frames reached?
327.             Frames = 0 '                                                           yes, reset frame counter
328.             Blink = 1 - Blink '                                                    toggle blink bit
329.         END IF
330.         LOCATE (SCREENHEIGHT \ 16), ((SCREENWIDTH \ 8) - 51) \ 2 + 1 '             position cursor on screen
331.         SELECT CASE Blink '                                                        which blinker bit?
332.             CASE 0 '                                                               blinker bit 0
333.                 IF NumPlayers = 0 THEN '                                           number of players chosen?
334.                     PRINT "    SELECT (1) OR (2) PLAYERS NOW : ESC TO EXIT    "; ' no, display player select
335.                 ELSE '                                                             yes
336.                     PRINT "(1) OR (2) PLAYERS : SPACEBAR TO PLAY : ESC TO EXIT"; ' display all instructions
337.                 END IF
338.             CASE 1 '                                                               blinker bit 1
339.                 PRINT SPACE$(51); '                                                remove instructions
340.         END SELECT
341.         LOCATE (SCREENHEIGHT \ 16) - 2, ((SCREENWIDTH \ 16) - 27) \ 2 + 1 '        position cursor on screen
342.         PRINT "PLAYER 1: W = UP / S = DOWN" '                                      display keys to player 1
343.         LOCATE (SCREENHEIGHT \ 16) - 2, ((SCREENWIDTH \ 8) - 31) \ 2 + (SCREENWIDTH \ 32) + 1 'position cursor
344.         SELECT CASE NumPlayers '                                                   how many players selected?
345.             CASE 0: PRINT " SELECT (1) OR (2) PLAYERS NOW " '                      ask number of players
346.             CASE 1: PRINT " PLAYER 2: THE CPU HAS CONTROL " '                      inform computer playing
347.             CASE 2: PRINT "PLAYER 2: UP ARROW / DOWN ARROW" '                      display keys player 2
348.         END SELECT
349.         IF NumPlayers <> 1 THEN '                                                  has one player been chosen?
350.             IF _KEYDOWN(49) THEN '                                                 no, "1" key been pressed?
351.                 NumPlayers = 1 '                                                   yes, set players to 1
352.                 Computer = TRUE '                                                  remember AI now has control
353.                 SOUND 440, 1 '                                                     play affirmation beep
354.                 SOUND 880, 1 '                                                     play affirmation beep
355.             END IF
356.         END IF
357.         IF NumPlayers <> 2 THEN '                                                  has two player been chosen?
358.             IF _KEYDOWN(50) THEN '                                                 no, "2" key been pressed?
359.                 NumPlayers = 2 '                                                   yes, set players to 2
360.                 Computer = FALSE '                                                 human is playing human
361.                 SOUND 440, 1 '                                                     play affirmation beep
362.                 SOUND 880, 1 '                                                     play affirmation beep
363.             END IF
364.         END IF
365.         _DISPLAY '                                                                 update screen with changes
366.     LOOP UNTIL (_KEYDOWN(32) AND NumPlayers) OR _KEYDOWN(27) '                     leave when players select
367.     Pscore(0) = 0 '                                                                reset scores
368.     Pscore(1) = 0
369.     UpdateScores '                                                                 update on screen scores
370.  
371. END SUB
372.  
373. '-------------------------------------------------------------------------------------------------------------
374. SUB Initialize ()
375.     '---------------------------------------------------------------------------------------------------------
376.  
377.     SHARED PlayField AS LONG '        need access to playing field image
378.     SHARED PlayFieldCopy AS LONG '    need access to playing field image copy
379.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
380.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
381.     SHARED Puck AS MOVINGOBJECT '     need access to puck
382.     SHARED Score() AS STRING * 15 '   need access to encoded font data
383.     DIM y AS INTEGER '                center line counter
384.  
385.     RANDOMIZE TIMER '                                               seed random number generator
386.  
387.     '** do as many precalculations as possible for values that will not change
388.  
389.     P1Paddle.x = PADDLEOFFSET + PADDLEWIDTH \ 2 '                   calculate player 1 paddle X coordinate
390.     P2Paddle.x = SCREENWIDTH - 1 - PADDLEOFFSET - PADDLEWIDTH \ 2 ' calculate player 2 paddle X coordinate
391.     P1Paddle.rect.x1 = P1Paddle.x - PADDLEWIDTH \ 2 '               calculate player 1 paddle rectangle
392.     P1Paddle.rect.x2 = P1Paddle.x + PADDLEWIDTH \ 2
393.     P2Paddle.rect.x1 = P2Paddle.x - PADDLEWIDTH \ 2 '               calculate player 2 paddle rectangle
394.     P2Paddle.rect.x2 = P2Paddle.x + PADDLEWIDTH \ 2
395.  
396.     '** draw default playing field
397.  
398.     PlayField = _NEWIMAGE(SCREENWIDTH, SCREENHEIGHT, 32) '          create image
399.     _DEST PlayField '                                               make it destination
400.     CLS '                                                           clear image
401.     LINE (0, 19)-(SCREENWIDTH - 1, 29), BRIGHTWHITE, BF '           draw top side line
402.     LINE (0, SCREENHEIGHT - 30)-(SCREENWIDTH - 1, SCREENHEIGHT - 20), BRIGHTWHITE, BF ' draw bottom side line
403.     FOR y = 40 TO SCREENHEIGHT - 52 STEP 30 '                       cycle top to bottom
404.         LINE ((SCREENWIDTH \ 2) - 5, y)-((SCREENWIDTH \ 2) + 5, y + 15), GRAY, BF '     draw center lines
405.     NEXT y
406.     _DEST 0 '                                                       destination back to screen
407.     PlayFieldCopy = _COPYIMAGE(PlayField) '                         save a copy of the playing field image
408.     Score(0) = "0000 00 00 0000" '                                  create numeric font data
409.     Score(1) = "  1  1  1  1  1"
410.     Score(2) = "222  22222  222"
411.     Score(3) = "333  3333  3333"
412.     Score(4) = "4 44 4444  4  4"
413.     Score(5) = "5555  555  5555"
414.     Score(6) = "6666  6666 6666"
415.     Score(7) = "777  7  7  7  7"
416.     Score(8) = "8888 88888 8888"
417.     Score(9) = "9999 9999  9999"
418.  
419. END SUB
420.  
421. '-------------------------------------------------------------------------------------------------------------
422. FUNCTION RectCollide (Rect1 AS RECTTYPE, Rect2 AS RECTTYPE)
423.     '---------------------------------------------------------------------------------------------------------
424.  
425.     RectCollide = FALSE '                       assume no collision
426.     IF Rect1.x2 >= Rect2.x1 THEN '              rect 1 lower right X >= rect 2 upper left  X ?
427.         IF Rect1.x1 <= Rect2.x2 THEN '          rect 1 upper left  X <= rect 2 lower right x ?
428.             IF Rect1.y2 >= Rect2.y1 THEN '      rect 1 lower right Y >= rect 2 upper left  Y ?
429.                 IF Rect1.y1 <= Rect2.y2 THEN '  rect 1 upper left  Y <= rect 2 lower right Y ?
430.                     RectCollide = TRUE '        if all 4 IFs TRUE then a collision is occurring
431.                 END IF
432.             END IF
433.         END IF
434.     END IF
435.  
436. END FUNCTION
437.  
438. '-------------------------------------------------------------------------------------------------------------
439. SUB Cleanup ()
440.     '---------------------------------------------------------------------------------------------------------
441.  
442.     SHARED PlayField AS LONG '     need access to playing field image
443.     SHARED PlayFieldCopy AS LONG ' need access to playing field image copy
444.  
445.     _FREEIMAGE PlayField '         free images from memory
446.     _FREEIMAGE PlayFieldCopy
447.     SYSTEM '                       return to operating system
448.  
449. END SUB
450.  
451. '-------------------------------------------------------------------------------------------------------------
452. FUNCTION Yvector (PaddleY AS INTEGER, PuckY AS INTEGER, PuckYV)
453.     '---------------------------------------------------------------------------------------------------------
454.  
455.  
456.     '** math here (ugh)
457.  
458.  
459. END FUNCTION
460.  
461.  

[bplus]

Here is plain old randomness:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. '-------------------------------------------------------------------------------------------------------------
4. '** Declare constants
5. '-------------------------------------------------------------------------------------------------------------
6.  
7. CONST FALSE = 0, TRUE = NOT FALSE '               truth detectors
8. CONST BRIGHTWHITE = _RGB32(255, 255, 255) '       define colors
9. CONST WHITE = _RGB32(192, 192, 192)
10. CONST GRAY = _RGB32(128, 128, 128) '
11. CONST SCREENWIDTH = 768 '                         screen width
12. CONST SCREENHEIGHT = 576 '                        screen height
13. CONST PUCKSIZE = 10 '                             puck square size
14. CONST PADDLEWIDTH = 10 '                          paddle width
15. CONST PADDLEHEIGHT = 60 '                         paddle height
16. CONST PADDLESPEED = 2 '                           paddle Y speed
17. CONST PADDLEOFFSET = 20 '                         paddle offset from side of screen
18. CONST P1MISSED = PUCKSIZE \ 2 '                   puck on left side edge of screen
19. CONST P2MISSED = SCREENWIDTH - 1 - PUCKSIZE \ 2 ' puck on right side edge of screen
20. CONST PADDLEYMIN = PADDLEHEIGHT \ 2 + 30 '                                     min Y coordinate for paddles
21. CONST PADDLEYMAX = SCREENHEIGHT - 30 - PADDLEHEIGHT \ 2 '                      max Y coordinate for paddles
22. CONST PUCKXMIN = PADDLEOFFSET + PADDLEWIDTH + PUCKSIZE \ 2 '                   min X coordinate for puck
23. CONST PUCKXMAX = SCREENWIDTH - 1 - PADDLEOFFSET - PADDLEWIDTH - PUCKSIZE \ 2 ' max X coordinate for puck
24. CONST PUCKYMIN = 30 + PUCKSIZE \ 2 '                                           min Y coordinate for puck
25. CONST PUCKYMAX = SCREENHEIGHT - 30 - PUCKSIZE \ 2 '                            max Y coordinate for puck
26. CONST FPS = 300 '                                                              game frames per second
27.  
28. '-------------------------------------------------------------------------------------------------------------
29. '** Declare TYPE definitions
30. '-------------------------------------------------------------------------------------------------------------
31.  
32. TYPE RECTTYPE '        rectangle definition for collision detection
33.     x1 AS INTEGER '    upper left X coordinate
34.     y1 AS INTEGER '    upper left Y coordinate
35.     x2 AS INTEGER '    lower right X coordinate
36.     y2 AS INTEGER '    lower right Y coordinate
37. END TYPE
38.  
39. TYPE MOVINGOBJECT '    moving object definition
40.     x AS SINGLE '      center X coordinate
41.     y AS SINGLE '      center Y coordinate
42.     xv AS SINGLE '     X vector component
43.     yv AS SINGLE '     Y vector component
44.     rect AS RECTTYPE ' rectangle coordinates for collision detection
45. END TYPE
46.  
47. '-------------------------------------------------------------------------------------------------------------
48. '** Declare global variables
49. '-------------------------------------------------------------------------------------------------------------
50.  
51. DIM PlayField AS LONG '        playing field image
52. DIM PlayFieldCopy AS LONG '    playing field image copy (without scores)
53. DIM P1Paddle AS MOVINGOBJECT ' player 1 paddle
54. DIM P2Paddle AS MOVINGOBJECT ' player 2 paddle
55. DIM Puck AS MOVINGOBJECT '     puck properties
56. DIM Computer AS INTEGER '      TRUE if computer playing
57. DIM Score(9) AS STRING * 15 '  encoded font data
58. DIM Pscore(1) AS INTEGER '     player scores (0=player1, 1=player2
59. DIM Missed AS INTEGER '        TRUE when a player misses the puck
60. DIM GameOver AS INTEGER '      TRUE when a player reaches a score of 9
61.  
62. '-------------------------------------------------------------------------------------------------------------
63. '** Begin main program
64. '-------------------------------------------------------------------------------------------------------------
65.  
66. SCREEN _NEWIMAGE(SCREENWIDTH, SCREENHEIGHT, 32) ' enter graphics screen
67. _TITLE "QB64 PONG!" '                             give window a title
68. _DELAY .5 '                                       slight delay
69. _SCREENMOVE _MIDDLE '                             move window to center of desktop
70. Initialize '                                      initialize game settings
71. DO '                                              begin main program loop
72.     NewGame '                                     start a new game
73.     DO '                                          begin game loop
74.         PlayGame '                                play the game
75.     LOOP UNTIL GameOver OR _KEYDOWN(27) '         leave when game over or player exits
76. LOOP UNTIL _KEYDOWN(27) '                         leave when player exits
77. Cleanup '                                         clean player's computer memory and exit to operating system
78.  
79. '-------------------------------------------------------------------------------------------------------------
80. '** end main program
81. '-------------------------------------------------------------------------------------------------------------
82.  
83. '-------------------------------------------------------------------------------------------------------------
84. '** Declare subroutines and functions
85. '-------------------------------------------------------------------------------------------------------------
86.  
87. '-------------------------------------------------------------------------------------------------------------
88. SUB ResetRound ()
89.     '---------------------------------------------------------------------------------------------------------
90.  
91.     SHARED Missed AS INTEGER '    need access to puck miss indicator
92.     SHARED Puck AS MOVINGOBJECT ' need access to puck
93.  
94.     IF SGN(Puck.xv) = 1 THEN '                          puck was heading right?
95.         Puck.x = SCREENWIDTH * .25 '                    yes, serve from player 1 side
96.         Puck.xv = .5 '                                  puck will travel right
97.     ELSE '                                              no, puck was travleing left
98.         Puck.x = SCREENWIDTH * .75 '                    serve from player 2 side
99.         Puck.xv = -.5 '                                 puck will travel left
100.     END IF
101.     Puck.y = INT(RND(1) * (SCREENHEIGHT - 100)) + 50 '  random puck Y coordinate
102.     Puck.yv = (RND(1) - RND(1)) / 2 '                   random puck Y vector component
103.     Missed = FALSE '                                    reset puck missed indicator
104.  
105. END SUB
106.  
107. '-------------------------------------------------------------------------------------------------------------
108. SUB PlayGame ()
109.     '---------------------------------------------------------------------------------------------------------
110.  
111.     SHARED PlayField AS LONG '    need access to playing field image
112.     SHARED Missed AS INTEGER '    need access to puck miss indicator
113.     SHARED Puck AS MOVINGOBJECT ' need access to puck
114.     SHARED Pscore() AS INTEGER '  need access to player scores
115.     SHARED GameOver AS INTEGER '  need access to game over indicator
116.  
117.     ResetRound '                                             set up next game round
118.     DO '                                                     begin round loop
119.         _LIMIT FPS '                                         limit game speed
120.         _PUTIMAGE , PlayField '                              reset playing field
121.         MovePaddles '                                        update player paddles
122.         MovePuck '                                           update puck
123.         _DISPLAY '                                           update screen with changes
124.     LOOP UNTIL Missed OR _KEYDOWN(27) '                      leave when puck missed or a player presses ESC
125.     IF SGN(Puck.xv) = -1 THEN '                              was puck heading left?
126.         Pscore(1) = Pscore(1) + 1 '                          yes, increase player 2 score
127.     ELSE '                                                   no, puck was heading right
128.         Pscore(0) = Pscore(0) + 1 '                          increase player 1 score
129.     END IF
130.     IF Pscore(0) = 9 OR Pscore(1) = 9 THEN GameOver = TRUE ' set game over indicator when player reaches 9
131.     UpdateScores '                                           update player scores
132.  
133. END SUB
134.  
135. '-------------------------------------------------------------------------------------------------------------
136. SUB UpdateScores ()
137.     '---------------------------------------------------------------------------------------------------------
138.  
139.     SHARED PlayField AS LONG '     need access to playing field image
140.     SHARED PlayFieldCopy AS LONG ' need access to playing field image copy
141.     SHARED Pscore() AS INTEGER '   need access to player scores
142.     DIM Clr AS _UNSIGNED LONG '    font color
143.  
144.     _PUTIMAGE , PlayFieldCopy, PlayField '                      restore playing field
145.     _DEST PlayField '                                           make playing field image the destination
146.     IF Pscore(0) = 9 THEN Clr = BRIGHTWHITE ELSE Clr = WHITE '  set color of font
147.     DrawScore SCREENWIDTH \ 2 - 100, 50, Pscore(0), Clr '       draw player 1's score
148.     IF Pscore(1) = 9 THEN Clr = BRIGHTWHITE ELSE Clr = WHITE '  set color of font
149.     DrawScore SCREENWIDTH \ 2 + 55, 50, Pscore(1), Clr '        draw player 2's score
150.     _DEST 0 '                                                   set destination back to screen
151.  
152. END SUB
153.  
154. '-------------------------------------------------------------------------------------------------------------
155. SUB DrawScore (dx AS INTEGER, dy AS INTEGER, n AS INTEGER, clr AS _UNSIGNED LONG)
156.     '---------------------------------------------------------------------------------------------------------
157.  
158.     SHARED Score() AS STRING * 15 ' need access to encoded font data
159.     DIM x AS INTEGER '              font column counter
160.     DIM y AS INTEGER '              font row counter
161.     DIM p AS INTEGER '              string position counter
162.  
163.     p = 0 '                                       reset string position counter
164.     FOR y = 0 TO 4 '                              cycle through 5 rows
165.         FOR x = 0 TO 2 '                          cycle through 3 columns
166.             p = p + 1 '                           increment string position counter
167.             IF MID$(Score(n), p, 1) <> " " THEN ' character in this position?
168.                 LINE (dx + x * 15, dy + y * 15)-(dx + x * 15 + 15, dy + y * 15 + 15), clr, BF ' yes, draw cube
169.             END IF
170.     NEXT x, y '                                   leave when all rows and columns processed
171.  
172. END SUB
173.  
174. '-------------------------------------------------------------------------------------------------------------
175. SUB MovePuck ()
176.     '---------------------------------------------------------------------------------------------------------
177.  
178.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
179.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
180.     SHARED Puck AS MOVINGOBJECT '     need access to puck
181.     SHARED Missed AS INTEGER '        need access to puck miss indicator
182.     SHARED Pscore() AS INTEGER '      need access to player scores
183.  
184.     Puck.x = Puck.x + Puck.xv '            add X vector component to X coordinate
185.     Puck.y = Puck.y + Puck.yv '            add Y vector component to Y coordinate
186.     Puck.rect.x1 = Puck.x - PUCKSIZE \ 2 ' calculate puck rectangle coordinates
187.     Puck.rect.y1 = Puck.y - PUCKSIZE \ 2
188.     Puck.rect.x2 = Puck.x + PUCKSIZE \ 2
189.     Puck.rect.y2 = Puck.y + PUCKSIZE \ 2
190.     IF Puck.x < PUCKXMIN OR Puck.x > PUCKXMAX THEN '                             is puck within a paddle area?
191.         IF SGN(Puck.xv) = -1 AND RectCollide(Puck.rect, P1Paddle.rect) THEN '    going left and hit paddle?
192.             Puck.xv = -Puck.xv + .025 '                                          yes, reverse X vector
193.             Puck.x = PUCKXMIN '                                                  place puck to right of paddle
194.             Puck.yv = RND * 3 - 1.5
195.             '** change in Y vector component here
196.  
197.             SOUND 440, 1 '                                                       audio report
198.         ELSEIF SGN(Puck.xv) = 1 AND RectCollide(Puck.rect, P2Paddle.rect) THEN ' going right and hit paddle?
199.             Puck.xv = -Puck.xv - .025 '                                          yes, reverse X vector
200.             Puck.x = PUCKXMAX '                                                  place puck to left of paddle
201.             Puck.yv = RND * 3 - 1.5
202.             '** change in Y vector component here
203.  
204.             SOUND 440, 1 '                                                       audio report
205.         END IF
206.     END IF
207.     IF Puck.y < PUCKYMIN OR Puck.y > PUCKYMAX THEN '                             is puck hitting a side line?
208.         IF SGN(Puck.yv) = -1 THEN Puck.y = PUCKYMIN ELSE Puck.y = PUCKYMAX '     yes, place puck above/below
209.         Puck.yv = -Puck.yv '                                                     reverse Y vector
210.         SOUND 880, 1 '                                                           audio report
211.     END IF
212.     IF Puck.x < P1MISSED OR Puck.x > P2MISSED THEN '                             did puck hit edge of screen?
213.         Missed = TRUE '                                                          yes, set missed indicator
214.         SOUND 220, 1 '                                                           audio report
215.     END IF
216.     LINE (Puck.rect.x1, Puck.rect.y1)-(Puck.rect.x2, Puck.rect.y2), BRIGHTWHITE, BF ' draw puck
217.  
218. END SUB
219.  
220. '-------------------------------------------------------------------------------------------------------------
221. SUB MovePaddles ()
222.     '---------------------------------------------------------------------------------------------------------
223.  
224.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
225.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
226.     SHARED Puck AS MOVINGOBJECT '     need access to puck
227.     SHARED Computer AS INTEGER '      need access to computer opponent
228.  
229.     IF _KEYDOWN(87) OR _KEYDOWN(119) THEN '                       player 1 pressing W or w keys?
230.         P1Paddle.y = P1Paddle.y - PADDLESPEED '                   yes, move paddle up
231.         IF P1Paddle.y < PADDLEYMIN THEN P1Paddle.y = PADDLEYMIN ' keep paddle in playing field
232.     ELSEIF _KEYDOWN(83) OR _KEYDOWN(115) THEN '                   player 1 pressing S or s keys?
233.         P1Paddle.y = P1Paddle.y + PADDLESPEED '                   yes, move paddle down
234.         IF P1Paddle.y > PADDLEYMAX THEN P1Paddle.y = PADDLEYMAX ' keep paddle in playing field
235.     END IF
236.     IF Computer THEN '                                            is player 1 playing computer?
237.         IF SGN(Puck.xv) = 1 THEN '                                yes, is puck heading for computer?
238.             IF Puck.y - P2Paddle.y < 0 THEN '                     yes, is puck higher than center of paddle?
239.                 P2Paddle.y = P2Paddle.y - .5 - RND(1) / 3 '       yes, move computer paddle up
240.                 IF P2Paddle.y < PADDLEYMIN THEN P2Paddle.y = PADDLEYMIN ' keep paddle in playing field
241.             ELSE '                                                no, puck is below center of paddle
242.                 P2Paddle.y = P2Paddle.y + .5 + RND(1) / 3 '       move computer paddle down
243.                 IF P2Paddle.y > PADDLEYMAX THEN P2Paddle.y = PADDLEYMAX ' keep paddle in playing field
244.             END IF
245.         END IF
246.     ELSEIF _KEYDOWN(18432) THEN '                                 player 2 pressing up arrow key?
247.         P2Paddle.y = P2Paddle.y - PADDLESPEED '                   yes, move paddle up
248.         IF P2Paddle.y < PADDLEYMIN THEN P2Paddle.y = PADDLEYMIN ' keep paddle in playing field
249.     ELSEIF _KEYDOWN(20480) THEN '                                 player 2 pressing down arrow key?
250.         P2Paddle.y = P2Paddle.y + PADDLESPEED '                   yes, move paddle down
251.         IF P2Paddle.y > PADDLEYMAX THEN P2Paddle.y = PADDLEYMAX ' keep paddle in playing field
252.     END IF
253.     P1Paddle.rect.y1 = P1Paddle.y - PADDLEHEIGHT \ 2 '            calc player 1 paddle rectangle
254.     P1Paddle.rect.y2 = P1Paddle.y + PADDLEHEIGHT \ 2
255.     P2Paddle.rect.y1 = P2Paddle.y - PADDLEHEIGHT \ 2 '            calc player 2 paddle rectangle
256.     P2Paddle.rect.y2 = P2Paddle.y + PADDLEHEIGHT \ 2
257.     LINE (P1Paddle.rect.x1, P1Paddle.rect.y1)-(P1Paddle.rect.x2, P1Paddle.rect.y2), BRIGHTWHITE, BF ' draw
258.     LINE (P2Paddle.rect.x1, P2Paddle.rect.y1)-(P2Paddle.rect.x2, P2Paddle.rect.y2), BRIGHTWHITE, BF ' paddles
259.  
260. END SUB
261.  
262. '-------------------------------------------------------------------------------------------------------------
263. SUB NewGame ()
264.     '---------------------------------------------------------------------------------------------------------
265.  
266.     SHARED P1Paddle AS MOVINGOBJECT ' need access toplayer 1 paddle
267.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
268.     SHARED Puck AS MOVINGOBJECT '     need access to puck
269.     SHARED PlayField AS LONG '        need access to playing field image
270.     SHARED Pscore() AS INTEGER '      need access to player scores
271.     SHARED Missed AS INTEGER '        need access to puck miss indicator
272.     SHARED GameOver AS INTEGER '      need access to game over indicator
273.     SHARED Computer AS INTEGER '      need access to computer opponent
274.     DIM Blink AS INTEGER '            blink bit
275.     DIM NumPlayers AS INTEGER '       number of players selected
276.     DIM Frames AS INTEGER '           frame counter
277.  
278.     P1Paddle.y = SCREENHEIGHT \ 2 '                                                reset paddle locations
279.     P2Paddle.y = P1Paddle.y
280.     Puck.xv = .5 '                                                                 reset puck X speed
281.     Puck.y = SCREENHEIGHT \ 2
282.     Missed = FALSE '                                                               reset missed indicator
283.     GameOver = FALSE '                                                             reset game over indicator
284.     Computer = FALSE '                                                             player 2 is human
285.     SOUND 440, 1 '                                                                 new game audio
286.     SOUND 880, 1
287.     DO '                                                                           begin setup loop
288.         _LIMIT FPS '                                                               limit frame speed
289.         _PUTIMAGE , PlayField '                                                    restore playing field
290.         MovePaddles '                                                              allow paddle movement
291.         Frames = Frames + 1 '                                                      increment frame counter
292.         IF Frames = FPS THEN '                                                     max frames reached?
293.             Frames = 0 '                                                           yes, reset frame counter
294.             Blink = 1 - Blink '                                                    toggle blink bit
295.         END IF
296.         LOCATE (SCREENHEIGHT \ 16), ((SCREENWIDTH \ 8) - 51) \ 2 + 1 '             position cursor on screen
297.         SELECT CASE Blink '                                                        which blinker bit?
298.             CASE 0 '                                                               blinker bit 0
299.                 IF NumPlayers = 0 THEN '                                           number of players chosen?
300.                     PRINT "    SELECT (1) OR (2) PLAYERS NOW : ESC TO EXIT    "; ' no, display player select
301.                 ELSE '                                                             yes
302.                     PRINT "(1) OR (2) PLAYERS : SPACEBAR TO PLAY : ESC TO EXIT"; ' display all instructions
303.                 END IF
304.             CASE 1 '                                                               blinker bit 1
305.                 PRINT SPACE$(51); '                                                remove instructions
306.         END SELECT
307.         LOCATE (SCREENHEIGHT \ 16) - 2, ((SCREENWIDTH \ 16) - 27) \ 2 + 1 '        position cursor on screen
308.         PRINT "PLAYER 1: W = UP / S = DOWN" '                                      display keys to player 1
309.         LOCATE (SCREENHEIGHT \ 16) - 2, ((SCREENWIDTH \ 8) - 31) \ 2 + (SCREENWIDTH \ 32) + 1 'position cursor
310.         SELECT CASE NumPlayers '                                                   how many players selected?
311.             CASE 0: PRINT " SELECT (1) OR (2) PLAYERS NOW " '                      ask number of players
312.             CASE 1: PRINT " PLAYER 2: THE CPU HAS CONTROL " '                      inform computer playing
313.             CASE 2: PRINT "PLAYER 2: UP ARROW / DOWN ARROW" '                      display keys player 2
314.         END SELECT
315.         IF NumPlayers <> 1 THEN '                                                  has one player been chosen?
316.             IF _KEYDOWN(49) THEN '                                                 no, "1" key been pressed?
317.                 NumPlayers = 1 '                                                   yes, set players to 1
318.                 Computer = TRUE '                                                  remember AI now has control
319.                 SOUND 440, 1 '                                                     play affirmation beep
320.                 SOUND 880, 1 '                                                     play affirmation beep
321.             END IF
322.         END IF
323.         IF NumPlayers <> 2 THEN '                                                  has two player been chosen?
324.             IF _KEYDOWN(50) THEN '                                                 no, "2" key been pressed?
325.                 NumPlayers = 2 '                                                   yes, set players to 2
326.                 Computer = FALSE '                                                 human is playing human
327.                 SOUND 440, 1 '                                                     play affirmation beep
328.                 SOUND 880, 1 '                                                     play affirmation beep
329.             END IF
330.         END IF
331.         _DISPLAY '                                                                 update screen with changes
332.     LOOP UNTIL (_KEYDOWN(32) AND NumPlayers) OR _KEYDOWN(27) '                     leave when players select
333.     Pscore(0) = 0 '                                                                reset scores
334.     Pscore(1) = 0
335.     UpdateScores '                                                                 update on screen scores
336.  
337. END SUB
338.  
339. '-------------------------------------------------------------------------------------------------------------
340. SUB Initialize ()
341.     '---------------------------------------------------------------------------------------------------------
342.  
343.     SHARED PlayField AS LONG '        need access to playing field image
344.     SHARED PlayFieldCopy AS LONG '    need access to playing field image copy
345.     SHARED P1Paddle AS MOVINGOBJECT ' need access to player 1 paddle
346.     SHARED P2Paddle AS MOVINGOBJECT ' need access to player 2 paddle
347.     SHARED Puck AS MOVINGOBJECT '     need access to puck
348.     SHARED Score() AS STRING * 15 '   need access to encoded font data
349.     DIM y AS INTEGER '                center line counter
350.  
351.     RANDOMIZE TIMER '                                               seed random number generator
352.  
353.     '** do as many precalculations as possible for values that will not change
354.  
355.     P1Paddle.x = PADDLEOFFSET + PADDLEWIDTH \ 2 '                   calculate player 1 paddle X coordinate
356.     P2Paddle.x = SCREENWIDTH - 1 - PADDLEOFFSET - PADDLEWIDTH \ 2 ' calculate player 2 paddle X coordinate
357.     P1Paddle.rect.x1 = P1Paddle.x - PADDLEWIDTH \ 2 '               calculate player 1 paddle rectangle
358.     P1Paddle.rect.x2 = P1Paddle.x + PADDLEWIDTH \ 2
359.     P2Paddle.rect.x1 = P2Paddle.x - PADDLEWIDTH \ 2 '               calculate player 2 paddle rectangle
360.     P2Paddle.rect.x2 = P2Paddle.x + PADDLEWIDTH \ 2
361.  
362.     '** draw default playing field
363.  
364.     PlayField = _NEWIMAGE(SCREENWIDTH, SCREENHEIGHT, 32) '          create image
365.     _DEST PlayField '                                               make it destination
366.     CLS '                                                           clear image
367.     LINE (0, 19)-(SCREENWIDTH - 1, 29), BRIGHTWHITE, BF '           draw top side line
368.     LINE (0, SCREENHEIGHT - 30)-(SCREENWIDTH - 1, SCREENHEIGHT - 20), BRIGHTWHITE, BF ' draw bottom side line
369.     FOR y = 40 TO SCREENHEIGHT - 52 STEP 30 '                       cycle top to bottom
370.         LINE ((SCREENWIDTH \ 2) - 5, y)-((SCREENWIDTH \ 2) + 5, y + 15), GRAY, BF '     draw center lines
371.     NEXT y
372.     _DEST 0 '                                                       destination back to screen
373.     PlayFieldCopy = _COPYIMAGE(PlayField) '                         save a copy of the playing field image
374.     Score(0) = "0000 00 00 0000" '                                  create numeric font data
375.     Score(1) = "  1  1  1  1  1"
376.     Score(2) = "222  22222  222"
377.     Score(3) = "333  3333  3333"
378.     Score(4) = "4 44 4444  4  4"
379.     Score(5) = "5555  555  5555"
380.     Score(6) = "6666  6666 6666"
381.     Score(7) = "777  7  7  7  7"
382.     Score(8) = "8888 88888 8888"
383.     Score(9) = "9999 9999  9999"
384.  
385. END SUB
386.  
387. '-------------------------------------------------------------------------------------------------------------
388. FUNCTION RectCollide (Rect1 AS RECTTYPE, Rect2 AS RECTTYPE)
389.     '---------------------------------------------------------------------------------------------------------
390.  
391.     RectCollide = FALSE '                       assume no collision
392.     IF Rect1.x2 >= Rect2.x1 THEN '              rect 1 lower right X >= rect 2 upper left  X ?
393.         IF Rect1.x1 <= Rect2.x2 THEN '          rect 1 upper left  X <= rect 2 lower right x ?
394.             IF Rect1.y2 >= Rect2.y1 THEN '      rect 1 lower right Y >= rect 2 upper left  Y ?
395.                 IF Rect1.y1 <= Rect2.y2 THEN '  rect 1 upper left  Y <= rect 2 lower right Y ?
396.                     RectCollide = TRUE '        if all 4 IFs TRUE then a collision is occurring
397.                 END IF
398.             END IF
399.         END IF
400.     END IF
401.  
402. END FUNCTION
403.  
404. '-------------------------------------------------------------------------------------------------------------
405. SUB Cleanup ()
406.     '---------------------------------------------------------------------------------------------------------
407.  
408.     SHARED PlayField AS LONG '     need access to playing field image
409.     SHARED PlayFieldCopy AS LONG ' need access to playing field image copy
410.  
411.     _FREEIMAGE PlayField '         free images from memory
412.     _FREEIMAGE PlayFieldCopy
413.     SYSTEM '                       return to operating system
414.  
415. END SUB
416.  
417. '-------------------------------------------------------------------------------------------------------------
418. FUNCTION Yvector (PaddleY AS INTEGER, PuckY AS INTEGER, PuckYV)
419.     '---------------------------------------------------------------------------------------------------------
420.  
421.  
422.     '** math here (ugh)
423.  
424.  
425. END FUNCTION
426.  
427.  
428.