Read character unter cursor

[Spacecaptain]

Is there any option to read the ascii-character at a specific screen location?
I would like to read and save a specific area of the text screen into an array before placing another text/window (a progress bar, for example) over it so I am able to restore this area afterwards.
Any help is appreciated!

[RhoSigma]

Long time ago, when I still used SCREEN 0 regulary, I made this two SUBs to save/restore screen areas. Note these SUBs are especially made for mode 0 (text only) screens, on other modes it probably won't respect the blinking colors.

see also http://www.qb64.org/wiki/SCREEN_(function)

Code: QB64: [Select]

1. '---------------------------------------------------------------------
2. 'Function:  Saving any text screen area for later restore, eg. any
3. '           area which is temporary covered/overwritten by other things.
4. '
5. 'Synopsis:  GetRefresh dat$, lin%, col%, hei%, wid%
6. '
7. 'Inputs:    dat$ --> this variable will become the ID for the specified
8. '                    area, don't change its content until the area was
9. '                    restored via PutRefresh() and you no longer need it
10. '                    for further refresh calls
11. '           lin% --> text line of top/left edge of the area
12. '           col% --> text column of top/left edge of the area
13. '           hei% --> height of the area as text lines
14. '           wid% --> width of the area as text columns
15. '
16. 'Notes:     Note the intended side effect on the argument "dat$".
17. '---------------------------------------------------------------------
18. SUB GetRefresh (dat$, lin%, col%, hei%, wid%)
19. '--- save dimensions ---
20. dat$ = CHR$(lin%) + CHR$(col%) + CHR$(hei%) + CHR$(wid%)
21. '--- save screen data ---
22. FOR y% = lin% TO lin% + hei% - 1
23.     FOR x% = col% TO col% + wid% - 1
24.         dat$ = dat$ + CHR$(SCREEN(y%, x%)) + CHR$(SCREEN(y%, x%, 1))
25.     NEXT x%
26. NEXT y%
27. END SUB
28.  
29. '---------------------------------------------------------------------
30. 'Function:  Restore a text screen area saved earlier by GetRefresh().
31. '           Note that the actual PRINT (cursor) position and COLOR is
32. '           changed after this call, so you have to use LOCATE and
33. '           COLOR to designate your next PRINT position and color.
34. '
35. 'Synopsis:  PutRefresh dat$
36. '
37. 'Inputs:    dat$ --> the same (and still unchanged) variable you did use
38. '                    as "dat$" for the respective GetRefresh() call.
39. '---------------------------------------------------------------------
40. SUB PutRefresh (dat$)
41. '--- get dimensions ---
42. lin% = ASC(MID$(dat$, 1, 1))
43. col% = ASC(MID$(dat$, 2, 1))
44. hei% = ASC(MID$(dat$, 3, 1))
45. wid% = ASC(MID$(dat$, 4, 1))
46. wc& = 5
47. '--- restore screen data ---
48. FOR y% = lin% TO lin% + hei% - 1
49.     FOR x% = col% TO col% + wid% - 1
50.         co% = ASC(MID$(dat$, wc& + 1, 1))
51.         fg% = (co% AND &HF)
52.         bg% = (co% AND &HF0) / 16
53.         IF bg% > 7 THEN 'MSB set in the bg% nibble indicates blinking fg%
54.             fg% = fg% + 16
55.             bg% = bg% - 8
56.         END IF
57.         LOCATE y%, x%, 0
58.         COLOR fg%, bg%
59.         PRINT MID$(dat$, wc&, 1);
60.         wc& = wc& + 2
61.     NEXT x%
62. NEXT y%
63. END SUB
64.  
65.  

P.S. - Und Grüße aus'm Harz nach Berlin :)

[SMcNeill]

Easiest solution to what it sounds like you're doing is PCOPY.


PRINT "Some junk on the screen"
PRINT "And some more junk"
PCOPY 0, 1
PRINT "PRESS <ANY KEY> TO ERASE THE SCREEN"
SLEEP
CLS
PRINT "It's all erased!  Press <ANY KEY> to restore the original>
SLEEP
PCOPY 1, 0

[Spacecaptain]

Excellent - thanks a lot for the quick reply!

Und Grüße zurück in den Harz ;-)