Math Question With Autocad Drawing Included

[lomalena]

So, I have R = 3 - Cos (t)  equation.
I want this equation use as a base of a conic
How can I write this?

[bplus]

Here are routines for drawing Ellipsii:
https://www.qb64.org/forum/index.php?topic=1069.0

[bplus]

Well crap there is no simple ellipsii (though could use CIRCLE with aspect but it sucks) so here is TiltedEllipse simplified to Ellipse with a conic demo:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Ellipsii No Fill" 'b+ 2020-04-11
3. CONST xmax = 700, ymax = 700
4. SCREEN _NEWIMAGE(xmax, ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7. DIM cx, cy, a, xRad, yRad, p, c~&, mx, my, dist, d
8.  
9. cx = xmax / 2: cy = ymax / 2
10. xRad = 350: yRad = 50: c~& = &HFF0000FF
11. WHILE 1
12.     CLS
13.     WHILE _MOUSEINPUT: WEND
14.     mx = _MOUSEX: my = _MOUSEY
15.     dist = ((mx - cx) ^ 2 + (my - cy) ^ 2) ^ .5
16.     FOR d = 0 TO dist STEP 15
17.         p = 1 - d / dist
18.         a = _ATAN2(my - cy, mx - cx)
19.         Ellipse cx + d * COS(a), cy + d * SIN(a), p * xRad, p * yRad, c~&
20.         Ellipse cx + d * COS(a), cy + d * SIN(a), p * yRad, p * xRad, &HFFFF0000
21.     NEXT
22.     _DISPLAY
23.     _LIMIT 100
24. WEND
25.  
26. 'use this for regular ellipse  
27. SUB Ellipse (CX, CY, xRadius, yRadius, C AS _UNSIGNED LONG)
28.     '  CX = center x coordinate
29.     '  CY = center y coordinate
30.     '  xRadius = x axis radius
31.     '  yRadius = y axis radius
32.     '   C = fill color
33.     DIM a, x, y, stepper
34.     stepper = .001 '.025 ain't enough
35.     FOR a = 0 TO 6.283185307179586 + stepper STEP stepper
36.         x = CX + xRadius * COS(a)
37.         y = CY + yRadius * SIN(a)
38.         IF a <> 0 THEN LINE -(x, y), C ELSE PSET (x, y), C
39.     NEXT
40. END SUB
41.  
42.  

   [ You are not allowed to view this attachment ]  

[STxAxTIC]

' major and minor axis is misleading as I already told Mr STx as major implies the bigger

say what?

[bplus]

say what?

Referring to: https://www.qb64.org/forum/index.php?topic=1069.0

Code: QB64: [Select]

1. SUB EllipseTilt (CX, CY, a, b, ang, C AS _UNSIGNED LONG)
2.     '  CX = center x coordinate
3.     '  CY = center y coordinate
4.     '   a = semimajor axis  ' <<<<<<<<<<<<<<<<<< I said this is mislabeled
5.     '   b = semiminor axis  ' <<<<<<<<<<<<<<<<<< I said this is mislabeled
6.     ' ang = clockwise orientation of semimajor axis in radians (0 default)
7.     '   C = fill color
8.     FOR k = 0 TO 6.283185307179586 + .025 STEP .025
9.         i = a * COS(k) * COS(ang) + b * SIN(k) * SIN(ang)
10.         j = -a * COS(k) * SIN(ang) + b * SIN(k) * COS(ang)
11.         i = i + CX
12.         j = -j + CY
13.         IF k <> 0 THEN
14.             LINE -(i, j), C
15.         ELSE
16.             PSET (i, j), C
17.         END IF
18.     NEXT
19. END SUB
20.  
21.  

You are using the lousy named "a" variable as x axis radius when angle is 0 and calling it the "major axis" and calling b the y axis radius when ang = 0 the "minor axis", neither one is an axis of the ellipse and Major and Minor axis imply the size and in fact b can be larger than a with the code above.

[STxAxTIC]

Oh right, this is because I'm one only one here who uses a sensible coordinate system, my mistake.

[bplus]

Oh right, this is because I'm one only one here who uses a sensible coordinate system, my mistake.

No it's not about coordinate system, the major axis of ellipse is the LONGER ONE and the minor axis of an ellipse is the shorter one and the variables a, b as you use them are neither.

https://www.google.com/search?client=opera&q=major+axis+of+an+ellipse&sourceid=opera&ie=UTF-8&oe=UTF-8

[STxAxTIC]

I'd say the smarter mathematician wouldn't lock himself in. Variables a and b have complete symmetry in the ellipse. I'm not sure what your complaint is now but honestly I'm not worried about it either. Let me know if you have any other questions about conic sections.

But seriously are you accusing me of calling "b" the semimajor axis? I haven't done that since 2003 and not publicly either.

[bplus]

I'd say the smarter mathematician wouldn't lock himself in. Variables a and b have complete symmetry in the ellipse. I'm not sure what your complaint is now but honestly I'm not worried about it either. Let me know if you have any other questions about conic sections.

But seriously are you accusing me of calling "b" the semimajor axis? I haven't done that since 2003 and not publicly either.

The a variable effects the spread along the x axis.

The b variable effects the spread along the y axis.

They have no association with Major or Minor axis of Ellipse, not the way they are used in the SUB for drawing the eliipse.

[STxAxTIC]

The a variable effects the spread along the x axis.

The b variable effects the spread along the y axis.

They have no association with Major or Minor axis of Ellipse, not the way they are used in the SUB.

That is pure horse shit, sorry man. If you know you're right and I'm not reading you correctly then just carry on, its all good. All my math works on this end so idk man.

[bplus]

That is pure horse shit, sorry man. If you know you're right and I'm not reading you correctly then just carry on, its all good. All my math works on this end so idk man.

I am talking about how this particular ellipse sub will draw the ellipse not math convention of calling a the major axis and b the minor.

If you want a tall skinny ellipse you better put the bigger length under the b variable.

[STxAxTIC]

If you want a tall skinny ellipse you better put the bigger length under the b variable.

Oooooooooooooh I get you.

Nah man, that's a feature and nowhere near a bug or anything else. The parameter theta is locked with the "a" variable, even if its smaller. So to modify your statement above, if you want a tall skinny ellipse let a be the bigger side (as usual) and let theta=90 degrees. Good?

[bplus]

Oooooooooooooh I get you.

Nah man, that's a feature and nowhere near a bug or anything else. The parameter theta is locked with the "a" variable, even if its smaller. So to modify your statement above, if you want a tall skinny ellipse let a be the bigger side (as usual) and let theta=90 degrees. Good?

Yes that will work too.

[bplus]

This might be faster ellipse because the loop is much shorter and there is no guessing as to increment steps:
( ie try the EllipseTilt with 400)

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Ellipse No Fill" 'b+ 2020-04-11
3. CONST xmax = 700, ymax = 700
4. SCREEN _NEWIMAGE(xmax, ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7. DIM cx, cy, a, xRad, yRad, p, c~&, mx, my, dist, d
8.  
9. cx = xmax / 2: cy = ymax / 2
10. xRad = 10: yRad = 300: c~& = &HFF0000FF
11. WHILE 1
12.     CLS
13.     WHILE _MOUSEINPUT: WEND
14.     mx = _MOUSEX: my = _MOUSEY
15.     dist = ((mx - cx) ^ 2 + (my - cy) ^ 2) ^ .5
16.     FOR d = 0 TO dist STEP 20
17.         p = 1 - d / dist
18.         a = _ATAN2(my - cy, mx - cx)
19.         Ellipse cx + d * COS(a), cy + d * SIN(a), p * xRad, p * yRad, c~&
20.         'Ellipse cx + d * COS(a), cy + d * SIN(a), p * yRad, p * xRad, &HFFFF0000
21.     NEXT
22.     _DISPLAY
23.     _LIMIT 100
24. WEND
25.  
26.  
27. 'there is a better way so there is no guessing the stepper size
28. SUB Ellipse (CX, CY, xRadius AS INTEGER, yRadius AS INTEGER, C AS _UNSIGNED LONG)
29.     '  CX = center x coordinate
30.     '  CY = center y coordinate
31.     '  xRadius = x axis radius
32.     '  yRadius = y axis radius
33.     '   C = fill color
34.     DIM a, x, y, sq, delta, lastDelta
35.     IF xRadius = 0 AND yRadius = 0 THEN EXIT SUB
36.     IF xRadius = 0 THEN
37.         LINE (CX, CY + yRadius)-(CX, CY - yRadius), C
38.     ELSEIF yRadius = 0 THEN
39.         LINE (CX + xRadius, CY)-(CX - xRadius, CY), C
40.     ELSE
41.         IF xRadius >= yRadius THEN
42.             a = yRadius / xRadius: sq = xRadius * xRadius
43.             FOR x = 0 TO xRadius
44.                 IF x = 0 THEN
45.                     lastDelta = SQR(sq - x * x) * a
46.                     PSET (CX + x, CY + lastDelta), C
47.                     PSET (CX + x, CY - lastDelta), C
48.                     PSET (CX - x, CY + lastDelta), C
49.                     PSET (CX - x, CY - lastDelta), C
50.                 ELSE
51.                     delta = SQR(sq - x * x) * a
52.                     LINE (CX + (x - 1), CY + lastDelta)-(CX + x, CY + delta), C
53.                     LINE (CX + (x - 1), CY - lastDelta)-(CX + x, CY - delta), C
54.                     LINE (CX - (x - 1), CY + lastDelta)-(CX - x, CY + delta), C
55.                     LINE (CX - (x - 1), CY - lastDelta)-(CX - x, CY - delta), C
56.                     lastDelta = delta
57.                 END IF
58.             NEXT
59.         ELSE
60.             a = xRadius / yRadius: sq = yRadius * yRadius
61.             FOR y = 0 TO yRadius
62.                 IF y = 0 THEN
63.                     lastDelta = SQR(sq - y * y) * a
64.                     PSET (CX + lastDelta, CY + y), C
65.                     PSET (CX - lastDelta, CY + y), C
66.                     PSET (CX + lastDelta, CY - y), C
67.                     PSET (CX - lastDelta, CY - y), C
68.                 ELSE
69.                     delta = SQR(sq - y * y) * a
70.                     LINE (CX + lastDelta, CY + (y - 1))-(CX + delta, CY + y), C
71.                     LINE (CX - lastDelta, CY + (y - 1))-(CX - delta, CY + y), C
72.                     LINE (CX + lastDelta, CY - (y - 1))-(CX + delta, CY - y), C
73.                     LINE (CX - lastDelta, CY - (y - 1))-(CX - delta, CY - y), C
74.                     lastDelta = delta
75.                 END IF
76.  
77.             NEXT
78.         END IF
79.     END IF
80. END SUB
81.  
82.  
83.