collision questions and hard work

[FellippeHeitor]

Oh, bplus. How will you get an a+ with this subpar work that doesn't meet the criteria? You better up your game man.

[FellippeHeitor]

that was a good code, and the link's code was amazing! but i meant a image, y'know, a bmp file containing a gray spike on it.

Stop requesting code. Present your work so people can help debug and/or improve or, if you have nothing, try to have something first.

[bplus]

Oh, bplus. How will you get an a+ with this subpar work that doesn't meet the criteria? You better up your game man.

He is pretty demanding isn't he?

[codevsb12]

Code: QB64: [Select]

1.  
2. spike& = _LOADIMAGE("spikeup.bmp")
3.  
4. xs = (RND * _WIDTH - 10): ys = (RND * _HEIGHT - 10)
5.  
6.     _PUTIMAGE (xs, ys), spike&
7.  
8.  

after that, simply asked to myself: what now?

[STxAxTIC]

Stop requesting code. Present your work so people can help debug and/or improve or, if you have nothing, try to have something first.

With all due respect, you call this "trying something"?

Code: QB64: [Select]

1. spike& = _LOADIMAGE("spikeup.bmp")
2.  
3. xs = (RND * _WIDTH - 10): ys = (RND * _HEIGHT - 10)
4.  
5.     _PUTIMAGE (xs, ys), spike&

..... right after bplus GAVE you the answer? Scroll up man.

[bplus]

Where ever you can put a rectangle, you can put an image and you can do 90 degree rotations maybe better than _maptriangle  until you need rotations like 30 degrees.

[codevsb12]

alright, first: now THIS was trying something

Code: QB64: [Select]

1. SUB rotation (xt, yt, x1, y1, x2, y2, x3, y3, sp)
2.  
3.     IF xt < _WIDTH / 2 THEN xt = 10
4.     IF xt > _WIDTH / 2 THEN xt = _WIDTH - 30
5.     IF yt < _HEIGHT / 2 THEN yt = (RND * _HEIGHT / 2)
6.     IF yt > _HEIGHT / 2 THEN yt = _HEIGHT - 30
7.     IF yt = 10 THEN _MAPTRIANGLE _SEAMLESS(xt, yt)-(xt, yt)-(xt, yt), sp TO(x1, y1)-(x2, y2)-(x3, y3)
8.  
9. END SUB
10.  

second: is there any statement  that can replace _maptriangle in case of 90 degrees rotation? cuz i'm sure there is not, even thought its qB A S I C

[STxAxTIC]

You're correct in that there is no way to rotate an underscore command by 90 degrees in any meaningful direction - so there's not a statement that does this. What you're surely needing to do is rotate the coordinates themselves, and then throw the rotated coordinates back into maptriangle to make a rotated picture.

Before understanding rotations, do you know how to say, reflect your image about the horizontal or vertical direction?

[codevsb12]

well, no. but actually yes. you guys taught me about how to flip my sprite using _PUTIMAGE.

[STxAxTIC]

Okay, cool - so a quick review.

To flip an image about the vertical axis, you might let all x-points just become negative x, as in: x -> -x

Similarly to flip an image along the horizontal axis, you would have y -> -y.

Of course, you can do both, etc. etc. - and this is what paint lets you do with one click basically.

... So rotations are a little bit harder, and involve changing coordinates like reflections. Now, for maptriangle, you have to feed it three points. I don't want to confuse things, so we'd better stick to rotating one point. To finish the job we will apply the methods of one point to all three and boom, you're rotating the whole triangle.

Unfortunately, there are three ways to get you into rotations: (i) vectors, (ii) trig functions, (iii) butcher a working example. While various people will see this post and probably get right to work on (iii) (or I will later if nobody does)... how is your proficiency with (i) and (ii)?

[codevsb12]

not that much of a proficiency...
but i suppose (i) is way easier, even for my first game ever on qb64.

funny story: when i tried improve my code to this

Code: QB64: [Select]

1. SUB rotation (xt, yt, x1, y1, x2, y2, x3, y3, sp)
2.  
3.     IF xt < _WIDTH / 2 THEN xt = 10
4.     IF xt > _WIDTH / 2 THEN xt = _WIDTH - 30
5.     IF yt < _HEIGHT / 2 THEN yt = (RND * _HEIGHT / 2)
6.     IF yt > _HEIGHT / 2 THEN yt = _HEIGHT - 30
7.     IF yt = 10 THEN _MAPTRIANGLE _SEAMLESS(xt, yt)-(xt, yt)-(xt, yt), sp TO(x1, y1)-(x2, y2)-(x3, y3)
8.     IF yt = _HEIGHT - 30 THEN _MAPTRIANGLE _SEAMLESS(xt, yt)-(xt, yt)-(xt, yt), sp TO(x1, y1)-(x2, y2)-(x3, y3)
9.  
10. END SUB
11.  

the spike started glitching in a certain way that made me grin

[STxAxTIC]

Question: Is maptriange irreducibly necessary, or can you work with putimage? I actually forget if putimage works well with rotations. i should go look that up...

Okay we're stuck with maptriangle. I'll cook something up.

[FellippeHeitor]

Might offer some insight: https://github.com/FellippeHeitor/Snippets/blob/master/rotateImage.bas

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. TYPE vertex
4.     x AS SINGLE
5.     y AS SINGLE
6. END TYPE
7.  
8. SCREEN _NEWIMAGE(800, 600, 32)
9. DIM bee AS LONG
10. bee = _LOADIMAGE("bee-12.jpg")
11.  
12. DIM i AS SINGLE
13. DO
14.     WHILE _MOUSEINPUT: WEND
15.     CLS
16.     i = map(_MOUSEX, 0, _WIDTH - 1, -90, 90)
17.     IF _KEYDOWN(100306) THEN i = INT(i)
18.     PRINT "rotation angle:"; i
19.     putImage _WIDTH / 2 - _WIDTH(bee) / 2, _HEIGHT / 2 - _HEIGHT(bee) / 2, bee, i
20.     _DISPLAY
21.     _LIMIT 30
22. LOOP
23.  
24. SUB putImage (__x AS SINGLE, __y AS SINGLE, image AS LONG, angleDegrees AS SINGLE)
25.     DIM i AS LONG
26.  
27.     DIM center AS vertex
28.     DIM corner(1 TO 4) AS vertex
29.  
30.     center.x = __x + _WIDTH(image) / 2
31.     center.y = __y + _HEIGHT(image) / 2
32.  
33.     FOR i = 1 TO 4
34.         SELECT CASE i
35.             CASE 1
36.                 corner(i).x = __x
37.                 corner(i).y = __y
38.             CASE 2
39.                 corner(i).x = __x
40.                 corner(i).y = (__y + _HEIGHT(image) - 1)
41.             CASE 3
42.                 corner(i).x = (__x + _WIDTH(image) - 1)
43.                 corner(i).y = __y
44.             CASE 4
45.                 corner(i).x = (__x + _WIDTH(image) - 1)
46.                 corner(i).y = (__y + _HEIGHT(image) - 1)
47.         END SELECT
48.  
49.         rotate corner(i), center, angleDegrees
50.     NEXT
51.  
52.     _MAPTRIANGLE (0, 0)-(0, _HEIGHT(image) - 1)-(_WIDTH(image) - 1, 0), image TO(corner(1).x, corner(1).y)-(corner(2).x, corner(2).y)-(corner(3).x, corner(3).y)
53.     _MAPTRIANGLE (0, _HEIGHT(image) - 1)-(_WIDTH(image) - 1, 0)-(_WIDTH(image) - 1, _HEIGHT(image) - 1), image TO(corner(2).x, corner(2).y)-(corner(3).x, corner(3).y)-(corner(4).x, corner(4).y)
54. END SUB
55.  
56. SUB rotate (p AS vertex, center AS vertex, angleDegrees AS SINGLE)
57.     'as seen on https://stackoverflow.com/questions/2259476/rotating-a-point-about-another-point-2d
58.     DIM s AS SINGLE, c AS SINGLE
59.     DIM newP AS vertex
60.     DIM angle AS SINGLE
61.  
62.     angle = _D2R(angleDegrees)
63.  
64.     s = SIN(angle)
65.     c = COS(angle)
66.  
67.     p.x = p.x - center.x
68.     p.y = p.y - center.y
69.  
70.     newP.x = p.x * c - p.y * s
71.     newP.y = p.x * s + p.y * c
72.  
73.     p.x = newP.x + center.x
74.     p.y = newP.y + center.y
75. END SUB
76.  
77. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
78.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
79. END FUNCTION

[STxAxTIC]

I hate the fact that BASIC uses the wrong coordinate system in screen modes. This puts 0,0 at the center and +y means up. Requires the image attached or any image if you rename.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. Image& = _LOADIMAGE("QB64-1.4-Release.png")
4.  
5. TYPE vec2
6.     x AS DOUBLE
7.     y AS DOUBLE
8. END TYPE
9.  
10. TYPE triplet
11.     u AS vec2
12.     v AS vec2
13.     w AS vec2
14. END TYPE
15.  
16. a = 0
17. DO
18.     CLS
19.     a = a + .005
20.     CALL showimage(0, 0, Image&, 1, 1, a)
21.     _DISPLAY
22.     _LIMIT 60
23. LOOP UNTIL _KEYHIT
24.  
25. END
26.  
27. SUB showimage (x0, y0, i&, sx, sy, ang)
28.     DIM sc AS triplet
29.     DIM dc AS triplet
30.     w = _WIDTH(i&) / 2
31.     h = _HEIGHT(i&) / 2
32.     sc.u.x = w - 1
33.     sc.u.y = h - 1
34.     sc.v.x = -w
35.     sc.v.y = h - 1
36.     sc.w.x = -w
37.     sc.w.y = -h
38.     dc.u.x = x0 + (sx * w) * COS(ang) - (sy * h) * SIN(ang)
39.     dc.u.y = y0 + (sx * w) * SIN(ang) + (sy * h) * COS(ang)
40.     dc.v.x = x0 + (-sx * w) * COS(ang) - (sy * h) * SIN(ang)
41.     dc.v.y = y0 + (-sx * w) * SIN(ang) + (sy * h) * COS(ang)
42.     dc.w.x = x0 + (-sx * w) * COS(ang) - (-sy * h) * SIN(ang)
43.     dc.w.y = y0 + (-sx * w) * SIN(ang) + (-sy * h) * COS(ang)
44.     CALL cmaptriangle(i&, 2 * w, 2 * h, sc, dc)
45.     sc.u.x = -w
46.     sc.u.y = -h
47.     sc.v.x = w - 1
48.     sc.v.y = -h
49.     sc.w.x = w - 1
50.     sc.w.y = h - 1
51.     dc.u.x = x0 + (-sx * w) * COS(ang) - (-sy * h) * SIN(ang)
52.     dc.u.y = y0 + (-sx * w) * SIN(ang) + (-sy * h) * COS(ang)
53.     dc.v.x = x0 + (sx * w) * COS(ang) - (-sy * h) * SIN(ang)
54.     dc.v.y = y0 + (sx * w) * SIN(ang) + (-sy * h) * COS(ang)
55.     dc.w.x = x0 + (sx * w) * COS(ang) - (sy * h) * SIN(ang)
56.     dc.w.y = y0 + (sx * w) * SIN(ang) + (sy * h) * COS(ang)
57.     CALL cmaptriangle(i&, 2 * w, 2 * h, sc, dc)
58. END SUB
59.  
60. SUB cmaptriangle (i&, w, h, s AS triplet, d AS triplet)
61.     _MAPTRIANGLE (w / 2 + s.u.x, -s.u.y + h / 2)-(w / 2 + s.v.x, -s.v.y + h / 2)-(w / 2 + s.w.x, -s.w.y + h / 2), i& TO(_WIDTH / 2 + d.u.x, -d.u.y + _HEIGHT / 2)-(_WIDTH / 2 + d.v.x, -d.v.y + _HEIGHT / 2)-(_WIDTH / 2 + d.w.x, -d.w.y + _HEIGHT / 2)
62. END SUB
63.  

[bplus]

Oh man what fun! Now 2nd time I use Paint 3D to make transparent background (except it left a gray halo around image thus gray background):