Plot

[bplus]

Why go outside QB64 for plotting data?

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Plot > Point mouse for coordinates" ' started 2019-09-14 B+
3. ' from: Remake Eval  2018-09-16 5:53 PM
4. ' goals test remake eval and plot math functions
5. '2019-09-14 basic plot working, now for sensable ticks on axis
6. ' OK maybe do some replotting with mousedown and setting up new rectangle area
7. ' On the other hand we could plot data from a file?
8.  
9.  
10. CONST XMAX = 1200
11. CONST YMAX = 700
12.  
13. SCREEN _NEWIMAGE(XMAX, YMAX, 32)
14. _SCREENMOVE 100, 0
15.  
16. DIM SHARED debug AS _BIT
17. debug = 0
18.  
19. 'evaluate$ and evalW setup
20. DIM SHARED DFlag AS _BIT, EvalErr$, GlobalX AS _FLOAT, RAD AS _FLOAT, DEG AS _FLOAT
21. DFlag = 0
22. EvalErr$ = ""
23. GlobalX = 5 'changeable
24. RAD = _PI / 180.0
25. DEG = 180 / _PI
26. REDIM SHARED fList(1 TO 1) AS STRING
27. Split "int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg,", ", ", fList()
28. REDIM SHARED oList(1 TO 1) AS STRING
29. Split "^, %, /, *, -, +, =, <, >, <=, >=, <>, or, and, not", ", ", oList()
30.  
31. 'DIM x
32.  
33. plot "(X+3)*(X+2)*(X-1)*(X-4), -5, 5"
34. 'plot "sin(x)^2 + sin(x), -6.3, 6.3"
35.  
36. SUB plot (pList$)
37.     REDIM p(1 TO 1) AS STRING, table(1000)
38.     DIM func$, LX, UX, dx, dy, x, y, LY, UY, clicks, midY, s$, mx, my, gx, gy
39.     Split pList$, ",", p()
40.     func$ = p(1): LX = VAL(p(2)): UX = VAL(p(3))
41.     dx = (UX - LX) / 1000
42.     FOR x = 0 TO 1000
43.         GlobalX = LX + x * dx
44.         table(x) = VAL(Evaluate$(func$))
45.         IF x = 0 THEN
46.             LY = table(x): UY = table(x)
47.         ELSE
48.             IF table(x) < LY THEN LY = table(x)
49.             IF table(x) > UY THEN UY = table(x)
50.         END IF
51.     NEXT
52.     dy = (UY - LY) / 500
53.  
54.     clicks = (UX - LX) / 20
55.     COLOR &HFF000000, &HFFFFFFFF: CLS
56.     yCP 42, "Plot " + func$
57.     yCP 640, "For x = " + dp2$(LX) + " to " + dp2$(UX) + " steps every " + dp2$(clicks)
58.     LINE (100, 100)-STEP(1000, 500), , B
59.     FOR x = 0 TO 20
60.         LINE (100 + x * 50, 595)-STEP(0, 10)
61.     NEXT
62.     IF 0 > LX AND 0 < UX THEN LINE ((0 - LX) / dx + 100, 100)-STEP(0, 500): _PRINTSTRING ((0 - LX) / dx + 100 - 12, 605), "x=0"
63.  
64.     clicks = (UY - LY) / 10
65.     IF 0 > LY AND 0 < UY THEN
66.         midY = 600 - (0 - LY) / dy
67.         LINE (100, midY)-STEP(1000, 0): _PRINTSTRING (43, midY + -8), "F(x)=0"
68.         FOR y = -500 TO 500 STEP 50
69.             IF midY + y >= 100 AND midY + y <= 600 AND y <> 0 THEN
70.                 LINE (95, midY + y)-STEP(10, 0)
71.                 s$ = RIGHT$(SPACE$(11) + dp2$(clicks * y / -50), 11)
72.                 _PRINTSTRING (0, midY + y - 8), s$
73.             END IF
74.         NEXT
75.     ELSE
76.         FOR y = 0 TO 10
77.             LINE (95, 100 + y * 50)-STEP(10, 0)
78.             s$ = RIGHT$(SPACE$(11) + dp2$(LY + clicks * y), 11)
79.             _PRINTSTRING (0, 600 - y * 50 - 8), s$
80.         NEXT
81.     END IF
82.     FOR x = 0 TO 1000
83.         y = (table(x) - LY) / dy
84.         LINE (x + 100, 600 - y)-STEP(2, 2), &HFF0000FF, BF
85.         PSET (x + 100, 600 - y), &HFF0000FF
86.     NEXT
87.     WHILE _KEYDOWN(27) = 0
88.         WHILE _MOUSEINPUT: WEND
89.         mx = _MOUSEX: my = _MOUSEY
90.         IF mx <= 1100 AND mx >= 100 THEN
91.             IF my >= 100 AND my <= 600 THEN
92.                 yCP 80, SPACE$(50)
93.                 gx = (mx - 100) / 1000 * (UX - LX) + LX
94.                 gy = (600 - my) / 500 * (UY - LY) + LY
95.                 yCP 80, "X = " + dp2$(gx) + ", Y = " + dp2$(gy)
96.             END IF
97.         END IF
98.         _DISPLAY
99.         _LIMIT 200
100.     WEND
101. END SUB
102.  
103. 'this preps e$ string for actual evaluation function and makes call to it,
104. 'checks results for error returns that or string form of result calculation
105. 'the new goal is to do string functions along side math
106. FUNCTION Evaluate$ (e$)
107.     DIM b$, c$
108.     DIM i AS INTEGER, po AS INTEGER
109.     ' isolateNeg = 0
110.     b$ = "" 'rebuild string with padded spaces
111.     'this makes sure ( ) + * / % ^ are wrapped with spaces, on your own with - sign
112.     FOR i = 1 TO LEN(e$) 'filter chars and count ()
113.         c$ = LCASE$(MID$(e$, i, 1))
114.         IF c$ = ")" THEN
115.             po = po - 1: b$ = b$ + " ) "
116.         ELSEIF c$ = "(" THEN
117.             po = po + 1: b$ = b$ + " ( "
118.         ELSEIF INSTR("+*/%^", c$) > 0 THEN
119.             b$ = b$ + " " + c$ + " "
120.         ELSEIF c$ = "-" THEN
121.             IF LEN(b$) > 0 THEN
122.                 IF INSTR(".0123456789abcdefghijklmnopqrstuvwxyz)", RIGHT$(RTRIM$(b$), 1)) > 0 THEN
123.                     b$ = b$ + " " + c$ + " "
124.                 ELSE
125.                     b$ = b$ + " " + c$
126.                 END IF
127.             ELSE
128.                 b$ = b$ + " " + c$
129.             END IF
130.         ELSEIF INSTR(" .0123456789abcdefghijklmnopqrstuvwxyz<>=", c$) > 0 THEN
131.             b$ = b$ + c$
132.         END IF
133.         IF po < 0 THEN EvalErr$ = "Too many )": EXIT FUNCTION
134.     NEXT
135.     IF po <> 0 THEN EvalErr$ = "Unbalanced ()": EXIT FUNCTION
136.     REDIM ev(1 TO 1) AS STRING
137.     Split b$, " ", ev()
138.     FOR i = LBOUND(ev) TO UBOUND(ev) 'subst constants
139.         IF ev(i) = "pi" THEN
140.             ev(i) = LTRIM$(STR$(_PI))
141.         ELSEIF ev(i) = "x" THEN
142.             ev(i) = LTRIM$(STR$(GlobalX))
143.         ELSEIF ev(i) = "e" THEN
144.             ev(i) = LTRIM$(STR$(EXP(1)))
145.         END IF
146.     NEXT
147.     c$ = evalW$(ev())
148.     IF EvalErr$ <> "" THEN Evaluate$ = EvalErr$ ELSE Evaluate$ = c$
149.  
150. END FUNCTION
151.  
152. ' the recursive part of EVAL
153. FUNCTION evalW$ (a() AS STRING)
154.     IF EvalErr$ <> "" THEN EXIT FUNCTION
155.  
156.     DIM fun$, test$, innerV$, m$, op$
157.     DIM pop AS INTEGER, lPlace AS INTEGER, i AS INTEGER, rPlace AS INTEGER
158.     DIM po AS INTEGER, p AS INTEGER, o AS INTEGER, index AS INTEGER
159.     DIM recurs AS INTEGER
160.     DIM innerVal AS _FLOAT, a AS _FLOAT, b AS _FLOAT
161.     IF debug THEN
162.         PRINT "evalW rec'd a() as:"
163.         FOR i = LBOUND(a) TO UBOUND(a)
164.             PRINT a(i); ", ";
165.         NEXT
166.         PRINT: INPUT "OK enter"; test$: PRINT
167.     END IF
168.     pop = find%(a(), "(") 'parenthesis open place
169.     WHILE pop > 0
170.         IF pop = 1 THEN
171.             fun$ = "": lPlace = 1
172.         ELSE
173.             test$ = a(pop - 1)
174.             IF find%(fList(), test$) > 0 THEN
175.                 fun$ = test$: lPlace = pop - 1
176.             ELSE
177.                 fun$ = "": lPlace = pop
178.             END IF
179.         END IF
180.         po = 1
181.         FOR i = pop + 1 TO UBOUND(a)
182.             IF a(i) = "(" THEN po = po + 1
183.             IF a(i) = ")" THEN po = po - 1
184.             IF po = 0 THEN rPlace = i: EXIT FOR
185.         NEXT
186.         REDIM inner(1 TO 1) AS STRING: index = 0: recurs = 0
187.         FOR i = (pop + 1) TO (rPlace - 1)
188.             index = index + 1
189.             REDIM _PRESERVE inner(1 TO index) AS STRING
190.             inner(index) = a(i)
191.             IF find%(oList(), a(i)) > 0 THEN recurs = -1
192.         NEXT
193.         IF recurs THEN innerV$ = evalW$(inner()) ELSE innerV$ = a(pop + 1)
194.         innerVal = VAL(innerV$)
195.  
196.         SELECT CASE fun$
197.             CASE "": m$ = innerV$
198.             CASE "int": m$ = ls$(INT(innerVal))
199.             CASE "sin": IF DFlag THEN m$ = ls$(SIN(RAD * innerVal)) ELSE m$ = ls$(SIN(innerVal))
200.             CASE "cos": IF DFlag THEN m$ = ls$(COS(RAD * innerVal)) ELSE m$ = ls$(COS(innerVal))
201.             CASE "tan": IF DFlag THEN m$ = ls$(TAN(RAD * innerVal)) ELSE m$ = ls$(TAN(innerVal))
202.             CASE "asin": IF DFlag THEN m$ = ls$(_ASIN(RAD * innerVal)) ELSE m$ = ls$(_ASIN(innerVal))
203.             CASE "acos": IF DFlag THEN m$ = ls$(_ACOS(RAD * innerVal)) ELSE m$ = ls$(_ACOS(innerVal))
204.             CASE "atan": IF DFlag THEN m$ = ls$(ATN(RAD * innerVal)) ELSE m$ = ls$(ATN(innerVal))
205.             CASE "log"
206.                 IF innerVal > 0 THEN
207.                     m$ = ls$(LOG(innerVal))
208.                 ELSE
209.                     EvalErr$ = "LOG only works on numbers > 0.": EXIT FUNCTION
210.                 END IF
211.             CASE "exp" 'the error limit is inconsistent in JB
212.                 IF -745 <= innerVal AND innerVal <= 709 THEN 'your system may have different results
213.                     m$ = ls$(EXP(innerVal))
214.                 ELSE
215.                     'what the heck???? 708 works fine all alone as limit ?????
216.                     EvalErr$ = "EXP(n) only works for n = -745 to 709.": EXIT FUNCTION
217.                 END IF
218.             CASE "sqr"
219.                 IF innerVal >= 0 THEN
220.                     m$ = ls$(SQR(innerVal))
221.                 ELSE
222.                     EvalErr$ = "SQR only works for numbers >= 0.": EXIT FUNCTION
223.                 END IF
224.             CASE "rad": m$ = ls$(innerVal * RAD)
225.             CASE "deg": m$ = ls$(innerVal * DEG)
226.             CASE ELSE: EvalErr$ = "Unidentified function " + fun$: EXIT FUNCTION
227.         END SELECT
228.         IF debug THEN
229.             PRINT "lPlace, rPlace"; lPlace, rPlace
230.         END IF
231.         arrSubst a(), lPlace, rPlace, m$
232.         IF debug THEN
233.             PRINT "After arrSubst a() is:"
234.             FOR i = LBOUND(a) TO UBOUND(a)
235.                 PRINT a(i); " ";
236.             NEXT
237.             PRINT: PRINT
238.         END IF
239.         pop = find%(a(), "(")
240.     WEND
241.  
242.     'all parenthesis cleared
243.     'ops$ = "% ^ / * + - = < > <= >= <> and or not" 'all () cleared, now for binary ops (not not binary but is last!)
244.     FOR o = 1 TO 15
245.         op$ = oList(o)
246.         p = find%(a(), op$)
247.         WHILE p > 0
248.             a = VAL(a(p - 1))
249.             b = VAL(a(p + 1))
250.             IF debug THEN
251.                 PRINT STR$(a) + op$ + STR$(b)
252.             END IF
253.             SELECT CASE op$
254.                 CASE "%"
255.                     IF b >= 2 THEN
256.                         m$ = ls$(INT(a) MOD INT(b))
257.                     ELSE
258.                         EvalErr$ = "For a Mod b, b value < 2."
259.                         EXIT FUNCTION
260.                     END IF
261.                 CASE "^"
262.                     IF INT(b) = b OR a >= 0 THEN
263.                         m$ = ls$(a ^ b)
264.                     ELSE
265.                         EvalErr$ = "For a ^ b, a needs to be >= 0 when b not integer."
266.                         EXIT FUNCTION
267.                     END IF
268.                 CASE "/"
269.                     IF b <> 0 THEN
270.                         m$ = ls$(a / b)
271.                     ELSE
272.                         EvalErr$ = "Div by 0"
273.                         EXIT FUNCTION
274.                     END IF
275.                 CASE "*": m$ = ls$(a * b)
276.                 CASE "-": m$ = ls$(a - b)
277.                 CASE "+": m$ = ls$(a + b)
278.                 CASE "=": IF a = b THEN m$ = "-1" ELSE m$ = "0"
279.                 CASE "<": IF a < b THEN m$ = "-1" ELSE m$ = "0"
280.                 CASE ">": IF a > b THEN m$ = "-1" ELSE m$ = "0"
281.                 CASE "<=": IF a <= b THEN m$ = "-1" ELSE m$ = "0"
282.                 CASE ">=": IF a >= b THEN m$ = "-1" ELSE m$ = "0"
283.                 CASE "<>": IF a <> b THEN m$ = "-1" ELSE m$ = "0"
284.                 CASE "and": IF a <> 0 AND b <> 0 THEN m$ = "-1" ELSE m$ = "0"
285.                 CASE "or": IF a <> 0 OR b <> 0 THEN m$ = "-1" ELSE m$ = "0"
286.                 CASE "not": IF b = 0 THEN m$ = "-1" ELSE m$ = "0" 'use b as nothing should be left of not
287.             END SELECT
288.             arrSubst a(), p - 1, p + 1, m$
289.  
290.             IF debug THEN
291.                 PRINT "a() reloaded after " + op$ + " as:"
292.                 FOR i = LBOUND(a) TO UBOUND(a)
293.                     PRINT a(i); ", ";
294.                 NEXT
295.                 PRINT: PRINT
296.             END IF
297.  
298.             p = find%(a(), op$)
299.         WEND
300.     NEXT
301.     fun$ = ""
302.     FOR i = LBOUND(a) TO UBOUND(a)
303.         fun$ = fun$ + " " + a(i)
304.     NEXT
305.     evalW$ = LTRIM$(fun$)
306. END FUNCTION
307.  
308. SUB arrSubst (a() AS STRING, substLow AS LONG, substHigh AS LONG, subst AS STRING)
309.     DIM i AS LONG, index AS LONG
310.     a(substLow) = subst: index = substLow + 1
311.     FOR i = substHigh + 1 TO UBOUND(a)
312.         a(index) = a(i): index = index + 1
313.     NEXT
314.     REDIM _PRESERVE a(LBOUND(a) TO UBOUND(a) + substLow - substHigh)
315. END SUB
316.  
317. 'notes: REDIM the array(0) to be loaded before calling Split '<<<<<<<<<<<<<<<<<<<<<<< IMPORTANT!!!!
318. SUB Split (mystr AS STRING, delim AS STRING, arr() AS STRING)
319.     ' bplus modifications of Galleon fix of Bulrush Split reply #13
320.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1612.0
321.     ' this sub further developed and tested here: \test\Strings\Split test.bas
322.     ' 2018-09-16 modified for base 1 arrays
323.     DIM copy AS STRING, p AS LONG, curpos AS LONG, arrpos AS LONG, lc AS LONG, dpos AS LONG
324.     copy = mystr 'make copy since we are messing with mystr
325.     'special case if delim is space, probably want to remove all excess space
326.     IF delim = " " THEN
327.         copy = RTRIM$(LTRIM$(copy))
328.         p = INSTR(copy, "  ")
329.         WHILE p > 0
330.             copy = MID$(copy, 1, p - 1) + MID$(copy, p + 1)
331.             p = INSTR(copy, "  ")
332.         WEND
333.     END IF
334.     REDIM arr(1 TO 1) 'clear it
335.     curpos = 1
336.     arrpos = 1
337.     lc = LEN(copy)
338.     dpos = INSTR(curpos, copy, delim)
339.     DO UNTIL dpos = 0
340.         arr(arrpos) = MID$(copy, curpos, dpos - curpos)
341.         arrpos = arrpos + 1
342.         REDIM _PRESERVE arr(1 TO arrpos + 1) AS STRING
343.         curpos = dpos + LEN(delim)
344.         dpos = INSTR(curpos, copy, delim)
345.     LOOP
346.     arr(arrpos) = MID$(copy, curpos)
347.     REDIM _PRESERVE arr(1 TO arrpos) AS STRING
348. END SUB
349.  
350. 'assume a() is base 1 array so if find comes back as 0 then found nothing
351. FUNCTION find% (a() AS STRING, s$)
352.     DIM i%
353.     FOR i% = LBOUND(a) TO UBOUND(a)
354.         IF a(i%) = s$ THEN find% = i%: EXIT FUNCTION
355.     NEXT
356. END FUNCTION
357.  
358. 'ltrim a number float
359. FUNCTION ls$ (n AS _FLOAT)
360.     ls$ = LTRIM$(STR$(n))
361. END FUNCTION
362.  
363. 'FUNCTION xDP$ (x, DP)
364. '    DIM xs$, dot AS INTEGER
365.  
366. '    IF x < 0 THEN xs$ = STR$(x - .5 * 10 ^ -DP)
367. '    IF x > 0 THEN xs$ = STR$(x + .5 * 10 ^ -DP)
368. '    IF INSTR(xs$, "D") > 0 OR INSTR(xs$, "E") > 0 THEN EXIT FUNCTION 'not dealing with exponents today
369. '    dot = INSTR(xs$, ".")
370. '    IF xs$ = "" OR ABS(x) < .5 * 10 ^ -DP THEN xs$ = "0"
371. '    IF dot THEN xDP$ = MID$(xs$, 1, dot) + MID$(xs$, dot + 1, DP) ELSE xDP$ = xs$
372. 'END FUNCTION
373.  
374. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
375.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
376. END SUB
377.  
378. FUNCTION dp2$ (n)
379.     dp2$ = _TRIM$(STR$(INT(n * 100) / 100))
380. END FUNCTION
381.  
382.  

 

Thick heavy line? or Thin precise line?

 

[STxAxTIC]

Beautiful bplus. I remember creating and deleting my own version(s) of this ad infinitum in the past. The version I ended up keeping was text-only, go figure...

[Qwerkey]

Thick heavy line?

Ah, the plot thickens!

[STxAxTIC]

Um bro that's far from true. I've seen straight up  Excel graphs published and presented at real math conferences before, if that flies then give bplus an aplus, will ya?

[bplus]

Hi BSpinoza,

Ha! It was your graph that inspired this as you might guess.

This is only first day out and I like the programming challenges graphing data or functions pose. For instance, how to get a better scale going along the left side for y axis, regular intervals of .1, 1, 10, 100... Would polar coordinate graphs require a whole different system? How about data from files or even clipboard?

How to work around the D or E of Scientific or Exponential notation, the following was rounding nicely but messed up by Ds or Es between 0 and .5 which is why I canned it for Steve's method used in dp2$ (which stands for 2 decimal places)

Code: QB64: [Select]

1. 'FUNCTION xDP$ (x, DP)
2. '    DIM xs$, dot AS INTEGER
3.  
4. '    IF x < 0 THEN xs$ = STR$(x - .5 * 10 ^ -DP)
5. '    IF x > 0 THEN xs$ = STR$(x + .5 * 10 ^ -DP)
6. '    IF INSTR(xs$, "D") > 0 OR INSTR(xs$, "E") > 0 THEN EXIT FUNCTION 'not dealing with exponents today
7. '    dot = INSTR(xs$, ".")
8. '    IF xs$ = "" OR ABS(x) < .5 * 10 ^ -DP THEN xs$ = "0"
9. '    IF dot THEN xDP$ = MID$(xs$, 1, dot) + MID$(xs$, dot + 1, DP) ELSE xDP$ = xs$
10. 'END FUNCTION
11.  

I do think having the mouse point out the coordinates is a great feature. We might be able to zoom in rectangular areas selected by the mouse.

My goal is not to get published in tech journals so much as to help visualize math functions or data relationships.

So you have answered why someone might go to outside sources :) they are accepted by the science community.

Thanks STxAxTIC for your support and Qwerkey for your wordplay, I had nice laugh :)

[Ashish]

Good Program!
1. If you add abs() function, then it will fantastic.
2. I see nothing for log(x) graph.

[Jack002]

That is cool! I've been thinking about doing the same thing. If you can do this, who needs a graphing calc?

[bplus]

Good Program!
1. If you add abs() function, then it will fantastic.
2. I see nothing for log(x) graph.

Hi Ashish,

Thank you for your interest. Adding functions to code is relatively easy just add name to list near top of code:

Code: QB64: [Select]

1. REDIM SHARED fList(1 TO 1) AS STRING
2. Split "int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg,", ", ", fList()
3.  

And then add the application of it to values found inside formula while evaluate processes the function values, this section in evalW$ SUB:

Code: QB64: [Select]

1.         SELECT CASE fun$
2.             CASE "": m$ = innerV$
3.             CASE "int": m$ = ls$(INT(innerVal))
4.             CASE "sin": IF DFlag THEN m$ = ls$(SIN(RAD * innerVal)) ELSE m$ = ls$(SIN(innerVal))
5.             CASE "cos": IF DFlag THEN m$ = ls$(COS(RAD * innerVal)) ELSE m$ = ls$(COS(innerVal))
6.             CASE "tan": IF DFlag THEN m$ = ls$(TAN(RAD * innerVal)) ELSE m$ = ls$(TAN(innerVal))
7.             CASE "asin": IF DFlag THEN m$ = ls$(_ASIN(RAD * innerVal)) ELSE m$ = ls$(_ASIN(innerVal))
8.             CASE "acos": IF DFlag THEN m$ = ls$(_ACOS(RAD * innerVal)) ELSE m$ = ls$(_ACOS(innerVal))
9.             CASE "atan": IF DFlag THEN m$ = ls$(ATN(RAD * innerVal)) ELSE m$ = ls$(ATN(innerVal))
10.             CASE "log"
11.                 IF innerVal > 0 THEN
12.                     m$ = ls$(LOG(innerVal))
13.                 ELSE
14.                     EvalErr$ = "LOG only works on numbers > 0.": EXIT FUNCTION
15.                 END IF
16.             CASE "exp" 'the error limit is inconsistent in JB
17.                 IF -745 <= innerVal AND innerVal <= 709 THEN 'your system may have different results
18.                     m$ = ls$(EXP(innerVal))
19.                 ELSE
20.                     'what the heck???? 708 works fine all alone as limit ?????
21.                     EvalErr$ = "EXP(n) only works for n = -745 to 709.": EXIT FUNCTION
22.                 END IF
23.             CASE "sqr"
24.                 IF innerVal >= 0 THEN
25.                     m$ = ls$(SQR(innerVal))
26.                 ELSE
27.                     EvalErr$ = "SQR only works for numbers >= 0.": EXIT FUNCTION
28.                 END IF
29.             CASE "rad": m$ = ls$(innerVal * RAD)
30.             CASE "deg": m$ = ls$(innerVal * DEG)
31.             CASE ELSE: EvalErr$ = "Unidentified function " + fun$: EXIT FUNCTION
32.         END SELECT
33.  

I see that I do already have LOG, so let's try using it and see how results look on my new scaling system for the Y axis in PLOT 2. Rules for LOG are seen in QB64 help: X must be > 0

Lets try this:
http://www.sosmath.com/algebra/logs/log4/log47/log47.html

f(x) = 7*LOG(3*X) - 15   f(x) = 0 at x ~ 46.31...

If answer is around 46 then let's try a range of x from 10 to 100 putting x = 45 right smack in the middle of graph (no, smack in middle of that would be 55 :P  ).
So here is the call to PLOT:

Code: QB64: [Select]

1. plot "7*LOG(3*X) - 15, 10, 100"
2.  

Notice: when we call the plot SUB, all the arguments are in just one string. That is because I plan on allowing an unlimited! number of functions to plot when I get all details of displaying one function worked out.

Opps! that didn't work! Why? because in example LOG is log 10 not log e, easy to convert LOG10(x) = LOG(x)/LOG(10) so

Code: QB64: [Select]

1. 'lets plot over giant range of 10 to 100 for x because quite frankly we've not a clue what's going on :D
2. plot "LOG(3*x)/LOG(10) - 15/7, 10, 100"
3.  

see attach 

Running the code and moving the mouse over to where f(x) = 0 I see a very gross estimate of x at 46 something, maybe .3, but let's refine the x range
from 46 to 47 to narrow in on x = 46.31 something...
see 2nd attach 

Looks like I need to alter my decimal places display as the precision is increased, 2 decimal places doesn't cut it for display.

I will attach a really cool graph of the polynomial with sequential roots for 1 to 7.
 

Thanks Jack002, all those showing interest in this project keeps me going trying to improve it.

Here is complete source code to plot 2 with LOG10 work shown above not commented out:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Plot > Point mouse for coordinates" ' started 2019-09-14 B+
3. ' from: Remake Eval  2018-09-16 5:53 PM
4. ' goals test remake eval and plot math functions
5. '2019-09-14 basic plot working, now for sensable ticks on axis
6. ' OK maybe do some replotting with mousedown and setting up new rectangle area
7. ' On the other hand we could plot data from a file?
8.  
9.  
10. CONST XMAX = 1200
11. CONST YMAX = 700
12.  
13. SCREEN _NEWIMAGE(XMAX, YMAX, 32)
14. _SCREENMOVE 100, 0
15.  
16. DIM SHARED debug AS _BIT
17. debug = 0
18.  
19. 'evaluate$ and evalW setup
20. DIM SHARED DFlag AS _BIT, EvalErr$, GlobalX AS _FLOAT, RAD AS _FLOAT, DEG AS _FLOAT
21. DFlag = 0
22. EvalErr$ = ""
23. GlobalX = 5 'changeable
24. RAD = _PI / 180.0
25. DEG = 180 / _PI
26. REDIM SHARED fList(1 TO 1) AS STRING
27. Split "int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg,", ", ", fList()
28. REDIM SHARED oList(1 TO 1) AS STRING
29. Split "^, %, /, *, -, +, =, <, >, <=, >=, <>, or, and, not", ", ", oList()
30.  
31.  
32. '     quick check Example #2 with QB64 printout between 46 and 47
33. 'DIM x       'check the http://www.sosmath.com/algebra/logs/log4/log47/log47.html Example #2
34.  
35. '    when the graph f(x) = 0 that is root to when LOG10(3*x) = 15/7
36.  
37. 'FOR x = 46 TO 47 STEP .1
38. '    PRINT x, LOG(3 * x) / LOG(10) - 15 / 7 'ah that's better!  breaks at 46.3 something
39. 'NEXT
40. 'END
41.  
42. 'lets plot over giant range because quite frankly we've not a clue what's going on
43. 'plot "LOG(3*x)/LOG(10) - 15/7, 10, 100"
44.  
45. ' OK narrow in on our solution x between 46 and 47!
46. plot "LOG(3*x)/LOG(10) - 15/7, 46, 47"
47.  
48. ' this is really cool PLOT!
49. 'plot "(x -1) * (x - 2) * (x - 3) * (x - 4)*(x-5)*(x-6)*(x-7) , .9, 7.1"
50. 'plot "sin(x)^2 + sin(x), -6.3, 6.3"
51.  
52. SUB plot (pList$)
53.     REDIM p(1 TO 1) AS STRING, table(1000)
54.     DIM func$, LX, UX, dx, dy, x, y, LY, UY, clicks, midY, s$, mx, my, gx, gy, p10
55.     Split pList$, ",", p()
56.     func$ = p(1): LX = VAL(p(2)): UX = VAL(p(3))
57.     dx = (UX - LX) / 1000
58.     FOR x = 0 TO 1000
59.         GlobalX = LX + x * dx
60.         table(x) = VAL(Evaluate$(func$))
61.         IF x = 0 THEN
62.             LY = table(x): UY = table(x)
63.         ELSE
64.             IF table(x) < LY THEN LY = table(x)
65.             IF table(x) > UY THEN UY = table(x)
66.         END IF
67.     NEXT
68.     dy = (UY - LY) / 500
69.  
70.     clicks = (UX - LX) / 20
71.     COLOR &HFF000000, &HFFFFFFFF: CLS
72.     yCP 42, "Plot " + func$
73.     yCP 640, "For x = " + xDP$(LX, 2) + " to " + xDP$(UX, 2) + " steps every " + xDP$(clicks, 2)
74.     LINE (100, 100)-STEP(1000, 500), , B
75.     FOR x = 0 TO 20
76.         LINE (100 + x * 50, 595)-STEP(0, 10)
77.     NEXT
78.     IF 0 > LX AND 0 < UX THEN LINE ((0 - LX) / dx + 100, 100)-STEP(0, 500): _PRINTSTRING ((0 - LX) / dx + 100 - 12, 605), "x=0"
79.  
80.     drawscale LY, UY
81.     'clicks = (UY - LY) / 10
82.  
83.     FOR x = 0 TO 1000
84.         y = (table(x) - LY) / dy
85.         'LINE (x + 99, 599 - y)-STEP(2, 2), &HFF0000FF, BF
86.         PSET (x + 100, 600 - y), &HFF0000FF 'use a fine line because we have very large x Range
87.     NEXT
88.     WHILE _KEYDOWN(27) = 0
89.         WHILE _MOUSEINPUT: WEND
90.         mx = _MOUSEX: my = _MOUSEY
91.         IF mx <= 1100 AND mx >= 100 THEN
92.             IF my >= 100 AND my <= 600 THEN
93.                 yCP 80, SPACE$(50)
94.                 gx = (mx - 100) / 1000 * (UX - LX) + LX
95.                 gy = (600 - my) / 500 * (UY - LY) + LY
96.                 yCP 80, "X = " + xDP$(gx, 2) + ", Y = " + xDP$(gy, 2)
97.             END IF
98.         END IF
99.         _DISPLAY
100.         _LIMIT 200
101.     WEND
102. END SUB
103.  
104. SUB drawscale (LY, UY)
105.     DIM clicks, p10 AS INTEGER, digit AS INTEGER, units AS SINGLE, midY, ty, gy, s$
106.  
107.     clicks = (UY - LY) / 10
108.  
109.     p10 = -10
110.     WHILE ABS(clicks) > 10 ^ p10
111.         p10 = p10 + 1
112.     WEND
113.     p10 = p10 - 1
114.     digit = INT(clicks / (10 ^ p10))
115.     units = digit * 10 ^ p10
116.     'PRINT p10, digit, units
117.  
118.     LINE (100, 100)-STEP(1000, 500), , B
119.     _PRINTSTRING (1105, 100 - 8), xDP$(UY, 2)
120.     _PRINTSTRING (1105, 600 - 8), xDP$(LY, 2)
121.     IF 0 > LY AND 0 < UY THEN
122.         midY = pixY(0, LY, UY)
123.         LINE (100, midY)-STEP(1000, 0): _PRINTSTRING (43, midY + -8), "F(x)=0"
124.         ty = units
125.         WHILE pixY(ty, LY, UY) >= 100 'from 0 + unit go up unit by unit
126.             gy = pixY(ty, LY, UY)
127.             LINE (95, gy)-STEP(10, 0)
128.             s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
129.             _PRINTSTRING (0, gy - 8), s$
130.             ty = ty + units
131.         WEND
132.         ty = -units
133.         WHILE pixY(ty, LY, UY) <= 600 'from 0 - unit go down unit by unit
134.             gy = pixY(ty, LY, UY)
135.             LINE (95, gy)-STEP(10, 0)
136.             s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
137.             _PRINTSTRING (0, gy - 8), s$
138.             ty = ty - units
139.         WEND
140.     ELSE
141.         ty = 0
142.         WHILE pixY(ty, LY, UY) < 600 'find first unit below or at bottom of graph
143.             ty = ty - units
144.         WEND
145.         ty = ty + units
146.         ' now go up drawing marks
147.         WHILE pixY(ty, LY, UY) >= 100
148.             gy = pixY(ty, LY, UY)
149.             IF gy <= 600 THEN
150.                 LINE (95, gy)-STEP(10, 0)
151.                 s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
152.                 _PRINTSTRING (0, gy - 8), s$
153.             END IF
154.             ty = ty + units
155.         WEND
156.     END IF
157. END SUB
158.  
159. FUNCTION pixY (graphY, lowY, UpY)
160.     pixY = 600 - 500 * (graphY - lowY) / (UpY - lowY)
161. END FUNCTION
162.  
163. 'this preps e$ string for actual evaluation function and makes call to it,
164. 'checks results for error returns that or string form of result calculation
165. 'the new goal is to do string functions along side math
166. FUNCTION Evaluate$ (e$)
167.     DIM b$, c$
168.     DIM i AS INTEGER, po AS INTEGER
169.     ' isolateNeg = 0
170.     b$ = "" 'rebuild string with padded spaces
171.     'this makes sure ( ) + * / % ^ are wrapped with spaces, on your own with - sign
172.     FOR i = 1 TO LEN(e$) 'filter chars and count ()
173.         c$ = LCASE$(MID$(e$, i, 1))
174.         IF c$ = ")" THEN
175.             po = po - 1: b$ = b$ + " ) "
176.         ELSEIF c$ = "(" THEN
177.             po = po + 1: b$ = b$ + " ( "
178.         ELSEIF INSTR("+*/%^", c$) > 0 THEN
179.             b$ = b$ + " " + c$ + " "
180.         ELSEIF c$ = "-" THEN
181.             IF LEN(b$) > 0 THEN
182.                 IF INSTR(".0123456789abcdefghijklmnopqrstuvwxyz)", RIGHT$(RTRIM$(b$), 1)) > 0 THEN
183.                     b$ = b$ + " " + c$ + " "
184.                 ELSE
185.                     b$ = b$ + " " + c$
186.                 END IF
187.             ELSE
188.                 b$ = b$ + " " + c$
189.             END IF
190.         ELSEIF INSTR(" .0123456789abcdefghijklmnopqrstuvwxyz<>=", c$) > 0 THEN
191.             b$ = b$ + c$
192.         END IF
193.         IF po < 0 THEN EvalErr$ = "Too many )": EXIT FUNCTION
194.     NEXT
195.     IF po <> 0 THEN EvalErr$ = "Unbalanced ()": EXIT FUNCTION
196.     REDIM ev(1 TO 1) AS STRING
197.     Split b$, " ", ev()
198.     FOR i = LBOUND(ev) TO UBOUND(ev) 'subst constants
199.         IF ev(i) = "pi" THEN
200.             ev(i) = LTRIM$(STR$(_PI))
201.         ELSEIF ev(i) = "x" THEN
202.             ev(i) = LTRIM$(STR$(GlobalX))
203.         ELSEIF ev(i) = "e" THEN
204.             ev(i) = LTRIM$(STR$(EXP(1)))
205.         END IF
206.     NEXT
207.     c$ = evalW$(ev())
208.     IF EvalErr$ <> "" THEN Evaluate$ = EvalErr$ ELSE Evaluate$ = c$
209.  
210. END FUNCTION
211.  
212. ' the recursive part of EVAL
213. FUNCTION evalW$ (a() AS STRING)
214.     IF EvalErr$ <> "" THEN EXIT FUNCTION
215.  
216.     DIM fun$, test$, innerV$, m$, op$
217.     DIM pop AS INTEGER, lPlace AS INTEGER, i AS INTEGER, rPlace AS INTEGER
218.     DIM po AS INTEGER, p AS INTEGER, o AS INTEGER, index AS INTEGER
219.     DIM recurs AS INTEGER
220.     DIM innerVal AS _FLOAT, a AS _FLOAT, b AS _FLOAT
221.     IF debug THEN
222.         PRINT "evalW rec'd a() as:"
223.         FOR i = LBOUND(a) TO UBOUND(a)
224.             PRINT a(i); ", ";
225.         NEXT
226.         PRINT: INPUT "OK enter"; test$: PRINT
227.     END IF
228.     pop = find%(a(), "(") 'parenthesis open place
229.     WHILE pop > 0
230.         IF pop = 1 THEN
231.             fun$ = "": lPlace = 1
232.         ELSE
233.             test$ = a(pop - 1)
234.             IF find%(fList(), test$) > 0 THEN
235.                 fun$ = test$: lPlace = pop - 1
236.             ELSE
237.                 fun$ = "": lPlace = pop
238.             END IF
239.         END IF
240.         po = 1
241.         FOR i = pop + 1 TO UBOUND(a)
242.             IF a(i) = "(" THEN po = po + 1
243.             IF a(i) = ")" THEN po = po - 1
244.             IF po = 0 THEN rPlace = i: EXIT FOR
245.         NEXT
246.         REDIM inner(1 TO 1) AS STRING: index = 0: recurs = 0
247.         FOR i = (pop + 1) TO (rPlace - 1)
248.             index = index + 1
249.             REDIM _PRESERVE inner(1 TO index) AS STRING
250.             inner(index) = a(i)
251.             IF find%(oList(), a(i)) > 0 THEN recurs = -1
252.         NEXT
253.         IF recurs THEN innerV$ = evalW$(inner()) ELSE innerV$ = a(pop + 1)
254.         innerVal = VAL(innerV$)
255.  
256.         SELECT CASE fun$
257.             CASE "": m$ = innerV$
258.             CASE "int": m$ = ls$(INT(innerVal))
259.             CASE "sin": IF DFlag THEN m$ = ls$(SIN(RAD * innerVal)) ELSE m$ = ls$(SIN(innerVal))
260.             CASE "cos": IF DFlag THEN m$ = ls$(COS(RAD * innerVal)) ELSE m$ = ls$(COS(innerVal))
261.             CASE "tan": IF DFlag THEN m$ = ls$(TAN(RAD * innerVal)) ELSE m$ = ls$(TAN(innerVal))
262.             CASE "asin": IF DFlag THEN m$ = ls$(_ASIN(RAD * innerVal)) ELSE m$ = ls$(_ASIN(innerVal))
263.             CASE "acos": IF DFlag THEN m$ = ls$(_ACOS(RAD * innerVal)) ELSE m$ = ls$(_ACOS(innerVal))
264.             CASE "atan": IF DFlag THEN m$ = ls$(ATN(RAD * innerVal)) ELSE m$ = ls$(ATN(innerVal))
265.             CASE "log"
266.                 IF innerVal > 0 THEN
267.                     m$ = ls$(LOG(innerVal))
268.                 ELSE
269.                     EvalErr$ = "LOG only works on numbers > 0.": EXIT FUNCTION
270.                 END IF
271.             CASE "exp" 'the error limit is inconsistent in JB
272.                 IF -745 <= innerVal AND innerVal <= 709 THEN 'your system may have different results
273.                     m$ = ls$(EXP(innerVal))
274.                 ELSE
275.                     'what the heck???? 708 works fine all alone as limit ?????
276.                     EvalErr$ = "EXP(n) only works for n = -745 to 709.": EXIT FUNCTION
277.                 END IF
278.             CASE "sqr"
279.                 IF innerVal >= 0 THEN
280.                     m$ = ls$(SQR(innerVal))
281.                 ELSE
282.                     EvalErr$ = "SQR only works for numbers >= 0.": EXIT FUNCTION
283.                 END IF
284.             CASE "rad": m$ = ls$(innerVal * RAD)
285.             CASE "deg": m$ = ls$(innerVal * DEG)
286.             CASE ELSE: EvalErr$ = "Unidentified function " + fun$: EXIT FUNCTION
287.         END SELECT
288.         IF debug THEN
289.             PRINT "lPlace, rPlace"; lPlace, rPlace
290.         END IF
291.         arrSubst a(), lPlace, rPlace, m$
292.         IF debug THEN
293.             PRINT "After arrSubst a() is:"
294.             FOR i = LBOUND(a) TO UBOUND(a)
295.                 PRINT a(i); " ";
296.             NEXT
297.             PRINT: PRINT
298.         END IF
299.         pop = find%(a(), "(")
300.     WEND
301.  
302.     'all parenthesis cleared
303.     'ops$ = "% ^ / * + - = < > <= >= <> and or not" 'all () cleared, now for binary ops (not not binary but is last!)
304.     FOR o = 1 TO 15
305.         op$ = oList(o)
306.         p = find%(a(), op$)
307.         WHILE p > 0
308.             a = VAL(a(p - 1))
309.             b = VAL(a(p + 1))
310.             IF debug THEN
311.                 PRINT STR$(a) + op$ + STR$(b)
312.             END IF
313.             SELECT CASE op$
314.                 CASE "%"
315.                     IF b >= 2 THEN
316.                         m$ = ls$(INT(a) MOD INT(b))
317.                     ELSE
318.                         EvalErr$ = "For a Mod b, b value < 2."
319.                         EXIT FUNCTION
320.                     END IF
321.                 CASE "^"
322.                     IF INT(b) = b OR a >= 0 THEN
323.                         m$ = ls$(a ^ b)
324.                     ELSE
325.                         EvalErr$ = "For a ^ b, a needs to be >= 0 when b not integer."
326.                         EXIT FUNCTION
327.                     END IF
328.                 CASE "/"
329.                     IF b <> 0 THEN
330.                         m$ = ls$(a / b)
331.                     ELSE
332.                         EvalErr$ = "Div by 0"
333.                         EXIT FUNCTION
334.                     END IF
335.                 CASE "*": m$ = ls$(a * b)
336.                 CASE "-": m$ = ls$(a - b)
337.                 CASE "+": m$ = ls$(a + b)
338.                 CASE "=": IF a = b THEN m$ = "-1" ELSE m$ = "0"
339.                 CASE "<": IF a < b THEN m$ = "-1" ELSE m$ = "0"
340.                 CASE ">": IF a > b THEN m$ = "-1" ELSE m$ = "0"
341.                 CASE "<=": IF a <= b THEN m$ = "-1" ELSE m$ = "0"
342.                 CASE ">=": IF a >= b THEN m$ = "-1" ELSE m$ = "0"
343.                 CASE "<>": IF a <> b THEN m$ = "-1" ELSE m$ = "0"
344.                 CASE "and": IF a <> 0 AND b <> 0 THEN m$ = "-1" ELSE m$ = "0"
345.                 CASE "or": IF a <> 0 OR b <> 0 THEN m$ = "-1" ELSE m$ = "0"
346.                 CASE "not": IF b = 0 THEN m$ = "-1" ELSE m$ = "0" 'use b as nothing should be left of not
347.             END SELECT
348.             arrSubst a(), p - 1, p + 1, m$
349.  
350.             IF debug THEN
351.                 PRINT "a() reloaded after " + op$ + " as:"
352.                 FOR i = LBOUND(a) TO UBOUND(a)
353.                     PRINT a(i); ", ";
354.                 NEXT
355.                 PRINT: PRINT
356.             END IF
357.  
358.             p = find%(a(), op$)
359.         WEND
360.     NEXT
361.     fun$ = ""
362.     FOR i = LBOUND(a) TO UBOUND(a)
363.         fun$ = fun$ + " " + a(i)
364.     NEXT
365.     evalW$ = LTRIM$(fun$)
366. END FUNCTION
367.  
368. SUB arrSubst (a() AS STRING, substLow AS LONG, substHigh AS LONG, subst AS STRING)
369.     DIM i AS LONG, index AS LONG
370.     a(substLow) = subst: index = substLow + 1
371.     FOR i = substHigh + 1 TO UBOUND(a)
372.         a(index) = a(i): index = index + 1
373.     NEXT
374.     REDIM _PRESERVE a(LBOUND(a) TO UBOUND(a) + substLow - substHigh)
375. END SUB
376.  
377. 'notes: REDIM the array(0) to be loaded before calling Split '<<<<<<<<<<<<<<<<<<<<<<< IMPORTANT!!!!
378. SUB Split (mystr AS STRING, delim AS STRING, arr() AS STRING)
379.     ' bplus modifications of Galleon fix of Bulrush Split reply #13
380.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1612.0
381.     ' this sub further developed and tested here: \test\Strings\Split test.bas
382.     ' 2018-09-16 modified for base 1 arrays
383.     DIM copy AS STRING, p AS LONG, curpos AS LONG, arrpos AS LONG, lc AS LONG, dpos AS LONG
384.     copy = mystr 'make copy since we are messing with mystr
385.     'special case if delim is space, probably want to remove all excess space
386.     IF delim = " " THEN
387.         copy = RTRIM$(LTRIM$(copy))
388.         p = INSTR(copy, "  ")
389.         WHILE p > 0
390.             copy = MID$(copy, 1, p - 1) + MID$(copy, p + 1)
391.             p = INSTR(copy, "  ")
392.         WEND
393.     END IF
394.     REDIM arr(1 TO 1) 'clear it
395.     curpos = 1
396.     arrpos = 1
397.     lc = LEN(copy)
398.     dpos = INSTR(curpos, copy, delim)
399.     DO UNTIL dpos = 0
400.         arr(arrpos) = MID$(copy, curpos, dpos - curpos)
401.         arrpos = arrpos + 1
402.         REDIM _PRESERVE arr(1 TO arrpos + 1) AS STRING
403.         curpos = dpos + LEN(delim)
404.         dpos = INSTR(curpos, copy, delim)
405.     LOOP
406.     arr(arrpos) = MID$(copy, curpos)
407.     REDIM _PRESERVE arr(1 TO arrpos) AS STRING
408. END SUB
409.  
410. 'assume a() is base 1 array so if find comes back as 0 then found nothing
411. FUNCTION find% (a() AS STRING, s$)
412.     DIM i%
413.     FOR i% = LBOUND(a) TO UBOUND(a)
414.         IF a(i%) = s$ THEN find% = i%: EXIT FUNCTION
415.     NEXT
416. END FUNCTION
417.  
418. 'ltrim a number float
419. FUNCTION ls$ (n AS _FLOAT)
420.     ls$ = LTRIM$(STR$(n))
421. END FUNCTION
422.  
423. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
424.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
425. END SUB
426.  
427. FUNCTION xDP$ (x, DP)
428.     DIM xx
429.     xx = x + .5 * 10 ^ -DP
430.     xDP$ = _TRIM$(STR$(INT(xx * 10 ^ DP) / 10 ^ DP))
431. END FUNCTION
432.  

As you can see what I did for the Y scale, I need to do for the X horizontal scale but haven't figured how to make nice display of x ticks unless draw digits / numbers with 90 degree rotation. Plus there is the problem of deciding the precision or number of decimals needed for displaying.

[SierraKen]

I just tried this program and all I get is a diagonal line and coordinates, etc. Isn't this supposed to be like a Plotting Calculator? How do you change the plots? There's no directions. Of course everyone else can figure it out, except me. lol

[Jack002]

This is a graph of LOG, its just a short narrow capture
find the line with this on it
plot "LOG(3*x)/LOG(10) - 15/7, 46, 47"
Change the 46, 47 to what you want x to be. try 0, 100
[edit]
I tried this, and it worked, it looks more like what you wanted to see
plot "LOG(3*x)/LOG(10) , 1, 20"
Even better, go up a couple lines, look for this
plot "LOG(3*x)/LOG(10) - 15/7, 10, 100"
take off the ' from the front. and comment the
plot "LOG(3*x)/LOG(10) - 15/7, 46, 47"
line.

B+, I love this split SUB. That is one handy sub we all can use. Any QB programmer should wade around in there and look at the neat stuff this has.

[SierraKen]

Oh LOL I skipped right over those, sorry about that. Awesome examples B+! This makes me wish I knew enough math to make random terrain hills with like the program Terragen can do. Like add a Z coordinate with X and Y somehow. :) But this is really cool!

[bplus]

Thanks Jack002, it is why I recommended split for tool box, though that one has been worked over some more.

For Ken and Ashish, I have made some changes by adding the ABS function and adding a more user friendly startup screen.

Ken, your request was absolutely right.

Hopefully you can input stuff as requested and your graph will pop up, use escape to loop around to inputs again and use function = nothing to quit (if you don't want to quit with X in top right corner).

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Plot v2_SierraKen > Point mouse for coordinates" ' started 2019-09-14 B+
3. ' from: Remake Eval  2018-09-16 5:53 PM
4. ' goals test remake eval and plot math functions
5. '2019-09-14 basic plot working, now for sensable ticks on axis
6. ' OK maybe do some replotting with mousedown and setting up new rectangle area
7. ' On the other hand we could plot data from a file?
8. '2019-09-19 post plot 2 with better Y scale except when precision needs to go beyond 2 places!
9. ' We practice with a LOG(x) example and learned LOG10(x) = LOG(x)/LOG(10) thanks to QB64 Help!
10. ' Need to do with x scale what we did with y scale after solve prcision problem = picking the
11. ' right precision for displays.
12. '2019-09-19 Plot v KenSierra add ABS function for Ashish, now with Opening inputs screen in main loop.
13.  
14. CONST XMAX = 1200
15. CONST YMAX = 700
16.  
17. SCREEN _NEWIMAGE(XMAX, YMAX, 32)
18. _SCREENMOVE 100, 0
19.  
20. DIM SHARED debug AS _BIT
21. debug = 0
22.  
23. 'evaluate$ and evalW setup
24. DIM SHARED DFlag AS _BIT, EvalErr$, GlobalX AS _FLOAT, RAD AS _FLOAT, DEG AS _FLOAT
25. DFlag = 0
26. EvalErr$ = ""
27. GlobalX = 5 'changeable
28. RAD = _PI / 180.0
29. DEG = 180 / _PI
30. REDIM SHARED fList(1 TO 1) AS STRING
31. Split "abs, int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg, ", ", ", fList()
32. REDIM SHARED oList(1 TO 1) AS STRING
33. Split "^, %, /, *, -, +, =, <, >, <=, >=, <>, or, and, not", ", ", oList()
34. DIM fn$, lowX$, highX$
35.  
36. DO
37.     COLOR &HFFBBBBFF, &HFF000066
38.     CLS
39.     _KEYCLEAR
40.     yCP 40, "Welcome to Plot v2_SierraKen       by B+ 2019-09-19"
41.     yCP 80, "Here is a listing of functions available so far:"
42.     yCP 100, "abs, int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg"
43.     yCP 140, " Please enter a function to plot in terms of x, ie x^2 + 4*x + 3 (nothing quits) "
44.     LOCATE 11, 40: INPUT "F(x) = ", fn$
45.     IF fn$ = "" THEN END
46.     LOCATE 13, 40: INPUT "Please enter lowest X for range "; lowX$
47.     LOCATE 15, 40: INPUT "Please enter highest X in range "; highX$
48.     plot fn$ + "," + lowX$ + "," + highX$
49. LOOP
50.  
51. SUB plot (pList$)
52.     REDIM p(1 TO 1) AS STRING, table(1000)
53.     DIM func$, LX, UX, dx, dy, x, y, LY, UY, clicks, midY, s$, mx, my, gx, gy, p10
54.     Split pList$, ",", p()
55.     func$ = p(1): LX = VAL(p(2)): UX = VAL(p(3))
56.     dx = (UX - LX) / 1000
57.     FOR x = 0 TO 1000
58.         GlobalX = LX + x * dx
59.         table(x) = VAL(Evaluate$(func$))
60.         IF x = 0 THEN
61.             LY = table(x): UY = table(x)
62.         ELSE
63.             IF table(x) < LY THEN LY = table(x)
64.             IF table(x) > UY THEN UY = table(x)
65.         END IF
66.     NEXT
67.     dy = (UY - LY) / 500
68.  
69.     clicks = (UX - LX) / 20
70.     COLOR &HFF000000, &HFFFFFFFF: CLS
71.     yCP 42, "Plot " + func$
72.     yCP 640, "For x = " + xDP$(LX, 2) + " to " + xDP$(UX, 2) + " steps every " + xDP$(clicks, 2)
73.     LINE (100, 100)-STEP(1000, 500), , B
74.     FOR x = 0 TO 20
75.         LINE (100 + x * 50, 595)-STEP(0, 10)
76.     NEXT
77.     IF 0 > LX AND 0 < UX THEN LINE ((0 - LX) / dx + 100, 100)-STEP(0, 500): _PRINTSTRING ((0 - LX) / dx + 100 - 12, 605), "x=0"
78.  
79.     drawscale LY, UY
80.     'clicks = (UY - LY) / 10
81.  
82.     FOR x = 0 TO 1000
83.         y = (table(x) - LY) / dy
84.         'LINE (x + 99, 599 - y)-STEP(2, 2), &HFF0000FF, BF
85.         PSET (x + 100, 600 - y), &HFF0000FF 'use a fine line because we have very large x Range
86.     NEXT
87.     WHILE _KEYDOWN(27) = 0
88.         WHILE _MOUSEINPUT: WEND
89.         mx = _MOUSEX: my = _MOUSEY
90.         IF mx <= 1100 AND mx >= 100 THEN
91.             IF my >= 100 AND my <= 600 THEN
92.                 yCP 80, SPACE$(50)
93.                 gx = (mx - 100) / 1000 * (UX - LX) + LX
94.                 gy = (600 - my) / 500 * (UY - LY) + LY
95.                 yCP 80, "X = " + xDP$(gx, 2) + ", Y = " + xDP$(gy, 2)
96.             END IF
97.         END IF
98.         _DISPLAY
99.         _LIMIT 200
100.     WEND
101. END SUB
102.  
103. SUB drawscale (LY, UY)
104.     DIM clicks, p10 AS INTEGER, digit AS INTEGER, units AS SINGLE, midY, ty, gy, s$
105.  
106.     clicks = (UY - LY) / 10
107.  
108.     p10 = -10
109.     WHILE ABS(clicks) > 10 ^ p10
110.         p10 = p10 + 1
111.     WEND
112.     p10 = p10 - 1
113.     digit = INT(clicks / (10 ^ p10))
114.     units = digit * 10 ^ p10
115.     'PRINT p10, digit, units
116.  
117.     LINE (100, 100)-STEP(1000, 500), , B
118.     _PRINTSTRING (1105, 100 - 8), xDP$(UY, 2)
119.     _PRINTSTRING (1105, 600 - 8), xDP$(LY, 2)
120.     IF 0 > LY AND 0 < UY THEN
121.         midY = pixY(0, LY, UY)
122.         LINE (100, midY)-STEP(1000, 0): _PRINTSTRING (43, midY + -8), "F(x)=0"
123.         ty = units
124.         WHILE pixY(ty, LY, UY) >= 100 'from 0 + unit go up unit by unit
125.             gy = pixY(ty, LY, UY)
126.             LINE (95, gy)-STEP(10, 0)
127.             s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
128.             _PRINTSTRING (0, gy - 8), s$
129.             ty = ty + units
130.         WEND
131.         ty = -units
132.         WHILE pixY(ty, LY, UY) <= 600 'from 0 - unit go down unit by unit
133.             gy = pixY(ty, LY, UY)
134.             LINE (95, gy)-STEP(10, 0)
135.             s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
136.             _PRINTSTRING (0, gy - 8), s$
137.             ty = ty - units
138.         WEND
139.     ELSE
140.         ty = 0
141.         WHILE pixY(ty, LY, UY) < 600 'find first unit below or at bottom of graph
142.             ty = ty - units
143.         WEND
144.         ty = ty + units
145.         ' now go up drawing marks
146.         WHILE pixY(ty, LY, UY) >= 100
147.             gy = pixY(ty, LY, UY)
148.             IF gy <= 600 THEN
149.                 LINE (95, gy)-STEP(10, 0)
150.                 s$ = RIGHT$(SPACE$(11) + xDP$(ty, 2), 11)
151.                 _PRINTSTRING (0, gy - 8), s$
152.             END IF
153.             ty = ty + units
154.         WEND
155.     END IF
156. END SUB
157.  
158. FUNCTION pixY (graphY, lowY, UpY)
159.     pixY = 600 - 500 * (graphY - lowY) / (UpY - lowY)
160. END FUNCTION
161.  
162. 'this preps e$ string for actual evaluation function and makes call to it,
163. 'checks results for error returns that or string form of result calculation
164. 'the new goal is to do string functions along side math
165. FUNCTION Evaluate$ (e$)
166.     DIM b$, c$
167.     DIM i AS INTEGER, po AS INTEGER
168.     ' isolateNeg = 0
169.     b$ = "" 'rebuild string with padded spaces
170.     'this makes sure ( ) + * / % ^ are wrapped with spaces, on your own with - sign
171.     FOR i = 1 TO LEN(e$) 'filter chars and count ()
172.         c$ = LCASE$(MID$(e$, i, 1))
173.         IF c$ = ")" THEN
174.             po = po - 1: b$ = b$ + " ) "
175.         ELSEIF c$ = "(" THEN
176.             po = po + 1: b$ = b$ + " ( "
177.         ELSEIF INSTR("+*/%^", c$) > 0 THEN
178.             b$ = b$ + " " + c$ + " "
179.         ELSEIF c$ = "-" THEN
180.             IF LEN(b$) > 0 THEN
181.                 IF INSTR(".0123456789abcdefghijklmnopqrstuvwxyz)", RIGHT$(RTRIM$(b$), 1)) > 0 THEN
182.                     b$ = b$ + " " + c$ + " "
183.                 ELSE
184.                     b$ = b$ + " " + c$
185.                 END IF
186.             ELSE
187.                 b$ = b$ + " " + c$
188.             END IF
189.         ELSEIF INSTR(" .0123456789abcdefghijklmnopqrstuvwxyz<>=", c$) > 0 THEN
190.             b$ = b$ + c$
191.         END IF
192.         IF po < 0 THEN EvalErr$ = "Too many )": EXIT FUNCTION
193.     NEXT
194.     IF po <> 0 THEN EvalErr$ = "Unbalanced ()": EXIT FUNCTION
195.     REDIM ev(1 TO 1) AS STRING
196.     Split b$, " ", ev()
197.     FOR i = LBOUND(ev) TO UBOUND(ev) 'subst constants
198.         IF ev(i) = "pi" THEN
199.             ev(i) = LTRIM$(STR$(_PI))
200.         ELSEIF ev(i) = "x" THEN
201.             ev(i) = LTRIM$(STR$(GlobalX))
202.         ELSEIF ev(i) = "e" THEN
203.             ev(i) = LTRIM$(STR$(EXP(1)))
204.         END IF
205.     NEXT
206.     c$ = evalW$(ev())
207.     IF EvalErr$ <> "" THEN Evaluate$ = EvalErr$ ELSE Evaluate$ = c$
208.  
209. END FUNCTION
210.  
211. ' the recursive part of EVAL
212. FUNCTION evalW$ (a() AS STRING)
213.     IF EvalErr$ <> "" THEN EXIT FUNCTION
214.  
215.     DIM fun$, test$, innerV$, m$, op$
216.     DIM pop AS INTEGER, lPlace AS INTEGER, i AS INTEGER, rPlace AS INTEGER
217.     DIM po AS INTEGER, p AS INTEGER, o AS INTEGER, index AS INTEGER
218.     DIM recurs AS INTEGER
219.     DIM innerVal AS _FLOAT, a AS _FLOAT, b AS _FLOAT
220.     IF debug THEN
221.         PRINT "evalW rec'd a() as:"
222.         FOR i = LBOUND(a) TO UBOUND(a)
223.             PRINT a(i); ", ";
224.         NEXT
225.         PRINT: INPUT "OK enter"; test$: PRINT
226.     END IF
227.     pop = find%(a(), "(") 'parenthesis open place
228.     WHILE pop > 0
229.         IF pop = 1 THEN
230.             fun$ = "": lPlace = 1
231.         ELSE
232.             test$ = a(pop - 1)
233.             IF find%(fList(), test$) > 0 THEN
234.                 fun$ = test$: lPlace = pop - 1
235.             ELSE
236.                 fun$ = "": lPlace = pop
237.             END IF
238.         END IF
239.         po = 1
240.         FOR i = pop + 1 TO UBOUND(a)
241.             IF a(i) = "(" THEN po = po + 1
242.             IF a(i) = ")" THEN po = po - 1
243.             IF po = 0 THEN rPlace = i: EXIT FOR
244.         NEXT
245.         REDIM inner(1 TO 1) AS STRING: index = 0: recurs = 0
246.         FOR i = (pop + 1) TO (rPlace - 1)
247.             index = index + 1
248.             REDIM _PRESERVE inner(1 TO index) AS STRING
249.             inner(index) = a(i)
250.             IF find%(oList(), a(i)) > 0 THEN recurs = -1
251.         NEXT
252.         IF recurs THEN innerV$ = evalW$(inner()) ELSE innerV$ = a(pop + 1)
253.         innerVal = VAL(innerV$)
254.  
255.         SELECT CASE fun$
256.             CASE "": m$ = innerV$
257.             CASE "abs": m$ = ls$(ABS(innerVal))
258.             CASE "int": m$ = ls$(INT(innerVal))
259.             CASE "sin": IF DFlag THEN m$ = ls$(SIN(RAD * innerVal)) ELSE m$ = ls$(SIN(innerVal))
260.             CASE "cos": IF DFlag THEN m$ = ls$(COS(RAD * innerVal)) ELSE m$ = ls$(COS(innerVal))
261.             CASE "tan": IF DFlag THEN m$ = ls$(TAN(RAD * innerVal)) ELSE m$ = ls$(TAN(innerVal))
262.             CASE "asin": IF DFlag THEN m$ = ls$(_ASIN(RAD * innerVal)) ELSE m$ = ls$(_ASIN(innerVal))
263.             CASE "acos": IF DFlag THEN m$ = ls$(_ACOS(RAD * innerVal)) ELSE m$ = ls$(_ACOS(innerVal))
264.             CASE "atan": IF DFlag THEN m$ = ls$(ATN(RAD * innerVal)) ELSE m$ = ls$(ATN(innerVal))
265.             CASE "log"
266.                 IF innerVal > 0 THEN
267.                     m$ = ls$(LOG(innerVal))
268.                 ELSE
269.                     EvalErr$ = "LOG only works on numbers > 0.": EXIT FUNCTION
270.                 END IF
271.             CASE "exp" 'the error limit is inconsistent in JB
272.                 IF -745 <= innerVal AND innerVal <= 709 THEN 'your system may have different results
273.                     m$ = ls$(EXP(innerVal))
274.                 ELSE
275.                     'what the heck???? 708 works fine all alone as limit ?????
276.                     EvalErr$ = "EXP(n) only works for n = -745 to 709.": EXIT FUNCTION
277.                 END IF
278.             CASE "sqr"
279.                 IF innerVal >= 0 THEN
280.                     m$ = ls$(SQR(innerVal))
281.                 ELSE
282.                     EvalErr$ = "SQR only works for numbers >= 0.": EXIT FUNCTION
283.                 END IF
284.             CASE "rad": m$ = ls$(innerVal * RAD)
285.             CASE "deg": m$ = ls$(innerVal * DEG)
286.             CASE ELSE: EvalErr$ = "Unidentified function " + fun$: EXIT FUNCTION
287.         END SELECT
288.         IF debug THEN
289.             PRINT "lPlace, rPlace"; lPlace, rPlace
290.         END IF
291.         arrSubst a(), lPlace, rPlace, m$
292.         IF debug THEN
293.             PRINT "After arrSubst a() is:"
294.             FOR i = LBOUND(a) TO UBOUND(a)
295.                 PRINT a(i); " ";
296.             NEXT
297.             PRINT: PRINT
298.         END IF
299.         pop = find%(a(), "(")
300.     WEND
301.  
302.     'all parenthesis cleared
303.     'ops$ = "% ^ / * + - = < > <= >= <> and or not" 'all () cleared, now for binary ops (not not binary but is last!)
304.     FOR o = 1 TO 15
305.         op$ = oList(o)
306.         p = find%(a(), op$)
307.         WHILE p > 0
308.             a = VAL(a(p - 1))
309.             b = VAL(a(p + 1))
310.             IF debug THEN
311.                 PRINT STR$(a) + op$ + STR$(b)
312.             END IF
313.             SELECT CASE op$
314.                 CASE "%"
315.                     IF b >= 2 THEN
316.                         m$ = ls$(INT(a) MOD INT(b))
317.                     ELSE
318.                         EvalErr$ = "For a Mod b, b value < 2."
319.                         EXIT FUNCTION
320.                     END IF
321.                 CASE "^"
322.                     IF INT(b) = b OR a >= 0 THEN
323.                         m$ = ls$(a ^ b)
324.                     ELSE
325.                         EvalErr$ = "For a ^ b, a needs to be >= 0 when b not integer."
326.                         EXIT FUNCTION
327.                     END IF
328.                 CASE "/"
329.                     IF b <> 0 THEN
330.                         m$ = ls$(a / b)
331.                     ELSE
332.                         EvalErr$ = "Div by 0"
333.                         EXIT FUNCTION
334.                     END IF
335.                 CASE "*": m$ = ls$(a * b)
336.                 CASE "-": m$ = ls$(a - b)
337.                 CASE "+": m$ = ls$(a + b)
338.                 CASE "=": IF a = b THEN m$ = "-1" ELSE m$ = "0"
339.                 CASE "<": IF a < b THEN m$ = "-1" ELSE m$ = "0"
340.                 CASE ">": IF a > b THEN m$ = "-1" ELSE m$ = "0"
341.                 CASE "<=": IF a <= b THEN m$ = "-1" ELSE m$ = "0"
342.                 CASE ">=": IF a >= b THEN m$ = "-1" ELSE m$ = "0"
343.                 CASE "<>": IF a <> b THEN m$ = "-1" ELSE m$ = "0"
344.                 CASE "and": IF a <> 0 AND b <> 0 THEN m$ = "-1" ELSE m$ = "0"
345.                 CASE "or": IF a <> 0 OR b <> 0 THEN m$ = "-1" ELSE m$ = "0"
346.                 CASE "not": IF b = 0 THEN m$ = "-1" ELSE m$ = "0" 'use b as nothing should be left of not
347.             END SELECT
348.             arrSubst a(), p - 1, p + 1, m$
349.  
350.             IF debug THEN
351.                 PRINT "a() reloaded after " + op$ + " as:"
352.                 FOR i = LBOUND(a) TO UBOUND(a)
353.                     PRINT a(i); ", ";
354.                 NEXT
355.                 PRINT: PRINT
356.             END IF
357.  
358.             p = find%(a(), op$)
359.         WEND
360.     NEXT
361.     fun$ = ""
362.     FOR i = LBOUND(a) TO UBOUND(a)
363.         fun$ = fun$ + " " + a(i)
364.     NEXT
365.     evalW$ = LTRIM$(fun$)
366. END FUNCTION
367.  
368. SUB arrSubst (a() AS STRING, substLow AS LONG, substHigh AS LONG, subst AS STRING)
369.     DIM i AS LONG, index AS LONG
370.     a(substLow) = subst: index = substLow + 1
371.     FOR i = substHigh + 1 TO UBOUND(a)
372.         a(index) = a(i): index = index + 1
373.     NEXT
374.     REDIM _PRESERVE a(LBOUND(a) TO UBOUND(a) + substLow - substHigh)
375. END SUB
376.  
377. 'notes: REDIM the array(0) to be loaded before calling Split '<<<<<<<<<<<<<<<<<<<<<<< IMPORTANT!!!!
378. SUB Split (mystr AS STRING, delim AS STRING, arr() AS STRING)
379.     ' bplus modifications of Galleon fix of Bulrush Split reply #13
380.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1612.0
381.     ' this sub further developed and tested here: \test\Strings\Split test.bas
382.     ' 2018-09-16 modified for base 1 arrays
383.     DIM copy AS STRING, p AS LONG, curpos AS LONG, arrpos AS LONG, lc AS LONG, dpos AS LONG
384.     copy = mystr 'make copy since we are messing with mystr
385.     'special case if delim is space, probably want to remove all excess space
386.     IF delim = " " THEN
387.         copy = RTRIM$(LTRIM$(copy))
388.         p = INSTR(copy, "  ")
389.         WHILE p > 0
390.             copy = MID$(copy, 1, p - 1) + MID$(copy, p + 1)
391.             p = INSTR(copy, "  ")
392.         WEND
393.     END IF
394.     REDIM arr(1 TO 1) 'clear it
395.     curpos = 1
396.     arrpos = 1
397.     lc = LEN(copy)
398.     dpos = INSTR(curpos, copy, delim)
399.     DO UNTIL dpos = 0
400.         arr(arrpos) = MID$(copy, curpos, dpos - curpos)
401.         arrpos = arrpos + 1
402.         REDIM _PRESERVE arr(1 TO arrpos + 1) AS STRING
403.         curpos = dpos + LEN(delim)
404.         dpos = INSTR(curpos, copy, delim)
405.     LOOP
406.     arr(arrpos) = MID$(copy, curpos)
407.     REDIM _PRESERVE arr(1 TO arrpos) AS STRING
408. END SUB
409.  
410. 'assume a() is base 1 array so if find comes back as 0 then found nothing
411. FUNCTION find% (a() AS STRING, s$)
412.     DIM i%
413.     FOR i% = LBOUND(a) TO UBOUND(a)
414.         IF a(i%) = s$ THEN find% = i%: EXIT FUNCTION
415.     NEXT
416. END FUNCTION
417.  
418. 'ltrim a number float
419. FUNCTION ls$ (n AS _FLOAT)
420.     ls$ = LTRIM$(STR$(n))
421. END FUNCTION
422.  
423. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
424.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
425. END SUB
426.  
427. FUNCTION xDP$ (x, DP)
428.     DIM xx
429.     xx = x + .5 * 10 ^ -DP
430.     xDP$ = _TRIM$(STR$(INT(xx * 10 ^ DP) / 10 ^ DP))
431. END FUNCTION
432.  
433.  

[SierraKen]

Very nice b+! Now it's a plotting calculator :). Good job.

[bplus]

Hi Ken,

I am glad it is working for you. Now I have the idea to make it a programmable plotting calculator :D

I've never worked with one! But I have already used evaluate code for a little interpreter so how hard can it be? ;)

[SierraKen]

Cool B+, yeah honestly I've never used one either. But so far I think this program is very similar. Plotting calculators were a little bit after my time in school. :)