Function Timestamp

[SMcNeill]

Code: QB64: [Select]

1. DO
2.     _LIMIT 10
3.     LOCATE 1, 1
4.     Countdown## = TimeStamp("01-01-2020", 0) - TimeStamp(DATE$, TIMER)
5.     PRINT USING "###,###,###,###.### seconds till Jan 01, 2020"; Countdown##
6. LOOP UNTIL Countdown## <= 0
7. CLS
8. PRINT "HAPPY NEW YEARS!!!!"
9. END
10.  
11. FUNCTION TimeStamp## (d$, t##) 'date and timer
12.     'Based on Unix Epoch time, which starts at year 1970.
13.     'Minor fixes to leap year logic by Bplus.  Many thanks!
14.     l = INSTR(d$, "-")
15.     l1 = INSTR(l + 1, d$, "-")
16.     m = VAL(LEFT$(d$, l))
17.     d = VAL(MID$(d$, l + 1))
18.     y = VAL(MID$(d$, l1 + 1)) - 1970
19.     FOR i = 1 TO m
20.         SELECT CASE i 'Add the number of days for each previous month passed
21.             CASE 1: d = d 'January doestn't have any carry over days.
22.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
23.             CASE 3: d = d + 28
24.             CASE 5, 7, 10, 12: d = d + 30
25.         END SELECT
26.     NEXT
27.     FOR i = 1 TO y
28.         d = d + 365
29.     NEXT
30.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards.
31.         d = d + 1 'add an extra day for leap year every 4 years, starting in 1970
32.     NEXT
33.     IF y > 30 THEN d = d - 1 'for year 2000, which wasn't a leap year.
34.     IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix for leap year, for the current year.
35.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
36.     TimeStamp## = (s~&& + t##)
37. END FUNCTION

Function gives a timestamp based on Unix Epoch Time, when we give it a date a time.  Simple enough, and thanks go to Bplus for helping catch a logic error in the leap year calculations. 

[STxAxTIC]

Thanks for making a new thread about this 'cause my time is so limited I got scared of losing this in the next few days - and the Librarian has even less time than *me*, so thanks again!

I can see that this code should replace the existing code in the Toolbox, no problem... But without studying the issue at all, I have a naive question - why did the function pass the test that led to the (obligatory) screenshot? Adjusting for local time it seemed correct - even when compared to the freebasic timecore and the one i translated for sxript. We all agreed on that test. Was the bug deep enough that only certain dates would trigger it? (Sorry, didn't read into this at all yet.)

[SMcNeill]

Code: [Select]


FUNCTION ExtendedTimer##
    d$ = DATE$
    l = INSTR(d$, "-")
    l1 = INSTR(l + 1, d$, "-")
    m = VAL(LEFT$(d$, l))
    d = VAL(MID$(d$, l + 1))
    y = VAL(MID$(d$, l1 + 1)) - 1970
    FOR i = 1 TO m
        SELECT CASE i 'Add the number of days for each previous month passed
            CASE 1: d = d 'January doestn't have any carry over days.
            CASE 2, 4, 6, 8, 9, 11: d = d + 31
            CASE 3: d = d + 28
            CASE 5, 7, 10, 12: d = d + 30
        END SELECT
    NEXT
    FOR i = 1 TO y
        d = d + 365
    NEXT
    FOR i = 2 TO y STEP 4
        IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970
    NEXT
    d = d - 1 'for year 2000
    s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
    ExtendedTimer## = (s~&& + TIMER)
END FUNCTION
 
The glitch was in this little line of code:
IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970

So if January and February, we didn’t add a day for each leap year...

The fix is as in the first post above; let the loop go to Year - 1 (don’t check the current year yet), and simply add one for each leap year.  Then check to see if the current year is leap year, and if so, is it after februrary where we need to count that extra day.

Note:  TimeStamp and ExtendedTimer are very similar functions, but slightly different,  TimeStamp lets you specify a time and date, creating a UET value for that moment; ExtendedTimer works exclusively with your current date and time, as a replacement for the TIMER command.


Corrected version of ExtendedTimer is as follows:

Code: QB64: [Select]

1. SHELL "https://www.epochconverter.com/"
2. DO
3.     CLS
4.     PRINT TIMER, INT(ExtendedTimer)
5.     PRINT "Compare to the time at https://www.epochconverter.com/"
6.     _DISPLAY
7.     _LIMIT 10
8. LOOP
9.  
10. FUNCTION ExtendedTimer##
11.     d$ = DATE$
12.     l = INSTR(d$, "-")
13.     l1 = INSTR(l + 1, d$, "-")
14.     m = VAL(LEFT$(d$, l))
15.     d = VAL(MID$(d$, l + 1))
16.     y = VAL(MID$(d$, l1 + 1)) - 1970
17.     FOR i = 1 TO m
18.         SELECT CASE i 'Add the number of days for each previous month passed
19.             CASE 1: d = d 'January doestn't have any carry over days.
20.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
21.             CASE 3: d = d + 28
22.             CASE 5, 7, 10, 12: d = d + 30
23.         END SELECT
24.     NEXT
25.     FOR i = 1 TO y
26.         d = d + 365
27.     NEXT
28.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year.
29.         IF i <> 30 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970, but skip year 2000
30.     NEXT
31.     IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix for leap year, for the current year.
32.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
33.     ExtendedTimer## = (s~&& + TIMER)
34. END FUNCTION
35.  

Or, for the minimalist folks out there, if they like TimeStamp, they could also have a quick version for:

Code: QB64: [Select]

1. FUNCTION ExtendedTimer##
2.     ExtendedTimer## = TimeStamp(DATE$, TIMER)
3. END FUNCTION

[STxAxTIC]

Alright -

So bplus hinted that this bug propagated out of the Toolbox somehow - does the Extended Timer code need to be updated? If it did something so wrong with leap years, then why did the screenshot check out?

Or is that code fine as-is?

Gotta fly - I won't be able to hit this again for 12 hours so...

[SMcNeill]

Alright -

So bplus hinted that this bug propagated out of the Toolbox somehow - does the Extended Timer code need to be updated? If it did something so wrong with leap years, then why did the screenshot check out?

Or is that code fine as-is?

Gotta fly - I won't be able to hit this again for 12 hours so...

The screenshot checks out because we're currently past the 2nd month...

IF m > 2 THEN d = d + 1   ...  We didn't need that IF check in there; we needed one after for the current year only.

Change is to replace:

Code: [Select]

    FOR i = 2 TO y STEP 4
        IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970
    NEXT
    d = d - 1 'for year 2000
With:

Code: [Select]

    FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year.
        IF i <> 30 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970, but skip year 2000
    NEXT
    IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix for leap year, for the current year.
As long as your current month was > 2, the existing code worked out right.  You just suddenly lost out on a bunch of leap days when Jan/Feb rolled around, to gain them all back once we were March again.  ;)

[bplus]

Steve, maybe you mean if i <> 30 for this part:

Code: QB64: [Select]

1.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year.
2.         'IF i <> 30....
3.         IF y <> 30 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970, but skip year 2000
4.     NEXT
5.  

This could be replaced by: d = d + y * 365  ' y or y -1 ?????????? OK y I think

Code: QB64: [Select]

1.     FOR i = 1 TO y  'y-1???? first 1970 y = 0, 1971 y = 1, 1972 y = 2  OK y not y-1
2.         d = d + 365
3.     NEXT
4.  

Update:
but now, I am wondering should't this be to y-1 as we count the days in y the partial year separately.
EDIT Update: No y starts at 0 not 1, so not y-1...

OK I am writing a tester for this Function. Starting at 01-01-1970, 0 time should be 0

[bplus]

Update: If timestamp##("01-01-1970", 0) should be 0, it is a whole day off.

This probably offsets all time##, so when compare differences in date and time will be OK but calc of absolute seconds from 01-01-1970 will be off a day = 86400 secs.

[SMcNeill]

Update: If timestamp##("01-01-1970", 0) should be 0, it is a whole day off.

This probably offsets all time##, so when compare differences in date and time will be OK but calc of absolute seconds from 01-01-1970 will be off a day = 86400 secs.

And, to think, we could avoid all these issues if we just used c++ to give us the solution in one line: 

Code: C++: [Select]

1. double now = std::chrono::duration_cast<std::chrono::seconds>(std::chrono::system_clock::now().time_since_epoch()).count();

There’s a page here which can be used to compare results: https://www.epochconverter.com/

Somehow, I was matching results before; how the heck did I break things so we’re off so badly now?  I’ll dig into it later this evening when my time frees up a little again.  ;)

(And I’ll probably add that single line into my repo and just make an _EXTENDEDTIMER command and use it.  I imagine it’d be much faster than doing all the calculations manually anyway.). ;)

[bplus]

There’s a page here which can be used to compare results: https://www.epochconverter.com/

OK it does look like 0 AM Jan 1, 1970 is suppose to be 0 at GMT:
 

So far minimal testing subtracting 1 from d, just after it is calc'd from date$. OK

Kinda makes sense to subtract a day from the date because it isn't complete yet, the fraction of it is in the time.

[bplus]

Alert!

 I caught another bug on day counts and I think I have worked up a fix, leap year again or rather not a leap year this time! Be right back! Still running checks with my code tester.

Good that was the last bug for day counts anyway.

The last bug was about checking for leap year for y. We forgot to consider if y is year 2000 which is NOT a leap year.

Here is my test code that tests day counts from 01-01-1970 to 01-01-2035 by comparing the day count current test date to the day count for the test date for day before, if the day count <> last day count + 1 the code stops running on the error producing date.

Code: QB64: [Select]

1. _TITLE "Test TimeStamp##" 'b+ started 2019-08-20
2. ' Steve's TimeStamp## even better than Toolbox tool!
3.  
4. DIM d AS INTEGER, m AS INTEGER, yr AS INTEGER
5. d = 0: m = 1: yr = 1970
6. DO
7.     d = d + 1
8.     IF d = 29 AND m = 2 THEN
9.         'is it leap year
10.         IF yr - 1970 = 30 THEN
11.             m = 3: d = 1
12.         ELSEIF ((yr - 1970) MOD 4 = 2) THEN
13.             'd is ok
14.         ELSE
15.             m = 3: d = 1
16.         END IF
17.     ELSEIF d = 30 AND m = 2 THEN 'must be leap year
18.         m = 3: d = 1
19.     ELSEIF d = 31 THEN
20.         IF m = 4 OR m = 6 OR m = 9 OR m = 11 THEN
21.             m = m + 1: d = 1
22.         END IF
23.     ELSEIF d = 32 THEN
24.         IF m = 12 THEN
25.             d = 1: m = 1: yr = yr + 1
26.         ELSE
27.             d = 1: m = m + 1
28.         END IF
29.     END IF
30.     d2$ = RIGHT$("0" + _TRIM$(STR$(m)), 2) + "-" + RIGHT$("0" + _TRIM$(STR$(d)), 2) + "-" + _TRIM$(STR$(yr))
31.     d1$ = "01-01-1970"
32.  
33.     a## = TimeStamp##(d1$, 5)
34.     b## = TimeStamp##(d2$, 5)
35.     moda## = BmodTimeStamp##(d1$, 5)
36.     modb## = BmodTimeStamp##(d2$, 5)
37.  
38.     dab& = (a## - b##) \ 1
39.     PRINT dab&
40.     IF dab& < 0 THEN
41.         flagNeg = -1: dab& = -dab&
42.     ELSE
43.         flagNeg = 0
44.     END IF
45.     days% = dab& \ (86400)
46.     dab& = dab& - days% * 86400
47.     hours% = dab& \ 3600
48.     dab& = dab& - hours% * 3600
49.     minutes% = dab& \ 60
50.     secs% = dab& - minutes% * 60
51.  
52.     moddab& = (moda## - modb##) \ 1
53.  
54.     IF moddab& < 0 THEN
55.         modflagNeg = -1: moddab& = -moddab&
56.     ELSE
57.         modflagNeg = 0
58.     END IF
59.     moddays% = moddab& \ (86400)
60.     moddab& = moddab& - moddays% * 86400
61.     modhours% = moddab& \ 3600
62.     moddab& = moddab& - modhours% * 3600
63.     modminutes% = moddab& \ 60
64.     modsecs% = moddab& - modminutes% * 60
65.  
66.     CLS
67.     PRINT "The two dates A and B: "; d1$, d2$
68.     PRINT
69.     'PRINT "Updated 2019-08-20 10:58 AM if i <> 30 fix from if y <> 30"
70.     PRINT "Steve TimeStamp## Function:"
71.     PRINT "A##, B## TimeStamps: "; a##, b##
72.     PRINT "Difference between A## and B##:"; days%; "days,"; hours%; "hours,"; minutes%; "minutes,"; secs%; "secs, ";
73.     IF flagNeg THEN
74.         PRINT "B## was later than A##"
75.     ELSE
76.         PRINT "A## was later than B##"
77.     END IF
78.  
79.     PRINT: PRINT "B mods compare:"
80.     PRINT "mod A##, mod B## TimeStamps: "; moda##, modb##
81.     PRINT "Difference between mod A## and mod B##:"; moddays%; "days,"; modhours%; "hours,"; modminutes%; "minutes,"; modsecs%; "secs, ";
82.     IF modflagNeg THEN
83.         PRINT "mod B## was later than mod A##"
84.     ELSE
85.         PRINT "mod A## was later than mod B##"
86.     END IF
87.     PRINT
88.     PRINT "DayCount this loop: "; moddays%, "DayCount last loop:"; lastDay%
89.  
90.     'INPUT "OK ... press enter "; w$
91.     IF lastDay% <> 0 THEN
92.         IF moddays% <> lastDay% + 1 THEN END
93.     END IF
94.     lastDay% = moddays%
95.     _DISPLAY
96.     _LIMIT 1000
97. LOOP UNTIL yr = 2035
98. PRINT "Done!"
99. _DELAY 5
100.  
101. ' b mod TimeStamp fixed. 2019-08-20 twiddled somemore and tested with code above
102. FUNCTION BmodTimeStamp## (d$, t##) 'date and timer
103.     DIM l AS INTEGER, l1 AS INTEGER, i AS INTEGER, s~&&
104.     DIM m AS INTEGER, y AS INTEGER, d AS INTEGER
105.     l = INSTR(d$, "-")
106.     l1 = INSTR(l + 1, d$, "-")
107.     m = VAL(LEFT$(d$, l))
108.     d = VAL(MID$(d$, l + 1)) - 1 '<<<<<<<<<< the day of date is partial, so count of full days is 1 less!!
109.     y = VAL(MID$(d$, l1 + 1)) - 1970
110.     FOR i = 1 TO m 'count up days for year y
111.         SELECT CASE i 'Add the number of days for each previous month passed, case 1 no change needed <<<<<<<<<<< removed case 1 line
112.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
113.             CASE 3: d = d + 28
114.             CASE 5, 7, 10, 12: d = d + 30
115.         END SELECT
116.     NEXT
117.     d = d + 365 * y ' <<<<<<<<<<<<<<< Steve uses loop number of days before counting leap years
118.     FOR i = 2 TO y - 1 STEP 4 ' to y-1 not y, leap years 1972, 1976, 1980... 2020 but not 2000
119.         IF i <> 30 THEN d = d + 1 'fix for year 2000
120.     NEXT
121.     IF y <> 30 THEN '!!!!!!!!!!!!!!!!!! Unless the current year is 2000 !!!!!!!!!!!!!
122.         IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix leap year adjustment for year y
123.     END IF
124.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
125.     BmodTimeStamp## = (s~&& + t##)
126. END FUNCTION
127.  
128.  
129. 'https://www.qb64.org/forum/index.php?topic=1638.msg108566#msg108566
130. 'Steve last edit 10:58 AM 2019-08-20
131. FUNCTION TimeStamp## (d$, t##) 'date and timer
132.     'Based on Unix Epoch time, which starts at year 1970.
133.     'Minor fixes to leap year logic by Bplus.  Many thanks!
134.     l = INSTR(d$, "-")
135.     l1 = INSTR(l + 1, d$, "-")
136.     m = VAL(LEFT$(d$, l))
137.     d = VAL(MID$(d$, l + 1))
138.     y = VAL(MID$(d$, l1 + 1)) - 1970
139.     FOR i = 1 TO m
140.         SELECT CASE i 'Add the number of days for each previous month passed
141.             CASE 1: d = d 'January doestn't have any carry over days.
142.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
143.             CASE 3: d = d + 28
144.             CASE 5, 7, 10, 12: d = d + 30
145.         END SELECT
146.     NEXT
147.     FOR i = 1 TO y
148.         d = d + 365
149.     NEXT
150.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year.
151.         IF i <> 30 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970, but skip year 2000
152.     NEXT
153.  
154.     'unless the current year is 2000!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!1
155.     IF y <> 30 THEN
156.         IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix for leap year, for the current year.
157.     END IF
158.  
159.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
160.     TimeStamp## = (s~&& + t##)
161. END FUNCTION
162.  
163.  

It stopped twice while I was testing. The first time because I didn't increment days for leap years correctly because I was using a different year formula, March 1, 1972, the 2nd time caught the bug for checking the y year if 2000, March 1, 2000. Hey Y2K bug strikes again!

The two TimeStamp## functions produce different results:

BmodTimeStamp## has 0 for date 01-01-1970 0 AM, because I subtract 1 from d calculated off Date$, that Day should not count as a full day. Also all the sub variables are DIM and the loop counting Days up is a one liner formula: d = d + 365 * y. I also removed CASE 1: d = d because it wasn't needed.

Steve's TimeStamp## function as of 11 AM this morning is exactly a days worth of seconds more for 01-01-1970 0 AM and I have fixed the same for the 2000 no leap year bug.

I think the BmodTimeStamp## is the more accrate.

[petoro]

In fact 2000 WAS a leap year as usual. It is because it was divisible but 100 BUT ALSO by 400!

[SMcNeill]

You're still glitching bplus...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 640, 32)
2. FOR i = 1970 TO 2005
3.  
4.     PRINT i, BmodTimeStamp##("03-01-" + STR$(i), 0), TimeStamp("03-01-" + STR$(i), 0);
5.     IF i = 2000 THEN PRINT " <== GLITCH STARTING" ELSE PRINT
6. NEXT
7.  
8.  
9. ' b mod TimeStamp fixed. 2019-08-20 twiddled somemore and tested with code above
10. FUNCTION BmodTimeStamp## (d$, t##) 'date and timer
11.     DIM l AS INTEGER, l1 AS INTEGER, i AS INTEGER, s~&&
12.     DIM m AS INTEGER, y AS INTEGER, d AS INTEGER
13.     l = INSTR(d$, "-")
14.     l1 = INSTR(l + 1, d$, "-")
15.     m = VAL(LEFT$(d$, l))
16.     d = VAL(MID$(d$, l + 1)) - 1 '<<<<<<<<<< the day of date is partial, so count of full days is 1 less!!
17.     y = VAL(MID$(d$, l1 + 1)) - 1970
18.     FOR i = 1 TO m 'count up days for year y
19.         SELECT CASE i 'Add the number of days for each previous month passed, case 1 no change needed <<<<<<<<<<< removed case 1 line
20.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
21.             CASE 3: d = d + 28
22.             CASE 5, 7, 10, 12: d = d + 30
23.         END SELECT
24.     NEXT
25.     d = d + 365 * y ' <<<<<<<<<<<<<<< Steve uses loop number of days before counting leap years
26.     FOR i = 2 TO y - 1 STEP 4 ' to y-1 not y, leap years 1972, 1976, 1980... 2020 but not 2000
27.         IF i <> 30 THEN d = d + 1 'fix for year 2000
28.     NEXT
29.     IF y <> 30 THEN '!!!!!!!!!!!!!!!!!! Unless the current year is 2000 !!!!!!!!!!!!!
30.         IF m > 2 AND (y MOD 4 = 2) THEN d = d + 1 'fix leap year adjustment for year y
31.     END IF
32.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
33.     BmodTimeStamp## = (s~&& + t##)
34. END FUNCTION
35.  
36. FUNCTION TimeStamp## (d$, t##) 'date and timer
37.     'Based on Unix Epoch time, which starts at year 1970.
38.     IF y < 1970 THEN TimeStamp## = -1 'a failure message, as there was no Unix Epoch Time before Jan 01, 1970.
39.     l = INSTR(d$, "-")
40.     l1 = INSTR(l + 1, d$, "-")
41.     m = VAL(LEFT$(d$, l))
42.     d = VAL(MID$(d$, l + 1))
43.     y = VAL(MID$(d$, l1 + 1)) - 1970
44.     FOR i = 1 TO m 'for this year,
45.         SELECT CASE i 'Add the number of days for each previous month passed
46.             CASE 1: d = d 'January doestn't have any carry over days.
47.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
48.             CASE 3 'Feb might be a leap year
49.                 IF (y MOD 4) = 2 THEN 'if this year is divisible by 4 (starting in 1972)
50.                     d = d + 29 'its a leap year
51.                     IF (y MOD 100) = 30 AND (y MOD 400) <> 30 THEN 'unless..
52.                         d = d - 1 'the year is divisible by 100, and not divisible by 400
53.                     END IF
54.                 ELSE 'year not divisible by 4, no worries
55.                     d = d + 28
56.                 END IF
57.             CASE 5, 7, 10, 12: d = d + 30
58.         END SELECT
59.     NEXT
60.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
61.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year (which we handled previously in the FOR loopp)
62.         d = d + 1 'add an extra day every leap year
63.         IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
64.     NEXT
65.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
66.     TimeStamp## = (s~&& + t##)
67. END FUNCTION

With the original ExtendedTimer on the forums here, I was wondering WHY we got the correct answer, without subtracting a day from our date entry.  It's because we were completely handling the leap years wrongly to begin with... The year 2000 *IS* a leap year, so by taking a day off for it (when we shouldn't have), it shifted the answer back a day, giving us the correct time for TODAY...

Which ended up making it one of those glitches which actually fixed another glitch, which ended up giving the proper result when it shouldn't have! Testing it as a TimeStamp, which allows us to flow up and down to any particular date, allowed us to finally showcase the glitch and make adjustments to it.

Unfortunately, by correcting one glitch (subtracting one from the day), you've now left the second glitch to run without correction (the false 2000 leap year subtraction), meaning things are still just as broken as ever!

I'm thinking the above fixes all issues and gets us up to EUT compliance, but test it out for yourself and see what you think.  If it passes muster this time around, I'll redo ExtendedTimer to be correct as well, and we'll have STx correct the code in the toolbox.

The toolbox ExtendedTimer gives us the right result just because it's wrong at being wrong!  0_o!!

[SMcNeill]

In fact 2000 WAS a leap year as usual. It is because it was divisible but 100 BUT ALSO by 400!

I was correcting that as you posted.  I think the latest version here takes all those subtle variations into account:

Code: QB64: [Select]

1. FUNCTION TimeStamp## (d$, t##) 'date and timer
2.     'Based on Unix Epoch time, which starts at year 1970.
3.     IF y < 1970 THEN TimeStamp## = -1 'a failure message, as there was no Unix Epoch Time before Jan 01, 1970.
4.     l = INSTR(d$, "-")
5.     l1 = INSTR(l + 1, d$, "-")
6.     m = VAL(LEFT$(d$, l))
7.     d = VAL(MID$(d$, l + 1))
8.     y = VAL(MID$(d$, l1 + 1)) - 1970
9.     FOR i = 1 TO m 'for this year,
10.         SELECT CASE i 'Add the number of days for each previous month passed
11.             CASE 1: d = d 'January doestn't have any carry over days.
12.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
13.             CASE 3 'Feb might be a leap year
14.                 IF (y MOD 4) = 2 THEN 'if this year is divisible by 4 (starting in 1972)
15.                     d = d + 29 'its a leap year
16.                     IF (y MOD 100) = 30 AND (y MOD 400) <> 30 THEN 'unless..
17.                         d = d - 1 'the year is divisible by 100, and not divisible by 400
18.                     END IF
19.                 ELSE 'year not divisible by 4, no worries
20.                     d = d + 28
21.                 END IF
22.             CASE 5, 7, 10, 12: d = d + 30
23.         END SELECT
24.     NEXT
25.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
26.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year (which we handled previously in the FOR loopp)
27.         d = d + 1 'add an extra day every leap year
28.         IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
29.     NEXT
30.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
31.     TimeStamp## = (s~&& + t##)
32. END FUNCTION

[SMcNeill]

And if you notice, I just toss an error value for when we end up below 1970 and look for a timestamp.  At that point, we have to count time in reverse to generate negative numbers, and I just didn't feel like putting in the effort for it.  :P

DEC 31, 1969, 23:59:59 = -1
DEC 31, 1969, 23:59:58 = -2
... and so on.

With the medications I'm on, I'm surprised I managed to count forward to get to the point where it's currently working properly; I sure don't feel like making it count backwards at the moment.  I leave that mod to Bplus, if he feels like adding it, otherwise positive timestamps are good enough for my needs...  ;)

[STxAxTIC]

Thanks for your diligence boys. I'll let this topic settle down for a short bit before updating our curated code. I unfortunately don't have the most time in the world to follow all the posts so preemptive apologies if I ask for something in a few days that should have been obvious to me.