Function Timestamp

[bplus]

In fact 2000 WAS a leap year as usual. It is because it was divisible but 100 BUT ALSO by 400!

Yikes! nothing like wasting allot of time under a false premise.

Well it's not wasted if I learn something positive from it!

[bplus]

The toolbox ExtendedTimer gives us the right result just because it's wrong at being wrong!  0_o!!

The toolbox code last edited August 11, 2019 is still flawed when the current month is < 3

Code: QB64: [Select]

1. SHELL "https://www.epochconverter.com/"
2. DO
3.     CLS
4.     PRINT TIMER, INT(ExtendedTimer)
5.     PRINT "Compare to the time at https://www.epochconverter.com/"
6.     _DISPLAY
7.     _LIMIT 10
8. LOOP
9.  
10. FUNCTION ExtendedTimer##
11.     d$ = DATE$
12.     l = INSTR(d$, "-")
13.     l1 = INSTR(l + 1, d$, "-")
14.     m = VAL(LEFT$(d$, l))
15.     d = VAL(MID$(d$, l + 1))
16.     y = VAL(MID$(d$, l1 + 1)) - 1970
17.     FOR i = 1 TO m
18.         SELECT CASE i 'Add the number of days for each previous month passed
19.             CASE 1: d = d 'January doestn't have any carry over days.
20.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
21.             CASE 3: d = d + 28
22.             CASE 5, 7, 10, 12: d = d + 30
23.         END SELECT
24.     NEXT
25.     FOR i = 1 TO y
26.         d = d + 365
27.     NEXT
28.     FOR i = 2 TO y STEP 4
29.         IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 1970
30.     NEXT
31.     d = d - 1 'for year 2000
32.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
33.     ExtendedTimer## = (s~&& + TIMER)
34. END FUNCTION

[petoro]

Yikes! nothing like wasting allot of time under a false premise.

Well it's not wasted if I learn something positive from it!

The western calendar has some twisted details :)

[bplus]

The western calendar has some twisted details :)

:)) What's twisted are the Earth's rotations and revolutions.

[SMcNeill]

TimeStamp should now work with all dates for us, even giving us the negative timestamps for dates/times before 1970.

Code: QB64: [Select]

1. SHELL "https://www.epochconverter.com/"
2. PRINT "Compare to time stamps generated at the website which popped up in your browser.https://www.epochconverter.com/"
3.  
4. DO
5.     PRINT
6.     PRINT
7.     INPUT "Give me a DATE$ in format of DD-MM-YYYY"; d$
8.     IF d$ = "" THEN SYSTEM
9.     INPUT "Give me a TIMER value from 0 to 86399.999"; t##
10.     PRINT
11.     PRINT
12.     PRINT "Your current timestamp is =>:"; TimeStamp(d$, t##)
13. LOOP
14.  
15.  
16. FUNCTION TimeStamp## (d$, t##) 'date and timer
17.     'Based on Unix Epoch time, which starts at year 1970.
18.     DIM l AS _INTEGER64, l1 AS _INTEGER64, m AS _INTEGER64
19.     DIM d AS _INTEGER64, y AS _INTEGER64, i AS _INTEGER64
20.     DIM s AS _FLOAT
21.  
22.     l = INSTR(d$, "-")
23.     l1 = INSTR(l + 1, d$, "-")
24.     m = VAL(LEFT$(d$, l))
25.     d = VAL(MID$(d$, l + 1))
26.     y = VAL(MID$(d$, l1 + 1))
27.     IF y < 1970 THEN 'calculate shit backwards
28.         SELECT CASE m 'turn the day backwards for the month
29.             CASE 1, 3, 5, 7, 8, 10, 12: d = 31 - d '31 days
30.             CASE 2: d = 28 - d 'special 28 or 29.
31.             CASE 4, 6, 9, 11: d = 30 - d '30 days
32.         END SELECT
33.         IF y MOD 4 = 0 AND m < 3 THEN 'check for normal leap year, and we're before it...
34.             d = d + 1 'assume we had a leap year, subtract another day
35.             IF y MOD 100 = 0 AND y MOD 400 <> 0 THEN d = d - 1 'not a leap year if year is divisible by 100 and not 400
36.         END IF
37.  
38.         'then count the months that passed after the current month
39.         FOR i = m + 1 TO 12
40.             SELECT CASE i
41.                 CASE 2: d = d + 28
42.                 CASE 3, 5, 7, 8, 10, 12: d = d + 31
43.                 CASE 4, 6, 9, 11: d = d + 30
44.             END SELECT
45.         NEXT
46.  
47.         'we should now have the entered year calculated.  Now lets add in for each year from this point to 1970
48.         d = d + 365 * (1969 - y) '365 days per each standard year
49.         FOR i = 1968 TO y + 1 STEP -4 'from 1968 onwards,backwards, skipping the current year (which we handled previously in the FOR loopp)
50.             d = d + 1 'subtract an extra day every leap year
51.             IF (i MOD 100) = 0 AND (i MOD 400) <> 0 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
52.         NEXT
53.         s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
54.         TimeStamp## = -(s## + 24 * 60 * 60 - t##)
55.         EXIT FUNCTION
56.     ELSE
57.         y = y - 1970
58.     END IF
59.  
60.     FOR i = 1 TO m 'for this year,
61.         SELECT CASE i 'Add the number of days for each previous month passed
62.             CASE 1: d = d 'January doestn't have any carry over days.
63.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
64.             CASE 3 'Feb might be a leap year
65.                 IF (y MOD 4) = 2 THEN 'if this year is divisible by 4 (starting in 1972)
66.                     d = d + 29 'its a leap year
67.                     IF (y MOD 100) = 30 AND (y MOD 400) <> 30 THEN 'unless..
68.                         d = d - 1 'the year is divisible by 100, and not divisible by 400
69.                     END IF
70.                 ELSE 'year not divisible by 4, no worries
71.                     d = d + 28
72.                 END IF
73.             CASE 5, 7, 10, 12: d = d + 30
74.         END SELECT
75.     NEXT
76.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
77.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year (which we handled previously in the FOR loopp)
78.         d = d + 1 'add an extra day every leap year
79.         IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
80.     NEXT
81.     s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
82.     TimeStamp## = (s## + t##)
83. END FUNCTION
84.  
85. FUNCTION ExtendedTimer##
86.     ExtendedTimer = TimeStamp(DATE$, TIMER)
87. END FUNCTION

[bplus]

LOL

   IF y < 1970 THEN 'calculate shit backwards

Nice to extend this back!

Steve, have you considered a timestamp decoder ring? a reverse function to restore date and time.

Also something I've noticed from start:

Code: QB64: [Select]

1.     l = INSTR(d$, "-")
2.     l1 = INSTR(l + 1, d$, "-")
3.     m = VAL(LEFT$(d$, l))
4.     d = VAL(MID$(d$, l + 1))
5.     y = VAL(MID$(d$, l1 + 1))
6.  

loose l and l1 variables and use straight MID$ extraction of m, d, y and you loose the restriction of the separator having to be "-" thusly a "/", a space, any single character would work just as well.

[bplus]

Wait... before we spend another second (or I in checking code of this coding exercise), can someone review for me the practical benefits it might serve?

Steve, you said yourself you use a different system for autosave, one I can appreciate for it's transparency.

Wait... maybe I can for myself, using it to calculate date and time differences. My code that I worked out yesterday was pretty inefficient counting one by one the days until I reach the later date. Converting to seconds, subtracting seconds and then converting to days hours minutes secs.... might be easier or more efficient.

[SMcNeill]

Wait... before we spend another second (or I in checking code of this coding exercise), can someone review for me the practical benefits it might serve?

Steve, you said yourself you use a different system for autosave, one I can appreciate for it's transparency.

Wait... maybe I can for myself, using it to calculate date and time differences. My code that I worked out yesterday was pretty inefficient counting one by one the days until I reach the later date. Converting to seconds, subtracting seconds and then converting to days hours minutes secs.... might be easier or more efficient.

I haven’t used it for a time stamp before (which is why there was so many little glitches to work out); what I use all the time is the ExtendedTimer.  QB64 has 2 ways we can track time — TIME$ and TIMER. For most usages, I find myself using TIMER a lot more than I would TIME$ (it’s hard to add and subtract hours, minutes, and seconds...), but TIMER has one great flaw...

MIDNIGHT!!

Start a program at 11:59:59 PM (86399 seconds), and wait 10 seconds to do something....  and you’ll wait forever with IF TIMER > StartTime + 10 THEN....

Your timer goes back to 0 at midnight, so you’ll never pass (86409 seconds) — putting your program into an endless loop.

Thus, I added ExtendedTimer.  It tracks time with days, months, years, so midnight is no longer an issue.  Where “IF TIMER > StartTime + 10 THEN....” fails at midnight, “IF ExtendedTimer > StartTime + 10 THEN...” doesn’t.

[bplus]

Easier way, check if Timer < StartTime and fix accordingly with a day's worth of secs, that saves bloating code with another procedure  If Timer < StartTime then StartTime = StartTime - 24*60*60

Extended timer would work if run something more than a day (I don't) and Timer is no good for that kind usage either.

[STxAxTIC]

Heya boys,

I apologize for not following this thread to a tee, and not doing my proper reading on the tit-for-tat that happened... but can one of you fine gentleman reply to this with what *should* appear in the toolbox? Thanks kindly.

[bplus]

Heya boys,

I apologize for not following this thread to a tee, and not doing my proper reading on the tit-for-tat that happened... but can one of you fine gentleman reply to this with what *should* appear in the toolbox? Thanks kindly.

Steve has something very interesting posted in #19 August 22

I have not had a chance to give it a test drive, I did want to check and see how it did calculating time & date differences for my submission for code challenge "Count Down 2020" but then Ken came up with more interesting problem and I got side tracked.

Not that you need my seal of approval, but it would be nice if someone tried to break it before submitting to librarian to save librarian's valuable time spent editing buggy code.

[SMcNeill]

Here's what I'd call the "official version" of these two routines reworked for goodness's sake:

Code: QB64: [Select]

1. SHELL "https://www.epochconverter.com/"
2. PRINT "Compare to time stamps generated at the website which popped up in your browser.https://www.epochconverter.com/"
3.  
4. CONST MyTimeZone## = 4 * 3600
5.  
6. DO
7.     _LIMIT 1
8.     CLS
9.     PRINT TimeStamp(DATE$, TIMER + MyTimeZone) 'Timezone difference with GMT, which is what the webpage sometimes points to.
10.     '                                           If the times seem off from the website, you'll want to change the timezone
11.     '                                           offset to match your current time zone.
12.     PRINT ExtendedTimer 'Unix Epoch Timer based on local time.
13.     _DISPLAY
14. LOOP
15.  
16.  
17. FUNCTION TimeStamp## (d$, t##) 'date and timer
18.     'Based on Unix Epoch time, which starts at year 1970.
19.     DIM l AS _INTEGER64, l1 AS _INTEGER64, m AS _INTEGER64
20.     DIM d AS _INTEGER64, y AS _INTEGER64, i AS _INTEGER64
21.     DIM s AS _FLOAT
22.  
23.     l = INSTR(d$, "-")
24.     l1 = INSTR(l + 1, d$, "-")
25.     m = VAL(LEFT$(d$, l))
26.     d = VAL(MID$(d$, l + 1))
27.     y = VAL(MID$(d$, l1 + 1))
28.     IF y < 1970 THEN 'calculate shit backwards
29.         SELECT CASE m 'turn the day backwards for the month
30.             CASE 1, 3, 5, 7, 8, 10, 12: d = 31 - d '31 days
31.             CASE 2: d = 28 - d 'special 28 or 29.
32.             CASE 4, 6, 9, 11: d = 30 - d '30 days
33.         END SELECT
34.         IF y MOD 4 = 0 AND m < 3 THEN 'check for normal leap year, and we're before it...
35.             d = d + 1 'assume we had a leap year, subtract another day
36.             IF y MOD 100 = 0 AND y MOD 400 <> 0 THEN d = d - 1 'not a leap year if year is divisible by 100 and not 400
37.         END IF
38.  
39.         'then count the months that passed after the current month
40.         FOR i = m + 1 TO 12
41.             SELECT CASE i
42.                 CASE 2: d = d + 28
43.                 CASE 3, 5, 7, 8, 10, 12: d = d + 31
44.                 CASE 4, 6, 9, 11: d = d + 30
45.             END SELECT
46.         NEXT
47.  
48.         'we should now have the entered year calculated.  Now lets add in for each year from this point to 1970
49.         d = d + 365 * (1969 - y) '365 days per each standard year
50.         FOR i = 1968 TO y + 1 STEP -4 'from 1968 onwards,backwards, skipping the current year (which we handled previously in the FOR loop)
51.             d = d + 1 'subtract an extra day every leap year
52.             IF (i MOD 100) = 0 AND (i MOD 400) <> 0 THEN d = d - 1 'but skipping every year divisible by 100, but not 400
53.         NEXT
54.         s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
55.         TimeStamp## = -(s## + 24 * 60 * 60 - t##)
56.         EXIT FUNCTION
57.     ELSE
58.         y = y - 1970
59.     END IF
60.  
61.     FOR i = 1 TO m 'for this year,
62.         SELECT CASE i 'Add the number of days for each previous month passed
63.             CASE 1: d = d 'January doestn't have any carry over days.
64.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
65.             CASE 3 'Feb might be a leap year
66.                 IF (y MOD 4) = 2 THEN 'if this year is divisible by 4 (starting in 1972)
67.                     d = d + 29 'its a leap year
68.                     IF (y MOD 100) = 30 AND (y MOD 400) <> 30 THEN 'unless..
69.                         d = d - 1 'the year is divisible by 100, and not divisible by 400
70.                     END IF
71.                 ELSE 'year not divisible by 4, no worries
72.                     d = d + 28
73.                 END IF
74.             CASE 5, 7, 10, 12: d = d + 30
75.         END SELECT
76.     NEXT
77.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
78.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year (which we handled previously in the FOR loopp)
79.         d = d + 1 'add an extra day every leap year
80.         IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
81.     NEXT
82.     s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
83.     TimeStamp## = (s## + t##)
84. END FUNCTION
85.  
86. FUNCTION ExtendedTimer##
87.     'Simplified version of the TimeStamp routine, streamlined to only give positive values based on the current timer.
88.     'Note:  Only good until the year 2100, as we don't do all the fancy calculations for leap years.
89.     'A timer should work quickly and efficiently in the background; and the less we do, the less lag we might insert
90.     'into a program.
91.  
92.     DIM m AS INTEGER, d AS INTEGER, y AS INTEGER
93.     DIM s AS _FLOAT, day AS STRING
94.     day = DATE$
95.     m = VAL(LEFT$(day, 2))
96.     d = VAL(MID$(day, 4, 2))
97.     y = VAL(RIGHT$(day, 4)) - 1970
98.     SELECT CASE m 'Add the number of days for each previous month passed
99.         CASE 2: d = d + 31
100.         CASE 3: d = d + 59
101.         CASE 4: d = d + 90
102.         CASE 5: d = d + 120
103.         CASE 6: d = d + 151
104.         CASE 7: d = d + 181
105.         CASE 8: d = d + 212
106.         CASE 9: d = d + 243
107.         CASE 10: d = d + 273
108.         CASE 11: d = d + 304
109.         CASE 12: d = d + 334
110.     END SELECT
111.     IF (y MOD 4) = 2 AND m > 2 THEN d = d + 1 'add a day if this is leap year and we're past february
112.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
113.     d = d + (y + 2) \ 4 'add in days for leap years passed
114.     s = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
115.     ExtendedTimer## = (s + TIMER)
116. END FUNCTION
117.  

The demo should speak for itself, I'd hope.  ;)

[bplus]

Hi Steve,

I am using this code to calculate difference in dates using your timeStamp## and code I used in my last post in Count  Down 2020:

Code: QB64: [Select]

1.  
2. FUNCTION TimeStampDiff$ (LaterDate$, LaterTime##, EarlierDate$, EarlierTime##)
3.     secLate## = TimeStamp##(LaterDate$, LaterTime##)
4.     secEarly## = TimeStamp##(EarlierDate$, EarlierTime##)
5.     secDiff = secLate## - secEarly##
6.     'covert to days, hours, minutes, secs I am dropping fraction secs for test
7.     days = INT(secDiff / 86400)
8.     secDiff = secDiff - days * 86400
9.     hours = INT(secDiff / 3600)
10.     secDiff = secDiff - hours * 3600
11.     minutes = INT(secDiff / 60)
12.     secs = INT(secDiff - minutes * 60)
13.     TimeStampDiff$ = _TRIM$(STR$(days)) + " Days and " + _TRIM$(STR$(hours)) + " Hours, " + _TRIM$(STR$(minutes)) + " Minutes, " + _TRIM$(STR$(secs))
14. END FUNCTION
15.  

The good news we agree for years >=1970, bad news there is difference in days for years earlier than 1970.
This is the completely new section of your timeStamp## code that I thought should be tested because the web site can't verify your numbers in those circumstances.

I am currently revising the test to maybe help see what is off.

[SMcNeill]

You can compare with the page here: https://www.epochconverter.com/

Times were matching at my last tests, unless I posted a glitchy version on the forums here...  I’ll recheck results again to see what’s up.

[bplus]

Hi Steve,

It's the new part of your code where you attempt dates before 1970, here is my test code:

Code: QB64: [Select]

1. _TITLE "Test Steve timeStamp" 'B+ test 2019-08-24
2. '2019-08-24 Quick test Steve timestamp by comparing DiffDateTime$ to TimeStampDiff$
3. 'I am just testing day counts
4.  
5. SCREEN _NEWIMAGE(600, 760, 32)
6. _SCREENMOVE 350, 0
7. times$ = "00:00:00": times## = 0
8.  
9. dates$(3) = "08-24-2019": dates$(2) = "01-01-2020": dates$(1) = "01-01-2021": dates$(0) = "01-01-2025"
10. dates$(4) = "01-01-2019": dates$(5) = "01-01-1970": dates$(6) = "01-01-1815"
11.  
12. FOR i = 0 TO 5
13.     FOR j = i + 1 TO 6
14.         PRINT dates$(i); " Minus "; dates$(j)
15.         PRINT DiffDateTime$(DateTime$(dates$(i), times$), DateTime$(dates$(j), times$))
16.         PRINT TimeStampDiff$(dates$(i), time##, dates$(j), time##)
17.         PRINT
18.     NEXT
19.     INPUT "OK ... press enter "; w$
20.     CLS
21. NEXT
22. d1970$ = "01-01-1970"
23. FOR y = 1970 TO 1950 STEP -1
24.     d$ = "01-01-" + _TRIM$(STR$(y))
25.     PRINT d1970$; " Minus "; d$
26.     PRINT DiffDateTime$(DateTime$(d1970$, times$), DateTime$(d$, times$))
27.     PRINT TimeStampDiff$(d1970$, time##, d$, time##)
28.     PRINT
29.     IF y MOD 5 = 0 THEN
30.         INPUT "OK ... press enter "; w$
31.         CLS
32.     END IF
33. NEXT
34.  
35. ' I used this code for Count Down 2020
36. 'note: this uses 2 dates and times formatted with DateTime$() Function
37. FUNCTION DiffDateTime$ (LaterDate$, MinusEarlierDate$)
38.     es = VAL(MID$(MinusEarlierDate$, 18, 2))
39.     ls = VAL(MID$(LaterDate$, 18, 2))
40.  
41.     em = VAL(MID$(MinusEarlierDate$, 15, 2))
42.     lm = VAL(MID$(LaterDate$, 15, 2))
43.  
44.     eh = VAL(MID$(MinusEarlierDate$, 12, 2))
45.     lh = VAL(MID$(LaterDate$, 12, 2))
46.  
47.     ed = VAL(MID$(MinusEarlierDate$, 9, 2))
48.     ld = VAL(MID$(LaterDate$, 9, 2))
49.  
50.     emm = VAL(MID$(MinusEarlierDate$, 6, 2))
51.     lmm = VAL(MID$(LaterDate$, 6, 2))
52.  
53.     ey = VAL(MID$(MinusEarlierDate$, 1, 4))
54.     ly = VAL(MID$(LaterDate$, 1, 4))
55.  
56.     IF es > ls THEN ls = ls + 60: lm = lm - 1
57.     DiffDateTime$ = STR$(ls - es) + " secs"
58.  
59.     IF em > lm THEN lm = lm + 60: lh = lh - 1
60.     DiffDateTime$ = STR$(lm - em) + " mins" + DiffDateTime$
61.  
62.     IF eh > lh THEN lh = lh + 24: ld = ld - 1
63.     DiffDateTime$ = STR$(lh - eh) + " hours" + DiffDateTime$
64.  
65.     ''did we barrow off day
66.     IF ld = 0 THEN
67.         SELECT CASE lmm
68.             CASE 1: ly = ly - 1: lmm = 12: ld = 31
69.             CASE 3: IF IsLeapYear(ly) = 1 THEN lmm = 2: ld = 29 ELSE lmm = 2: ld = 28
70.             CASE 5, 7, 8, 10, 12: lmm = lmm - 1: ld = 30
71.             CASE 2, 4, 6, 9, 11: lmm = lmm - 1: ld = 31
72.         END SELECT
73.     END IF
74.     'PRINT ly, lmm, ld   ' check target and start
75.     'PRINT ey, emm, ed
76.  
77.     'now count days
78.     DO
79.         IF ly = ey THEN
80.             IF lmm = emm THEN
81.                 IF ld = ed THEN EXIT DO '  all date numbers match, done calc
82.             END IF
83.         END IF
84.         ed = ed + 1
85.         cnt = cnt + 1
86.         IF ed = 29 AND emm = 2 THEN
87.             'is it leap year
88.             IF IsLeapYear%(ey) = 1 THEN
89.                 'pass
90.             ELSE
91.                 emm = 3: ed = 1
92.             END IF
93.         ELSEIF ed = 30 AND emm = 2 THEN 'must be leap year
94.             emm = 3: ed = 1
95.         ELSEIF ed = 31 THEN
96.             IF emm = 4 OR emm = 6 OR emm = 9 OR emm = 11 THEN
97.                 emm = emm + 1: ed = 1
98.             END IF
99.         ELSEIF ed = 32 THEN
100.             IF emm = 12 THEN
101.                 ed = 1: emm = 1: ey = ey + 1
102.             ELSE
103.                 ed = 1: emm = emm + 1
104.             END IF
105.         END IF
106.         'PRINT ey, emm, ed, ly; " "; lmm; " "; ld   'Check progress
107.         '_LIMIT 2
108.     LOOP
109.     DiffDateTime$ = _TRIM$(STR$(cnt)) + " Days and" + DiffDateTime$
110. END FUNCTION
111.  
112. FUNCTION CurrentDateTime$
113.     CurrentDateTime$ = "    -  -  _  :  :  "
114.     MID$(CurrentDateTime$, 1, 4) = MID$(DATE$, 7, 4)
115.     MID$(CurrentDateTime$, 6, 5) = MID$(DATE$, 1, 5)
116.     MID$(CurrentDateTime$, 12, 8) = TIME$
117. END FUNCTION
118.  
119. FUNCTION DateTime$ (mm_dd_yy$, hh_mm_ss$)
120.     DateTime$ = "    -  -  _  :  :  "
121.     MID$(DateTime$, 1, 4) = MID$(mm_dd_yy$, 7, 4)
122.     MID$(DateTime$, 6, 5) = MID$(mm_dd_yy$, 1, 5)
123.     MID$(DateTime$, 12, 8) = hh_mm_ss$
124. END FUNCTION
125.  
126. FUNCTION IsLeapYear% (yr) 'mod from Pete's calendar this is a very clear calc
127.     IF yr MOD 4 = 0 THEN
128.         IF yr MOD 100 = 0 THEN
129.             IF yr MOD 400 = 0 THEN IsLeapYear = 1
130.         ELSE
131.             IsLeapYear = 1
132.         END IF
133.     END IF
134. END FUNCTION
135.  
136. 'this calc date time diff using Steve' TimeStamp## secs
137. FUNCTION TimeStampDiff$ (LaterDate$, LaterTime##, EarlierDate$, EarlierTime##)
138.     secLate## = TimeStamp##(LaterDate$, LaterTime##)
139.     secEarly## = TimeStamp##(EarlierDate$, EarlierTime##)
140.     secDiff = secLate## - secEarly##
141.     'covert to days, hours, minutes, secs I am dropping fraction secs for test
142.     days = INT(secDiff / 86400)
143.     secDiff = secDiff - days * 86400
144.     hours = INT(secDiff / 3600)
145.     secDiff = secDiff - hours * 3600
146.     minutes = INT(secDiff / 60)
147.     secs = INT(secDiff - minutes * 60)
148.     TimeStampDiff$ = _TRIM$(STR$(days)) + " Days and " + _TRIM$(STR$(hours)) + " Hours, " + _TRIM$(STR$(minutes)) + " Minutes, " + _TRIM$(STR$(secs))
149. END FUNCTION
150.  
151. ' Steve's latest version
152. ' https://www.qb64.org/forum/index.php?topic=1638.msg108650#msg108650
153. FUNCTION TimeStamp## (d$, t##) 'date and timer
154.     'Based on Unix Epoch time, which starts at year 1970.
155.     DIM m AS _INTEGER64, d AS _INTEGER64, y AS _INTEGER64
156.     DIM i AS _INTEGER64, s AS _FLOAT
157.  
158.     m = VAL(LEFT$(d$, 2))
159.     d = VAL(MID$(d$, 4, 2))
160.     y = VAL(RIGHT$(d$, 4))
161.     IF y < 1970 THEN 'calculate shit backwards
162.         SELECT CASE m 'turn the day backwards for the month
163.             CASE 1, 3, 5, 7, 8, 10, 12: d = 31 - d '31 days
164.             CASE 2: d = 28 - d 'special 28 or 29.
165.             CASE 4, 6, 9, 11: d = 30 - d '30 days
166.         END SELECT
167.         IF y MOD 4 = 0 AND m < 3 THEN 'check for normal leap year, and we're before it...
168.             d = d - 1 'assume we had a leap year, subtract another day
169.             IF y MOD 100 = 0 AND y MOD 400 <> 0 THEN d = d + 1 'not a leap year if year is divisible by 100 and not 400
170.         END IF
171.  
172.         'then count the months that passed after the current month
173.         FOR i = m + 1 TO 12
174.             SELECT CASE i
175.                 CASE 2: d = d - 28
176.                 CASE 3, 5, 7, 8, 10, 12: d = d - 31
177.                 CASE 4, 6, 9, 11: d = d - 30
178.             END SELECT
179.         NEXT
180.  
181.         'we should now have the entered year calculated.  Now lets add in for each year from this point to 1970
182.         d = d + 365 * (1969 - y) '365 days per each standard year
183.         FOR i = 1968 TO y + 1 STEP -4 'from 1968 onwards,backwards, skipping the current year (which we handled previously in the FOR loopp)
184.             d = d + 1 'subtract an extra day every leap year
185.             IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
186.         NEXT
187.         s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
188.         TimeStamp## = -(s## + 24 * 60 * 60 - t##)
189.         EXIT FUNCTION
190.     ELSE
191.         y = y - 1970
192.     END IF
193.  
194.     FOR i = 1 TO m 'for this year,
195.         SELECT CASE i 'Add the number of days for each previous month passed
196.             CASE 1: d = d 'January doestn't have any carry over days.
197.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
198.             CASE 3 'Feb might be a leap year
199.                 IF (y MOD 4) = 2 THEN 'if this year is divisible by 4 (starting in 1972)
200.                     d = d + 29 'its a leap year
201.                     IF (y MOD 100) = 30 AND (y MOD 400) <> 30 THEN 'unless..
202.                         d = d - 1 'the year is divisible by 100, and not divisible by 400
203.                     END IF
204.                 ELSE 'year not divisible by 4, no worries
205.                     d = d + 28
206.                 END IF
207.             CASE 5, 7, 10, 12: d = d + 30
208.         END SELECT
209.     NEXT
210.     d = (d - 1) + 365 * y 'current month days passed + 365 days per each standard year
211.     FOR i = 2 TO y - 1 STEP 4 'from 1972 onwards, skipping the current year (which we handled previously in the FOR loopp)
212.         d = d + 1 'add an extra day every leap year
213.         IF (i MOD 100) = 30 AND (i MOD 400) <> 30 THEN d = d - 1 'but skiping every year divisible by 100, but not 400
214.     NEXT
215.     s## = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
216.     TimeStamp## = (s## + t##)
217. END FUNCTION
218.