Pattern Challenge 2

[_vince]

In spirit of bplus's thread, I challenge you to draw the attached image.  The only rule is that it has to be a fully re-sizable vector image that doesn't lose detail with change in size (ie no bitmaps/putimage).  Bonus points if you can make the circles and widths variable size. I will be very impressed if someone pulls this off!

[johnno56]

Cool... Has a Celt-like feel... Nice.

[bplus]

Hi _vince,

You got me thinking... :D

[SMcNeill]

I haven’t tried this yet, as I’ve been pressed for time with family stuff, but isn’t this just a series of 4 rotated arcs?

For example, take the far north circle and study it.  It’s 4 arcs with equidistant gaps in it.  Far south, NE, SE, NW, SW are as well; just rotated.  What remains are a series of 2 half-circle arcs, just as the previous 4; just offset to meet the endpoints of the previous arcs...

I haven’t did it yet,but it seems to me like that’s how one would do it.

[bplus]

Still cleaning up end points. My eyes so blurry I can't do anymore tonight but I have a good start:
  [ You are not allowed to view this attachment ]  

[bplus]

Hi _vince,

I did share your challenge at JB with my snap shot of my solution translated to JB.

Obviously I can scale size and change color easy enough but change thickness or width between inner & outer radii? nope!

Needs formula to convert thickness at radius to arc degrees, which I attempted and failed because that still needed more adjustments for the angle at which the thickness was being seen from the arc's origin. (If anyone can follow what I just said, I will be impressed!)

So I am wondering, is your code able to change thickness or distance between inner and outer radii? ie you can draw a large knot with a very thin thickness of a small knot with a very thick "rope" for "knot".

My code is based on the outer radius being 4 * thickness and inner radius being 3 * thickness. So still more challenge left for me... maybe?

Oh, another good thing to try is to see if the border lines can hold PAINT.

[TempodiBasic]

Hi
It should be well in the Escher's tables...
each circle is incomplete at the point of touching the invisible external exagon... and each circle is under the circle at its right and  upon the circle that is at its left!....
but all these affirmations are only bad hypothesis...

if you create a function that draws arches with two lines  and you build this image you cannot get any good images because in a circular situation the arch on the left must be drawn before the arch at right, but the last arch is at left of the first arch.

LOL

as in the Escher's pictures if you try to see in different manner you can get the rivelation of the solution...
you can divide the circle into an arch of 180* that have a single part void of the dimension of the distance between the two lines...
after creating this function  you need calculate the start and end point of each arch of the 18 arches

Good math to who has will and patience to get the good calculations.

[bplus]

Ohhhh Escher! I love Escher drawings :-) hmm... challenge #3?


Well I thought I had cleaned up all my end points pretty well until I tried PAINT and found a couple holes, fixed now:

  [ You are not allowed to view this attachment ]  

[bplus]

This is the skeleton from which I eyeballed 12 arcs with 24 start and end angles for the Arc sub to draw (in Radians of course).

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Vince Celtic Challenge Skeleton"
3. CONST xmax = 1200, ymax = 700, pi = 3.14159265
4. CONST xc = xmax / 2, yc = ymax / 2
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 100, 20
7.  
8. celticKnot xc, yc, 30
9. SLEEP
10.  
11. SUB celticKnot (xc, yc, thick)
12.     DIM distr, r, r1, hex, hd2, nHex, x0, y0, c AS _UNSIGNED LONG
13.  
14.     distr = 5 * thick
15.     r = 4 * thick
16.     r1 = 3 * thick
17.     hex = pi * 2 / 6
18.     hd2 = hex / 2
19.  
20.     FOR nHex = 1 TO 6
21.         IF nHex <= 2 THEN c = &HFFFFFFFF ELSE c = &HFF444444
22.         'circles with origins in main circle
23.         x0 = xc + distr * COS(nHex * hex - hd2)
24.         y0 = yc + distr * SIN(nHex * hex - hd2)
25.  
26.         'outer radius
27.         CIRCLE (x0, y0), r, c
28.         'inner radius
29.         CIRCLE (x0, y0), r1, c
30.  
31.  
32.         ' circles with outside origins
33.         x0 = xc + (2 * distr - 1.5 * thick) * COS(nHex * hex)
34.         y0 = yc + (2 * distr - 1.5 * thick) * SIN(nHex * hex)
35.         IF nHex = 1 THEN c = &HFF0000FF ELSE c = &HFF444444
36.         'outer radius
37.         CIRCLE (x0, y0), r, c
38.         'inner radius
39.         CIRCLE (x0, y0), r1, c
40.  
41.     NEXT
42. END SUB
43.  
44.  

I had to have Vince screen shot on the side to see where all there bridges go.

Vince how did you do yours?

[_vince]

Nice bplus.  I'm assuming you eye-balled each arc angle instead of calculating the intersection points in terms of all the parameters?  Mine takes four variables:  three radii (r, r1, r2) and width to render the image.  There is some tedious geometry but there are a lot of symmetries so it's very prone to simplifications.  I'd imagine it can be done with very little code.  I'll give this another couple of days before posting my solution.

[bplus]

A brain buster but the math is doing all the eyeballing now, so can change thickness and circle opening closing at will (within limits of design).

[bplus]

I'd imagine it can be done with very little code.

Not by bplus! :D

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Celtic Challenge Advanced Sub" 'B+ 2019-07-06 develop as a sub
3. ' parameters are x, y origin, radius of Knot, thicknes of rings, border color and fill color
4. ' is there a max radius of knot?
5.  
6. CONST xmax = 700, ymax = 700, pi = 3.14159265
7. CONST xc = xmax / 2, yc = ymax / 2
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _SCREENMOVE 100, 20
10.  
11. DIM knot, thick, w$
12. WHILE 1
13.     CLS
14.     INPUT "Enter knot size, 20 to 150 best "; knot
15.     INPUT "Enter ring thickness, 1 to 20% knot best ", thick
16.     INPUT "Enter f to fill in with green, best not to fill when thickness < %5 knot "; w$
17.     IF w$ = "f" THEN celticKnot xc, yc, knot, thick, &HFFFFFF00, &HFF00BB00 ELSE celticKnot xc, yc, knot, thick, &HFFFFFF00, 0
18.     INPUT "press enter to cont... "; w$
19.     _DISPLAY
20.  
21. WEND
22.  
23. 'the max thickness for the knotRadius is .25 * knotRadius, ideal max is about 20%
24. ' use 0 for fill color to skip PAINT jobs, recommended for small or thin knots
25. SUB celticKnot (xc, yc, knotR, ringThick, outline AS _UNSIGNED LONG, fill AS _UNSIGNED LONG)
26.     DIM r, r1, hex, hd2, nHex
27.  
28.     'a good naming system is crucial i/o = inner/outer circle,
29.     'p1/m1 plus1/minus1 (actually it's plus and minus 1/2 for outer rings)
30.     DIM xi, yi, xim1, yim1, xip1, yip1, xom1, yom1, xop1, yop1
31.  
32.     'points of interest
33.     DIM xm1, xm2, xm3, xm4, xm5, xm6, xm7, xm9, xm10, xm12
34.     DIM ym1, ym2, ym3, ym4, ym5, ym6, ym7, ym9, ym10, ym12
35.     DIM xn1, xn2, xn3, xn4, xn5, xn6, xn8, xn9, xn10, xn11
36.     DIM yn1, yn2, yn3, yn4, yn5, yn6, yn8, yn9, yn10, yn11
37.     DIM xp1, xp2, xp3, xp4, xp5, xp6, xp7, xp8
38.     DIM xq1, xq2, xq3, xq4, xq5, xq6
39.     DIM yp1, yp2, yp3, yp4, yp5, yp6, yp7, yp8
40.     DIM yq1, yq2, yq3, yq4, yq5, yq6
41.  
42.     r = .8 * knotR '4
43.     r1 = r - ringThick '3 * ringThick ' 3
44.     hex = pi * 2 / 6
45.     hd2 = hex / 2
46.  
47.     FOR nHex = 1 TO 6
48.  
49.         '5 circle origin sets
50.  
51.         'inner ring before main ring
52.         xim1 = xc + knotR * COS((nHex - 1) * hex - hd2)
53.         yim1 = yc + knotR * SIN((nHex - 1) * hex - hd2)
54.  
55.         'main inner ring to draw up
56.         xi = xc + knotR * COS(nHex * hex - hd2)
57.         yi = yc + knotR * SIN(nHex * hex - hd2)
58.  
59.         'inner ring after main
60.         xip1 = xc + knotR * COS((nHex + 1) * hex - hd2)
61.         yip1 = yc + knotR * SIN((nHex + 1) * hex - hd2)
62.  
63.         'outer ring before main ring
64.         xom1 = xc + (2 * knotR - 1.5 * ringThick) * COS((nHex - 1) * hex)
65.         yom1 = yc + (2 * knotR - 1.5 * ringThick) * SIN((nHex - 1) * hex)
66.  
67.         'outer ring after main ring
68.         xop1 = xc + (2 * knotR - 1.5 * ringThick) * COS(nHex * hex)
69.         yop1 = yc + (2 * knotR - 1.5 * ringThick) * SIN(nHex * hex)
70.  
71.         'working main ring from 0 to 2*pi  one segment at a time
72.  
73.         'first point of interest on main is out circle /\ out circle of op1
74.         intersect2Circles xi, yi, r, xop1, yop1, r, xm1, ym1, xm4, ym4
75.         intersect2Circles xi, yi, r, xop1, yop1, r1, xm2, ym2, xm3, ym3
76.  
77.         intersect2Circles xi, yi, r, xop1, yop1, r1, xm2, ym2, xm3, yn3
78.         intersect2Circles xi, yi, r1, xop1, yop1, r1, xn2, yn2, xn3, yn3
79.  
80.         minorArc xi, yi, r, rAngle(xi, yi, xm1, ym1), rAngle(xi, yi, xm3, ym3), outline
81.         minorArc xi, yi, r1, rAngle(xi, yi, xn2, yn2), rAngle(xi, yi, xn3, yn3), outline
82.  
83.         'inside main outside po1
84.         intersect2Circles xi, yi, r1, xop1, yop1, r, xn1, yn1, xn4, yn4
85.  
86.         'outside main with outside im1
87.         intersect2Circles xi, yi, r, xim1, yim1, r, xm5, ym5, xm10, ym10
88.  
89.         'inside main outside im1
90.         intersect2Circles xi, yi, r1, xim1, yim1, r, xn5, yn5, xn10, yn10
91.  
92.         minorArc xi, yi, r, rAngle(xi, yi, xm4, ym4), rAngle(xi, yi, xm5, ym5), outline
93.         minorArc xi, yi, r1, rAngle(xi, yi, xn4, yn4), rAngle(xi, yi, xn5, yn5), outline
94.  
95.  
96.         'outside main to inside im1
97.         intersect2Circles xi, yi, r, xim1, yim1, r1, xm6, ym6, xm9, ym9
98.  
99.         'inside main to inside im1
100.         intersect2Circles xi, yi, r1, xim1, yim1, r1, xn6, yn6, xn9, yn9
101.  
102.         minorArc xi, yi, r, rAngle(xi, yi, xm6, ym6), rAngle(xi, yi, xm9, ym9), outline
103.         minorArc xi, yi, r1, rAngle(xi, yi, xn6, yn6), rAngle(xi, yi, xn9, yn9), outline
104.  
105.         'outer main to outer om1
106.         intersect2Circles xi, yi, r, xom1, yom1, r, xm7, ym7, xm12, ym12
107.  
108.         'inner main to inner om1
109.         intersect2Circles xi, yi, r1, xom1, yom1, r1, xn8, yn8, xn11, yn11
110.  
111.         minorArc xi, yi, r, rAngle(xi, yi, xm10, ym10), rAngle(xi, yi, xm12, ym12), outline
112.         minorArc xi, yi, r1, rAngle(xi, yi, xn10, yn10), rAngle(xi, yi, xn11, yn11), outline
113.  
114.  
115.         'now for the two that fold inward
116.  
117.         'outer op1 to outer  ip1
118.         intersect2Circles xop1, yop1, r, xip1, yip1, r, xp1, yp1, xp4, yp4
119.         'outer op1 to inner p1
120.         intersect2Circles xop1, yop1, r, xip1, yip1, r1, xp2, yp2, xp3, yp3
121.         'inner op1 to inner p1
122.         intersect2Circles xop1, yop1, r1, xip1, yip1, r1, xq2, yq2, xq3, yq3
123.  
124.         minorArc xop1, yop1, r, rAngle(xop1, yop1, xp1, yp1), rAngle(xop1, yop1, xp3, yp3), outline
125.         minorArc xop1, yop1, r1, rAngle(xop1, yop1, xq2, yq2), rAngle(xop1, yop1, xq3, yq3), outline
126.  
127.         'inner op1 outer inner p1
128.         intersect2Circles xop1, yop1, r1, xip1, yip1, r, xq1, yq1, xq4, yq4
129.  
130.         minorArc xop1, yop1, r, rAngle(xop1, yop1, xp4, yp4), rAngle(xop1, yop1, xm1, ym1), outline
131.  
132.  
133.         'last test?
134.         minorArc xop1, yop1, r1, rAngle(xop1, yop1, xq4, yq4), rAngle(xop1, yop1, xn1, yn1), outline
135.  
136.  
137.         'outer om1 to outer outer main
138.         intersect2Circles xom1, yom1, r, xi, yi, r, xp5, yp5, xp8, yp8
139.         'inner om1 to inner main
140.         intersect2Circles xom1, yom1, r1, xi, yi, r1, xq5, yq5, xq6, yq6
141.         'outer om1to inner main
142.         intersect2Circles xom1, yom1, r, xi, yi, r1, xp6, yp6, xp7, yp7
143.  
144.         minorArc xom1, yom1, r, rAngle(xom1, yom1, xp5, yp5), rAngle(xom1, yom1, xp7, yp7), outline
145.         minorArc xom1, yom1, r1, rAngle(xom1, yom1, xq5, yq5), rAngle(xom1, yom1, xq6, yq6), outline
146.  
147.     NEXT
148.  
149.     IF fill THEN
150.         DIM px, py, midR
151.         midR = (r + r1) / 2 + .5
152.         FOR nHex = 1 TO 6
153.             'circles with origins in main circle
154.             'main inner ring to draw up
155.             xi = xc + knotR * COS(nHex * hex - hd2)
156.             yi = yc + knotR * SIN(nHex * hex - hd2)
157.  
158.             '4 paint points
159.             px = xi + midR * COS(nHex * hex + .1 * pi)
160.             py = yi + midR * SIN(nHex * hex + .1 * pi)
161.             'CIRCLE (px, py), 1, fill
162.             PAINT (px, py), fill, outline
163.  
164.             px = xi + midR * COS(nHex * hex + .7 * pi)
165.             py = yi + midR * SIN(nHex * hex + .7 * pi)
166.             'CIRCLE (px, py), 1, fill
167.             PAINT (px, py), fill, outline
168.  
169.             px = xi + midR * COS(nHex * hex + 1.3 * pi)
170.             py = yi + midR * SIN(nHex * hex + 1.3 * pi)
171.             'CIRCLE (px, py), 1, fill
172.             PAINT (px, py), fill, outline
173.  
174.             px = xi + midR * COS(nHex * hex + 1.7 * pi)
175.             py = yi + midR * SIN(nHex * hex + 1.7 * pi)
176.             'CIRCLE (px, py), 1, fill
177.             PAINT (px, py), fill, outline
178.  
179.         NEXT
180.     END IF
181. END SUB
182.  
183. 'given a circles origin and point on the circumference return the arc measure of that point
184. FUNCTION rAngle (coX, coY, circumX, circumY)
185.     rAngle = _ATAN2(circumY - coY, circumX - coX)
186.     IF rAngle < 0 THEN rAngle = rAngle + _PI(2)
187. END FUNCTION
188.  
189. 'given two arc angles I want the one that draws the smaller arc drawn
190. SUB minorArc (x, y, r, ra1, ra2, c AS _UNSIGNED LONG)
191.     DIM raStart, raStop
192.  
193.     'which has smaller arc measure
194.     IF ra1 < ra2 THEN
195.         IF ra2 - ra1 < _PI THEN raStart = ra1: raStop = ra2 ELSE raStart = ra2: raStop = ra1
196.     ELSE
197.         IF ra1 - ra2 < _PI THEN raStart = ra2: raStop = ra1 ELSE raStart = ra1: raStop = ra2
198.     END IF
199.     arc x, y, r, raStart, raStop, c
200. END SUB
201.  
202. SUB intersect2Circles (x1, y1, r1, x2, y2, r2, ix1, iy1, ix2, iy2)
203.     'x1, y1 origin of circle 1 with radius r1
204.     'x2, y2 origin of circle 2 with radius r2
205.     'ix1, iy1 is the first point of intersect
206.     'ix2, iy2 is the 2nd point of intersect
207.     'if ix1 = ix2 = iy1 = iy2 = 0 then no points returned
208.  
209.     DIM d, a, h, Px, Py, offset, rang1, rang2
210.     d = distance(x1, y1, x2, y2) 'distance between two origins
211.     IF r1 + r2 < d THEN
212.         'PRINT "The circles are too far apart to intersect.": END
213.         'some signal ???    if ix1 = ix2 = iy1 = iy2 = 0 then no points returned
214.         ix1 = 0: ix2 = 0: iy1 = 0: iy2 = 0
215.         EXIT SUB
216.     END IF
217.     IF (d < r1 AND r2 + d < r1) OR (d < r2 AND r1 + d < r2) THEN ' no intersect
218.         ix1 = 0: ix2 = 0: iy1 = 0: iy2 = 0
219.         EXIT SUB
220.     END IF
221.     'results
222.     a = (r1 ^ 2 - r2 ^ 2 + d ^ 2) / (2 * d)
223.     Px = x1 + a * (x2 - x1) / d
224.     Py = y1 + a * (y2 - y1) / d
225.     h = (r1 ^ 2 - a ^ 2) ^ .5
226.     ix1 = INT(Px - h * (y2 - y1) / d)
227.     iy1 = INT(Py + h * (x2 - x1) / d)
228.     ix2 = INT(Px + h * (y2 - y1) / d)
229.     iy2 = INT(Py - h * (x2 - x1) / d)
230.  
231.     ''getting the order of points matched to varaible labels
232.     offset = rAngle(xc, yc, x1, y1)
233.     rang1 = rAngle(x1, y1, ix1, iy1) - offset
234.     IF rang1 < 0 THEN rang1 = rang1 + 2 * pi
235.     rang2 = rAngle(x1, y1, ix2, iy2) - offset
236.     IF rang2 < 0 THEN rang2 = rang2 + 2 * pi
237.     IF rang2 < rang1 THEN SWAP ix1, ix2: SWAP iy1, iy2
238.  
239. END SUB
240.  
241. SUB arc (x, y, r, raStart, raStop, c AS _UNSIGNED LONG)
242.     'x, y origin, r = radius, c = color
243.  
244.     'raStart is first angle clockwise from due East = 0 degrees
245.     ' arc will start drawing there and clockwise until raStop angle reached
246.  
247.     DIM al, a
248.     IF raStop < raStart THEN
249.         arc x, y, r, raStart, _PI(2), c
250.         arc x, y, r, 0, raStop, c
251.     ELSE
252.         ' modified to easier way suggested by Steve
253.         'Why was the line method not good? I forgot.
254.         al = _PI * r * r * (raStop - raStart) / _PI(2)
255.         FOR a = raStart TO raStop STEP 1 / al
256.             PSET (x + r * COS(a), y + r * SIN(a)), c
257.         NEXT
258.     END IF
259. END SUB
260.  
261. FUNCTION rrnd (n1, n2) 'return real number between
262.     rrnd = (n2 - n1) * RND + n1
263. END FUNCTION
264.  
265. FUNCTION distance (x1, y1, x2, y2)
266.     distance = ((x1 - x2) ^ 2 + (y1 - y2) ^ 2) ^ .5
267. END FUNCTION
268.  
269.  

[bplus]

OK here is an easy way. Drawing the basic shape of knot and then drawing in "bridges" to show the overpass/underpass is probably the way human artists might draw the design:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Celtic Knot 2" ' B+ developed in JB, translated to QB64 2019-07-11
3. ' Instead of worrying about 2 circles (or arcs of them) for one ring, draw one circle with really wide pen!
4. ' Draw shape twice with Outline color then Fill color (smaller width) then lay "Bridges"
5. ' over sections for underpass/overpass. Thanks to tsh73 for demo of this method with another Celtic Knot.
6.  
7. CONST xmax = 720, ymax = 720, pi = 3.14159265, xc = xmax / 2, yc = ymax / 2
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _SCREENMOVE 100, 20
10. COLOR , &HFF888888: CLS
11. DIM r
12. r = 350
13. knot2 xc, yc, r, 30, &HFFFFFF00, &HFF008800
14. CIRCLE (xc, yc), r
15. SLEEP
16.  
17. 'for best results: 50+ (pixels) and up for knotR to see details
18. 'max thickness for knotR (impreceise overall radius) is about 10%
19. SUB knot2 (x, y, knotR, thick, outlineC AS _UNSIGNED LONG, fillC AS _UNSIGNED LONG)
20.     DIM hCenterX(6), hCenterY(6), hCX(6), hCY(6)
21.     DIM w, hexAngle, h, hexD2, PD96, tD2
22.     hexAngle = pi / 3: hexD2 = hexAngle / 2: PD96 = pi / 96 '<<<< all angles are refined to 96 parts of semicircle
23.     w = knotR / 15: tD2 = thick / 2
24.     FOR h = 1 TO 6
25.         hCenterX(h) = x + 8 * w * COS(h * hexAngle + pi / 6)
26.         hCenterY(h) = y + 8 * w * SIN(h * hexAngle + pi / 6)
27.         hCX(h) = x + 14 * w * COS(h * hexAngle)
28.         hCY(h) = y + 14 * w * SIN(h * hexAngle)
29.     NEXT
30.     FOR h = 1 TO 6
31.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + pi / 6 + PD96 * 7, h * hexAngle + pi / 6 + PD96 * 185, tD2, outlineC
32.         penArc hCX(h), hCY(h), 6 * w, h * hexAngle + PD96 * 55, h * hexAngle + PD96 * 137, tD2, outlineC
33.     NEXT
34.     FOR h = 1 TO 6
35.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + pi / 6 + PD96 * 7, h * hexAngle + pi / 6 + PD96 * 185, tD2 - 1, fillC
36.         penArc hCX(h), hCY(h), 6 * w, h * hexAngle + PD96 * 55, h * hexAngle + PD96 * 137, tD2 - 1, fillC
37.     NEXT
38.     'bridges
39.     FOR h = 1 TO 6
40.         'boarder color arc 7
41.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 51, h * hexAngle + PD96 * 58, tD2, outlineC
42.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 102, h * hexAngle + PD96 * 109, tD2, outlineC
43.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 148, h * hexAngle + PD96 * 155, tD2, outlineC
44.         penArc hCX(h), hCY(h), 6 * w, h * hexAngle + PD96 * 83, h * hexAngle + PD96 * 90, tD2, outlineC
45.  
46.         'fill color arc 2 before 3 after
47.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 49, h * hexAngle + PD96 * 61, tD2 - 1, fillC
48.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 99, h * hexAngle + PD96 * 111, tD2 - 1, fillC
49.         penArc hCenterX(h), hCenterY(h), 6 * w, h * hexAngle + PD96 * 145, h * hexAngle + PD96 * 158, tD2 - 1, fillC
50.         penArc hCX(h), hCY(h), 6 * w, h * hexAngle + PD96 * 80, h * hexAngle + PD96 * 92, tD2 - 1, fillC
51.     NEXT
52. END SUB
53.  
54. SUB penArc (x, y, r, raStart, raStop, penWidth, c AS _UNSIGNED LONG)
55.     'x, y origin, r = radius, c = color
56.     'raStart is first angle clockwise from due East = 0 degrees
57.     ' arc will start drawing there and clockwise until raStop angle reached
58.     DIM aStep, a
59.     IF raStop < raStart THEN
60.         penArc x, y, r, raStart, pi * 2, penWidth, c
61.         penArc x, y, r, 0, raStop, penWidth, c
62.     ELSE
63.         aStep = 1 / (pi * r * 2)
64.         FOR a = raStart TO raStop STEP aStep
65.             fcirc x + r * COS(a), y + r * SIN(a), penWidth, c
66.         NEXT
67.     END IF
68. END SUB
69.  
70. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
71.     DIM Radius AS INTEGER, RadiusError AS INTEGER
72.     DIM X AS INTEGER, Y AS INTEGER
73.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
74.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
75.     LINE (CX - X, CY)-(CX + X, CY), C, BF
76.     WHILE X > Y
77.         RadiusError = RadiusError + Y * 2 + 1
78.         IF RadiusError >= 0 THEN
79.             IF X <> Y + 1 THEN
80.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
81.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
82.             END IF
83.             X = X - 1
84.             RadiusError = RadiusError - X * 2
85.         END IF
86.         Y = Y + 1
87.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
88.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
89.     WEND
90. END SUB
91.  
92.  

You still eyeball in the 'bridges" but you don't have to be pixel perfect and you dont PAINT. Problem with thickness > 10% of knot radius is that the bridges start to run into other overlapping or "underlapping" (yeah Pete, a new word in my vocabulary!) rings.

[bplus]

To show how effective this method is, I've drawn a Celtic Knot that has no straight lines nor circular arcs, just a single set of fancy sin/cos equations for x, y coordinates:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Celtic Knot 3" ' B+ 2019-07-12
3. ' To demo Celtic Knot mastery, attempt another one!
4.  
5. CONST xmax = 720, ymax = 720, pi = 3.14159265
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 100, 20
8.  
9. DIM rr, w$
10. FOR rr = 30 TO 350 STEP 20
11.     CLS
12.     Knot3 xmax / 2, ymax / 2, rr, .12 * rr, &HFFFFFFFF, &HFFFF000088
13.     CIRCLE (xmax / 2, ymax / 2), rr, &HFFFFFF00
14.     INPUT "OK ..."; w$
15. NEXT
16. SLEEP
17.  
18. 'KnotR tested OK from 30 to 350, thick 1 to 13% knotR, at thick = 1 and 2 just see fillC.
19. SUB Knot3 (xc, yc, knotR, thick, borderC AS _UNSIGNED LONG, fillC AS _UNSIGNED LONG)
20.     DIM p, r, s, t, br, fr, x, y
21.     CONST pm2d3 = pi * 2 / 3 '  all crucial points are 1/3 circle symmetric
22.     r = knotR / 2.6: p = 35 * pi * r: s = 2 * pi / p
23.     br = thick / 2 ' border radius
24.     fr = br - 2 ' fill radius
25.  
26.     'outline whole design
27.     FOR t = 0 TO 2 * _PI STEP s
28.         x = xc + r * (COS(t) + COS(4 * t) / .7 + SIN(2 * t) / 12)
29.         y = yc + r * (SIN(t) + SIN(4 * t) / .7 + COS(2 * t) / 12)
30.         'PSET (x, y)
31.         fcirc x, y, br, borderC
32.         'code to help me find where in the 0 to 2*PI points are
33.         'IF t = 0 THEN fcirc x, y, 3, &HFF0000FF
34.         'IF ABS(t - pi) < .0025 THEN fcirc x, y, 3, &HFF000066
35.     NEXT
36.     'fill in design, same as above only smaller circle fills
37.     FOR t = 0 TO 2 * _PI STEP s
38.         x = xc + r * (COS(t) + COS(4 * t) / .7 + SIN(2 * t) / 12)
39.         y = yc + r * (SIN(t) + SIN(4 * t) / .7 + COS(2 * t) / 12)
40.         'PSET (x, y)
41.         fcirc x, y, fr, fillC
42.     NEXT
43.     'over bridges  borders, locate over the top passes and draw circles over the over pass
44.     FOR t = 0 TO 2 * _PI STEP s
45.         x = xc + r * (COS(t) + COS(4 * t) / .7 + SIN(2 * t) / 12)
46.         y = yc + r * (SIN(t) + SIN(4 * t) / .7 + COS(2 * t) / 12)
47.  
48.         IF ABS(t - pi * 51 / 384) < .11 THEN fcirc x, y, br, borderC
49.         IF ABS(t - pi * 51 / 384 - pm2d3) < .11 THEN fcirc x, y, br, borderC
50.         IF ABS(t - pi * 51 / 384 - 2 * pm2d3) < .11 THEN fcirc x, y, br, borderC
51.  
52.         IF ABS(t - pi * 111 / 384) < .11 THEN fcirc x, y, br, borderC
53.         IF ABS(t - pi * 111 / 384 - pm2d3) < .11 THEN fcirc x, y, br, borderC
54.         IF ABS(t - pi * 111 / 384 - 2 * pm2d3) < .11 THEN fcirc x, y, br, borderC
55.  
56.  
57.         IF ABS(t - pi * 424 / 384) < .11 THEN fcirc x, y, br, borderC
58.         IF ABS(t - pi * 424 / 384 - pm2d3) < .11 THEN fcirc x, y, br, borderC
59.         IF ABS(t - pi * 424 / 384 + 1 * pm2d3) < .11 THEN fcirc x, y, br, borderC
60.  
61.         IF ABS(t - pi * 680 / 384) < .11 THEN fcirc x, y, br, borderC
62.         IF ABS(t - pi * 680 / 384 + 2 * pm2d3) < .11 THEN fcirc x, y, br, borderC
63.         IF ABS(t - pi * 680 / 384 + 1 * pm2d3) < .11 THEN fcirc x, y, br, borderC
64.     NEXT
65.     'over bridges fills , now draw farther up and down the bridge work with the fill color
66.     FOR t = 0 TO 2 * _PI STEP s
67.         x = xc + r * (COS(t) + COS(4 * t) / .7 + SIN(2 * t) / 12)
68.         y = yc + r * (SIN(t) + SIN(4 * t) / .7 + COS(2 * t) / 12)
69.  
70.         IF ABS(t - pi * 51 / 384) < .14 THEN fcirc x, y, fr, fillC
71.         IF ABS(t - pi * 51 / 384 - pm2d3) < .14 THEN fcirc x, y, fr, fillC
72.         IF ABS(t - pi * 51 / 384 - 2 * pm2d3) < .14 THEN fcirc x, y, fr, fillC
73.  
74.         IF ABS(t - pi * 111 / 384) < .14 THEN fcirc x, y, fr, fillC
75.         IF ABS(t - pi * 111 / 384 - pm2d3) < .14 THEN fcirc x, y, fr, fillC
76.         IF ABS(t - pi * 111 / 384 - 2 * pm2d3) < .14 THEN fcirc x, y, fr, fillC
77.  
78.         IF ABS(t - pi * 424 / 384) < .14 THEN fcirc x, y, fr, fillC
79.         IF ABS(t - pi * 424 / 384 - pm2d3) < .14 THEN fcirc x, y, fr, fillC
80.         IF ABS(t - pi * 424 / 384 + 1 * pm2d3) < .14 THEN fcirc x, y, fr, fillC
81.  
82.         IF ABS(t - pi * 680 / 384) < .14 THEN fcirc x, y, fr, fillC
83.         IF ABS(t - pi * 680 / 384 + 2 * pm2d3) < .14 THEN fcirc x, y, fr, fillC
84.         IF ABS(t - pi * 680 / 384 + 1 * pm2d3) < .14 THEN fcirc x, y, fr, fillC
85.     NEXT
86. END SUB
87.  
88. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
89.     DIM Radius AS INTEGER, RadiusError AS INTEGER
90.     DIM X AS INTEGER, Y AS INTEGER
91.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
92.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
93.     LINE (CX - X, CY)-(CX + X, CY), C, BF
94.     WHILE X > Y
95.         RadiusError = RadiusError + Y * 2 + 1
96.         IF RadiusError >= 0 THEN
97.             IF X <> Y + 1 THEN
98.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
99.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
100.             END IF
101.             X = X - 1
102.             RadiusError = RadiusError - X * 2
103.         END IF
104.         Y = Y + 1
105.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
106.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
107.     WEND
108. END SUB
109.  
110.  

[Ashish]

Wonderful Bplus! some very beautiful knots there....
Here are some 3D knots...

Code: QB64: [Select]

1. 'http://paulbourke.net/geometry/knots/
2. _TITLE "3D Knot [Press space for next knot]"
3.  
4. SCREEN _NEWIMAGE(700, 700, 32)
5.  
6. TYPE vec3
7.     x AS SINGLE
8.     y AS SINGLE
9.     z AS SINGLE
10. END TYPE
11. DECLARE LIBRARY
12.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#)
13. END DECLARE
14.  
15. DIM SHARED glAllow AS _BYTE, knot_type, ma
16. knot_type = 1
17. glAllow = -1
18.  
19. DO
20.     k& = _KEYHIT
21.     IF k& = ASC(" ") THEN
22.         knot_type = knot_type + 1
23.         ma = 0
24.         IF knot_type > 7 THEN knot_type = 1
25.     END IF
26.     _LIMIT 60
27. LOOP
28.  
29. SUB _GL ()
30.     STATIC glInit, clock
31.     ' static r, pos, theta, phi, beta
32.  
33.     IF NOT glAllow THEN EXIT SUB
34.  
35.     IF NOT glInit THEN
36.         glInit = -1
37.         aspect# = _WIDTH / _HEIGHT
38.         _glViewport 0, 0, _WIDTH, _HEIGHT
39.     END IF
40.    
41.     _glEnable _GL_DEPTH_TEST
42.     _glDepthMask _GL_TRUE
43.    
44.     _glMatrixMode _GL_PROJECTION
45.     _glLoadIdentity
46.     _gluPerspective 45.0, aspect#, 1.0, 100.0
47.    
48.     _glMatrixMode _GL_MODELVIEW
49.     _glLoadIdentity
50.     ' gluLookAt 0,0,-1,0,0,0,0,1,0
51.    
52.     _glColor3f 1, 1, 1
53.     _glTranslatef 0, 0, 0
54.     _glRotatef clock * 90, 0, 1, 0
55.     _glLineWidth 10.0
56.    
57.     SELECT CASE knot_type
58.         CASE 7
59.             _glBegin _GL_LINE_STRIP
60.             FOR beta = 0 TO ma STEP .005
61.                 r = .3 + .6 * SIN(6 * beta)
62.                 theta = 2 * beta
63.                 phi = _PI(.6) * SIN(12 * beta)
64.                 x = r * COS(phi) * COS(theta)
65.                 y = r * COS(phi) * SIN(theta)
66.                 z = r * SIN(phi)
67.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
68.                 _glVertex3f x, y, z
69.             NEXT
70.             _glEnd
71.             IF ma <= _PI THEN ma = ma + .005
72.         CASE 6
73.             _glBegin _GL_LINE_STRIP
74.             FOR beta = 0 TO ma STEP .005
75.                 r = 1.2 * 0.6 * SIN(_PI(.5) * 6 * beta)
76.                 theta = 4 * beta
77.                 phi = _PI(.2) * SIN(6 * beta)
78.                 x = r * COS(phi) * COS(theta)
79.                 y = r * COS(phi) * SIN(theta)
80.                 z = r * SIN(phi)
81.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
82.                 _glVertex3f x, y, z
83.             NEXT
84.             _glEnd
85.             IF ma <= _PI(2) THEN ma = ma + .005
86.         CASE 5
87.             k = 1
88.             _glBegin _GL_LINE_STRIP
89.             FOR u = 0 TO ma STEP .005
90.                 x = COS(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
91.                 y = SIN(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
92.                 z = -SIN(2 * u / (2 * k + 1)) / 5
93.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
94.                 _glVertex3f x, y, z
95.             NEXT
96.             _glEnd
97.             IF ma < _PI(4 * k + 2) THEN ma = ma + .045
98.         CASE 4
99.             k = 2
100.             _glBegin _GL_LINE_STRIP
101.             FOR u = 0 TO ma STEP .005
102.                 x = COS(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
103.                 y = SIN(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
104.                 z = -SIN(2 * u / (2 * k + 1)) / 5
105.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
106.                 _glVertex3f x, y, z
107.             NEXT
108.             _glEnd
109.             IF ma < _PI(4 * k + 2) THEN ma = ma + .045
110.         CASE 3
111.             k = 3
112.             _glBegin _GL_LINE_STRIP
113.             FOR u = 0 TO ma STEP .005
114.                 x = COS(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
115.                 y = SIN(u) * (2 - COS(2 * u / (2 * k + 1))) / 5
116.                 z = -SIN(2 * u / (2 * k + 1)) / 5
117.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
118.                 _glVertex3f x, y, z
119.             NEXT
120.             _glEnd
121.             IF ma < _PI(4 * k + 2) THEN ma = ma + .045
122.         CASE 2
123.             _glBegin _GL_LINE_STRIP
124.             FOR u = 0 TO ma STEP .005
125.                 x = (41 * COS(u) - 18 * SIN(u) - 83 * COS(2 * u) - 83 * SIN(2 * u) - 11 * COS(3 * u) + 27 * SIN(3 * u)) / 200
126.                 y = (36 * COS(u) + 27 * SIN(u) - 113 * COS(2 * u) + 30 * SIN(2 * u) + 11 * COS(3 * u) - 27 * SIN(3 * u)) / 200
127.                 z = (45 * SIN(u) - 30 * COS(2 * u) + 113 * SIN(2 * u) - 11 * COS(3 * u) + 27 * SIN(3 * u)) / 200
128.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
129.                 _glVertex3f x, y, z
130.             NEXT
131.             _glEnd
132.             IF ma < _PI(2) THEN ma = ma + .005
133.         CASE 1
134.             _glBegin _GL_LINE_STRIP
135.             FOR u = 0 TO ma STEP .005
136.                 x = (-22 * COS(u) - 128 * SIN(u) - 44 * COS(3 * u) - 78 * SIN(3 * u)) / 200
137.                 y = (-10 * COS(2 * u) - 27 * SIN(2 * u) + 38 * COS(4 * u) + 46 * SIN(4 * u)) / 200
138.                 z = (70 * COS(3 * u) - 40 * SIN(3 * u)) / 200
139.                 _glColor3f map(x, -1, 1, 0, 1), map(y, -1, 1, 0, 1), map(z, -1, 1, 0, 1)
140.                 _glVertex3f x, y, z
141.             NEXT
142.             _glEnd
143.             IF ma < _PI(2) THEN ma = ma + .01
144.     END SELECT
145.     _glFlush
146.    
147.     clock = clock + .01
148. END SUB
149.  
150. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
151.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
152. END FUNCTION
153.  
154.