CatChum for CP/M

[FellippeHeitor]

This is the idea:

Screenshot attached.

Code: QB64: [Select]

1. $RESIZE:STRETCH
2. SCREEN _NEWIMAGE(52, 24, 0)
3.  
4. _TITLE "CatChum for CP/M"
5.  
6. COLOR 2 'for a phosphor look
7.  
8. _CONTROLCHR OFF
9.  
10. CONST true = -1, false = NOT true
11. CONST powerPelletMAX = 7 'duration of the power pellet effects
12.  
13. TYPE new_DOT
14.     x AS INTEGER
15.     y AS INTEGER
16.     state AS _BYTE '0 = taken; 1 = dot; 2 = power pellet
17. END TYPE
18.  
19. DIM SHARED dot(1 TO 201) AS new_DOT
20. DIM SHARED mapData(1 TO 23) AS STRING
21. DIM SHARED PacMan AS new_DOT
22. DIM SHARED ghost(1 TO 4) AS new_DOT
23. DIM SHARED direction AS _BYTE, nextDirection AS _BYTE
24. DIM SHARED endGame AS _BYTE, lastMove!
25. DIM SHARED score AS LONG, powerPelletTimer AS SINGLE
26.  
27. DO
28.     setupMap
29.     setupDots
30.     endGame = false
31.     direction = 1
32.     lastMove! = 0
33.  
34.     DO
35.         CLS
36.         processInput
37.         movePacMan
38.         detectColision
39.  
40.         drawLabyrinth
41.         IF NOT _KEYDOWN(100306) THEN drawItems
42.  
43.         _PRINTSTRING (1, 24), STR$(score)
44.         _DISPLAY
45.         _LIMIT 30
46.     LOOP UNTIL endGame
47. LOOP
48.  
49. SUB detectColision
50.     FOR i = 1 TO UBOUND(dot)
51.         IF dot(i).x = PacMan.x AND dot(i).y = PacMan.y THEN
52.             SELECT CASE dot(i).state
53.                 CASE 1
54.                     'dot
55.                     score = score + 10
56.                     dot(i).state = 0
57.                 CASE 2
58.                     'power pellet
59.                     score = score + 20
60.                     dot(i).state = 0
61.                     powerPelletTimer = TIMER
62.             END SELECT
63.         END IF
64.     NEXT
65. END SUB
66.  
67. SUB movePacMan
68.     STATIC didMove AS _BYTE
69.  
70.     DIM refreshRate!
71.  
72.     IF direction = 1 OR direction = 3 THEN refreshRate! = .1
73.     IF direction = 2 OR direction = 4 THEN refreshRate! = .12
74.  
75.     IF TIMER - lastMove! < refreshRate! THEN EXIT SUB
76.  
77.     IF didMove = false AND lastMove! > 0 THEN direction = 0
78.  
79.     lastMove! = TIMER
80.  
81.     'same axis changes are immediately applied
82.     SELECT CASE nextDirection
83.         CASE 1, 3
84.             IF direction = 1 OR direction = 3 THEN direction = nextDirection: nextDirection = 0
85.         CASE 2, 4
86.             IF direction = 2 OR direction = 4 THEN direction = nextDirection: nextDirection = 0
87.     END SELECT
88.  
89.     IF direction = 0 THEN direction = nextDirection
90.  
91.     DIM prevDirection AS _BYTE
92.  
93.     IF nextDirection THEN
94.         prevDirection = direction
95.         direction = nextDirection
96.     END IF
97.  
98.     didMove = false
99.     DIM i AS INTEGER
100.     FOR i = 1 TO 2
101.         SELECT CASE direction
102.             CASE 1 'left
103.                 IF PacMan.x > 1 THEN
104.                     IF ASC(mapData(PacMan.y), PacMan.x - 1) = 32 THEN
105.                         PacMan.x = PacMan.x - 1
106.                         didMove = true
107.                         EXIT FOR
108.                     ELSE
109.                         IF prevDirection THEN
110.                             nextDirection = direction
111.                             direction = prevDirection
112.                         END IF
113.                     END IF
114.                 ELSE 'warp
115.                     PacMan.x = LEN(mapData(1))
116.                     didMove = true
117.                 END IF
118.             CASE 2 'up
119.                 IF PacMan.y > 1 THEN
120.                     IF ASC(mapData(PacMan.y - 1), PacMan.x) = 32 THEN
121.                         PacMan.y = PacMan.y - 1
122.                         didMove = true
123.                         EXIT FOR
124.                     ELSE
125.                         IF prevDirection THEN
126.                             nextDirection = direction
127.                             direction = prevDirection
128.                         END IF
129.                     END IF
130.                 ELSE 'warp
131.                     PacMan.y = 23
132.                     didMove = true
133.                 END IF
134.             CASE 3 'right
135.                 IF PacMan.x < LEN(mapData(1)) THEN
136.                     IF ASC(mapData(PacMan.y), PacMan.x + 1) = 32 THEN
137.                         PacMan.x = PacMan.x + 1
138.                         didMove = true
139.                         EXIT FOR
140.                     ELSE
141.                         IF prevDirection THEN
142.                             nextDirection = direction
143.                             direction = prevDirection
144.                         END IF
145.                     END IF
146.                 ELSE 'warp
147.                     PacMan.x = 1
148.                     didMove = true
149.                 END IF
150.             CASE 4 'down
151.                 IF PacMan.y < 23 THEN
152.                     IF ASC(mapData(PacMan.y + 1), PacMan.x) = 32 THEN
153.                         PacMan.y = PacMan.y + 1
154.                         didMove = true
155.                         EXIT FOR
156.                     ELSE
157.                         IF prevDirection THEN
158.                             nextDirection = direction
159.                             direction = prevDirection
160.                         END IF
161.                     END IF
162.                 ELSE 'warp
163.                     PacMan.y = 1
164.                     didMove = true
165.                 END IF
166.         END SELECT
167.     NEXT
168. END SUB
169.  
170. SUB processInput
171.     DIM k AS LONG
172.  
173.     k = _KEYHIT
174.     IF k = 27 THEN endGame = true
175.  
176.     IF _KEYDOWN(19200) THEN nextDirection = 1
177.     IF _KEYDOWN(18432) THEN nextDirection = 2
178.     IF _KEYDOWN(19712) THEN nextDirection = 3
179.     IF _KEYDOWN(20480) THEN nextDirection = 4
180. END SUB
181.  
182. SUB setupMap
183.     DIM i AS INTEGER
184.  
185.     RESTORE
186.     FOR i = 1 TO 23
187.         READ mapData(i)
188.     NEXT
189. END SUB
190.  
191. SUB setupDots
192.     DIM i AS INTEGER
193.  
194.     FOR i = 1 TO 23
195.         DIM c AS INTEGER, thisDot AS INTEGER, thisGhost AS INTEGER
196.  
197.         FOR c = 1 TO LEN(mapData(i))
198.             SELECT CASE ASC(mapData(i), c)
199.                 CASE 46
200.                     'dot
201.                     ASC(mapData(i), c) = 32
202.                     thisDot = thisDot + 1
203.                     dot(thisDot).x = c
204.                     dot(thisDot).y = i
205.                     dot(thisDot).state = 1
206.                 CASE 111
207.                     'power pellet
208.                     ASC(mapData(i), c) = 32
209.                     thisDot = thisDot + 1
210.                     dot(thisDot).x = c
211.                     dot(thisDot).y = i
212.                     dot(thisDot).state = 2
213.                 CASE 65
214.                     'ghost
215.                     ASC(mapData(i), c) = 32
216.                     thisGhost = thisGhost + 1
217.                     ghost(thisGhost).x = c
218.                     ghost(thisGhost).y = i
219.                     ghost(thisGhost).state = true
220.                 CASE 67
221.                     'PacMan
222.                     ASC(mapData(i), c) = 32
223.                     PacMan.x = c
224.                     PacMan.y = i
225.                 CASE 35
226.                     'wall separator
227.                     ASC(mapData(i), c) = 0
228.             END SELECT
229.         NEXT
230.     NEXT
231. END SUB
232.  
233. SUB drawLabyrinth
234.     DIM i AS INTEGER
235.  
236.     FOR i = 1 TO 23
237.         _PRINTSTRING (3, i), mapData(i)
238.     NEXT
239. END SUB
240.  
241. SUB drawItems
242.     DIM i AS INTEGER, c$
243.  
244.     FOR i = 1 TO UBOUND(dot)
245.         c$ = " "
246.         IF dot(i).state = 1 THEN c$ = "."
247.         IF dot(i).state = 2 THEN c$ = "o"
248.         _PRINTSTRING (2 + dot(i).x, dot(i).y), c$
249.     NEXT
250.  
251.     SELECT CASE direction
252.         CASE 0
253.             PacManChar$ = "C"
254.         CASE 1, 3 'left or right
255.             IF PacMan.x MOD 2 = 0 THEN PacManChar$ = "C" ELSE PacManChar$ = "c"
256.         CASE 2, 4 'up or down
257.             IF PacMan.y MOD 2 <> 0 THEN PacManChar$ = "C" ELSE PacManChar$ = "c"
258.     END SELECT
259.  
260.     _PRINTSTRING (2 + PacMan.x, PacMan.y), PacManChar$
261.  
262.     IF TIMER - powerPelletTimer < powerPelletMAX THEN ghostChar$ = "m" ELSE ghostChar$ = "A"
263.  
264.     FOR i = 1 TO UBOUND(ghost)
265.         _PRINTSTRING (2 + ghost(i).x, ghost(i).y), ghostChar$
266.     NEXT
267. END SUB
268.  
269. 'Map data
270. DATA "+-------------------+# #+# #+-------------------+"
271. DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
272. DATA "|#.#+-----+#.#+-----+#.#|#.#+-----+#.#+-----+#.#|"
273. DATA "|#o#|     |#.#|     |#.#|#.#|     |#.#|     |#o#|"
274. DATA "|#.#+-----+#.#+-----+#.#|#.#+-----+#.#+-----+#.#|"
275. DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
276. DATA "|#.#-------#.#|#.#------+------#.#|#.#-------#.#|"
277. DATA "|#. . . . . .#|#. . . .#|#. . . .#|#. . . . . .#|"
278. DATA "+---------+#.#------+# #|# #+-----+#.#+---------+"
279. DATA "          |#.#|#                 #|#.#|          "
280. DATA "----------+#.#|# #+-----#-----+# #|#.#+----------"
281. DATA "            .    #|  A A A A  |#    .            "
282. DATA "----------+#.#|# #+-----#-----+# #|#.#+----------"
283. DATA "          |#.#|#                 #|#.#|          "
284. DATA "+---------+#.#|# #------+------# #|#.#+---------+"
285. DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
286. DATA "|#.#------+#.#-------#.#|#.#-------#.#+------#.#|"
287. DATA "|#o . . .#|#. . . . . . C . . . . . .#|#. . . o#|"
288. DATA "+------#.#|#.#|# #-------------# #|#.#|#.#------+"
289. DATA "|#. . . . . .#|#. . . . . . . . .#|#. . . . . .#|"
290. DATA "|#.#----------+------#.#|#.#------+----------#.#|"
291. DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
292. DATA "+-------------------+# #+# #+-------------------+"
293.  

I'll be posting the progress here as I go.

[Ashish]

Nice! I like it! :)

[keybone]

Wow, CP/M. Now thats oldschool. :)

[Aureal]

I like it a lot!

[Petr]

Hi, nice game!

[SMcNeill]

If you're looking to reproduce authentic style Pacman gameplay, you might want to take a look at this link: http://gameinternals.com/post/2072558330/understanding-pac-man-ghost-behavior

That does the best job of any write up which I've ever seen, explaining how the Ghost AI behaves and operates in Pacman.  It might be of some use to you.  ;)

[FellippeHeitor]

Thanks for sharing the link, Steve!

I'd looked at that article before, and it kinda slowed me down, as I figured it'd be harder than just chasing Pacman. This updated version in the attachment has ghosts doing just that, chasing Pacman blindly.

Maybe I'll get to it when I'm on vacation again.

PS: Hit "m" for a more "modern" look, as in the screenshot.

PS2: Ghosts are harmless for now.

[Petr]

Hi Fellippe, on line 139 - its new command _CONTINUE ? My IDE write syntax error for this, i comment this line and then it start. I like new graphic after m press.

[FellippeHeitor]

Hi Petr.

Yes, _CONTINUE is a new QB64 statement introduced in build 20170628/55. It works exactly like its C counterpart:

The continue statement in C programming works somewhat like the break statement. Instead of forcing termination, it forces the next iteration of the loop to take place, skipping any code in between.

From https://www.tutorialspoint.com/cprogramming/c_continue_statement.htm

It's a shortcut to a goto, and if you look in the C++ output, that's exactly what it does. Take the code below:

Code: QB64: [Select]

1. FOR i = 1 to 10
2.     IF i = 5 THEN GOTO skip
3.     PRINT i;
4.     skip:
5. NEXT

You can write the same using _CONTINUE as follows:

Code: QB64: [Select]

1. FOR i = 1 to 10
2.     IF i = 5 THEN _CONTINUE
3.     PRINT i;
4. NEXT

Both will output:

1 2 3 4 6 7 8 9 10

You can also use _CONTINUE in DO/LOOP and WHILE/WEND blocks, with the same purpose of skipping to the end of the block without exiting it.

[Petr]

Hi FellippeHeitor, thank you for your clear explanation. So it's time to upgrade my IDE ...