Seeking best ellipse fill function. (For everyone's sake.)

[bplus]

For the record, Titled Ellipse Fill does not compare well with CIRCLE with same radius as a and aspect b/a. Look at what happens when b exceeds a! but I am supposed to switch radius for CIRCLE when b > a.

Are you knocking down straw men intentionally, or just need some coffee?

I could use some more sleep but I am seeing with the comparison code that CIRCLE must be drawing ellipse (using aspect) with an entirely different method than any discussed here ie pretty good overlap on left side, complete miss on right.

[SMcNeill]

Circle is easy to find, complicated to work on.  Just open libqb.cpp and search “circle”— it’s the first result I found.  (Sub__circle, or something similar, is the actual name.)

From memory, first section of code is declarations, followed by boundary checks (make certain the circle is being drawn inside the viewports), followed by the actual plotting routine at the end.

One thing to keep in mind: Circle also plots arcs; not just circles.  To adapt the existing code to a fill routine, you’d basically need to plot lines inside that arc routine.

Which, really, I wouldn’t mind seeing a fast arc fill routine to boot.  ;)

[bplus]

B+

In meantime, I am keeping CircleFill in my tool box...

STATIC

Based on the outline/pixels issue, I agree with this. Do you mind posting your freshest copy of the function? Be sure to nerf it down to handle just circles, which I imagine render without boobs.

Code: QB64: [Select]

1. 'from Steve Gold standard
2. SUB fcirc0 (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
3.     DIM Radius AS INTEGER, RadiusError AS INTEGER
4.     DIM X AS INTEGER, Y AS INTEGER
5.  
6.     Radius = ABS(R)
7.     RadiusError = -Radius
8.     X = Radius
9.     Y = 0
10.  
11.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
12.  
13.     ' Draw the middle span here so we don't draw it twice in the main loop,
14.     ' which would be a problem with blending turned on.
15.     LINE (CX - X, CY)-(CX + X, CY), C, BF
16.  
17.     WHILE X > Y
18.         RadiusError = RadiusError + Y * 2 + 1
19.         IF RadiusError >= 0 THEN
20.             IF X <> Y + 1 THEN
21.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
22.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
23.             END IF
24.             X = X - 1
25.             RadiusError = RadiusError - X * 2
26.         END IF
27.         Y = Y + 1
28.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
29.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
30.     WEND
31.  
32. END SUB
33.  

Here is consolidation of speed tests with other Circle Fills tried:

Code: QB64: [Select]

1. _TITLE "Circle Fill speed tests"
2. SCREEN _NEWIMAGE(1220, 680, 32)
3. _SCREENMOVE 100, 20
4. _DELAY 1
5. ntests = 100000 'it takes a really long run to prove Gold Standard Speed 167.9 versus vince 168.1
6. ntests = 1000 'fast elimination
7.  
8. 'It has been noticed that the one going first has a disadvantage
9.  
10. start## = TIMER 'this runs the Gold standard to beat  on Right Side of screen
11. FOR i = 1 TO ntests
12.     fcirc0 915, 305, 300, _RGBA32(0, 100, 0, 100)
13. NEXT
14. finish## = TIMER - start##
15. _PRINTSTRING (700, 615), "Time for" + STR$(ntests) + " Gold Standard Circle Fills:" + STR$(finish##)
16.  
17. ' ==================================================== the contender on left of screen
18.  
19. start## = TIMER
20. FOR i = 1 TO ntests
21.     fCirc4 305, 305, 300, _RGBA32(0, 100, 0, 100)
22. NEXT
23. finish## = TIMER - start##
24. _PRINTSTRING (100, 615), "Time for" + STR$(ntests) + " Contender Fills:" + STR$(finish##)
25.  
26. 'from Steve Gold standard
27. SUB fcirc0 (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
28.     DIM Radius AS INTEGER, RadiusError AS INTEGER
29.     DIM X AS INTEGER, Y AS INTEGER
30.  
31.     Radius = ABS(R)
32.     RadiusError = -Radius
33.     X = Radius
34.     Y = 0
35.  
36.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
37.  
38.     ' Draw the middle span here so we don't draw it twice in the main loop,
39.     ' which would be a problem with blending turned on.
40.     LINE (CX - X, CY)-(CX + X, CY), C, BF
41.  
42.     WHILE X > Y
43.         RadiusError = RadiusError + Y * 2 + 1
44.         IF RadiusError >= 0 THEN
45.             IF X <> Y + 1 THEN
46.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
47.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
48.             END IF
49.             X = X - 1
50.             RadiusError = RadiusError - X * 2
51.         END IF
52.         Y = Y + 1
53.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
54.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
55.     WEND
56.  
57. END SUB
58.  
59.  
60. 'vince's circle fill   this one does not bother with types good almost identical to Steve's
61. SUB fcirc1 (x, y, r, c AS _UNSIGNED LONG)
62.     x0 = r
63.     y0 = 0
64.     e = -r
65.     DO WHILE y0 < x0
66.         IF e <= 0 THEN
67.             y0 = y0 + 1
68.             LINE (x - x0, y + y0)-(x + x0, y + y0), c, BF
69.             LINE (x - x0, y - y0)-(x + x0, y - y0), c, BF
70.             e = e + 2 * y0
71.         ELSE
72.             LINE (x - y0, y - x0)-(x + y0, y - x0), c, BF
73.             LINE (x - y0, y + x0)-(x + y0, y + x0), c, BF
74.             x0 = x0 - 1
75.             e = e - 2 * x0
76.         END IF
77.     LOOP
78.     LINE (x - r, y)-(x + r, y), c, BF
79. END SUB
80.  
81. 'this does not overlap with circle well 2.13 x's Gold Time
82. SUB fCirc2 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
83.     DIM r2 AS LONG, x AS LONG, y AS LONG, xstop AS LONG
84.     r2 = r * r
85.     x = 1
86.     xstop = r + 1
87.     WHILE x < xstop 'remove FOR loop
88.         y = SQR(r2 - x * x)
89.         LINE (xx - x, yy + y)-(xx - x, yy - y), K, BF
90.         LINE (xx + x, yy + y)-(xx + x, yy - y), K, BF
91.         x = x + 1
92.     WEND
93.     LINE (xx, yy - r)-(xx, yy + r), K, BF
94. END SUB
95.  
96. 'andy amaya's version from SB, way too much overlapping!   Junk as is but 1.1 Gold Standard Time
97. SUB fCirc3 (CX AS LONG, CY AS LONG, R AS LONG, K AS _UNSIGNED LONG) 'thanks Andy Amaya for heads up
98.     DIM x AS LONG, y AS LONG, Xchange AS INTEGER, yChange AS INTEGER, RadiusError AS INTEGER
99.     x = R
100.     y = 0
101.     Xchange = 1 - 2 * R
102.     yChange = 1
103.     RadiusError = 0
104.  
105.     WHILE x >= y
106.         LINE (CX - x, CY + y)-(CX + x, CY + y), K, BF ';used calc'd values to draw
107.         LINE (CX - x, CY - y)-(CX + x, CY - y), K, BF ';scan lines from points
108.         LINE (CX - y, CY + x)-(CX + y, CY + x), K, BF ';in opposite octants
109.         LINE (CX - y, CY - x)-(CX + y, CY - x), K, BF
110.         y = y + 1
111.         RadiusError = RadiusError + yChange
112.         yChange = yChange + 2
113.  
114.         IF 2 * RadiusError + Xchange > 0 THEN
115.             x = x - 1
116.             RadiusError = RadiusError + Xchange
117.             Xchange = Xchange + 2
118.         END IF
119.     WEND
120. END SUB
121.  
122. 'fCirc but doing octants until get to square, then just do square fill! 1.18 Gold Sdt
123. 'this is closer to matching the Gold Standard
124. SUB fCirc4 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
125.     DIM r2 AS LONG, t AS LONG, dist AS LONG, tstop AS LONG
126.     r2 = r * r
127.     t = r 'r - 1 gets rid of nipples but...
128.     tstop = r * .707106781
129.     WHILE t > tstop 'remove FOR loop
130.         dist = SQR(r2 - t * t) ' + .5 for rounding down
131.         LINE (xx - t, yy + dist)-(xx - t, yy - dist), K, BF
132.         LINE (xx + t, yy + dist)-(xx + t, yy - dist), K, BF
133.         LINE (xx + dist, yy + t)-(xx - dist, yy + t), K, BF
134.         LINE (xx + dist, yy - t)-(xx - dist, yy - t), K, BF
135.         t = t - 1
136.     WEND
137.     LINE (xx - tstop, yy - tstop)-(xx + tstop, yy + tstop), K, BF
138. END SUB
139.  
140. 'add a routine for sqr root   1,16 X's Gold Std
141. SUB fCirc5 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
142.     DIM r2 AS LONG, t AS LONG, tstop AS LONG
143.     DIM dist1 AS SINGLE, dist AS SINGLE, dist2 AS LONG, s AS LONG
144.     r2 = r * r
145.     t = r 'r - 1 gets rid of nipples but...
146.     tstop = r * .707106781
147.     WHILE t > tstop 'remove FOR loop
148.  
149.         'VVVVVVVVVVVVVVVVVVV this might now save a shade off SQR
150.         s = r2 - t * t
151.         dist = s / 10
152.         dist2 = dist * dist
153.         'WHILE ABS(dist ^ 2 - s) >= 1  'no! avoid function calls!
154.         WHILE dist2 - s > 1 OR dist2 - s < -1
155.             dist = .5 * (dist + s / dist)
156.             dist2 = dist * dist
157.         WEND
158.  
159.         'VVVVVVVVVVVVVVVVV  faster to use this YES
160.         'dist = SQR(r2 - t * t) ' + .5 for rounding down
161.  
162.  
163.         LINE (xx - t, yy + dist)-(xx - t, yy - dist), K, BF
164.         LINE (xx + t, yy + dist)-(xx + t, yy - dist), K, BF
165.         LINE (xx + dist, yy + t)-(xx - dist, yy + t), K, BF
166.         LINE (xx + dist, yy - t)-(xx - dist, yy - t), K, BF
167.         t = t - 1
168.     WEND
169.     LINE (xx - tstop, yy - tstop)-(xx + tstop, yy + tstop), K, BF
170. END SUB
171.  
172. 'too slow, dest can't just be 0  Junk as is
173. SUB fcirc6 (xOrigin AS LONG, yOrigin AS LONG, radius AS LONG, K AS _UNSIGNED LONG)
174.     a& = _NEWIMAGE(1, 1, 32)
175.     _DEST a&
176.     PSET (0, 0), K
177.     _DEST 0
178.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, i AS INTEGER
179.     DIM polyAngle AS SINGLE
180.     polyAngle = _PI(2) / 60
181.     x1 = xOrigin + radius * COS(polyAngle)
182.     y1 = yOrigin + radius * SIN(polyAngle)
183.     FOR i = 2 TO 61
184.         x2 = xOrigin + radius * COS(i * polyAngle)
185.         y2 = yOrigin + radius * SIN(i * polyAngle)
186.         _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a& TO(xOrigin, yOrigin)-(x1, y1)-(x2, y2), 0
187.         x1 = x2: y1 = y2
188.     NEXT
189.     _FREEIMAGE a& '<<< this is important!
190. END SUB
191.  

Here is consolidation of size and overlap with circle tests (checking for nipples, or dots... BTW discovered from these tests, the CIRCLE sub overlaps itself at 0, 90, 180, 270 degrees!):

Code: QB64: [Select]

1. _TITLE "CircleFill Overlap test"
2. SCREEN _NEWIMAGE(1000, 700, 32)
3. _SCREENMOVE 180, 20
4. 'B+ 2019-02-10 resave this code to
5. 'just test this code for proper filling without overlap, timed tests are else where
6.  
7. FOR i = 0 TO 200 'draw circle at various radii
8.     CLS
9.     PRINT "Radius"; i; "   press any to add until get to 200, <backspace> to go back one, <esc> for next test."
10.     'CIRCLE (500, 350), i, _RGBA(255, 255, 255, 40)
11.     fcirc6 500, 350, i, _RGBA(255, 255, 255, 100)
12.     k$ = ""
13.     WHILE LEN(k$) = 0: k$ = INKEY$: WEND
14.     IF k$ = CHR$(8) THEN i = i - 2
15.     IF k$ = CHR$(27) THEN EXIT FOR
16. NEXT
17.  
18. 'from Steve Gold standard
19. SUB fcirc0 (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
20.     DIM Radius AS INTEGER, RadiusError AS INTEGER
21.     DIM X AS INTEGER, Y AS INTEGER
22.  
23.     Radius = ABS(R)
24.     RadiusError = -Radius
25.     X = Radius
26.     Y = 0
27.  
28.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
29.  
30.     ' Draw the middle span here so we don't draw it twice in the main loop,
31.     ' which would be a problem with blending turned on.
32.     LINE (CX - X, CY)-(CX + X, CY), C, BF
33.  
34.     WHILE X > Y
35.         RadiusError = RadiusError + Y * 2 + 1
36.         IF RadiusError >= 0 THEN
37.             IF X <> Y + 1 THEN
38.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
39.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
40.             END IF
41.             X = X - 1
42.             RadiusError = RadiusError - X * 2
43.         END IF
44.         Y = Y + 1
45.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
46.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
47.     WEND
48.  
49. END SUB
50.  
51.  
52. 'vince's circle fill   this one does not bother with types good almost identical to Steve's
53. SUB fcirc1 (x, y, r, c AS _UNSIGNED LONG)
54.     x0 = r
55.     y0 = 0
56.     e = -r
57.     DO WHILE y0 < x0
58.         IF e <= 0 THEN
59.             y0 = y0 + 1
60.             LINE (x - x0, y + y0)-(x + x0, y + y0), c, BF
61.             LINE (x - x0, y - y0)-(x + x0, y - y0), c, BF
62.             e = e + 2 * y0
63.         ELSE
64.             LINE (x - y0, y - x0)-(x + y0, y - x0), c, BF
65.             LINE (x - y0, y + x0)-(x + y0, y + x0), c, BF
66.             x0 = x0 - 1
67.             e = e - 2 * x0
68.         END IF
69.     LOOP
70.     LINE (x - r, y)-(x + r, y), c, BF
71. END SUB
72.  
73. 'this does not overlap with circle well
74. SUB fCirc2 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
75.     DIM r2 AS LONG, x AS LONG, y AS LONG, xstop AS LONG
76.     r2 = r * r
77.     x = 1
78.     xstop = r + 1
79.     WHILE x < xstop 'remove FOR loop
80.         y = SQR(r2 - x * x)
81.         LINE (xx - x, yy + y)-(xx - x, yy - y), K, BF
82.         LINE (xx + x, yy + y)-(xx + x, yy - y), K, BF
83.         x = x + 1
84.     WEND
85.     LINE (xx, yy - r)-(xx, yy + r), K, BF
86. END SUB
87.  
88. 'andy amaya's version from SB, way too much overlapping!   Junk as is
89. SUB fCirc3 (CX AS LONG, CY AS LONG, R AS LONG, K AS _UNSIGNED LONG) 'thanks Andy Amaya for heads up
90.     DIM x AS LONG, y AS LONG, Xchange AS INTEGER, yChange AS INTEGER, RadiusError AS INTEGER
91.     x = R
92.     y = 0
93.     Xchange = 1 - 2 * R
94.     yChange = 1
95.     RadiusError = 0
96.  
97.     WHILE x >= y
98.         LINE (CX - x, CY + y)-(CX + x, CY + y), K, BF ';used calc'd values to draw
99.         LINE (CX - x, CY - y)-(CX + x, CY - y), K, BF ';scan lines from points
100.         LINE (CX - y, CY + x)-(CX + y, CY + x), K, BF ';in opposite octants
101.         LINE (CX - y, CY - x)-(CX + y, CY - x), K, BF
102.         y = y + 1
103.         RadiusError = RadiusError + yChange
104.         yChange = yChange + 2
105.  
106.         IF 2 * RadiusError + Xchange > 0 THEN
107.             x = x - 1
108.             RadiusError = RadiusError + Xchange
109.             Xchange = Xchange + 2
110.         END IF
111.     WEND
112. END SUB
113.  
114. 'fCirc but doing octants until get to square, then just do square fill!
115. 'this is closer to matching the Gold Standard
116. SUB fCirc4 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
117.     DIM r2 AS LONG, t AS LONG, dist AS LONG, tstop AS LONG
118.     r2 = r * r
119.     t = r 'r - 1 gets rid of nipples but...
120.     tstop = r * .707106781
121.     WHILE t > tstop 'remove FOR loop
122.         dist = SQR(r2 - t * t) ' + .5 for rounding down
123.         LINE (xx - t, yy + dist)-(xx - t, yy - dist), K, BF
124.         LINE (xx + t, yy + dist)-(xx + t, yy - dist), K, BF
125.         LINE (xx + dist, yy + t)-(xx - dist, yy + t), K, BF
126.         LINE (xx + dist, yy - t)-(xx - dist, yy - t), K, BF
127.         t = t - 1
128.     WEND
129.     LINE (xx - tstop, yy - tstop)-(xx + tstop, yy + tstop), K, BF
130. END SUB
131.  
132. 'add a routine for sqr root
133. SUB fCirc5 (xx AS LONG, yy AS LONG, r AS LONG, K AS _UNSIGNED LONG)
134.     DIM r2 AS LONG, t AS LONG, tstop AS LONG
135.     DIM dist1 AS SINGLE, dist AS SINGLE, dist2 AS LONG, s AS LONG
136.     r2 = r * r
137.     t = r 'r - 1 gets rid of nipples but...
138.     tstop = r * .707106781
139.     WHILE t > tstop 'remove FOR loop
140.  
141.         'VVVVVVVVVVVVVVVVVVV this might now save a shade off SQR
142.         s = r2 - t * t
143.         dist = s / 10
144.         dist2 = dist * dist
145.         'WHILE ABS(dist ^ 2 - s) >= 1  'no! avoid function calls!
146.         WHILE dist2 - s > 1 OR dist2 - s < -1
147.             dist = .5 * (dist + s / dist)
148.             dist2 = dist * dist
149.         WEND
150.  
151.         'VVVVVVVVVVVVVVVVV  faster to use this YES
152.         'dist = SQR(r2 - t * t) ' + .5 for rounding down
153.  
154.  
155.         LINE (xx - t, yy + dist)-(xx - t, yy - dist), K, BF
156.         LINE (xx + t, yy + dist)-(xx + t, yy - dist), K, BF
157.         LINE (xx + dist, yy + t)-(xx - dist, yy + t), K, BF
158.         LINE (xx + dist, yy - t)-(xx - dist, yy - t), K, BF
159.         t = t - 1
160.     WEND
161.     LINE (xx - tstop, yy - tstop)-(xx + tstop, yy + tstop), K, BF
162. END SUB
163.  
164. 'terrible overlap too slow, dest can't just be 0  Junk as is
165. SUB fcirc6 (xOrigin AS LONG, yOrigin AS LONG, radius AS LONG, K AS _UNSIGNED LONG)
166.     a& = _NEWIMAGE(1, 1, 32)
167.     _DEST a&
168.     PSET (0, 0), K
169.     _DEST 0
170.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, i AS INTEGER
171.     DIM polyAngle AS SINGLE
172.     polyAngle = _PI(2) / 60
173.     x1 = xOrigin + radius * COS(polyAngle)
174.     y1 = yOrigin + radius * SIN(polyAngle)
175.     FOR i = 2 TO 61
176.         x2 = xOrigin + radius * COS(i * polyAngle)
177.         y2 = yOrigin + radius * SIN(i * polyAngle)
178.         _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a& TO(xOrigin, yOrigin)-(x1, y1)-(x2, y2), 0
179.         x1 = x2: y1 = y2
180.     NEXT
181.     _FREEIMAGE a& '<<< this is important!
182. END SUB
183.  

[STxAxTIC]

I swear I wanted to lay this thing to rest like 5 pages ago... Are you saying the so-called gold standard function overlaps itself at the cardinal points 0, pi/2, pi, 3pi/2? Wouldn't that make it bronze or worse?

[bplus]

I swear I wanted to lay this thing to rest like 5 pages ago... Are you saying the so-called gold standard function overlaps itself at the cardinal points 0, pi/2, pi, 3pi/2? Wouldn't that make it bronze or worse?

NO! I am saying THE QB64 CIRCLE function is overlapping itself at the named angles.

Here is a demo that makes it clear as a bell:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _SCREENMOVE 250, 60
3. FOR r = 0 TO 250
4.     CIRCLE (400, 300), r, _RGBA(255, 255, 255, 100)
5. NEXT
6.  

 

 

I swear I wanted to lay this thing to rest like 5 pages ago...

Voltaire — 'The secret of being a bore is to tell everything.'

The Gold Standard is even better than THE QB64 CIRCLE sub in this respect!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _SCREENMOVE 250, 60
3. FOR r = 250 TO 0 STEP -60
4.     fcirc 400, 300, r, _RGBA(255, 255, 255, 100)
5. NEXT
6. 'from Steve Gold standard
7. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
8.     DIM Radius AS INTEGER, RadiusError AS INTEGER
9.     DIM X AS INTEGER, Y AS INTEGER
10.  
11.     Radius = ABS(R)
12.     RadiusError = -Radius
13.     X = Radius
14.     Y = 0
15.  
16.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
17.  
18.     ' Draw the middle span here so we don't draw it twice in the main loop,
19.     ' which would be a problem with blending turned on.
20.     LINE (CX - X, CY)-(CX + X, CY), C, BF
21.  
22.     WHILE X > Y
23.         RadiusError = RadiusError + Y * 2 + 1
24.         IF RadiusError >= 0 THEN
25.             IF X <> Y + 1 THEN
26.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
27.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
28.             END IF
29.             X = X - 1
30.             RadiusError = RadiusError - X * 2
31.         END IF
32.         Y = Y + 1
33.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
34.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
35.     WEND
36. END SUB
37.  
38.  

 

[bplus]

Steve:

Circle is easy to find, complicated to work on.  Just open libqb.cpp and search “circle”— it’s the first result I found.  (Sub__circle, or something similar, is the actual name.)

Thanks Steve, found it and see why no one wants to mess with it! Yeeou-sa! It seems it's main concern is handling the arcs, and yet we still have to fix the arcs if we want to PAINT pie slices with it.

[_vince]

bplus is right about the inherent CIRCLE command (with eccentricity) not perfectly agreeing without our results. The difference is SO minuscule that our algorithms should probably not change though.

https://www.qb64.org/forum/index.php?topic=287.msg1806#msg1806

want to know why?

[STxAxTIC]

I ain't religious but "Dammit Allah", said Mohamed :-(

Am I gonna be killed by assassin for depicting the prophet like that? (I'll be waiting for you.)

So this means CIRCLE has a bug. We should start a new thread for that where it belongs if nobody has yet.

[bplus]

bplus is right about the inherent CIRCLE command (with eccentricity) not perfectly agreeing without our results. The difference is SO minuscule that our algorithms should probably not change though.

https://www.qb64.org/forum/index.php?topic=287.msg1806#msg1806

want to know why?

My guess after peeking into the qblib.cpp file, circle sub, that they are using Double Precision and Gold Standard is using Integers and the LINE sub rounds things it's own way. :)

[bplus]

I ain't religious but "Dammit Allah", said Mohamed :-(

Am I gonna be killed by assassin for depicting the prophet like that? (I'll be waiting for you.)

So this means CIRCLE has a bug. We should start a new thread for that where it belongs if nobody has yet.

Don't think anyone is going to mess with CIRCLE to fix it, it is an extremely rare case where the overlap bug enters awareness. Look how long it took me to run across it. Just file it under weird things about CIRCLE like the problem with arcs and PAINTING pie slices.

[FellippeHeitor]

Don't think anyone is going to mess with CIRCLE to fix it, it is an extremely rare case where the overlap bug enters awareness. Look how long it took me to run across it. Just file it under weird things about CIRCLE like the problem with arcs and PAINTING pie slices.

One question I haven't seen asked here yet (I just skimmed, may have missed it) is: Did QB4.5 do the same? If the odd behavior was already there, then CIRCLE should remain "buggy" concerning those middle lines.

That wouldn't prevent a new circle implementation to be added.

Not adding a new _CIRCLE command - that would be ridiculous -, but adding a new switch to the old existing CIRCLE command sounds feasible - one for the filled version, maybe another for an anti-aliased alternative routine that doesn't contain the vice of yore, what have you.

Who's willing to get their hands dirty with c code?

[FellippeHeitor]

Looking at the sample code provided, I take back my "did the bug already exist" question. It's using semi-transparent color, something not existing in QB4.5.

[STxAxTIC]

Alrighty, considering using this for the final submission. Super bare-bones as it should be (whoever wants some backstory will be able to click a link to this thread). The obvious contributors are, in ABC order, bplus, pete, smcneill, and yours truly. Anyone not in favor, speak now or forever hold your peace. (I'm interested in moving on to the next thing, as is probably everyone.)

I made an effort to unify the notation, so if you *do* have an edit to make, use what's posted below, or make sure the notation is maintained.

EDIT

Opps, didn't add the un-filled, yes-tilted ellipse yet. Luckily this is so easy even *I* can do that, as it won't be needing any newfangled underscore technology. Just my original post without the PAINT statement.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM TransRed AS _UNSIGNED LONG
4. DIM TransGreen AS _UNSIGNED LONG
5. DIM TransBlue AS _UNSIGNED LONG
6. TransRed = _RGBA(255, 0, 0, 128)
7. TransGreen = _RGBA(0, 255, 0, 128)
8. TransBlue = _RGBA(0, 0, 255, 128)
9.  
10. CALL CircleFill(100, 100, 75, TransRed)
11. CALL CircleFill(120, 120, 75, TransBlue)
12.  
13. CALL EllipseFill(550, 100, 150, 75, TransBlue)
14. CALL EllipseFill(570, 120, 150, 75, TransGreen)
15.  
16. CALL EllipseTiltFill(0, 350, 400, 150, 75, 3.14 / 6, TransGreen)
17. CALL EllipseTiltFill(0, 370, 420, 150, 75, 3.14 / 4, TransRed)
18.  
19. END
20.  
21. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
22.     ' CX = center x coordinate
23.     ' CY = center y coordinate
24.     '  R = radius
25.     '  C = fill color
26.     DIM Radius AS INTEGER, RadiusError AS INTEGER
27.     DIM X AS INTEGER, Y AS INTEGER
28.     Radius = ABS(R)
29.     RadiusError = -Radius
30.     X = Radius
31.     Y = 0
32.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
33.     LINE (CX - X, CY)-(CX + X, CY), C, BF
34.     WHILE X > Y
35.         RadiusError = RadiusError + Y * 2 + 1
36.         IF RadiusError >= 0 THEN
37.             IF X <> Y + 1 THEN
38.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
39.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
40.             END IF
41.             X = X - 1
42.             RadiusError = RadiusError - X * 2
43.         END IF
44.         Y = Y + 1
45.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
46.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
47.     WEND
48. END SUB
49.  
50. SUB EllipseFill (CX AS INTEGER, CY AS INTEGER, a AS INTEGER, b AS INTEGER, C AS _UNSIGNED LONG)
51.     ' CX = center x coordinate
52.     ' CY = center y coordinate
53.     '  a = semimajor axis
54.     '  b = semiminor axis
55.     '  C = fill color
56.     IF a = 0 OR b = 0 THEN EXIT SUB
57.     DIM h2 AS _INTEGER64
58.     DIM w2 AS _INTEGER64
59.     DIM h2w2 AS _INTEGER64
60.     DIM x AS INTEGER
61.     DIM y AS INTEGER
62.     w2 = a * a
63.     h2 = b * b
64.     h2w2 = h2 * w2
65.     LINE (CX - a, CY)-(CX + a, CY), C, BF
66.     DO WHILE y < b
67.         y = y + 1
68.         x = SQR((h2w2 - y * y * w2) \ h2)
69.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
70.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
71.     LOOP
72. END SUB
73.  
74. SUB EllipseTiltFill (destHandle&, CX, CY, a, b, ang, C AS _UNSIGNED LONG)
75.     '  destHandle& = destination handle
76.     '  CX = center x coordinate
77.     '  CY = center y coordinate
78.     '   a = semimajor axis
79.     '   b = semiminor axis
80.     ' ang = clockwise orientation of semimajor axis in radians (0 default)
81.     '   C = fill color
82.     DIM max AS INTEGER, mx2 AS INTEGER, i AS INTEGER, j AS INTEGER
83.     DIM prc AS _UNSIGNED LONG
84.     DIM D AS INTEGER, S AS INTEGER
85.     D = _DEST: S = _SOURCE
86.     prc = _RGB32(255, 255, 255, 255)
87.     IF a > b THEN max = a + 1 ELSE max = b + 1
88.     mx2 = max + max
89.     tef& = _NEWIMAGE(mx2, mx2)
90.     _DEST tef&
91.     _SOURCE tef&
92.     FOR k = 0 TO 6.283185307179586 + .025 STEP .025
93.         i = max + a * COS(k) * COS(ang) + b * SIN(k) * SIN(ang)
94.         j = max + a * COS(k) * SIN(ang) - b * SIN(k) * COS(ang)
95.         IF k <> 0 THEN
96.             LINE (lasti, lastj)-(i, j), prc
97.         ELSE
98.             PSET (i, j), prc
99.         END IF
100.         lasti = i: lastj = j
101.     NEXT
102.     DIM xleft(mx2) AS INTEGER, xright(mx2) AS INTEGER, x AS INTEGER, y AS INTEGER
103.     FOR y = 0 TO mx2
104.         x = 0
105.         WHILE POINT(x, y) <> prc AND x < mx2
106.             x = x + 1
107.         WEND
108.         xleft(y) = x
109.         WHILE POINT(x, y) = prc AND x < mx2
110.             x = x + 1
111.         WEND
112.         WHILE POINT(x, y) <> prc AND x < mx2
113.             x = x + 1
114.         WEND
115.         IF x = mx2 THEN xright(y) = xleft(y) ELSE xright(y) = x
116.     NEXT
117.     _DEST destHandle&
118.     FOR y = 0 TO mx2
119.         IF xleft(y) <> mx2 THEN LINE (xleft(y) + CX - max, y + CY - max)-(xright(y) + CX - max, y + CY - max), C, BF
120.     NEXT
121.     _DEST D: _DEST S
122.     _FREEIMAGE tef&
123. END SUB
124.  

[Pete]

Ironic Bill, if you used your real name, you'd receive top bill-ing. Oh well, if B-Plus gets his grades up next semester, we're all screwed! And no Steve, I'm not modifying my name to A-Peter. :D

Wow, who'd ah thunk this project would have us going around in circles? I guess we all should have seen that one coming. Well now that's it's over, I'd have to say it's been a blast. It's the second group project I've taken part in over 25 years and amazingly enough, both times everybody got along really well from start to finish. You guys rock and thinks for letting me participate!

Pete

[STxAxTIC]

Bumping this topic, hopefully for the last time (by me - anyone else is invited to speak up about whatever crosses their mind).

https://www.qb64.org/forum/index.php?topic=1069.msg102619