Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.

Messages - Virtusoroca

Pages: [1] 2

QB64 Discussion / Re: Recursively maze creation

« on: June 21, 2020, 05:50:51 pm »

@MasterGy thanks for this one! And thanks @FellippeHeitor for pointing it out. I was trying to implement the backtrack algorithm but had to stop because of work. Hope to come back to the forum in a couple of weeks. Very excited to run and explore this code! Looks very nice! <3

Programs / Re: Maze Generator

« on: June 10, 2020, 10:11:34 am »

@bplus great! I will look for it in you maze game. Downloaded it yesterday. Ive looked up some pathfinding algorithms. After the backtrack for the maze I will probably start with the wave propagation (Dijkstra's algorithm) for the pathfinding. A* algorithm seems to be a more complex implementation to me.

Programs / Re: Maze Generator

« on: June 10, 2020, 12:22:37 am »

@bplus thanks for the link regarding mazes. Im going to look into it for sure. Working in text mode here, so there is always some different trick to explore. ;)

Programs / Re: Maze Generator

« on: June 09, 2020, 09:57:51 pm »

@SierraKen um trying to code the backtrack algorithm. I have little training in math but quite a bit in data arrays. If yoi want to give it a try, look at this video:

. The guy works in C but the best part is in the logical steps. As soon as I finsh my experiment I get back to you.

Programs / Re: Maze Generator

« on: June 09, 2020, 03:28:38 am »

I was just working in some maze algorithms! Definetly gona check this one :D

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

« on: June 08, 2020, 12:24:39 am »

@Ashish @bplus <3 <3 <3

No conversion. 100% drawn by hand. :)

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

« on: June 07, 2020, 11:36:57 pm »

Final art work, with drawing blocks: codes 178, 177 and 176.
A small gift for you, my friend @Ashish :D

The attachments include de CSV file of the image
It can be embeded into the code usind DATA/READ
Format: CoordX, CoordY, FontColor, BackColor, ASCIIcode, BlockProperty (0/1)

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

« on: June 07, 2020, 07:34:58 pm »

Thanks @Ashish! See the attachments: work in progress, defining the pallette. Thinking of a mini game ;D

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

« on: June 06, 2020, 09:02:33 pm »

ASCII Editor v2.0

Download the pack and unzip at QB64 root
Pack: BAS + EXE + 6 demos + font file

New: ZoomIn and ZoomOut
Fixed: Error when brush size > 1 hits the border
Fixed: Control characters allowed

Tip: Load your files from ASCII Generator: https://www.qb64.org/forum/index.php?topic=2649.msg118624#msg118624

Note1: Special characters may not appear in zoom other than 16, 14 and 8. But data is ok in the file
Note2: Not compatible yet with ASCII Terrain Engine: https://www.qb64.org/forum/index.php?topic=2547.msg117823#msg117823

Let me know you opinion if you try! :)

Code: QB64: [Select]

'ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ      ASCII TERRAIN ENGINE     ÛÛßßÛÛ ÛÛßßÛÛ º
'º ÛÛ     Û     ÛÛ     ® Editor Module v2.0 ¯    ÛÛ ÞÛÛ ÛÛÛÛÛ  º
'º ÛÛ  Û  Û  Û  ÛÛ   (to be integreated in ATE)  ÛÛÜÞÛÛ ÛÛÜÜÛÛ º
'º    Û  Û  Û        Still rough but usable      ßß          º
'º ÛÛ  Û  Û  Û  ÛÛ          ------------         ÛÛßßßß ÛÛ  ÛÛ º
'º ÛÛ  Û     Û  ÛÛ  By Virtusoroca-Brazil, 2020  ÛÛßßÛÛ ÛÛÜÜÛÛ º
'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ          Made in QB64         ÛÛÜÜÛÛ     ÛÛ º
'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 1.    SYSTEM SETTINGS
_CONTROLCHR OFF '                                                      Allows ASCII Control Characters to be printed
OPTION BASE 1 '                                                        Sets the begining of arrays at 1
SCREEN _NEWIMAGE(1280, 800, 256) '                                     Set Screen to 1280x800 resolution, 256 colors
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 2.    SUBPROCEDURES
DECLARE SUB PrintMainMenu'                                             Prints options and settings on screen
DECLARE SUB PrintPallete'                                              Prints color and ASCII palletes on screen
DECLARE SUB HandleOptions'                                             Handles keyboard input (controls program flow)
DECLARE SUB DrawOnCanvas'                                              Handles mouse input on canvas
DECLARE SUB PrintImageDesign'                                          Prints image represented by its design (ASCII code)
DECLARE SUB PrintImageStructure'                                       Prints image represented by its structure (0s and 1s for block property)
DECLARE SUB SaveImageFile'                                             Saves image in CSV format file
DECLARE SUB LoadImageFile'                                             Load image from CSV file
DECLARE SUB LoadImageDefault'                                          Starts new project reloading default canvas
DECLARE SUB ReloadFont'                                                Reloads font size as zoom increases or descreases
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 3.    VARIABLES
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.1.  Basic variables declaration
DIM SHARED KeyPress AS STRING
DIM SHARED ScreenMode AS STRING
DIM SHARED CurrentFontColor AS INTEGER
DIM SHARED CurrentBackColor AS INTEGER
DIM SHARED CurrentASCII AS INTEGER
DIM SHARED CurrentSize AS INTEGER
DIM SHARED FilePath AS STRING
DIM SHARED FileName AS STRING
DIM SHARED FontResized AS LONG
DIM SHARED FontSize AS INTEGER
DIM SHARED MenuTextY AS INTEGER
DIM SHARED Pallete AS INTEGER
DIM SHARED MouseX AS INTEGER
DIM SHARED MouseY AS INTEGER
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.2.  Basic variables default settings
Pallete = 0
CurrentFontColor = 7
CurrentBackColor = 0
CurrentASCII = 219
CurrentBlock = 0
CurrentSize = 1
ScreenMode = "Design"
FilePath = "./ATE_editor_files/"
FontSize = 16
FontResized = _LOADFONT("PerfectDOSVGA437Win.ttf", FontSize, "monospace")
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.3.  Type variables declaration
TYPE Tiles
    x AS INTEGER ' X Coordinate
    y AS INTEGER ' Y Coordinate
    a AS INTEGER ' Ascii code
    fc AS INTEGER 'FontColor
    bc AS INTEGER 'BackColor
    b AS INTEGER ' Block property (game)
END TYPE
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.4.  Type arrays declaration and default settings
DIM SHARED Tile(50, 100) AS Tiles
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 4.    MAIN PROCEDURE
LoadImageDefault
PrintImageDesign
DO
    KeyPress = UCASE$(INKEY$)
    WHILE _MOUSEINPUT
        ReloadFont FontSize
        MouseX = INT(_MOUSEY / _FONTHEIGHT) + 1
        MouseY = INT(_MOUSEX / _FONTWIDTH) + 1
        DrawOnCanvas
    WEND
    PrintMainMenu
    PrintPallete
    HandleOptions
    _DISPLAY
LOOP UNTIL KeyPress = "Q"
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 5.    SUBPROCEDURES
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.1.  DrawOnCanvas
SUB DrawOnCanvas
    IF (MouseX > 0 AND MouseX < 50) AND (MouseY > 0 AND MouseY < 100) THEN
        SELECT CASE _MOUSEBUTTON(1)
            CASE -1
                IF MouseX < 1 THEN MouseX = 1
                IF MouseX >= 50 THEN MouseX = 50
                IF MouseY < 1 THEN MouseY = 1
                IF MouseY >= 100 THEN MouseY = 100
                CheckX = MouseX + CurrentSize - 1
                CheckY = MouseY + CurrentSize - 1
                IF CheckX < 1 THEN CheckX = 1
                IF CheckX >= 50 THEN CheckX = 50
                IF CheckY < 1 THEN CheckY = 1
                IF CheckY >= 100 THEN CheckY = 100
                FOR A = MouseX TO CheckX
                    FOR B = MouseY TO CheckY
                        Tile(A, B).fc = CurrentFontColor
                        Tile(A, B).bc = CurrentBackColor
                        Tile(A, B).a = CurrentASCII
                        Tile(A, B).b = 0
                        LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
                    NEXT
                NEXT
        END SELECT
        SELECT CASE _MOUSEBUTTON(2)
            CASE -1
                FOR A = MouseX TO MouseX + CurrentSize - 1
                    FOR B = MouseY TO MouseY + CurrentSize - 1
                        Tile(A, B).fc = CurrentFontColor
                        Tile(A, B).bc = CurrentBackColor
                        Tile(A, B).a = CurrentASCII
                        Tile(A, B).b = 1
                        LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
                    NEXT
                NEXT
        END SELECT
    END IF
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.2.  PrintMainMenu
SUB PrintMainMenu
    _FONT 16
    COLOR 15, 0: MenuColumnY = INT(1200 / 8) * 0.70
    FOR MenuColumnX = 1 TO 50: LOCATE MenuColumnX, MenuColumnY: PRINT "º";: NEXT
    MenuTextX = 1: MenuTextY = MenuColumnY + 2
    COLOR 15, 0
    LOCATE MenuTextX + 0, MenuTextY: PRINT "CURRENT STATUS"
    COLOR 7, 0
    LOCATE MenuTextX + 2, MenuTextY: PRINT "ScreenMode: "; ScreenMode
    LOCATE MenuTextX + 3, MenuTextY: PRINT "Character:  "; CHR$(CurrentASCII)
    LOCATE MenuTextX + 4, MenuTextY: PRINT "FontColor: "; CurrentFontColor
    LOCATE MenuTextX + 5, MenuTextY: PRINT "BackColor: "; CurrentBackColor
    LOCATE MenuTextX + 6, MenuTextY: PRINT "Preview:    ";: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);: COLOR 7, 0
    LOCATE MenuTextX + 7, MenuTextY: PRINT "BrushSize: "; CurrentSize
    LOCATE MenuTextX + 8, MenuTextY: PRINT "FontSize:  "; FontSize
    LOCATE MenuTextX + 11, MenuTextY: PRINT "File: ";
    IF FileName = "" THEN PRINT "Not Saved" ELSE PRINT FileName
    LOCATE MenuTextX + 34, MenuTextY: PRINT "MouseClick = PlaceTile";
    LOCATE MenuTextX + 35, MenuTextY: PRINT "LeftClick  = no Block ";
    LOCATE MenuTextX + 36, MenuTextY: PRINT "RightClick = w/ Block"
    LOCATE MenuTextX + 37, MenuTextY: PRINT "A = AsciiCode";
    LOCATE MenuTextX + 38, MenuTextY: PRINT "F = FontColor";
    LOCATE MenuTextX + 39, MenuTextY: PRINT "B = BackColor";
    LOCATE MenuTextX + 40, MenuTextY: PRINT "Z = BrushSize";
    LOCATE MenuTextX + 41, MenuTextY: PRINT "- = ZoomOut";
    LOCATE MenuTextX + 42, MenuTextY: PRINT "+ = ZoomIn";
    LOCATE MenuTextX + 43, MenuTextY: PRINT "D = DesignScreen";
    LOCATE MenuTextX + 44, MenuTextY: PRINT "X = StructureScreen";
    LOCATE MenuTextX + 45, MenuTextY: PRINT "N = NewProject";
    LOCATE MenuTextX + 46, MenuTextY: PRINT "L = LoadFile";
    LOCATE MenuTextX + 47, MenuTextY: PRINT "S = SaveFile";
    LOCATE MenuTextX + 48, MenuTextY: PRINT "Q = Quit";
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.3.  HandleOption
SUB HandleOptions
    _FONT 16
    MenuInputX = 13: MenuColumnY = INT(1200 / 8) * 0.70: MenuTextY = MenuColumnY + 2
    LOCATE MenuInputX, MenuTextY: COLOR 7, 0
    SELECT CASE KeyPress
        CASE "A": INPUT "AsciiCode: ", CurrentASCII: PrintImageDesign
        CASE "F": INPUT "FontColor: ", CurrentFontColor: PrintImageDesign
        CASE "B": INPUT "BackColor: ", CurrentBackColor: PrintImageDesign
        CASE "Z": INPUT "BrushSize: ", CurrentSize
        CASE "D": CLS: ScreenMode = "Design": PrintImageDesign
        CASE "X": CLS: ScreenMode = "Structure": PrintImageStructure
        CASE "N": ScreenMode = "Design": LoadImageDefault
        CASE "S": ScreenMode = "Design": SaveImageFile
        CASE "L": ScreenMode = "Design": LoadImageFile
        CASE "+"
            FontSize = FontSize + 1
            IF FontSize > 16 THEN FontSize = 16
            IF ScreenMode = "Design" THEN PrintImageDesign ELSE PrintImageStructure
        CASE "-"
            FontSize = FontSize - 1
            IF FontSize < 1 THEN FontSize = 1
            IF ScreenMode = "Design" THEN PrintImageDesign ELSE PrintImageStructure
    END SELECT
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.4.  PrintImageDesign
SUB PrintImageDesign
    CLS
    ReloadFont FontSize
    FOR A = 1 TO 50
        FOR B = 1 TO 100
            COLOR Tile(A, B).fc, Tile(A, B).bc
            LOCATE Tile(A, B).x, Tile(A, B).y
            PRINT CHR$(Tile(A, B).a);
            IF B = 100 THEN: LOCATE A, B + 1: PRINT "Û";
            IF FontSize < 16 THEN
                IF A = 50 THEN: LOCATE A + 1, B: PRINT "Û";
                LOCATE A + 1, B + 1: PRINT "Û";
            END IF
        NEXT
    NEXT
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.5.  PrintImageStructute
SUB PrintImageStructure
    CLS: COLOR 7, 0
    ReloadFont FontSize
    FOR A = 1 TO 50
        FOR B = 1 TO 100
            IF FontSize < 16 THEN
                IF B = 100 THEN: LOCATE A, B + 1: PRINT "Û";
                IF A = 50 THEN: LOCATE A + 1, B: PRINT "Û";
                LOCATE A + 1, B + 1: PRINT "Û";
            END IF
            SELECT CASE Tile(A, B).b
                CASE 1
                    LOCATE Tile(A, B).x, Tile(A, B).y
                    PRINT "1";
                CASE 0
                    LOCATE Tile(A, B).x, Tile(A, B).y
                    PRINT " ";
            END SELECT
        NEXT
    NEXT
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.6.  SaveImageFile
SUB SaveImageFile
    LOCATE 13, MenuTextY: COLOR 7, 0: INPUT "SaveFile: ", FileName
    OPEN FilePath + FileName FOR OUTPUT AS #1
    FOR A = 1 TO 50
        FOR B = 1 TO 100
            WRITE #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
        NEXT
    NEXT
    CLOSE #1
    CLS: PrintImageDesign
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.7.  LoadImageFile
SUB LoadImageFile
    LOCATE 13, MenuTextY: COLOR 7, 0: INPUT "LoadFile: ", FileName
    OPEN FilePath + FileName FOR INPUT AS #1
    FOR A = 1 TO 50
        FOR B = 1 TO 100
            INPUT #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
        NEXT
    NEXT
    CLOSE #1
    CLS: PrintImageDesign
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.8.  LoadImageDefault
SUB LoadImageDefault
    CLS
    FOR A = 1 TO 50
        FOR B = 1 TO 100
            Tile(A, B).x = A
            Tile(A, B).y = B
            Tile(A, B).a = 0
            Tile(A, B).fc = 7
            Tile(A, B).bc = 0
            Tile(A, B).b = 0
        NEXT
    NEXT
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.9.  RealoadFont
SUB ReloadFont (FontSize)
    IF FontSize = 16 OR FontSize = 14 OR FontSize = 8 THEN
        _FONT FontSize
    ELSE
        FontResized = _LOADFONT("PerfectDOSVGA437Win.ttf", FontSize, "monospace")
        _FONT FontResized
    END IF
END SUB
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.10. PrintPallete
SUB PrintPallete
    IF Pallete = 1 THEN
        X = 14: MenuColorY = MenuTextY
        'Colors 0 to 15
        LOCATE X, MenuColorY
        FOR A = 0 TO 15
            COLOR A: PRINT "Û";
        NEXT
        X = X + 1
        'Colors 16 to 31
        LOCATE X, MenuColorY
        FOR A = 16 TO 31
            COLOR A: PRINT "Û";
        NEXT
        'Colors 32 to 255
        X = X + 1: L = 1
        FOR A = 32 TO 255
            IF MenuColorY = MenuTextY + 24 THEN
                X = X + 1
                MenuColorY = MenuTextY
            END IF
            LOCATE X, MenuColorY
            COLOR A: PRINT "Û";: MenuColorY = MenuColorY + 1
        NEXT
        MenuAsciiY = MenuTextY
        'Ascii 0 to 255
        FOR A = 0 TO 255
            IF MenuAsciiY = MenuTextY + 24 THEN
                X = X + 1
                MenuAsciiY = MenuTextY
            END IF
            LOCATE X, MenuAsciiY
            COLOR 7: PRINT CHR$(A);: MenuAsciiY = MenuAsciiY + 1
        NEXT
    END IF
END SUB
'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 6.   END OF PROGRAM

Programs / Re: CRASHLANDED (game, survival, building)

« on: June 01, 2020, 03:02:45 am »

Im enjoying this game a lot! :) almost building the rocket so I can escape 2020! Thanks @MrFreyer for that. Very nice

Programs / Re: Procedural Generation (to be integrated into ASCII Terrain Engine)

« on: May 31, 2020, 10:08:48 pm »

Glad you liked it @SierraKen! Exactly what im going for here. Those retro RPGs. Rogue, Nethack, Dwarf Fortress, but not so complex. My procedural generation experiment is much simplier than those too. I belive we have one of those retro RPGs here in the forum. "Crashlanded" if im not mistaken. Didnt played it yet but looks nice.

Programs / Procedural Generation (to be integrated into ASCII Terrain Engine)

« on: May 31, 2020, 09:15:07 pm »

Still rough but usabe
1. Run code
2. Select theme (UserDefined, BayArea, Archipelago, Swamp, Icelands, Barren, AlienPlanet)
3. Loop trough results and Save the selected Terrain (in the CSV file will be included the terrain block properties)
4. Open CSV file with Editor Module (select StructureMode to see block properties): https://www.qb64.org/forum/index.php?topic=2608.0
5. Load CSV (from Generator or Editor) in ATE MainModule and play (current version not compatible yet): https://www.qb64.org/forum/index.php?topic=2547.0
6. Modify variables as you like and run again

Code: QB64: [Select]

'ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ      ASCII TERRAIN ENGINE     ÛÛßßÛÛ ÛÛßßÛÛ º
'º ÛÛ     Û     ÛÛ   ® Generator Module v1.0 ¯   ÛÛ ÞÛÛ ÛÛÛÛÛ  º
'º ÛÛ  Û  Û  Û  ÛÛ   (to be integreated in ATE)  ÛÛÜÞÛÛ ÛÛÜÜÛÛ º
'º    Û  Û  Û        Still rough but usable      ßß          º
'º ÛÛ  Û  Û  Û  ÛÛ          ------------         ÛÛßßßß ÛÛ  ÛÛ º
'º ÛÛ  Û     Û  ÛÛ  By Virtusoroca-Brazil, 2020  ÛÛßßÛÛ ÛÛÜÜÛÛ º
'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ          Made in QB64         ÛÛÜÜÛÛ     ÛÛ º
'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
'================================================================= 1.    SYSTEM SETTINGS
_CONTROLCHR OFF
RANDOMIZE TIMER
ScreenX = 800: ScreenY = 1200
CharX = 50: CharY = 100
'FontSize = 16
SCREEN _NEWIMAGE(ScreenY, ScreenX, 256)
'================================================================= 2.    SUBPROCEDURES DECLARATIONS
DECLARE SUB PrintMenu
DECLARE SUB Reload (ScreenX, ScreenY, CharX, CharY)
DECLARE SUB ProceduralGeneration (CharX, CharY, MoundAscii$, MoundFColor, MoundBColor, PlainAscii$, PlainFColor, PlainBColor, WaterAscii$, WaterFColor, WaterBColor, MoundChance, MoundBoldness, WaterLevel)
'================================================================= 3.    VARIABLES DECLARATION
DIM SHARED KeyPress AS STRING
TYPE Map
    x AS INTEGER
    y AS INTEGER
    sum AS INTEGER
    num AS INTEGER
    ascii AS STRING
    block AS INTEGER
    fcolor AS INTEGER
    bcolor AS INTEGER
    check AS INTEGER
END TYPE
REDIM SHARED Tile(1, 1) AS Map
'================================================================= 4.    MAIN PROCEDURE
DO
    PrintMenu
    Reload ScreenX, ScreenY, CharX, CharY
    ProceduralGeneration CharX, CharY, MoundAscii$, MoundFColor, MoundBColor, PlainAscii$, PlainFColor, PlainBColor, WaterAscii$, WaterFColor, WaterBColor, MoundChance, MoundBoldness, WaterLevel
    KeyPress = UCASE$(INKEY$)
    SELECT CASE KeyPress
        '========================================================= 4.1.  UserDefined
        CASE CHR$(0) + CHR$(59)
            MoundAscii$ = "²": MoundFColor = 6: MoundBColor = 7
            PlainAscii$ = "Û": PlainFColor = 2: PlainBColor = 0
            WaterAscii$ = "Û": WaterFColor = 3: WaterBColor = 0
            MoundChance = 0: MoundBoldness = 55: WaterLevel = 1
            '===================================================== 4.2.  BayArea
        CASE CHR$(0) + CHR$(60)
            MoundAscii$ = "²": MoundFColor = 2: MoundBColor = 7
            PlainAscii$ = "Û": PlainFColor = 2: PlainBColor = 0
            WaterAscii$ = "Û": WaterFColor = 3: WaterBColor = 0
            MoundChance = 0: MoundBoldness = 55: WaterLevel = 1
            '===================================================== 4.3.  Archipelago
        CASE CHR$(0) + CHR$(61)
            MoundAscii$ = "^": MoundFColor = 6: MoundBColor = 2
            PlainAscii$ = "Û": PlainFColor = 2: PlainBColor = 0
            WaterAscii$ = "Û": WaterFColor = 3: WaterBColor = 0
            MoundChance = 0: MoundBoldness = 35: WaterLevel = 2
            '===================================================== 4.4.  Swamp
        CASE CHR$(0) + CHR$(62)
            MoundAscii$ = "°": MoundFColor = 2: MoundBColor = 0
            PlainAscii$ = "°": PlainFColor = 6: PlainBColor = 0
            WaterAscii$ = "°": WaterFColor = 6: WaterBColor = 3
            MoundChance = 10: MoundBoldness = 25: WaterLevel = 2
            '===================================================== 4.5.  Icelands
        CASE CHR$(0) + CHR$(63)
            MoundAscii$ = "^": MoundFColor = 29: MoundBColor = 27
            PlainAscii$ = "Û": PlainFColor = 27: PlainBColor = 0
            WaterAscii$ = "Û": WaterFColor = 11: WaterBColor = 0
            MoundChance = 30: MoundBoldness = 0: WaterLevel = 1
            '===================================================== 4.6.  Barren
        CASE CHR$(0) + CHR$(64)
            MoundAscii$ = " ": MoundFColor = 14: MoundBColor = 6
            PlainAscii$ = ".": PlainFColor = 14: PlainBColor = 6
            WaterAscii$ = "": WaterFColor = 14: WaterBColor = 6
            MoundChance = 5: MoundBoldness = 45: WaterLevel = 2
            '===================================================== 4.7.  AlienPlanet
        CASE CHR$(0) + CHR$(65)
            MoundAscii$ = " ": MoundFColor = 21: MoundBColor = 18
            PlainAscii$ = "^": PlainFColor = 0: PlainBColor = 18
            WaterAscii$ = "°": WaterFColor = 18: WaterBColor = 5
            MoundChance = 5: MoundBoldness = 45: WaterLevel = 5
            '=====================================================
            'CASE "-": FontSize = FontSize - 1
            'CASE "+": FontSize = FontSize + 1
        CASE "S"
            SaveImageFile CharX, CharY
    END SELECT
    '=============================================================
LOOP UNTIL KeyPress = "Q"
'================================================================= 5.   SUBROUTINES
'================================================================= 5.1. PrintMenu
SUB PrintMenu
    FOR MenuColumnX = 1 TO 50
        LOCATE MenuColumnX, 101: COLOR 7, 0: PRINT "º";
    NEXT
    LOCATE 1, 103: PRINT "SELECT OPTION"
    LOCATE 3, 103: PRINT "F1 = UserCustomized"
    LOCATE 4, 103: PRINT "F2 = BayArea"
    LOCATE 5, 103: PRINT "F3 = Archipelago"
    LOCATE 6, 103: PRINT "F4 = Swamp"
    LOCATE 7, 103: PRINT "F5 = Icelands"
    LOCATE 8, 103: PRINT "F6 = Barren"
    LOCATE 9, 103: PRINT "F7 = AlienPlanet"
    LOCATE 11, 103: PRINT "S  = SaveFile"
END SUB
'================================================================= 5.2. Reload
SUB Reload (ScreenX, ScreenY, CharX, CharY)
    '    font& = _LOADFONT("PerfectDOSVGA437Win.ttf", FontSize, "monospace")
    '    _FONT font&
    '    CharX = INT(ScreenX / _FONTHEIGHT)
    '    CharY = INT(ScreenY / _FONTWIDTH)
    REDIM Tile(CharX, CharY) AS Map
    FOR X = 1 TO CharX
        FOR Y = 1 TO CharY
            Tile(X, Y).block = 0
            Tile(X, Y).check = 0
            Tile(X, Y).num = 0
            Tile(X, Y).sum = 0
            Tile(X, Y).x = X
            Tile(X, Y).y = Y
        NEXT
    NEXT
END SUB
'================================================================= 5.3. ProceduralGeneration
SUB ProceduralGeneration (CharX, CharY, MoundAscii$, MoundFColor, MoundBColor, PlainAscii$, PlainFColor, PlainBColor, WaterAscii$, WaterFColor, WaterBColor, MoundChance, MoundBoldness, WaterLevel)
    '============================================================= 5.3.1. MoundChance
    FOR X = 1 TO CharX
        FOR Y = 1 TO CharY
            Char = INT(RND * 100)
            IF Char >= 0 AND Char <= MoundChance THEN
                Tile(X, Y).ascii = MoundAscii$: Tile(X, Y).fcolor = MoundFColor: Tile(X, Y).bcolor = MoundBColor
                Tile(X, Y).num = 1
                Tile(X, Y).check = 1
                LOCATE X, Y: COLOR Tile(X, Y).fcolor, Tile(X, Y).bcolor: PRINT Tile(X, Y).ascii;
            END IF
        NEXT
    NEXT
    '============================================================= 5.3.2. MoundBoldness
    FOR X = 1 TO CharX - 1
        FOR Y = 1 TO CharY - 1
            IF Tile(X, Y).check = 0 THEN
                Char = INT(RND * 100)
                IF Char >= 0 AND Char <= MoundBoldness THEN
                    FOR Z = -1 TO 1
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y - 1).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y + 0).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y + 1).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 0, Y - 1).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 0, Y + 1).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y - 1).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y + 0).num
                        Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y + 1).num
                    NEXT
                END IF
                IF Tile(X, Y).sum >= 1 THEN '===================== Higher the sum restrictions for MoundBoldness, higher the WaterLevel
                    Tile(X, Y).ascii = MoundAscii$: Tile(X, Y).fcolor = MoundFColor: Tile(X, Y).bcolor = MoundBColor
                    Tile(X, Y).num = 1
                    Tile(X, Y).check = 2
                    LOCATE X, Y: COLOR Tile(X, Y).fcolor, Tile(X, Y).bcolor: PRINT Tile(X, Y).ascii;
                END IF
            END IF
        NEXT
    NEXT
    '============================================================= 5.3.3. Plains (surrounding Mounds)
    FOR X = 1 TO CharX - 1
        FOR Y = 1 TO CharY - 1
            IF Tile(X, Y).check = 0 THEN
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y - 1).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y + 0).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X - 1, Y + 1).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 0, Y - 1).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 0, Y + 1).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y - 1).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y + 0).num
                Tile(X, Y).sum = Tile(X, Y).sum + Tile(X + 1, Y + 1).num
                IF Tile(X, Y).sum >= WaterLevel THEN
                    Tile(X, Y).ascii = PlainAscii$: Tile(X, Y).fcolor = PlainFColor: Tile(X, Y).bcolor = PlainBColor
                    Tile(X, Y).check = 3
                    LOCATE X, Y: COLOR Tile(X, Y).fcolor, Tile(X, Y).bcolor: PRINT Tile(X, Y).ascii;
                END IF
            END IF
        NEXT
    NEXT
    '============================================================= 5.3.4. Water (fill the rest in) [for WaterLevel see MoundBoldness)
    FOR X = 1 TO CharX
        FOR Y = 1 TO CharY
            IF Tile(X, Y).check = 0 THEN
                Tile(X, Y).ascii = WaterAscii$: Tile(X, Y).fcolor = WaterFColor: Tile(X, Y).bcolor = WaterBColor: Tile(X, Y).block = 1
                LOCATE X, Y: COLOR Tile(X, Y).fcolor, Tile(X, Y).bcolor: PRINT Tile(X, Y).ascii;
            END IF
        NEXT
    NEXT
    SLEEP
END FUNCTION
'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.4. SaveImageFile
SUB SaveImageFile (CharX, CharY)
    LOCATE 12, 103: COLOR 7, 0: INPUT "SaveFile: ", FileName$
    OPEN FileName$ FOR OUTPUT AS #1
    FOR A = 1 TO CharX
        FOR B = 1 TO CharY
            WRITE #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fcolor, Tile(A, B).bcolor, ASC(Tile(A, B).ascii), Tile(A, B).block
        NEXT
    NEXT
    CLOSE #1
    SLEEP
END SUB
'================================================================= 6. END OF PROGRAM
 

QB64 Discussion / Re: QB64SOURCECODE.COM

« on: May 26, 2020, 04:04:10 pm »

The simplest way is as you described. Its two independent characters that cant ocuppy the same space. If the space is the same, then collision. Done.

But imagine first that you have layers. Some characters you can walk through, other you cant. It will require arrays. Maybe you want the forefront character to inherit the background color from below or have its spaces ignored for "transparency" effect. And then imagine youre dealing with a non rectacular set of characters that may have its own collision structure, independently of its design layer. For the collision you will need to do a "player structure layer" calculation against a "terrain structure layer", for each ajdecent array position, dependent on player size, shape, direction and speed.

Thats what I did in my engine, in a clumsy way I believe. For example, you can make the player with up to 3x3 characters (for now), but that is blocked at its corners only, passing through blocks that fit into it (moving over those characters that dont block it, with transparency effect). Its customizable shape will fit perfectly in the terrain structure, like tetris. None of this requiere any particulary dificult function, but the whole construct has its own complexity, different from a pixel/graphics approach.

For the code mess i manage to pull off trying this, take a look at my ASCII Terrain Engine, MovePlayer function (I mean, Sub). Ashish helped me with that mess and in the next version this segment will much more clear and compact.

QB64 Discussion / Re: QB64SOURCECODE.COM

« on: May 26, 2020, 01:56:26 pm »

Hi @TerryRitchie. I was follwing your tutorial even before join the community. Very broad and helpful. Thanks for the effort. A humble suggestion: maybe some comments could be added in tasks 16 (transparency) and 17 (collision) regarding games based on text characters. It sounds simple but there are some tricky aspects to it, specially in edge-sensitive collision detection between complex (non-rectangular) character sets. I had a hard time figuring that out and ended up hard coding the calculations. @Ashish help me to abstract it further (I didnt posted that yet). Tutoriais on these topics would be great I think. Im willing to help but not sure if Im up to the task.

Programs / Re: Build yourself a fancy menu!

« on: May 20, 2020, 11:28:07 pm »

Deal! Thanks again for sharing this. <3

Pages: [1] 2

News:

Show Posts

Messages - Virtusoroca

QB64 Discussion / Re: Recursively maze creation

Programs / Re: Maze Generator

Programs / Re: Maze Generator

Programs / Re: Maze Generator

Programs / Re: Maze Generator

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

Programs / Re: ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

Programs / Re: CRASHLANDED (game, survival, building)

Programs / Re: Procedural Generation (to be integrated into ASCII Terrain Engine)

Programs / Procedural Generation (to be integrated into ASCII Terrain Engine)

QB64 Discussion / Re: QB64SOURCECODE.COM

QB64 Discussion / Re: QB64SOURCECODE.COM

Programs / Re: Build yourself a fancy menu!