Is There a Mouse Equivalent of _KEYCLEAR?

[Qwerkey]

Is There a Mouse Equivalent of _KEYCLEAR, where any stray mouse events are used up?  From my reading of the Wiki, there isn't and I could code and have coded a routine to use up any _MOUSEBUTTON events.  But an existing command would be easier.

[SMcNeill]

WHILE _MOUSEINPUT: WEND

[Qwerkey]

Steve, I thought that it had to be slightly more complicated:

Code: QB64: [Select]

1. DO 'make sure that mouse button is released
2.     Dum` = _MOUSEINPUT
3.  LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)

[SMcNeill]

Steve, I thought that it had to be slightly more complicated:

Code: QB64: [Select]

1. DO 'make sure that mouse button is released
2.     Dum` = _MOUSEINPUT
3.  LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)

What you've got is a No-No code snippet, except under very controlled situations.   Here it is, in an actual program:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. _SCREENMOVE _MIDDLE
3.  
4. LINE (100, 100)-(200, 200), &HFFFF0000, BF
5. LINE (250, 100)-(350, 200), &HFF00FF00, BF
6. LINE (400, 100)-(500, 200), &HFF0000FF, BF
7.  
8.  
9. ButtonNo%% = 1 'left mouse
10. DO
11.     _LIMIT 60
12.     DO 'make sure that mouse button is released
13.         Dum` = _MOUSEINPUT
14.     LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)
15.     LOCATE 1, 1
16.     PRINT _MOUSEX, _MOUSEY
17. LOOP

Now, scroll your mouse around the screen a few times and watch the X/Y location print for you.  STOP moving the mouse, and watch the X/Y location... 

It's still updating from the mousebuffer, LOOOOOOOOOOONG after you quit moving the mouse!

Not the effect you're looking for at all, I'd imagine.  :)

[SMcNeill]

For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. _SCREENMOVE _MIDDLE
3.  
4. TYPE Point
5.     x AS INTEGER
6.     y AS INTEGER
7.     Color AS _UNSIGNED LONG
8.     Click AS LONG
9. END TYPE
10.  
11. DIM Box(3) AS Point
12. FOR i = 100 TO 400 STEP 150
13.     count = count + 1
14.     Box(count).x = i
15.     Box(count).y = 100
16. NEXT
17. Box(1).Color = &HFFFF0000
18. Box(2).Color = &HFF00FF00
19. Box(3).Color = &HFF0000FF
20.  
21.  
22.  
23. DO
24.     _LIMIT 60
25.     CLS
26.     WHILE _MOUSEINPUT: WEND
27.     FOR i = 1 TO 3
28.         LINE (Box(i).x, Box(i).y)-STEP(100, 100), Box(i).Color, BF
29.     NEXT
30.  
31.     IF OMB = 0 THEN 'The mouse button was up on a previous pass
32.         IF _MOUSEBUTTON(1) THEN
33.             FOR i = 1 TO 3
34.                 IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
35.                     Box(i).Click = Box(i).Click + 1
36.                 END IF
37.             NEXT
38.         END IF
39.     END IF
40.     LOCATE 1, 1
41.     PRINT _MOUSEX, _MOUSEY
42.     FOR i = 1 TO 3: PRINT "Box"; i; "Clicked:", Box(i).Click: NEXT
43.     OMB = _MOUSEBUTTON(1) 'Old Mouse Button
44.     _DISPLAY
45. LOOP
46.  

Notice how I update the mouseinput buffer?

Code: QB64: [Select]

1.     WHILE _MOUSEINPUT: WEND  

It's as simple as it gets.  Clear the buffer, deal with what's going on with the mouse as your program makes each current loop.  ;)

[SMcNeill]

And here's a more elaborate mouse routine:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. _SCREENMOVE _MIDDLE
3.  
4. TYPE Point
5.     x AS INTEGER
6.     y AS INTEGER
7.     Color AS _UNSIGNED LONG
8.     Click AS LONG
9. END TYPE
10.  
11. DIM Box(3) AS Point
12. FOR i = 100 TO 400 STEP 150
13.     count = count + 1
14.     Box(count).x = i
15.     Box(count).y = 100
16. NEXT
17. Box(1).Color = &HFFFF0000
18. Box(2).Color = &HFF00FF00
19. Box(3).Color = &HFF0000FF
20.  
21.  
22.  
23. DO
24.     _LIMIT 60
25.     CLS
26.     WHILE _MOUSEINPUT: WEND
27.     FOR i = 1 TO 3
28.         LINE (Box(i).x, Box(i).y)-STEP(100, 100), Box(i).Color, BF
29.     NEXT
30.  
31.     IF OMB = 0 THEN 'The mouse button was up on a previous pass
32.         IF _MOUSEBUTTON(1) THEN
33.             StartX = _MOUSEX: StartY = _MOUSEY
34.             t# = TIMER(0.001)
35.             WHILE _MOUSEBUTTON(1)
36.                 junk = _MOUSEINPUT
37.                 held = TIMER(0.001) - t# 'check to see if the button is held down for .2 seconds or more
38.                 IF held > 0.2 THEN EXIT WHILE 'After .2 seconds, we declare this a "hold event"
39.             WEND
40.  
41.             IF held < 0.2 THEN 'if we're not held down, it's a click
42.                 FOR i = 1 TO 3
43.                     IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
44.                         Box(i).Click = Box(i).Click + 1
45.                     END IF
46.                 NEXT
47.             ELSE ' If we're held down, let's store the original coordinates of the box we're held over (if any)
48.                 BO = 0
49.                 FOR i = 1 TO 3
50.                     IF StartX >= Box(i).x AND StartX <= Box(i).x + 100 AND StartY >= Box(i).y AND StartY <= Box(i).y + 100 THEN
51.                         BOX = Box(i).x: BOY = Box(i).y 'Box Original X and Box Original Y
52.                         BO = i 'Box the mouse is Over
53.                     END IF
54.                 NEXT
55.             END IF
56.         END IF
57.     ELSE 'If the button was down on a previous pass, we'll deal with a "hold button" event, if we have one.
58.         IF held THEN
59.             IF StartX >= BOX AND StartX <= BOX + 100 AND StartY >= BOY AND StartY <= BOY + 100 THEN 'we held the mouse down over a box
60.                 Xshift = StartX - _MOUSEX
61.                 Yshift = StartY - _MOUSEY
62.                 Box(BO).x = BOX - Xshift
63.                 Box(BO).y = BOY - Yshift
64.             END IF
65.         END IF
66.     END IF
67.     LOCATE 1, 1
68.     PRINT _MOUSEX, _MOUSEY
69.     FOR i = 1 TO 3: PRINT "Box"; i; "Clicked:", Box(i).Click: NEXT
70.     OMB = _MOUSEBUTTON(1) 'Old Mouse Button
71.     IF _MOUSEBUTTON(1) = 0 THEN held = 0
72.     _DISPLAY
73. LOOP
74.  

For this sample, click on the boxes just as you did before, and you can see how we interact with a "click event".

Then click on a box and hold the mouse down and move it across the screen.  You can see how we'd deal with a "mouse down/ drag event". 

In either case, our main routine for mouse handling is:

Code: QB64: [Select]

1. WHILE _MOUSEINPUT: WEND

If you notice, I *do* have a routine in this code which looks rather similar to the one you posted:

Code: QB64: [Select]

1.                 WHILE _MOUSEBUTTON(1)
2.                     junk = _MOUSEINPUT
3.                     held = TIMER(0.001) - t# 'check to see if the button is held down for .2 seconds or more
4.                     IF held > 0.2 THEN EXIT WHILE
5.                 WEND

The difference here?

The main process handles all the real mouse input work, and I only trap the input for 2/10ths of a second, so I can to see if I'm dealing with a "click event", or starting a "hold button" event.  The "WHILE _MOUSEINPUT: WEND" keeps the mousebuffer clear for us, and stops the input backlog from building up like we saw in the very first little demo I showcased above. 

"WHILE _MOUSEINPUT: WEND" is normally your main mouse loop, and the only thing you normally see inside it might be a counter if you're tracking the mouse scroll status.  ;)

[FellippeHeitor]

Instead of timers, I'd recommend using flags for mouse down, as in the code I posted at https://www.qb64.org/forum/index.php?topic=912.0 (and everything mouse related I post).

Look in SUB checkMouseAction.

[FellippeHeitor]

In summary:

'poll mouse buffer
WHILE _MOUSEINPUT: WEND

SUB checkMouseAction STATIC
    IF _MOUSEBUTTON(1) THEN
        IF mouseDown = 0 THEN
            'first pressed
            mouseDown = -1
        ELSE
            'dragging
        END IF
    ELSE
        IF mouseDown THEN
            mouseDown = 0
            'release/click (if st same coordinates of initial mousedown above)
        END IF
    END IF
END SUB

[SMcNeill]

Instead of timers, I'd recommend using flags for mouse down, as in the code I posted at https://www.qb64.org/forum/index.php?topic=912.0 (and everything mouse related I post).

Look in SUB checkMouseAction.

That’s what OMB does for us.  The 0.2 second timer is basically an “escape timer”, so a user won’t hold the button forever and pause program execution, like I’ve seen in some mouse routines.  ;)

[FellippeHeitor]

The above leaves little to no room for hanging, check it out.

[SMcNeill]

The above leaves little to no room for hanging, check it out.

It also leaves no time for someone to do a mouse click with a sticky mouse button.  As long as it polls down then up, it’s a “mouse click”.  If your button sticks for a few milliseconds, it’s called a “drag event”.

And, correct me if I’m wrong, but doesn’t it also generate a “click event” when the “drag event” ends?  Or is that accounted for in the commented out ‘dragging section? 

[FellippeHeitor]

It does, just like all modern systems. It's up to the programmer to ignore a drag if a drag is not interesting in context.

Like a double click always implies a single click.

[Qwerkey]

O Magnificent Gurus of the Great Spiritual Mouse, what then is the correct method for using up stray mouse clicks?  Pray, graciously enlighten your lowly, humble and ignorant follower.

From Steve (edited):

For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]

1. DO
2.     _LIMIT 60
3.     CLS
4.     WHILE _MOUSEINPUT: WEND
5.    
6.     IF _MOUSEBUTTON(1) THEN
7.             FOR i = 1 TO 3
8.                 IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
9.                     Box(i).Click = Box(i).Click + 1
10.                 END IF
11.             NEXT
12.     END IF
13.     _DISPLAY
14. LOOP
15.  

Steve's mouse polling is inside a limited WHILE/WEND.

My code would look like:

Code: QB64: [Select]

1. WHILE SomeCondition`
2.     _LIMIT 60
3.     'Do Something
4.     WHILE _MOUSEINPUT
5.         IF _MOUSEBUTTON(1) THEN
6.             'Set some flag
7.         END IF
8.     WEND
9.     '_DISPLAY if display update required
10. WEND

The program actioning is inside a WHILE/WEND with a _LIMIT, but inside that the Mouse polling is inside an unlimited WHILE/WEND, and therfore there is no delay.  My Use-Up-Mouse Routine would be before the next required mouse polling.

When I first coded a use up mouse click routine, I did the simple WHILE _MOUSEINPUT: WEND, and I thought that it didn't seem to work properly, hence my version.  Maybe I just didn't look correctly.  If WHILE _MOUSEINPUT:WEND is guaranteed to use up mouse clicks (it ought, I suppose), I'll use that in future.

[Qwerkey]

Ah!  My Use-Up-Mouse Routine mouse polling (_MOUSEINPUT) is NOT inside an umilited WHILE:WEND (whereas all my other mouse polling is).  I see Steve's concerns now.  Will change to WHILE _MOUSEINPUT: WEND

What a goon!

[SMcNeill]

O Magnificent Gurus of the Great Spiritual Mouse, what then is the correct method for using up stray mouse clicks?  Pray, graciously enlighten your lowly, humble and ignorant follower.

From Steve (edited):

For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]

1. DO
2.     _LIMIT 60
3.     CLS
4.     WHILE _MOUSEINPUT: WEND
5.    
6.     IF _MOUSEBUTTON(1) THEN
7.             FOR i = 1 TO 3
8.                 IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
9.                     Box(i).Click = Box(i).Click + 1
10.                 END IF
11.             NEXT
12.     END IF
13.     _DISPLAY
14. LOOP
15.  

Steve's mouse polling is inside a limited WHILE/WEND.

My code would look like:

Code: QB64: [Select]

1. WHILE SomeCondition`
2.     _LIMIT 60
3.     'Do Something
4.     WHILE _MOUSEINPUT
5.         IF _MOUSEBUTTON(1) THEN
6.             'Set some flag
7.         END IF
8.     WEND
9.     '_DISPLAY if display update required
10. WEND

The program actioning is inside a WHILE/WEND with a _LIMIT, but inside that the Mouse polling is inside an unlimited WHILE/WEND, and therfore there is no delay.  My Use-Up-Mouse Routine would be before the next required mouse polling.

When I first coded a use up mouse click routine, I did the simple WHILE _MOUSEINPUT: WEND, and I thought that it didn't seem to work properly, hence my version.  Maybe I just didn't look correctly.  If WHILE _MOUSEINPUT:WEND is guaranteed to use up mouse clicks (it ought, I suppose), I'll use that in future.

If you look, my mouse polling is in an unlimited WHILE: WEND, inside the DO:LOOP...

DO
   LIMIT
   WHILE _MOUSEINPUT: WEND
   IF _MOUSEBUTTON .....


Compared to your:

WHILE
   LIMIT
   WHILE _MOUSEINPUT
        IF _MOUSEBUTTON.....
   WEND


The mouse polls an unbelievable number of times each second.  Adding IF conditions and other code inside the update/polling routine is almost guaranteed to create a backlog of information to be processed, resulting in your program always racing to try and catch up to past events and getting stuck inside that loop much longer than you’d intend/want.

The best practice is:  WHILE _MOUSEINPUT: WEND.    It truly is the equivalent to _KEYCLEAR, for the mouse.