Help with a pcopy question

[robpugh0829]

Hey all,
I'm not usually a game programmer, but I'm taking the plunge into doing some stuff with graphics and games type stuff, but I ran into a problem that I just can't seem to work out. Let's say I have 5 different sprites(png images) on the page and when one of them is clicked, it disappears. I can do everything up to the disappearing part. Actually, I can make it disappear, but they all disappear. I'm using pcopy _display, 1 then pcopy 1, _display (probably incorrectly). Do I need to draw them on seperate screens and then put them, which I did also try that too but again can't make them disappear correctly. If somebody could please give insight, I would appreciate it.

Thanks so much!

Have a great day all!

[TempodiBasic]

Hi robpugh0829
wellcome

about your question I have understood this:
5 sprites (PNG files) to put on the screen visible, clicking on an image it must disappear

you are using

Code: QB64: [Select]

1.  pcopy _display, 1
2. .....
3. .....
4. pcopy 1, _display
5.  

reading wiki  http://qb64.org/wiki/PCOPY
The PCOPY statement copies one source screen page to a destination page in memory
(run examples to see details of its behaviour9

so it seems good to copy a whole panel/canvas onto panel/canvas used as screen visible
and so if you use many different panels/canvases you overwrite each with the next one that you Pcopy on.

If you need to draw the sprites on separate screens and then put together onto visible screen you can use _PUTIMAGE

http://qb64.org/wiki/PUTIMAGE
together with _DEST and _SOURCE as showed in examples of _PUTIMAGE

I think this can solve your issue.

Waiting your feedback or more details....
Good Coding

[robpugh0829]

I've been messing with pcopy and I do make copies of the visible screen and then the other screens I make, but then when I go to make one disappear, I make them all disappear and I can't seem to figure out what I am doing wrong.

[TempodiBasic]

Hi
1. take the image from this link

https://www.google.it/imgres?imgurl=https%3A%2F%2Fhackadaycom.files.wordpress.com%2F2018%2F02%2Fqb64_logo1.png%3Fw%3D200&imgrefurl=https%3A%2F%2Fhackaday.com%2F2018%2F02%2F22%2Fquickbasic-lives-on-with-qb64%2F&docid=6AhQFaY-QXxeXM&tbnid=HTjLzwKaTJiZ9M%3A&vet=10ahUKEwiop6K70qffAhWNSxUIHQpwBUwQMwhtKCIwIg..i&w=200&h=180&client=opera&bih=627&biw=1326&q=qb64&ved=0ahUKEwiop6K70qffAhWNSxUIHQpwBUwQMwhtKCIwIg&iact=mrc&uact=8

 right click and save image as qb64_logo1.png in QB64 folder

2. open IDE QB64 and paste this code into it

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM image AS LONG, ShowImage(1 TO 3) AS INTEGER
3. image = _LOADIMAGE("qb64_logo1.png", 32)
4. IF image > -1 THEN
5.     PRINT "No image found"
6. ELSE
7.     ShowImage(1) = -1
8.     ShowImage(2) = -1
9.     ShowImage(3) = -1
10.     WHILE 1
11.         CLS , _RGB(33, 211, 61)
12.         _PRINTSTRING (10, 400), "Press rightclick to QUIT"
13.         IF ShowImage(1) = -1 THEN _PUTIMAGE (1, 1)-(40, 40), image ELSE CIRCLE (20, 20), 20, _RGB(255, 0, 0)
14.         IF ShowImage(2) = -1 THEN _PUTIMAGE (60, 60)-(100, 100), image ELSE CIRCLE (80, 80), 20, _RGB(255, 0, 0)
15.         IF ShowImage(3) = -1 THEN _PUTIMAGE (1, 160)-(40, 200), image ELSE CIRCLE (20, 180), 20, _RGB(255, 0, 0)
16.         WHILE _MOUSEINPUT = -1
17.             IF _MOUSEBUTTON(1) THEN switchImage
18.             IF _MOUSEBUTTON(2) THEN END
19.         WEND
20.         _LIMIT 10
21.     WEND
22. END IF
23.  
24. SUB switchImage
25.     SHARED ShowImage() AS INTEGER
26.     SELECT CASE _MOUSEX
27.         CASE 1 TO 40
28.             SELECT CASE _MOUSEY
29.                 CASE 1 TO 40
30.                     ' first image on the topleft
31.                     IF ShowImage(1) = -1 THEN ShowImage(1) = 0 ELSE ShowImage(1) = -1
32.                 CASE 160 TO 200
33.                     ' third image on the bottom left
34.                     IF ShowImage(3) = -1 THEN ShowImage(3) = 0 ELSE ShowImage(3) = -1
35.             END SELECT
36.         CASE 60 TO 100
37.             SELECT CASE _MOUSEY
38.                 CASE 60 TO 100
39.                     ' second image in the middle at right
40.                     IF ShowImage(2) = -1 THEN ShowImage(2) = 0 ELSE ShowImage(2) = -1
41.             END SELECT
42.     END SELECT
43. END SUB
44.  
45.  

3. press F5 and see if it is what you are searching

if so you don't need to use PCOPY

[Petr]

Maybe this help. This source use CLS for not-active images, but better is using _PUTIMAGE with original background stored before is image placed to this area. Or LINE, BF for 1 color background.

Code: QB64: [Select]

1. TYPE image
2.     img AS LONG
3.     active AS _BYTE
4.     x AS INTEGER
5.     y AS INTEGER
6. END TYPE
7. DIM i(4) AS image
8.  
9. FOR do_images = 0 TO 4
10.     i(do_images).img = _NEWIMAGE(50, 50, 256)
11.     i(do_images).active = 1
12.     i(do_images).x = RND * 800
13.     i(do_images).y = RND * 600
14.     _DEST i(do_images).img
15.     CLS , 50 + 4 * do_images
16. NEXT
17. _DEST 0
18.  
19. SCREEN _NEWIMAGE(800, 600, 256)
20. DO
21.     CLS
22.     FOR show = 0 TO 4
23.         IF i(show).active = 1 THEN _PUTIMAGE (i(show).x, i(show).y), i(show).img
24.     NEXT
25.  
26.     WHILE _MOUSEINPUT: WEND
27.     IF _MOUSEBUTTON(1) THEN
28.         IF _MOUSEX > i(i).x AND _MOUSEX < i(i).x + 50 AND _MOUSEY > i(i).y AND _MOUSEY < i(i).y + 50 THEN i(i).active = i(i).active * -1: _DELAY .3
29.     END IF
30.  
31.     i = i + 1: IF i > 4 THEN i = 0
32.     _DISPLAY
33. LOOP
34.  

[Cobalt]

Any chance of seeing the code? It would help us help you find a solution to the problem.
Until then, while PCOPY was handy back in QB45 its not so useful now, as screen memory is simply emulated through QB64, its simpler now-a-days to use multiple layers made with _NEWIMAGE() then combining them with _PUTIMAGE while using _CLEARCOLOR to make things transparent.(like making BLACK transparent so you copy the sprites without erasing all the existing background).

[Petr]

Upgraded source, now use PCOPY + _PUTIMAGE, not CLS and show numbers to image areas.
add _CLEARCOLOR 0 before _DEST 0 to line 28 for transparency.

Code: QB64: [Select]

1. TYPE image
2.     img AS LONG 'here are your fotos
3.     active AS _BYTE
4.     x AS INTEGER
5.     y AS INTEGER
6. END TYPE
7. DIM i(4) AS image, not_active AS LONG
8. not_active = _NEWIMAGE(50, 50, 256)
9.  
10.  
11. FOR do_images = 0 TO 4
12.     i(do_images).img = _NEWIMAGE(50, 50, 256) '      use here = _LOADIMAGE (....), image resolution can be solved placing images to specified NEWIMAGE using PUTIMAGE.
13.     i(do_images).active = 1
14.     i(do_images).x = RND * 800
15.     i(do_images).y = RND * 600
16.  
17.     '------- use this not wit LOADIMAGE -------------
18.     _DEST i(do_images).img
19.     CLS , 50 + 4 * do_images
20.     _PRINTMODE _KEEPBACKGROUND , i(do_images).img
21.     _PRINTSTRING (16, 16), STR$(do_images + 1)
22.     ' -----------------------------------------------
23. NEXT
24. _DEST not_active
25. LINE (0, 0)-(49, 49), 2
26. LINE (0, 0)-(49, 49), 2, B
27. LINE (0, 49)-(49, 0), 2
28. _DEST 0
29.  
30.  
31. SCREEN _NEWIMAGE(800, 600, 32)
32. FOR background = 0 TO 799
33.     b = b + (512 / 800)
34.     LINE (background, 0)-(background, 599), _RGB32(b, 255 - b, 127 + b), BF
35. NEXT
36.  
37.  
38. PCOPY _DISPLAY, 1
39. DO
40.     PCOPY 1, _DISPLAY
41.     FOR show = 0 TO 4
42.         IF i(show).active = 1 THEN
43.             _PUTIMAGE (i(show).x, i(show).y), i(show).img
44.         ELSE
45.             _PUTIMAGE (i(show).x, i(show).y), not_active
46.         END IF
47.     NEXT
48.  
49.     WHILE _MOUSEINPUT: WEND
50.     IF TIMER > delay THEN
51.         IF _MOUSEBUTTON(1) THEN
52.             IF _MOUSEX > i(i).x AND _MOUSEX < i(i).x + 50 AND _MOUSEY > i(i).y AND _MOUSEY < i(i).y + 50 THEN i(i).active = i(i).active * -1: delay = TIMER + .3
53.         END IF
54.     END IF
55.     i = i + 1: IF i > 4 THEN i = 0
56.     _DISPLAY
57. LOOP
58.  
59.  

[robpugh0829]

Thanks for the help everybody. I haven't been able to try this yet due to work, but I plan on trying it this evening. I appreciate everyones help. This is the most helpful programming forum I have ever been on. Thanks everyone!

[Cobalt]

Upgraded source, now use PCOPY + _PUTIMAGE, not CLS and show numbers to image areas.
add _CLEARCOLOR 0 before _DEST 0 to line 28 for transparency.

if your using a 32bit layer be sure to use:
_CLEARCOLOR _RGB32(0,0,0)
for black.

[robpugh0829]

Petr,
This helped greatly! Thank you so much! It works.

Have a very happy holiday season!