Don't get me started on START!

[Pete]

I'm glad Rob decided to keep START in the SHELL part of QB64, but those great switches like ?MIN and ?MAX are lost these days due to software circumventing control even over the startup shortcuts. Programs like Paint.net, FireFox, and others simply track how they were last closed, and open the same way. It doesn't matter what your startup window in a shortcut is designated to do and it doesn't matter if you use START with a switch. I wrote a bit more about it at: https://www.tapatalk.com/groups/qbasic/the-start-command-seems-to-be-irrelevant-these-day-t39413.html

So a possible way around this, other than _SCREENCLICK, is the Windows API. Does anyone know how to get the handle of a program like FireFox?

Pete

[SMcNeill]

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "user32"
2.   FUNCTION FindWindowA& (BYVAL ClassName AS _OFFSET, WindowName$) 'handle by title
3. END DECLARE
4.  
5. title$ = "Example Title" 'string variable avoids title typo's
6. _TITLE title$
7. _DELAY .5 'Give Windows time to register the title
8. hwnd& = FindWindowA(0, title$ + CHR$(0))[\code]
9.  
10. Substitute program title for one your want to search for, such as "FireFox"
11.  

[Pete]

Thanks!

I'm looking into it now. I printed the variable hwnd& and I noticed each time I run the program, the value changes, even though the firefox window remains open and idle. I would think that number would be constant but if it isn't that would mean you have to poll it each time before taking an action. Does that sound right to you?

Well. To test I tried to minimize firefox, so either I'm doing something wrong or an title you give it is just registered as the title of the QB program, because it's the QB program that gets minimized, not firefox.

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "user32"
2.     FUNCTION FindWindowA& (BYVAL ClassName AS _OFFSET, WindowName$) 'handle by title
3.     FUNCTION ShowWindow& (BYVAL hwnd AS _OFFSET, BYVAL nCmdShow AS LONG) 'maximize process
4. END DECLARE
5.  
6. title$ = "firefox" 'string variable avoids title typo's
7. _TITLE title$
8. _DELAY .5 'Give Windows time to register the title
9. hwnd& = FindWindowA(0, title$ + CHR$(0))
10. PRINT hwnd&
11. x& = ShowWindow&(hwnd&, 2)

If I remark out _TITLE$, it returns 0, which makes me think the routine is specific to the QB program only, and as coded cannot be used to find the handle of another program. :(

Pete

[SMcNeill]

Set the title of the QB64 program to something else.

find$ = "Firefox"
_TITLE$ = "QB64 hwnd Finder"
hwnd& = FindWindowA(0, find$ + CHR$(0))
PRINT hwnd&

When multiple windows have the same title, FindWindowA simply returns the value for the first one it comes across.  It's like using a bloodhound named "Rambo"  to hunt an escaped prisoner named "Rambo".

Every time you get close to catching the guy, he gets away when you yell for him to, "Stop Rambo!!"

[Pete]

:(  :(  :( ...

It's more complicated, I'm afraid. As I suspected, it isn't just looking for the process, it's trying to find the title of the page, so when it's firefox, it depends on what page is in the active tab. You have to use the title of that page. So even if you shelled to that page, the author of that page could change the title, after which your program could no longer find it.

Here are some tests I conducted. Weird, but in the case of Task manager, it found it but could not minimize it...

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "user32"
2.     FUNCTION FindWindowA%& (BYVAL ClassName AS _OFFSET, WindowName$) 'handle by title
3.     FUNCTION ShowWindow& (BYVAL hwnd AS _OFFSET, BYVAL nCmdShow AS LONG) 'maximize process
4. END DECLARE
5.  
6. 'find$ = "calculator" ' Works
7. 'find$ = "qb64 x32" ' Works
8. find$ = "Bing - mozilla firefox" ' Works but you need active window displayed.
9. 'find$ = "QB64.org Forum - Index - mozilla firefox"
10. 'find$ = "Document - WordPad" ' Works
11. 'find$ = "untitled - Nvu" ' Works
12. 'find$ = "Untitled - Notepad" ' Works
13. 'find$ = "Task Manager" ' Finds but cannot minimize.
14. _TITLE "hwnd Finder"
15. _DELAY .1
16. hwnd%& = FindWindowA(0, find$ + CHR$(0))
17. _DELAY .1
18. PRINT hwnd%&
19. x& = ShowWindow&(hwnd%&, 2)
20. PRINT x& ' Should return value 24.
21. END
22.  

I really want to find a better way to find and control just the firefox browser, itself. Maybe looking into some parent/child function is the answer?

Pete

[Pete]

Well I'm going to settle for this Mickey Mouse work around. If I can't get the title to the open tab, I can just force a tab I know the tile of onto the browser, and then control it. New Tab would be one, but I'm going to use Bing.com in the example. One WARNING is if you do the last step, to close the browser, the Restore Previous Session info gets lost. Just restore the previous session with the tools selection, and close the browser. You can "x" to exit the program or just hit a key one more time.

This demo only works in Windows, because it uses the Windows API calls. It opens firefox, keeps the QB app in focus, and minimizes it, restores it, makes it full screen, and closes it.

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "user32"
2.     FUNCTION FindWindowA%& (BYVAL ClassName AS _OFFSET, WindowName$) 'handle by title
3.     FUNCTION ShowWindow& (BYVAL hwnd AS _OFFSET, BYVAL nCmdShow AS LONG) 'maximize process
4.     FUNCTION SetForegroundWindow& (BYVAL hwnd AS _OFFSET) 'set foreground window process(focus)
5.     FUNCTION GetForegroundWindow%& 'find currently focused process handle
6. END DECLARE
7.  
8. _SCREENMOVE 300, 200
9. title$ = "hwnd Finder"
10. _TITLE title$
11. find$ = "Bing - mozilla firefox" ' Works but you need active window displayed.
12. findqb$ = title$
13. SHELL _HIDE "firefox.exe bing.com"
14. _DELAY 5
15. GOSUB focus
16. PRINT "Make Firefox window size and press any key to minimize."
17. PRINT "It will restore in 5 sec."
18. SLEEP
19. x& = ShowWindow&(hwnd%&, 2)
20. _DELAY 5
21. ' 0 closes app. 1 restores app. 2 minimizes app. 3 maximizes app.
22. y& = ShowWindow&(hwnd%&, 1)
23. _DELAY .1
24. GOSUB focus
25. PRINT "Press any key to Maximize Firefox."
26. SLEEP
27. y& = ShowWindow&(hwnd%&, 3)
28. _DELAY .1
29. GOSUB focus
30. PRINT "Press any key to Close Firefox."
31. SLEEP
32. y& = ShowWindow&(hwnd%&, 0)
33. END
34.  
35. focus:
36. hwnd%& = FindWindowA(0, findqb$ + CHR$(0))
37. _DELAY .1
38. FGwin%& = GetForegroundWindow%& 'get current process in focus
39. _DELAY .1
40. IF FGwin%& <> hwnd%& THEN z& = SetForegroundWindow&(hwnd%&) 'set focus when necessary
41. _DELAY .1
42. hwnd%& = FindWindowA(0, find$ + CHR$(0))
43. _DELAY .1
44. RETURN
45.  

Pete

[robpugh0829]

What's funny is at work the other day I was tasked to create a user interface that would run 360 videos but I needed to use 2 different programs to run them. Oh, and they needed it the next day, so I turned to trusty old QB64 and I actually was able to run batch scripts that did what I needed it to do using START and /MAX and they worked fine. I was quite surprised by it. I made the interface less than 2MB as well, which size was important to them as well. I was very happy with how QB64 performed.

[Pete]

Sure, some programs will still work with START /M, but not all. Programs like Firefox override it. In other words, yes, it still works in QB64, as it did in QBasic, but it depends on if the program you are using it on accepts it. I'm glad your video program(s) did!

Pete

[TempodiBasic]

Hi Pete

in my experience this method doesn't work for QB64 because when we load a file into it  the title bar show the name of the file loaded...
 so you need search exactly the title bar that is now....
the same does Notepad.exe, Wordpad.exe....
IMHO  FindWindowA%& finds the exact string of the  WindowName$ in the title of the window.
just to say if I use

'find$ = "Untitled - Notepad" ' Works

I must localize to my language to let work the code after using in a previous line the following code

Code: QB64: [Select]

1. SHELL _DONTWAIT "Notepad.exe"
2. _delay .5 ' to wait OS while it loads Notepad

It maybe that in API windows there is a findwindow like INSTR keyword of  QB64 or another way to get a list of the titles of the windows opened on the desktop to search that one we must manage from into QB64 application.


Thanks for share your experience

[Pete]

I actually got through all that stuff this week and made the program!

It also uses the Windows API to wait until the title loads, so you don't need a delay.

Code: QB64: [Select]

1. i = 0
2. DO ' Wait until title is registered.
3.     i = i + 1
4.     hwnd%& = FindWindowA(0, findbrowsertitle$ + CHR$(0))
5.     _DELAY .2
6.     IF hwnd%& THEN EXIT DO
7. LOOP UNTIL i = 100 ' Fail safe in case SHELL fails.

https://www.qb64.org/forum/index.php?topic=860.0

Check it out.

Pete

[TempodiBasic]

Check it out.

Thanks I'll do tomorrow
I need some sleep now. Your creature needs more time to be watched.