Pig

[bplus]

Yeah, Pig, I found it at Rosetta, I was curious if it was an interesting game.
You get to keep rolling a die and accumulating a score unless you roll a 1 then the accumulated score is lost.
If you don't roll a 1 you have option of holding or rolling again. First to 100 wins.

I have AI programmed to roll 4 times here:

Code: QB64: [Select]

1. RANDOMIZE TIMER
2. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
3.     turn = (turn + 1) MOD 2
4.     di = INT(RND * 6) + 1
5.     PRINT: PRINT "Player:"; player; "  AI:"; AI
6.     accum = 0 '<<<<<<<<<<<<<<<<< EDIT  one line instead of two
7.     IF turn THEN 'player
8.         DO
9.             IF di = 1 THEN
10.                 INPUT "Player you rolled a 1, your turn is over, press enter..."; wate$
11.                 EXIT DO
12.             ELSE
13.                 accum = accum + di
14.                 PRINT "Player you rolled a "; di; "your accumulated total is now "; accum
15.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h > "; choice$
16.                 IF choice$ = "r" THEN
17.                     di = INT(RND * 6) + 1
18.                 ELSE
19.                     player = player + accum
20.                     EXIT DO
21.                 END IF
22.             END IF
23.         LOOP
24.     ELSE
25.         FOR i = 1 TO 5
26.             IF di = 1 THEN
27.                 INPUT "AI rolled a 1, it's turn is over, press enter..."; wate$
28.                 EXIT FOR
29.             ELSE
30.                 accum = accum + di
31.                 PRINT "AI rolled a "; di; "it's total accumulated now is"; accum
32.                 IF i < 4 AND accum + AI < 100 THEN  '<<<<<<<<<<<<<<<<<<<<<<<<<EDIT
33.                     PRINT "AI is rolling again."
34.                     INPUT "press enter..."; wate$
35.                     di = INT(RND * 6) + 1
36.                 ELSE
37.                     PRINT "AI is holding with"; accum; "added to it's score."
38.                     INPUT "press enter..."; wate$
39.                     AI = AI + accum
40.                     EXIT FOR
41.                 END IF
42.             END IF
43.         NEXT
44.     END IF
45. WEND
46. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"
47. END
48.  

Oh, I see I should tell the AI not to roll again if it's got 100 points with accum.

I've only played with this for about 45 mins. anyone have ideas for improvements?

[bplus]

38 lines now (fits completely in IDE window), not a single :

Code: QB64: [Select]

1. _TITLE "Pig 1 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     turn = (turn + 1) MOD 2
5.     IF turn THEN Who$ = "Player" ELSE Who$ = "AI"
6.     PRINT "Player =" + STR$(player) + "  AI =" + STR$(AI) + CHR$(10)
7.     accum = 0
8.     FOR i = 1 TO 100
9.         di = INT(RND * 6) + 1
10.         IF di = 1 THEN
11.             PRINT Who$ + " rolled a 1, the turn is over, press enter...";
12.             INPUT "", wate$
13.             EXIT FOR
14.         ELSE
15.             accum = accum + di
16.             PRINT Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
17.             IF turn THEN
18.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
19.                 IF choice$ <> "r" THEN player = player + accum
20.                 IF choice$ <> "r" THEN EXIT FOR
21.             ELSE
22.                 IF i < 3 AND accum + AI < 100 THEN
23.                     PRINT "AI is rolling again,";
24.                     INPUT " press enter...", wate$
25.                 ELSE
26.                     PRINT "AI is holding with"; accum; "added to it's score,";
27.                     INPUT " press enter...", wate$
28.                     AI = AI + accum
29.                     EXIT FOR
30.                 END IF
31.             END IF
32.         END IF
33.         PRINT
34.     NEXT
35.     PRINT
36. WEND
37. PRINT "Player =" + STR$(player) + "  AI =" + STR$(AI)
38. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"
39.  

;-)) Yes, I used a FOR loop to save from having to use an i = i+1 line!

EDIT 2x's found 2 more lines to cut.

[bplus]

Update 35 lines now.

[SMcNeill]

Update 35 lines now.

Line Count reduction -- from:

PRINT "AI is rolling again,";
                    INPUT " press enter...", wate$

to:

INPUT "AI is rolling again, press enter...", wate$

[bplus]

Hi Steve,

I think you are looking at the code in OP, with your suggestion.

I removed duplicate code sections with who$ variable.

I wish I could use INPUT like PRINT with variable(s) in prompt. I could cut more lines.

Here is update at 35 lines to check ideas out.

Code: QB64: [Select]

1. _TITLE "Pig 2 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     turn = (turn + 1) MOD 2
5.     IF turn THEN Who$ = "Player" ELSE Who$ = "AI"
6.     accum = 0
7.     FOR i = 1 TO 100
8.         di = INT(RND * 6) + 1
9.         IF di = 1 THEN
10.             PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
11.             INPUT "", wate$
12.             EXIT FOR
13.         ELSE
14.             accum = accum + di
15.             PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
16.             IF turn THEN
17.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
18.                 IF choice$ <> "r" THEN player = player + accum
19.                 IF choice$ <> "r" THEN EXIT FOR
20.             ELSE
21.                 IF i < 3 AND accum + AI < 100 THEN
22.                     PRINT "AI is rolling again,";
23.                     INPUT " press enter... ", wate$
24.                 ELSE
25.                     AI = AI + accum
26.                     PRINT "AI is holding with"; accum; "added to it's score,";
27.                     INPUT " press enter...", wate$
28.                     EXIT FOR
29.                 END IF
30.             END IF
31.         END IF
32.     NEXT
33.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
34. WEND
35. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"
36.  

I am eyeing _Title and Randomize, nah... not desparate yet, maybe if I get to 20's.

It is not a bad game, I am liking it better than 21!

Oh hey just got an idea!

[bplus]

34 lines:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN
9.             PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
10.             INPUT "", wate$
11.             EXIT FOR
12.         ELSE
13.             accum = accum + di
14.             PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
15.             IF Who$ = "Player" THEN
16.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
17.                 IF choice$ <> "r" THEN player = player + accum
18.                 IF choice$ <> "r" THEN EXIT FOR
19.             ELSE
20.                 IF i < 3 AND accum + AI < 100 THEN
21.                     PRINT "AI is rolling again,";
22.                     INPUT " press enter... ", wate$
23.                 ELSE
24.                     AI = AI + accum
25.                     PRINT "AI is holding with"; accum; "added to it's score,";
26.                     INPUT " press enter...", wate$
27.                     EXIT FOR
28.                 END IF
29.             END IF
30.         END IF
31.     NEXT
32.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
33. WEND
34. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"

[bplus]

Oh I see it now! Sorry Steve you are right!
33 lines:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN
9.             PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
10.             INPUT "", wate$
11.             EXIT FOR
12.         ELSE
13.             accum = accum + di
14.             PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
15.             IF Who$ = "Player" THEN
16.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
17.                 IF choice$ <> "r" THEN player = player + accum
18.                 IF choice$ <> "r" THEN EXIT FOR
19.             ELSE
20.                 IF i < 3 AND accum + AI < 100 THEN
21.                     INPUT "AI is rolling again, press enter... ", wate$
22.                 ELSE
23.                     AI = AI + accum
24.                     PRINT "AI is holding with"; accum; "added to it's score,";
25.                     INPUT " press enter...", wate$
26.                     EXIT FOR
27.                 END IF
28.             END IF
29.         END IF
30.     NEXT
31.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
32. WEND
33. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"
34.  

EDIT: sorry I pasted wrong update.

Thanks Steve!!!

[bplus]

Oh heck, do it again in next block, there is no real loss of information reporting:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN
9.             PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
10.             INPUT "", wate$
11.             EXIT FOR
12.         ELSE
13.             accum = accum + di
14.             PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
15.             IF Who$ = "Player" THEN
16.                 INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
17.                 IF choice$ <> "r" THEN player = player + accum
18.                 IF choice$ <> "r" THEN EXIT FOR
19.             ELSE
20.                 IF i < 3 AND accum + AI < 100 THEN
21.                     INPUT "AI is rolling again, press enter... ", wate$
22.                 ELSE
23.                     AI = AI + accum
24.                     INPUT "AI is holding so accumulated amount added it's score, press enter", wate$
25.                     EXIT FOR
26.                 END IF
27.             END IF
28.         END IF
29.     NEXT
30.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
31. WEND
32. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"
33.  

32 lines, thanks again Steve.

[SMcNeill]

Let's reverse those numbers -- 23 Lines:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
9.         IF di = 1 THEN INPUT "", wate$
10.         IF di = 1 THEN EXIT FOR
11.         accum = accum + di
12.         PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
13.         IF Who$ = "Player" THEN INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
14.         IF Who$ = "Player" THEN IF choice$ <> "r" THEN player = player + accum
15.         IF Who$ = "Player" THEN IF choice$ <> "r" THEN EXIT FOR
16.         IF Who$ <> "Player" AND i < 3 AND accum + AI < 100 THEN INPUT "AI is rolling again, press enter... ", wate$
17.         IF Who$ <> "Player" AND i >= 3 OR accum + AI >= 100 THEN AI = AI + accum
18.         IF Who$ <> "Player" AND i >= 3 OR accum + AI >= 100 THEN INPUT "AI is holding so accumulated amount added it's score, press enter", wate$
19.         IF Who$ <> "Player" AND i >= 3 OR accum + AI >= 100 THEN EXIT FOR
20.     NEXT
21.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
22. WEND
23. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"

[bplus]

That is amazing but I've noticed a bug while player is rolling suddenly the AI is holding ...???

and now this!!! ? (Dang! I thought I had a 2nd shot of buggy code giving all points racked up by Player to AI.)

[SMcNeill]

Give me a sec and I'll see what I missed with the IF statements...  :P

[bplus]

I am sure there is big savings here!

[SMcNeill]

Try this:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN PRINT CHR$(10) + Who$ + " rolled a 1, the turn is over, press enter...";
9.         IF di = 1 THEN INPUT "", wate$
10.         IF di = 1 THEN EXIT FOR
11.         accum = accum + di
12.         PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum)
13.         IF Who$ = "Player" THEN INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
14.         IF Who$ = "Player" THEN IF choice$ <> "r" THEN player = player + accum
15.         IF Who$ = "Player" THEN IF choice$ <> "r" THEN EXIT FOR
16.         IF Who$ <> "Player" AND (i < 3 AND accum + AI < 100) THEN INPUT "AI is rolling again, press enter... ", wate$
17.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN AI = AI + accum
18.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN INPUT "AI is holding so accumulated amount added it's score, press enter", wate$
19.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN EXIT FOR
20.     NEXT
21.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
22. WEND
23. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"

I'm thinking the glitch was with the binary operators...
IF this AND that OR otherthing THEN....  Anytime otherthing was valid, it made the statement valid...

Whereas:
IF this AND (that OR otherthing) THEN...  Now one of the secondary options have to be valid, while the primary option is valid as well.  It's not just saying "IF the third choice is good, then we're good."  Now it's "IF the first choice is good AND (either the second or third choice are good) THEN...

[bplus]

Looking good! Nice job tracking down bug!

[SMcNeill]

And a little reworking of the PRINT statements and INPUT, reduces one more line:

Code: QB64: [Select]

1. _TITLE "Pig 3 (Rosetta task)" ' attempt to pare down (no :'s) first version B+ started 2018-10-17
2. RANDOMIZE TIMER
3. WHILE player < 100 AND AI < 100 'pig from Rosetta  B+ started 2018-10-16
4.     IF Who$ <> "Player" THEN Who$ = "Player" ELSE Who$ = "AI"
5.     accum = 0
6.     FOR i = 1 TO 100
7.         di = INT(RND * 6) + 1
8.         IF di = 1 THEN accum = 0 ELSE accum = accum + di
9.         IF di = 1 THEN PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + CHR$(10) ELSE PRINT CHR$(10) + Who$ + " rolled a" + RTRIM$(STR$(di)) + ", the accumulated total is" + STR$(accum) + CHR$(10);
10.         IF di = 1 THEN INPUT "The turn is over, press enter...", wate$
11.         IF di = 1 THEN EXIT FOR
12.         IF Who$ = "Player" THEN INPUT "Do you want to (r)oll again or (h)old, Enter r or h"; choice$
13.         IF Who$ = "Player" AND choice$ <> "r" THEN player = player + accum
14.         IF Who$ = "Player" AND choice$ <> "r" THEN EXIT FOR
15.         IF Who$ <> "Player" AND (i < 3 AND accum + AI < 100) THEN INPUT "AI is rolling again, press enter... ", wate$
16.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN AI = AI + accum
17.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN INPUT "AI is holding so accumulated amount added it's score, press enter", wate$
18.         IF Who$ <> "Player" AND (i >= 3 OR accum + AI >= 100) THEN EXIT FOR
19.     NEXT
20.     PRINT CHR$(10) + "Player =" + STR$(player) + "  AI =" + STR$(AI)
21. WEND
22. IF player > AI THEN PRINT "Player wins!" ELSE PRINT "AI wins!"

And, I don't think I see anything else which I can chip away, to reduce line count any further.  22 Lines is where I say, "That's it for Steve!'  ;D