New and BETTER Challenge. Make a game 20-lines or less.

[Pete]

It just has to be stand alone code, that means no $INCLUDE files, library calls, etc. and no colons. No tricks like using REM or a long variable that the program parses and feeds to another program, and then runs that much larger (More program lines) program.

2-Line Card Game Example:

Code: QB64: [Select]

1. RANDOMIZE TIMER
2. DO
3.     a$ = LTRIM$(STR$(INT(RND * 13 + 2))) + "." + LTRIM$(STR$(INT(RND * 4 + 1)))
4.     IF INT(VAL(a$)) > 10 THEN b$ = MID$("JQKA", VAL(a$) - 10, 1) + MID$(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), VAL(MID$(a$, INSTR(a$, ".") + 1)), 1) ELSE b$ = LTRIM$(STR$(INT(VAL(a$)))) + MID$(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), VAL(MID$(a$, INSTR(a$, ".") + 1)), 1)
5.     IF INSTR(mystring$, b$) = 0 THEN mystring$ = b$ + "=" + MID$(a$, 1, INSTR(a$, ".") - 1) + "|" + mystring$
6. LOOP WHILE LEN(mystring$) < 284
7. DO
8.     msg$ = MID$(mystring$, 1, INSTR(mystring$, "=") - 1) + " "
9.     x = VAL(MID$(mystring$, INSTR(mystring$, "=") + 1))
10.     DO
11.         IF LEN(msg$) < 5 THEN PRINT msg$;
12.         LINE INPUT "Will the next card be [h]igher or [l]ower? "; hl$
13.         mystring$ = MID$(mystring$, INSTR(mystring$, "|") + 1)
14.         IF UCASE$(hl$) = "H" THEN IF VAL(MID$(mystring$, INSTR(mystring$, "=") + 1)) > x THEN msg$ = "1|Correct! Plus 1-Point." ELSE IF VAL(MID$(mystring$, INSTR(mystring$, "=") + 1)) = x THEN msg$ = "0|It's a push, try again!" ELSE msg$ = "-1|Wrong. Minus 1-Point."
15.         IF UCASE$(hl$) = "L" THEN IF VAL(MID$(mystring$, INSTR(mystring$, "=") + 1)) < x THEN msg$ = "1|Correct! Plus 1-Point." ELSE IF VAL(MID$(mystring$, INSTR(mystring$, "=") + 1)) = x THEN msg$ = "0|It's a push, try again!" ELSE msg$ = "-1|Wrong. Minus 1-Point."
16.     LOOP WHILE LEN(msg$) < 5
17.     score = score + VAL(msg$)
18.     PRINT " ... "; MID$(msg$, INSTR(msg$, "|") + 1) + " Score = "; LTRIM$(STR$(score)); CHR$(13)
19.     IF mystring$ = "" THEN EXIT DO
20. LOOP

[Cobalt]

Here you go 20 lines of code for a game!(ish) padded it out to 20 lines, the original was only 16
Simple card guessing game with 1 hint.

Code: QB64: [Select]

1. 'Card Guessing Game, Kobolt 9/17/2018-12:15pm Ver 1.0, 20 line Challenge!
2. DIM hints(8) AS STRING
3. FOR i% = 1 TO 8
4.  READ hints(i%)
5. NEXT i%
6. RANDOMIZE TIMER
7. DO
8.  c% = INT(RND * 4) + 1
9.  n% = INT(RND * 13) + 1
10.  PRINT hints(c%)
11.  DO
12.   INPUT "What card is it (S,C,H,D:A-1,J-11,Q-12,K-13|ex-D8=8 of Diamonds)"; a$
13.   Try~% = Try~% + 1
14.  LOOP UNTIL UCASE$(a$) = (hints(4 + c%) + LTRIM$(RTRIM$(STR$(n%))))
15.  Good~% = Good~% + 1
16.  BEEP
17.  INPUT "Try again?"; a$
18. LOOP UNTIL LCASE$(a$) = "n"
19. PRINT "Total trys:"; Try~%; " for "; Good~%; " Correct!"
20. DATA "a garden tool","used when somebody is bad","gotta love with this","Ladies best friend","S","C","H","D"
21.  

[Pete]

FUN! But I had difficulty because I thought a "Ladies best friend." started with a "V" and I couldn't find that as one of the selection choices. Other than that, nice job! It really gave me a good vibe!

Pete :)

[Cobalt]

FUN! But I had difficulty because I thought a "Ladies best friend." started with a "V" and I couldn't find that as one of the selection choices. Other than that, nice job! It really gave me a good vibe!

Pete :)

You know somebody I used to work with brought back a deck of cards like that from Vegas! Instead of the normal spade,clubs,hearts,and diamonds it was right up the "V" alley!(or gutter if you like)
One thing a program of only 20 lines comes up short on is instructions!(and pictures like the ones on the deck of cards ;)
Glad you found it interesting, never done one of these challenges before.

[Pete]

Glad you enjoyed it. We had a whole forum dedicated to QB coding challenges at the N54 QBasic forum. We had a couple of coders who made it their home. I hardly ever got involved but I the ones I did participate in were fun. My friend Mac, who ran the forum at the time and who was a career programmer for IBM couldn't believe I just programmed as a hobby. I often thought if I had been somehow introduced to BASIC programming just a year earlier, instead of the BS FORTRAN cards I had to punch to take chemistry tests for an idiot chem teacher, I might have chosen this as my field instead of healthcare.

Pete

[bplus]

Code: QB64: [Select]

1. RANDOMIZE TIMER ' digit thief.bas for QB64 2018-09-16 B+
2. DO UNTIL _KEYDOWN(27)
3.     gCount% = 0
4.     thief% = INT(RND * 10)
5.     robbed$ = "0123456789"
6.     PRINT
7.     WHILE _KEYDOWN(27) = 0 AND robbed$ <> STRING$(10, " ")
8.         INPUT "Enter Guess (0 to 9) where the digit thief is now "; guess%
9.         gCount% = gCount% + 1
10.         IF guess% = thief% THEN
11.             PRINT "You caught the thief in" + STR$(gCount%) + " guesses."
12.             EXIT WHILE
13.         ELSE
14.             MID$(robbed$, thief% + 1, 1) = " "
15.             PRINT "Game Update: " + robbed$
16.             thief% = ABS(INT(RND * 3) - 1 + thief%) MOD 10
17.             IF robbed$ = STRING$(10, " ") THEN PRINT "Dang! too late! Gone in" + STR$(gCount%) + " guesses."
18.         END IF
19.     WEND
20. LOOP
21.  

It is really hard to loose all your digits. ;)

[Pete]

It took me 13 guesses to catch the Democrat. Is that a lot?

Nice job! I just guessed at random, not sure if there is a strategy.

Pete

[bplus]

I think I have the essence of it:

Code: QB64: [Select]

1. RANDOMIZE TIMER '21.bas for QB64 2018-09-17 B+
2. DIM deck%(1 TO 52)
3. FOR i% = 1 TO 52
4.     IF i% MOD 13 + 1 > 10 THEN deck%(i%) = 10 ELSE deck%(i%) = i% MOD 13 + 1
5.     IF deck%(i%) = 1 THEN deck%(i%) = 11 'aces always 11
6. NEXT
7. FOR i% = 52 TO 2 STEP -1 'shuffle
8.     r% = INT(RND * i%) + 1
9.     SWAP deck%(r%), deck%(i%)
10. NEXT
11. WHILE playerT% < 15
12.     di% = di% + 1
13.     playerT% = playerT% + deck%(di%)
14.     _PRINTSTRING (27, di% + 5), "Player card: " + RIGHT$(SPACE$(2) + STR$(deck%(di%)), 2) + " total is " + RIGHT$(SPACE$(2) + STR$(playerT%), 2)
15. WEND
16. WHILE playerT% < 22 AND dealerT% < playerT%
17.     di% = di% + 1
18.     dealerT% = dealerT% + deck%(di%)
19.     _PRINTSTRING (27, di% + 7), "Dealer card: " + RIGHT$(SPACE$(2) + STR$(deck%(di%)), 2) + " total is " + RIGHT$(SPACE$(2) + STR$(dealerT%), 2)
20. WEND
21.  

[Pete]

Ah Black Jack, nice! I wrote a much larger version in the 1980s to evaluate different strategies. I actually found one that if you played enough hands and bet enough money, you might want to quit your day job and consider moving to Vegas. The problem was that would be putting in a 16 hour day and 100-500 bets. The odds also went down if you were playing from a shoe. Now what kept me from it is the days that you played a lot of hands, but were still down. Also, a book I read. It stated that if you think the people who put Vegas together with drugs, booze, and broads wouldn't cheat you at cards, well, you deserve what's coming to you. I actually saw a dealer wipe a player out in Reno by dealing seconds. I had a great view of him flipping the deck from a balcony. The guy was doing pretty well, so he started to bet heavy. He got wiped out in 7 straight losses.

Pete

[SMcNeill]

My Graphical Game:  CHASE IT!!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. RANDOMIZE TIMER
3. GOTO movebox
4. DO UNTIL loss = 3
5.     CLS
6.     IF TIMER > timelimit## THEN
7.         loss = loss + 1
8.         movebox:
9.         timelimit## = TIMER + 10 * 0.9 ^ (loss + tag)
10.         x = RND * (_WIDTH - 50)
11.         y = RND * (_HEIGHT - 25)
12.     END IF
13.     LINE (x, y)-STEP(50, 25), &HFFFF0000, BF
14.     WHILE _MOUSEINPUT: WEND
15.     'Two lines from combined WEND statement above
16.     IF _MOUSEX >= x AND _MOUSEX <= x + 50 AND _MOUSEY >= y AND _MOUSEY <= y + 25 THEN tag = tag + 1: GOTO movebox 'clicked in the box
17.     'Two lines from combined IF statement above
18.     PRINT "You've tagged the box"; STR$(tag); " times."; CHR$(13); "You've missed the box"; loss; "times."; CHR$(13); "Time Limit this turn"; timelimit## - TIMER
19.     _DISPLAY
20. LOOP

The challenge here is to see how many times you can chase and tag the red box with your mouse.   

GASP!!

That's RIGHT!!   A 20 line game which even includes mouse support to play it!   HURRAH!!

/STRUT  /PRANCE  /GIGGLE

It's nothing too fancy, but I think it's nice for the short number of lines which comprises it.   We have mouse support, increasing time constraints, a counter so we can compete against ourselves or others...   Basically, we have a cheesy little "game" in 20 lines. 

And I didn't even have to break Pete's rules to post an entry,  or change them to make a new challenge.  :P

[bplus]

Nice to see graphics in 20 lines and a real game but weird jumping into middle of loop and this:
timelimit## = TIMER + 10 * 0.9 ^ (loss + tag)

that one needs some study. :)

[SMcNeill]

Nice to see graphics in 20 lines and a real game but weird jumping into middle of loop and this:
timelimit## = TIMER + 10 * 0.9 ^ (loss + tag)

that one needs some study. :)

TIMER plus ( 10 seconds...  reduced by 90% each time you tag the box or "lose")

10
9
8.1
7.21

And down it counts, giving less response time as it goes.

[Pete]

BZZZZZZZZZ

The rules clearly state no colons. ICE has been notified and you will be de-ported to FREEBASIC, immediately! :D

OK, just kidding about the Idiot Code Enforcement people. They've been under staffed ever since FB came on the seen, anyway.

It works! Actually it would be pretty darn challenging if you had to click the mouse on the box before it moved. That's especially true using just one finger on a touch pad. Now is getting that in 20-lines possible?

Pete

[SMcNeill]

BZZZZZZZZZ

The rules clearly state no colons. ICE has been notified and you will be de-ported to FREEBASIC, immediately! :D

OK, just kidding about the Idiot Code Enforcement people. They've been under staffed ever since FB came on the seen, anyway.

It works! Actually it would be pretty darn challenging if you had to click the mouse on the box before it moved. That's especially true using just one finger on a touch pad. Now is getting that in 20-lines possible?

Pete

You could if you took out the RANDOMIZE TIMER.  Or perhaps actually label the lines 1,2,3...  Then you could remove the movebox: label, freeing up a line of code.

Just add a OldButton = _MOUSEBUTTON(1) to track old mouse button state before the _DISPLAY, and then add 2 conditions to the IF check....

IF (existing junk)  AND _MOUSEBUTTON(1) AND NOT OldButton THEN.....

Then the user would have to UP the mouse each "click", before the next DOWN would register for the button.

Close enough to "mouse click" behavior for such a line limitation program.   

[TempodiBasic]

Hi guys
in this weekend I got some time to code my little idea
here the game
Pick Highest card
you start the game and pick a card, after AI does the same
you can replay while the program shows the scores of the two player (user vs AI)

Code: QB64: [Select]

1. RANDOMIZE TIMER
2. _CONTROLCHR ON
3. PRINT "WELCOME TO HIGH CARD GAME:"
4. PRINT "Pick a card and see if you have more fortune than AI"
5. SLEEP 4
6. 6 CLS , 4
7. PRINT "To play press Enter, another key to quit       Player "; scoreP%; " vs AI "; scoreA%
8. IF (INPUT$(1) <> CHR$(13)) THEN END
9. PLAYER(1) = (INT(RND * 12) + 1) + ((INT(RND * 4) + 1) * 100)
10. DO
11.     PLAYER(0) = (INT(RND * 12) + 1) + ((INT(RND * 4) + 1) * 100)
12. LOOP UNTIL PLAYER(1) <> PLAYER(0)
13. PRINT "Player card: "; RIGHT$(STR$(PLAYER(1)), 2) + MID$("", (PLAYER(1) \ 100), 1)
14. PRINT "AI card: "; RIGHT$(STR$(PLAYER(0)), 2) + MID$("", (PLAYER(0) \ 100), 1)
15. IF (PLAYER(1) - PLAYER(0) > 0) THEN PRINT "Player wins. AI looses"
16. IF (PLAYER(1) - PLAYER(0) > 0) THEN scoreP% = scoreP% + 1
17. IF (PLAYER(1) - PLAYER(0) < 0) THEN PRINT "Player looses. AI wins"
18. IF (PLAYER(1) - PLAYER(0) < 0) THEN scoreA% = scoreA% + 1
19. SLEEP 4
20. GOTO 6
21.  

Thanks to try