What to do about non ASCII characters in file names?

[Cobalt]

So i've made good headway on my duplicate file finder program to help clean up my polluted disk drive. but have hit a snag with files that contain non-ASCII characters like the example below:
"[Audio-4U] 妖精帝國 — Yousei Teikoku 2.0 (vorbis)"

which turns into this in the IDE:
"[Audio-4U] ???? — Yousei Teikoku 2.0 (vorbis)"

which cannot be found, and causes my program to crash. is there anyway to get the IDE to handle characters like the ones above(Japanese Kanji) or will I need to figure out how to code something that will "identify" these directories and files and skip them? Not that any of my text editors can handle those characters so might be mute to try but I'm willing to give it a go, if its possible.

[TerryRitchie]

IF INSTR(filename$, "?") THEN  ' skip this file

Look for invalid characters in the string first before trying to process it perhaps. Any invalid character will cause the file name to be skipped.

or

IF NOT _FILEEXISTS(filename$) THEN 'skip this file

[Cobalt]

IF INSTR(filename$, "?") THEN  ' skip this file
Look for invalid characters in the string first before trying to process it perhaps. Any invalid character will cause the file name to be skipped.
or
IF NOT _FILEEXISTS(filename$) THEN 'skip this file

yeah I tried the INSTR made it farther but still failed, trying the _FILEEXISTS now. be an hour or so before it hits the last fail point.

anybody know why this line more than doubles the time the program takes to run a cycle?
    IF RTRIM$(FFiles(1).NameL) = RTRIM$(FFiles(0).NameL) THEN
unless the file names match it does nothing, yet it increases the cycle time just over 100%(1.019 sec to 2.25 secs per cycle)
is RTRIM$ really that slow?

[TerryRitchie]

Perhaps setting a predetermined length for your string will eliminate the need for RTRIM$()

The example below shows that it does not matter how many trailing spaces there are, they still equal.

Code: QB64: [Select]

1. TYPE test
2.     NameL AS STRING * 255
3. END TYPE
4.  
5. DIM FFiles(2) AS test
6.  
7. FFiles(1).NameL = "This is a test      "
8. FFiles(2).NameL = "This is a test"
9.  
10. IF FFiles(1).NameL = FFiles(2).NameL THEN PRINT "Yes"

[SMcNeill]

Or Trim it outside of the loop if they're DIM AS STRING.

FOR I = 1 TO LIMIT
    FFiles(I).NameL = RTRIM$(FFiles(I).NameL)
NEXT

Then do the IFs and all.

[Petr]

Hello Cobalt.

File omission would mean having a program that is not 100 percent. So I'll ask about the nature of the problem. How do you get a list of files on a disk? Are you using Linux and / or Windows? I have solved the same problem. When a file was found in UNICODE, an invalid name was returned.
There are two ways I tried, one is complicated and the other one even more. The first method I obtained from a disk listing was full list with DIR, but after the tests I found out that this listing is not the same in all windows. Ashish pointed out to me that his DIR is 2-bytes shifted to the right compared to my DIR listing, and that caused great problems. To access the files, I used the 8.3 format listings, but I used the full name to display the file name (after the required font and the transcription using _MAPUNICODE). This is a tricky approach that works.

The other way showed me Eoredson. Erik wrote a program using Windows libraries to print and access all the files on the disk correctly (first but use correct _MAPUNICODE block for correct on screen view, but as file acces it work). I made a simple textual interface for that. This way should work properly everywhere. I give this program here, first find the files if they are displayed correctly (after _MAPUNICODE use) but as acces it works so at is is. If you have any questions, I will try to answer, but with regard to libraries, Erik knows more details because he is the author of the program kernel.

try use MP3 file contains unicode charcters in folder/file name for show, that fileacces works correctly. Just find it and press enter.

Code: QB64: [Select]

1. 'info:
2. ' FileNames array contains long file names without path
3. ' ShortNames array contains short file names without path
4. ' Directories array contains long directories names without path
5. ' ShortNameDir array contains short directories names without path
6. ' FUNCTION  __File$ (mask$, parameter)  - if is parameter 1, this function return SHORT filename AND PATH to this file (after is this file with Enter selected)
7. '                                       - if is parameter 2, return 2 arrays (STRING): first array is FilesVisible. Contains long filesnames + path. Second is FilesUsable. Contains short filesnames + path.
8. '                                       - in X$ = __Files$ (mask$, 2) you need NOT X$, is for call only. In this mode select more files using Enter and then go back pressing Esc.
9. '                                      in function __Files$ use arrow Up and Down, PageUP, PageDN, Home, End, Enter and Esc. Is possible switching drives and selecting files in more places not in 1 dir only!
10.  
11. ' Please test it. Use UNICODE paths, UNICODE filenames, for real hard test. For me all works correctly.
12.  
13.  
14. 'typy a zpusoby navratu: - vrati seznam souboru ze slozky formou pole  ---- v poli FileNames - dlouha jmena, ShortNameFile vraci kratka jmena
15. '                        - vrati seznam adresaru                       ---- v poli Directories dlouha jmena, ShortNameDir vraci kratka jmena adresaru
16. '                        - vrati jeden soubor po vyberu (soucasny stav)  -- __Files (mask$, 1)
17. '                        - vrati vice souboru po vyberu               ----- __Files (mask$, 2)
18.  
19. 'this program in main loop contains _SNDPLAY statement, so please try selecting and then playing some your MP3 files using your national unicode names.
20.  
21.  
22.  
23.  
24. REM sample program to get/list/sort lists of filenames/directories v1.0a PD. Upgraded Erik's code for solving FILES statement unusuality.
25. ' detect operating system
26. $IF WIN = 0 THEN
27.     COLOR 15, 0
28.     CLS
29.     PRINT "Sorry, this program only works in Windows.."
30.     END
31. $END IF
32. REM $DYNAMIC
33. CONST MAX_PATH = 260
34. CONST INVALID_HANDLE_VALUE = -1
35. CONST ERROR_FILE_NOT_FOUND = 2
36. CONST ERROR_NO_MORE_FILES = &H12
37.  
38.  
39.  
40.  
41.  
42. TYPE FILETIME
43.     dwLowDateTime AS _UNSIGNED LONG
44.     dwHighDateTime AS _UNSIGNED LONG
45. END TYPE
46.  
47. TYPE SYSTEMTIME
48.     wYear AS INTEGER
49.     wMonth AS INTEGER
50.     wDayOfWeek AS INTEGER
51.     wDay AS INTEGER
52.     wHour AS INTEGER
53.     wMinute AS INTEGER
54.     wSecond AS INTEGER
55.     wMilliseconds AS INTEGER
56. END TYPE
57.  
58. TYPE WIN32_FIND_DATAA
59.     dwFileAttributes AS _UNSIGNED LONG
60.     ftCreationTime AS FILETIME
61.     ftLastAccessTime AS FILETIME
62.     ftLastWriteTime AS FILETIME
63.     nFileSizeHigh AS _UNSIGNED LONG
64.     nFileSizeLow AS _UNSIGNED LONG
65.     dwReserved0 AS _UNSIGNED LONG
66.     dwReserved1 AS _UNSIGNED LONG
67.     cFileName AS STRING * MAX_PATH
68.     cAlternateFileName AS STRING * 14
69. END TYPE
70.  
71. DECLARE DYNAMIC LIBRARY "kernel32"
72.     FUNCTION FindFirstFileA~%& (BYVAL lpFileName~%&, BYVAL lpFindFileData~%&)
73.     FUNCTION FindNextFileA& (BYVAL hFindFile~%&, BYVAL lpFindFileData~%&)
74.     FUNCTION FindClose& (BYVAL hFindFile~%&)
75.     FUNCTION FileTimeToSystemTime& (lpFileTime AS FILETIME, lpSystemTime AS SYSTEMTIME)
76.     FUNCTION GetVolumeInformationA& (lpRootPathName$, lpVolumeNameBuffer$, BYVAL nVolumeNameSize~&, lpVolumeSerialNumber~&, lpMaximumComponentLength~&, lpFileSystemFlags~&, lpFileSystemNameBuffer$, BYVAL nFileSystemNameSize&)
77.     FUNCTION GetDiskFreeSpaceA& (f$, sectors&, bytes&, free&, total&)
78.     FUNCTION GetDiskFreeSpaceExA& (filename$, free AS _UNSIGNED _INTEGER64, total AS _UNSIGNED _INTEGER64, free2 AS _UNSIGNED _INTEGER64)
79. END DECLARE
80.  
81. DECLARE LIBRARY
82.     FUNCTION GetFileAttributes& (f$)
83.     FUNCTION SetFileAttributes& (f$, BYVAL a&)
84.     FUNCTION GetDriveType& (d$)
85.     FUNCTION GetShortPathName& (InP$, OutP$, BYVAL length&)
86.     FUNCTION GetModuleFileNameA (BYVAL Module AS LONG, FileName AS STRING, BYVAL nSize AS LONG)
87. END DECLARE
88.  
89. ' declare library variables.
90. DIM SHARED finddata AS WIN32_FIND_DATAA
91. DIM SHARED hfind AS _UNSIGNED _OFFSET
92. DIM SHARED SysTime AS SYSTEMTIME
93. DIM SHARED Out3 AS STRING
94. DIM SHARED DriveType AS STRING
95.  
96. ' declare byte divisor variable.
97. DIM SHARED ByteDivisor AS DOUBLE
98. '--------------------------------
99. 'moje vklady
100. DIM SHARED Drives(1) AS STRING 'vrati pole s pismeny jednotek
101. DIM SHARED DriveLabels(1) AS STRING
102. DIM SHARED DriveSerials(1) AS STRING
103. DIM SHARED DriveType(1) AS STRING
104. DIM SHARED DiskTotalSpace(1) AS STRING
105. DIM SHARED DiskFreeSpace(1) AS STRING
106.  
107.  
108. DIM SHARED Filenames(1) AS STRING
109. DIM SHARED Directories(1) AS STRING
110.  
111. DIM SHARED FileCount AS SINGLE
112. DIM SHARED DirCount AS SINGLE
113.  
114. DIM SHARED FileSize(1) AS DOUBLE
115.  
116. DIM SHARED DateTimeDir(1) AS STRING * 19
117. DIM SHARED DateTimeFile(1) AS STRING * 19
118.  
119. DIM SHARED AttributesDir(1) AS INTEGER
120. DIM SHARED AttributesFile(1) AS INTEGER
121.  
122. DIM SHARED ShortNameDir(1) AS STRING
123. DIM SHARED ShortNameFile(1) AS STRING
124.  
125. DIM SHARED DateTimeType AS INTEGER
126. DIM SHARED LineCount AS INTEGER
127.  
128. REDIM SHARED FilesVisible(1) AS STRING 'pro vicenasobny vyber - dlouha jmena 'multiple select array, long names + path
129. REDIM SHARED FilesUsable(1) AS STRING 'pro vicenasobny vyber - kratka jmena  'multiple select array, short names + path
130.  
131. REDIM SHARED Attrib(1) AS STRING
132. REDIM SHARED Size(1) AS STRING
133.  
134. DateTimeType = 1
135. StoreSort1 = 1
136. StoreSort2 = -1
137.  
138. ' ------------ start mych uprav ------------- Petr's upgrade start
139.  
140.  
141. rst:
142. Maska$ = "*.mp3" 'mask
143. CALL GetFiles(Maska$) '                 load files list from kernel32 to memory, Erik work
144. CALL SortFiles(StoreSort1, StoreSort2) 'sort files, Erik work
145. REDIM SHARED Adresar(0) AS STRING 'its help array, Petr work - for Dirs
146. REDIM SHARED Soubor(0) AS STRING ' its help array, Petr work - for files
147.  
148.  
149.  
150. 'telo programu disk
151. ON ERROR GOTO Error.Routine
152. ' declare some constants.
153. CONST Nul = ""
154. CONST True = -1
155. _TITLE "DRIVE INFO"
156.  
157. REM Start program loop.
158.  
159. IF INSTR(_OS$, "[WINDOWS]") THEN
160.     ByteDivisor = 1024
161. ELSE
162.     IF INSTR(_OS$, "[MACOSX]") THEN
163.         ByteDivisor = 1000
164.     ELSE
165.         ByteDivisor = 1024
166.     END IF
167. END IF
168.  
169.  
170. ListDrives Nul, 0
171. ListFiles
172. 'telo disk konec
173.  
174. SCREEN _NEWIMAGE(640, 480, 256)
175. _FULLSCREEN
176. one$ = __Files$("*.*", 1) '__Files$ (function) is Petr's program full based on Erik's demo.
177. CLS '
178. PRINT "Function return this path to 1 selected file: "; one$
179. IF _SNDPLAYING(m&) THEN _SNDSTOP (m&): _SNDCLOSE m&
180. IF LCASE$(RIGHT$(one$, 4)) = ".mp3" THEN m& = _SNDOPEN(one$): _SNDPLAY m& ELSE _SCREENICON: SHELL one$
181. SLEEP 1
182. PRINT "Select more files with enter, quit with Esc"
183. SLEEP
184. e$ = __Files$("*.mp3", 2): e$ = "" 'function return with ,2 outputs in arrays FilesVisible and FilesUsable
185. CLS
186. PRINT "Selected files:"
187. PRINT "Long names (use with _MAPUNICODE NOT FOR ACCESS! and short system name, use for access:):"
188.  
189. FOR w = 0 TO UBOUND(FilesVisible)
190.     COLOR 15
191.     PRINT FilesVisible(w); CHR$(32);: COLOR 4: PRINT FilesUsable(w)
192.     IF w MOD 5 = 0 AND w >= 5 THEN COLOR 15: PRINT "Press any key...": SLEEP: CLS: PRINT "Long names (use with _MAPUNICODE NOT FOR ACCESS! and short system name, use for access:):"
193. NEXT w
194. PRINT "After pressing key, sound will stopped and is played selected from mode 2 (if are some MP3 selected)"
195. SLEEP
196. COLOR 15, 0
197.  
198. _SNDSTOP m&: _SNDCLOSE m&: CLS
199. FOR w = 1 TO UBOUND(FilesVisible)
200.     IF LCASE$(RIGHT$(FilesUsable(w), 4)) = ".mp3" THEN
201.         m& = _SNDOPEN(FilesUsable(w))
202.         _SNDPLAY m&
203.         DO UNTIL NOT _SNDPLAYING(m&)
204.             i$ = INKEY$
205.             IF i$ = CHR$(27) THEN END
206.             LOCATE 5, 1: PRINT "Playing "; FilesVisible(w)
207.             LOCATE 6, 1: PRINT FilesUsable(w)
208.             _LIMIT 10
209.         LOOP
210.         IF m& THEN _SNDCLOSE m&
211.         CLS
212.     END IF
213. NEXT w
214.  
215.  
216.  
217.  
218. END
219.  
220.  
221. ' critical error trap
222. Error.Routine:
223. IF ERR THEN CHDIR "C:\": RESUME NEXT
224.  
225. FUNCTION __Files$ (mask AS STRING, typ AS _BYTE) 'mask - use "*.*" for all files.... typ: 1 for one file select, 2 for more files (and it can be in different directories) selecting, this is ending after pressing Esc, values are then in arrays FilesVisible and FilesUsable. Visible for long names viewing, Usable for file access!  THIS MUSS WORKING ON ALL WINDOWS WORLDWIDE!
226.  
227.     begin:
228.     DirLevel = 0
229.     sizindex = 1
230.     CLS
231.     path$ = _CWD$
232.     IF _PIXELSIZE = 0 THEN LOCATE 1, 1: PRINT "Current path: "; path$
233.  
234.     GetFiles mask$
235.     SortFiles StoreSort1, StoreSort2
236.     REDIM Adresar(DirCount) AS STRING '             Directories
237.     REDIM Soubor(FileCount) AS STRING '             Files
238.     REDIM Vse(DirCount + FileCount) AS STRING '     Both - first directories, then files - contains long names, unussable for stable file access in other as english languages (not coded in Unicode)
239.     REDIM Acces(UBOUND(vse)) AS STRING '            Both - short names, usable for worldwide file / folder access
240.     REDIM ostatni(UBOUND(vse)) AS STRING 'date and time
241.     REDIM Attrib(FileCount + DirCount) AS STRING
242.     REDIM Size(FileCount) AS STRING
243.     ListDirs '                                                              modified - give dir names to array adresar$
244.     ListFiles '                                                             modified - give long file names to array soubor$
245.     akt = 1
246.     vklad = 1
247.     FOR rew0 = 1 TO DirCount
248.         Vse(rew0) = UCASE$(Adresar(rew0))
249.         ostatni(rew0) = DateTimeDir(rew0)
250.         IF ShortNameDir(rew0) <> "" THEN Acces(rew0) = ShortNameDir(rew0) ELSE Acces(rew0) = UCASE$(Directories(rew0))
251.     NEXT rew0
252.     FOR rew1 = 1 TO FileCount
253.         Vse(DirCount + rew1) = Soubor(rew1)
254.         ostatni(DirCount + rew1) = DateTimeFile(rew1)
255.         IF ShortNameFile(rew1) <> "" THEN Acces(DirCount + rew1) = ShortNameFile(rew1) ELSE Acces(DirCount + rew1) = Filenames(rew1)
256.     NEXT rew1
257.  
258.     IF LEN(path$) > 3 THEN REDIM _PRESERVE Vse(UBOUND(vse) + 1) AS STRING: Vse(UBOUND(vse)) = ".." '.. is for return up one level in directory structure
259.  
260.     Celkem = UBOUND(vse)
261.     IF Celkem < 1 THEN Celkem = 1
262.     ListStart = 1
263.     ListEnd = 15
264.     pul = CINT(ListEnd - ListStart) / 2
265.     IF ListEnd > Celkem THEN ListEnd = Celkem
266.     akt = 1 'what is selected. First name in list after start
267.     vypis = 1
268.     Pso = 5 ' start printing folder list. This number muss be the same as in line 177!
269.  
270.     REDIM _PRESERVE ostatni(UBOUND(vse)) AS STRING
271.     DO
272.         FOR vypis = ListStart TO ListEnd
273.             IF ListEnd > UBOUND(vse) THEN ListEnd = UBOUND(vse)
274.             Pso = Pso + 1
275.             i$ = INKEY$
276.             SELECT CASE i$
277.                 CASE CHR$(0) + CHR$(72)
278.                     akt = akt - 1: IF akt < 1 THEN akt = 1
279.                     IF akt < pul + ListStart THEN ListStart = ListStart - 1: ListEnd = ListEnd - 1
280.                     IF ListStart < 1 THEN ListStart = 1: ListEnd = ListStart + (ListEnd - ListStart + 1)
281.                 CASE CHR$(0) + CHR$(80)
282.                     akt = akt + 1: IF akt > Celkem THEN akt = Celkem
283.                     IF akt > pul + ListStart THEN ListEnd = ListEnd + 1: ListStart = ListStart + 1
284.                     IF ListEnd > UBOUND(vse) THEN ListEnd = UBOUND(vse): ListStart = ListEnd - (ListEnd - ListStart + 1)
285.                 CASE CHR$(0) + CHR$(71): akt = 1: ListStart = 1: IF UBOUND(vse) > 15 THEN ListEnd = 15 ELSE ListEnd = UBOUND(vse) 'home
286.                 CASE CHR$(0) + CHR$(79): akt = UBOUND(vse): ListEnd = akt: IF akt > 15 THEN ListStart = akt - 15 ELSE ListStart = 1 ' end
287.                 CASE CHR$(0) + CHR$(73) 'pgUp
288.                     akt = akt - 15: IF akt < 1 THEN akt = 1
289.                     ListStart = ListStart - 15
290.                     IF ListStart < 1 THEN ListStart = 1
291.                     IF ListStart + 15 < UBOUND(vse) THEN ListEnd = ListStart + 15 ELSE ListEnd = UBOUND(vse)
292.                 CASE CHR$(0) + CHR$(81)
293.                     akt = akt + 15: IF akt > UBOUND(vse) THEN akt = UBOUND(vse)
294.                     ListEnd = ListEnd + 15
295.                     IF ListEnd > UBOUND(vse) THEN ListEnd = UBOUND(vse)
296.                     IF ListEnd - 15 > 1 THEN ListStart = ListEnd - 15 ELSE ListStart = 1
297.                 CASE CHR$(13)
298.                     SELECT CASE typ
299.                         CASE 1: EXIT DO
300.                         CASE 2:
301.                             IF Vse(akt) = ".." THEN CHDIR "..": DirLevel = DirLevel - 1: t$ = "": GOTO begin
302.                             IF akt <= DirCount THEN CHDIR Acces(akt): DirLevel = DirLevel + 1: t$ = "": GOTO begin ' CHDIR MUSS BE!!!!! set to Acces array for long DIRECTORIES names!!!!
303.                             zaznam = zaznam + 1
304.                             REDIM _PRESERVE FilesVisible(zaznam) AS STRING: FilesVisible(zaznam) = path$ + CHR$(92) + Vse(akt)
305.                             REDIM _PRESERVE FilesUsable(zaznam) AS STRING: FilesUsable(zaznam) = path$ + CHR$(92) + Acces(akt)
306.                     END SELECT
307.                 CASE CHR$(27): IF typ = 2 THEN _AUTODISPLAY: EXIT FUNCTION
308.             END SELECT
309.             IF LEN(useavailable$) THEN
310.                 FOR fr = 1 TO LEN(useavailable$)
311.                     IF MID$(UCASE$(useavailable$), fr, 1) = UCASE$(i$) THEN disc = fr: DriveSelect$ = i$ + LTRIM$(":\"): CHDIR DriveSelect$: GOTO begin
312.                 NEXT fr
313.             END IF
314.             COLOR 15, 0: LOCATE Pso, 20: PRINT SPACE$(55)
315.             IF vypis = akt THEN COLOR 14, 9 ELSE COLOR 15, 0
316.             IF LEN(Vse(vypis)) > 24 THEN t$ = LEFT$(Vse(vypis), 21) + "..." ELSE t$ = Vse(vypis)
317.             IF vypis > UBOUND(vse) THEN
318.                 navic$ = ""
319.             ELSE
320.                 navic$ = ostatni(vypis)
321.             END IF
322.  
323.             IF t$ = ".." THEN t$ = t$ + SPC(57)
324.  
325.             IF typ = 2 THEN
326.                 FOR porovnej = 0 TO UBOUND(FilesVisible)
327.                     IF FilesVisible(porovnej) = path$ + CHR$(92) + Vse(vypis) THEN COLOR 2 'musi byt shoda i s cestou
328.                     IF FilesUsable(porovnej) = path$ + CHR$(92) + Vse(vypis) THEN COLOR 2
329.                 NEXT
330.             END IF
331.             IF vypis > DirCount AND vypis <= FileCount + DirCount THEN
332.                 LOCATE Pso, 54: PRINT "  "; Attrib(vypis - DirCount) + SPC(14) ' atributy   [pole attrib je velke jako dircount + filecount]
333.                 LOCATE Pso, 63: PRINT Size(vypis - DirCount)
334.             ELSE LOCATE Pso, 54: PRINT " <DIR> " + SPC(12)
335.             END IF
336.             LOCATE Pso, 10: PRINT t$; SPC(25 - LEN(t$)); navic$; CHR$(32)
337.             COLOR 15, 0
338.         NEXT vypis
339.         i3 = 0
340.         Pso = 5
341.         sizindex = 0
342.  
343.         IF _PIXELSIZE > 0 THEN
344.             LINE (30, 30)-(610, 360), 15, B
345.             LINE (35, 35)-(605, 355), 15, B
346.             LINE (35, 60)-(605, 65), 15, B
347.             _PRINTSTRING (40, 40), "         Select file. Use Esc in mode 2 for end. Mode: " + STR$(typ)
348.  
349.             IF LEN(path$) > 44 THEN pat$ = LEFT$(path$, 44) + "..." ELSE pat$ = path$
350.             _PRINTSTRING (70, 370), "Current path: " + pat$
351.             LINE (610, 360)-(30, 395), 15, B
352.             LINE (605, 360)-(35, 390), 15, B
353.             IF Available$ = "" THEN
354.                 FOR HowDisk = 1 TO UBOUND(drives)
355.                     IF UCASE$(LEFT$(pat$, 1)) = UCASE$(Drives(HowDisk)) THEN disc = HowDisk
356.                     Available$ = Available$ + Drives(HowDisk) + " "
357.                     useavailable$ = useavailable$ + Drives(HowDisk)
358.                 NEXT
359.             END IF
360.             _PRINTSTRING (30, 400), "Disk info: " + Drives(disc) + LTRIM$(":\  Total space: ") + DiskTotalSpace(disc) + " Free space: " + DiskFreeSpace(disc) + RTRIM$(" [" + DriveLabels(disc) + "]")
361.             _PRINTSTRING (30, 420), "Press correct key for select drive. Drives: " + Available$
362.         END IF
363.         _DISPLAY
364.         _LIMIT 15
365.     LOOP
366.     _AUTODISPLAY
367.     IF Vse(akt) = ".." THEN CHDIR "..": DirLevel = DirLevel - 1: t$ = "": GOTO begin
368.     IF akt <= DirCount THEN CHDIR Acces(akt): DirLevel = DirLevel + 1: GOTO begin
369.     IF akt <= DirCount THEN __Files$ = path$ + CHR$(92) + Acces(akt) ELSE __Files$ = path$ + CHR$(92) + Acces(akt)
370. END FUNCTION
371. SUB GetFiles (Var$)
372.     maska$ = Var$
373.     Var$ = "*.*"
374.     DIM Attribute AS INTEGER
375.     DIM ASCIIZ AS STRING * 260
376.     DIM finddata AS WIN32_FIND_DATAA
377.     DIM Wfile.Handle AS _UNSIGNED _OFFSET
378.     DIM SysTime AS SYSTEMTIME
379.  
380.     DirCount = 0!
381.     FileCount = 0!
382.  
383.     ASCIIZ = Var$ + CHR$(0)
384.     Wfile.Handle = FindFirstFileA(_OFFSET(ASCIIZ), _OFFSET(finddata))
385.     IF Wfile.Handle <> INVALID_HANDLE_VALUE THEN ' OR WDIR.Handle <> INVALID_HANDLE_VALUE THEN
386.         DO
387.             Attribute = finddata.dwFileAttributes
388.             Filename$ = finddata.cFileName
389.             Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
390.             IF Filename$ <> "." AND Filename$ <> ".." THEN
391.  
392.                 ' store date/time
393.                 SELECT CASE DateTimeType
394.                     CASE 1
395.                         x& = FileTimeToSystemTime&(finddata.ftCreationTime, SysTime)
396.                     CASE 2
397.                         x& = FileTimeToSystemTime&(finddata.ftLastAccessTime, SysTime)
398.                     CASE 3
399.                         x& = FileTimeToSystemTime&(finddata.ftLastWriteTime, SysTime)
400.                 END SELECT
401.  
402.                 Var1$ = RIGHT$("00" + LTRIM$(STR$(SysTime.wMonth)), 2) + "-"
403.                 Var1$ = Var1$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wDay)), 2) + "-"
404.                 Var1$ = Var1$ + LTRIM$(STR$(SysTime.wYear)) + " "
405.  
406.                 Var1$ = Var1$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wHour)), 2) + ":"
407.                 Var1$ = Var1$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wMinute)), 2) + ":"
408.                 Var1$ = Var1$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wSecond)), 2)
409.                 IF (Attribute AND &H10) = &H10 THEN
410.                     DirCount = DirCount + 1!
411.                     REDIM _PRESERVE Directories(DirCount) AS STRING
412.                     Directories(DirCount) = Filename$
413.  
414.                     REDIM _PRESERVE DateTimeDir(DirCount) AS STRING * 19
415.                     DateTimeDir(DirCount) = Var1$
416.  
417.                     REDIM _PRESERVE AttributesDir(DirCount) AS INTEGER
418.                     AttributesDir(DirCount) = Attribute
419.  
420.                     Filename$ = finddata.cAlternateFileName
421.                     Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
422.                     REDIM _PRESERVE ShortNameDir(DirCount) AS STRING
423.                     ShortNameDir(DirCount) = Filename$
424.                 ELSE
425.                     FileCount = FileCount + 1!
426.                     REDIM _PRESERVE Filenames(FileCount) AS STRING
427.                     Filenames(FileCount) = Filename$
428.                     REDIM _PRESERVE FileSize(FileCount) AS DOUBLE
429.                     F# = finddata.nFileSizeHigh * &H100000000~&& OR finddata.nFileSizeLow
430.                     FileSize(FileCount) = F#
431.  
432.                     REDIM _PRESERVE DateTimeFile(FileCount) AS STRING * 19
433.                     DateTimeFile(FileCount) = Var1$
434.  
435.                     REDIM _PRESERVE AttributesFile(FileCount) AS INTEGER
436.                     AttributesFile(FileCount) = Attribute
437.  
438.                     Filename$ = finddata.cAlternateFileName
439.                     Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
440.                     REDIM _PRESERVE ShortNameFile(FileCount) AS STRING
441.                     ShortNameFile(FileCount) = Filename$
442.                 END IF
443.             END IF
444.         LOOP WHILE FindNextFileA(Wfile.Handle, _OFFSET(finddata))
445.         x = FindClose(Wfile.Handle)
446.     END IF
447.     IF maska$ <> "*.*" THEN Var$ = maska$: Filtruj maska$ 'prepise FileCount podle predimenzovaneho poctu zanamu do poli FileNames, FileSize, DateTimeFile a ShortNameFile. Zaznamy adresaru zustanou stejne!
448.  
449. END SUB
450.  
451. ' Var1=1 filename, Var1=2 datetime, Var1=3 filesize
452. ' Var2=-1 ascending, Var2=0 descending
453. SUB SortFiles (Var1, Var2)
454.     FOR X! = 1! TO FileCount - 1!
455.         FOR Y! = X! + 1! TO FileCount
456.             SELECT CASE Var1
457.                 CASE 1
458.                     IF Var2 THEN
459.                         IF Filenames(X!) > Filenames(Y!) THEN
460.                             SWAP Filenames(X!), Filenames(Y!)
461.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
462.                             SWAP FileSize(X!), FileSize(Y!)
463.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
464.                             SWAP AttributesFile(X!), AttributesFile(Y!)
465.                         END IF
466.                     ELSE
467.                         IF Filenames(X!) < Filenames(Y!) THEN
468.                             SWAP Filenames(X!), Filenames(Y!)
469.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
470.                             SWAP FileSize(X!), FileSize(Y!)
471.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
472.                             SWAP AttributesFile(X!), AttributesFile(Y!)
473.                         END IF
474.                     END IF
475.                 CASE 2
476.                     IF Var2 THEN
477.                         IF DateTimeFile(X!) > DateTimeFile(Y!) THEN
478.                             SWAP Filenames(X!), Filenames(Y!)
479.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
480.                             SWAP FileSize(X!), FileSize(Y!)
481.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
482.                             SWAP AttributesFile(X!), AttributesFile(Y!)
483.                         END IF
484.                     ELSE
485.                         IF DateTimeFile(X!) < DateTimeFile(Y!) THEN
486.                             SWAP Filenames(X!), Filenames(Y!)
487.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
488.                             SWAP FileSize(X!), FileSize(Y!)
489.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
490.                             SWAP AttributesFile(X!), AttributesFile(Y!)
491.                         END IF
492.                     END IF
493.                 CASE 3
494.                     IF Var2 THEN
495.                         IF FileSize(X!) > FileSize(Y!) THEN
496.                             SWAP Filenames(X!), Filenames(Y!)
497.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
498.                             SWAP FileSize(X!), FileSize(Y!)
499.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
500.                             SWAP AttributesFile(X!), AttributesFile(Y!)
501.                         END IF
502.                     ELSE
503.                         IF FileSize(X!) < FileSize(Y!) THEN
504.                             SWAP Filenames(X!), Filenames(Y!)
505.                             SWAP ShortNameFile(X!), ShortNameFile(Y!)
506.                             SWAP FileSize(X!), FileSize(Y!)
507.                             SWAP DateTimeFile(X!), DateTimeFile(Y!)
508.                             SWAP AttributesFile(X!), AttributesFile(Y!)
509.                         END IF
510.                     END IF
511.             END SELECT
512.         NEXT
513.     NEXT
514.     IF Var1 = 3 THEN EXIT SUB
515.     FOR X! = 1! TO DirCount - 1!
516.         FOR Y! = X! + 1! TO DirCount
517.             SELECT CASE Var1
518.                 CASE 1
519.                     IF Var2 THEN
520.                         IF Directories(X!) > Directories(Y!) THEN
521.                             SWAP Directories(X!), Directories(Y!)
522.                             SWAP ShortNameDir(X!), ShortNameDir(Y!)
523.                             SWAP DateTimeDir(X!), DateTimeDir(Y!)
524.                             SWAP AttributesDir(X!), AttributesDir(Y!)
525.                         END IF
526.                     ELSE
527.                         IF Directories(X!) < Directories(Y!) THEN
528.                             SWAP Directories(X!), Directories(Y!)
529.                             SWAP ShortNameDir(X!), ShortNameDir(Y!)
530.                             SWAP DateTimeDir(X!), DateTimeDir(Y!)
531.                             SWAP AttributesDir(X!), AttributesDir(Y!)
532.                         END IF
533.                     END IF
534.                 CASE 2
535.                     IF Var2 THEN
536.                         IF DateTimeDir(X!) > DateTimeDir(Y!) THEN
537.                             SWAP Directories(X!), Directories(Y!)
538.                             SWAP ShortNameDir(X!), ShortNameDir(Y!)
539.                             SWAP DateTimeDir(X!), DateTimeDir(Y!)
540.                             SWAP AttributesDir(X!), AttributesDir(Y!)
541.                         END IF
542.                     ELSE
543.                         IF DateTimeDir(X!) < DateTimeDir(Y!) THEN
544.                             SWAP Directories(X!), Directories(Y!)
545.                             SWAP ShortNameDir(X!), ShortNameDir(Y!)
546.                             SWAP DateTimeDir(X!), DateTimeDir(Y!)
547.                             SWAP AttributesDir(X!), AttributesDir(Y!)
548.                         END IF
549.                     END IF
550.             END SELECT
551.         NEXT
552.     NEXT
553. END SUB
554.  
555. SUB ListFiles
556.     LineCount = 3
557.     c = 0
558.     q = 0
559.     t = 0
560.     F! = 0!
561.     FOR VarQ = 1 TO FileCount
562.         F! = F! + 1!
563.         q = -1
564.         Var% = AttributesFile(VarQ)
565.         Attr$ = SPACE$(5)
566.         IF (Var% AND &H20) = &H20 THEN Attrib(VarQ) = "A"
567.         IF (Var% AND &H4) = &H4 THEN Attrib(VarQ) = "S"
568.         IF (Var% AND &H2) = &H2 THEN Attrib(VarQ) = "H"
569.         IF (Var% AND &H1) = &H1 THEN Attrib(VarQ) = "R"
570.         ' print filesize
571.         Var# = FileSize(VarQ)
572.         VarX# = VarX# + Var# ' add bytes
573.         CALL Suffix(Var#, z$) ' 1,024.0 KB
574.         z$ = LEFT$(z$, 10)
575.         z$ = SPACE$(10 - LEN(z$)) + z$ 'suffix
576.         Size(VarQ) = z$
577.         ' print longfilename
578.         z$ = Filenames(VarQ)
579.         z$ = RTRIM$(z$)
580.         IF LEN(z$) THEN
581.             Soubor$(VarQ) = z$
582.         END IF
583.     NEXT
584.     IF q = 0 THEN
585.         COLOR 14
586.         PRINT "  No files found."
587.     END IF
588.     CALL Suffix(VarX#, z$) ' 1,024.0 KB
589. END SUB
590.  
591. SUB ListDirs
592.     LineCount = 3
593.     c = 0
594.     q = 0
595.     t = 0
596.     F! = 0!
597.     FOR VarQ = 1 TO DirCount
598.         F! = F! + 1!
599.         q = -1
600.         z$ = ShortNameDir(VarQ)
601.         z$ = RTRIM$(z$)
602.         IF z$ = "" THEN
603.             z$ = Directories(VarQ)
604.         END IF
605.         IF LEN(z$) > 12 THEN
606.             z$ = LEFT$(z$, 12)
607.         END IF
608.         Var% = AttributesDir(VarQ)
609.         Attr$ = SPACE$(5)
610.         IF (Var% AND &H20) = &H20 THEN Attrib(VarQ) = "A"
611.         IF (Var% AND &H4) = &H4 THEN Attrib(VarQ) = "S"
612.         IF (Var% AND &H2) = &H2 THEN Attrib(VarQ) = "H"
613.         IF (Var% AND &H1) = &H1 THEN Attrib(VarQ) = "R"
614.  
615.         z$ = Directories(VarQ)
616.         z$ = RTRIM$(z$)
617.         IF LEN(z$) THEN Adresar$(VarQ) = z$
618.     NEXT
619.     IF q = 0 THEN Adresar$(0) = "None"
620. END SUB
621.  
622. ' formats a double numeric string
623. FUNCTION FormatString$ (s#)
624.     x$ = ""
625.     s$ = STR$(s#)
626.     IF INSTR(s$, "D") THEN ' return string
627.         FormatString$ = s$
628.         EXIT FUNCTION
629.     END IF
630.     IF LEFT$(s$, 1) = "-" THEN ' store sign
631.         e$ = "-"
632.         s$ = MID$(s$, 2)
633.     END IF
634.     s$ = LTRIM$(s$) ' format string
635.     IF INSTR(s$, ".") THEN
636.         q$ = MID$(s$, INSTR(s$, "."))
637.         s$ = LEFT$(s$, INSTR(s$, ".") - 1)
638.     END IF
639.     FOR l = LEN(s$) TO 3 STEP -3
640.         x$ = MID$(s$, l - 2, 3) + "," + x$
641.     NEXT
642.     IF l > 0 THEN
643.         x$ = MID$(s$, 1, l) + "," + x$
644.     END IF
645.     IF LEN(s$) < 3 THEN
646.         x$ = s$
647.     END IF
648.     IF RIGHT$(x$, 1) = "," THEN
649.         x$ = LEFT$(x$, LEN(x$) - 1)
650.     END IF
651.     x$ = e$ + x$ + q$ ' construct string
652.     FormatString$ = x$
653. END FUNCTION
654.  
655. ' calculate byte suffix
656. SUB Suffix (Var#, Var3$)
657.     REM B  (Byte) = 00x - 0FFx (hexidecimal zero-based)
658.     REM KB (Kilobyte) = 1024 B
659.     REM MB (Megabyte) = 1024 KB (1 MB B)
660.     REM GB (Gigabyte) = 1024 MB
661.     REM TB (Terabyte) = 1024 GB (1 MB MB)
662.     REM PB (Petabyte) = 1024 TB
663.     REM EB (Exabyte) = 1024 PB (1 MB TB)
664.  
665.     ' check double
666.     VarX# = Var#
667.     s$ = STR$(VarX#)
668.     IF INSTR(s$, "D") THEN
669.         Var3$ = s$
670.         EXIT SUB
671.     END IF
672.  
673.     ' get sign
674.     IF VarX# < 0# THEN
675.         Sign = True
676.         VarX# = ABS(VarX#)
677.     END IF
678.  
679.     ' calculate bytes
680.     TempA = False
681.     DO
682.         IF VarX# >= 1024 THEN
683.             VarX# = VarX# / 1024
684.             TempA = TempA + 1
685.             IF TempA = 6 THEN
686.                 EXIT DO
687.             END IF
688.         ELSE
689.             EXIT DO
690.         END IF
691.     LOOP
692.  
693.     ' calculate byte string
694.     Var3$ = FormatString$(VarX#)
695.     IF INSTR(Var3$, ".") THEN
696.         Var3$ = LEFT$(Var3$, INSTR(Var3$, ".") + 1)
697.     ELSE
698.         Var3$ = Var3$ + ".0"
699.     END IF
700.  
701.     ' calculate byte suffix
702.     Var$ = ""
703.     IF TempA > 0 THEN
704.         Var$ = MID$("KMGTPE", TempA, 1)
705.     END IF
706.     Var3$ = Var3$ + " " + Var$ + "B"
707.  
708.     ' calculate byte sign
709.     IF Sign THEN
710.         Var3$ = "-" + Var3$
711.     END IF
712. END SUB
713.  
714.  
715.  
716.  
717. SUB MorePrompt (Input.String$, Input.Mask$, Output.String$)
718.     COLOR White, Black
719.     PRINT Input.String$ + " ";
720.     Input.Char$ = Nul
721.     DO
722.         LOCATE , , 1
723.         _LIMIT 100
724.         Input.Char$ = INKEY$
725.         IF LEN(Input.Char$) THEN
726.             Input.Char$ = LCASE$(Input.Char$)
727.             IF INSTR(Input.Mask$, Input.Char$) THEN
728.                 PRINT Input.Char$
729.                 Output.String$ = Input.Char$
730.                 EXIT DO
731.             END IF
732.         END IF
733.     LOOP
734. END SUB
735.  
736. ' lists specified drives.
737. SUB ListDrives (Var$, VarQ)
738.     ' Var$ = "x..." only list drives in string,
739.     ' otherwise,
740.     '   VarQ = 0 list all drives.
741.     '   VarQ = -1 except A: and B:
742.     CLS
743.     l = 0
744.     FOR c = 1 TO 26
745.         IF Var$ <> Nul THEN ' display specific drives.
746.             x$ = UCASE$(Var$)
747.             IF INSTR(x$, CHR$(c + 64)) THEN
748.                 x = INSTR(x$, CHR$(c + 64))
749.                 x = ASC(MID$(x$, x, 1))
750.                 IF x >= 65 AND x <= 90 THEN
751.                     x = x - 64
752.                     IF c = x THEN
753.  
754.                         GOSUB DisplayDrive
755.                     END IF
756.                 END IF
757.             END IF
758.         ELSE
759.             IF VarQ = 0 THEN ' list all drives
760.                 GOSUB DisplayDrive
761.             ELSE
762.                 ' except A: or B:
763.                 IF c >= 3 THEN
764.                     GOSUB DisplayDrive
765.                 END IF
766.             END IF
767.         END IF
768.         IF h = 20 THEN
769.             h = 0
770.             PRINT "-more-";
771.             DO
772.                 _LIMIT 50
773.                 I$ = INKEY$
774.                 IF LEN(I$) THEN
775.                     EXIT DO
776.                 END IF
777.             LOOP
778.         END IF
779.     NEXT
780.     EXIT SUB
781.  
782.     DisplayDrive:
783.     c$ = CHR$(c + 64)
784.     Out3 = c$
785.     IF DRIVEEXISTS(c) = 0 THEN
786.         h = h + 1
787.         l = l + 1
788.         q = -1
789.         REDIM _PRESERVE Drives(l) AS STRING
790.         Drives(l) = c$
791.  
792.         ' display volume label
793.         Out3 = c$
794.         CALL Vlabel(Out3)
795.         IF RTRIM$(Out3) = Nul THEN
796.             z$ = DriveType
797.         ELSE
798.             z$ = LEFT$(Out3, 12)
799.         END IF
800.         z$ = z$ + SPACE$(13 - LEN(z$))
801.  
802.         REDIM _PRESERVE DriveLabels(l) AS STRING
803.         DriveLabels(l) = z$
804.  
805.         ' display volume serial number
806.         Out3 = c$
807.         CALL Vserial(Out3)
808.         z$ = LEFT$(Out3, 12)
809.         z$ = z$ + SPACE$(13 - LEN(z$))
810.  
811.         REDIM _PRESERVE DriveSerials(l) AS STRING
812.         DriveSerials(l) = z$
813.  
814.         ' display volume file system type
815.         Out3 = c$
816.         CALL Vtype(Out3)
817.         z$ = LEFT$(Out3, 8)
818.         z$ = z$ + SPACE$(9 - LEN(z$))
819.  
820.         REDIM _PRESERVE DriveType(l) AS STRING
821.         DriveType(l) = z$
822.  
823.         ' display volume total disk space
824.         COLOR 11, 0
825.         CALL TotalSpace(Out3)
826.         x# = INT(VAL(Out3))
827.         x1# = x#
828.  
829.  
830.         REDIM _PRESERVE DiskTotalSpace(l) AS STRING
831.         IF x# > 0# THEN
832.             CALL Suffix(x#, S$) ' 1,024.0 KB
833.             DiskTotalSpace(l) = S$
834.         ELSE
835.             DiskTotalSpace(l) = "<n/a>"
836.         END IF
837.  
838.         ' display volume free disk space
839.         Out3 = c$
840.         CALL FreeSpace(Out3)
841.         y# = INT(VAL(Out3))
842.         y1# = y#
843.  
844.         REDIM _PRESERVE DiskFreeSpace(l) AS STRING
845.         IF y# > 0# THEN
846.             CALL Suffix(y#, S$) ' 1,024.0 KB
847.             DiskFreeSpace(l) = S$
848.         ELSE
849.             DiskFreeSpace(l) = "<n/a>"
850.         END IF
851.  
852.         ' display volume used disk space
853.         REDIM _PRESERVE DiskUsedSpace(l) AS STRING
854.         IF x1# > 0# OR y1# > 0# THEN
855.             z# = x1# - y1#
856.             CALL Suffix(z#, S$) ' 1,024.0 KB
857.             DiskUsedSpace(l) = S$
858.         ELSE
859.             DiskUsedSpace(l) = "<n/a>"
860.         END IF
861.     END IF
862.     RETURN
863.  
864.     '    DriveHeader:
865.     '    h = 2
866.     '   RETURN
867. END SUB
868.  
869. ' calculate byte suffix
870.  
871. ' formats a double numeric string
872.  
873. ' check drive exists.
874. '  returns -1 if drive not detected.
875. FUNCTION DRIVEEXISTS (V)
876.     VarX$ = CHR$(V + 64) + ":\" + CHR$(0)
877.     VarX = GetDriveType(VarX$)
878.     DriveType = Nul
879.     SELECT CASE VarX
880.         CASE 0
881.             DriveType = "[UNKNOWN]"
882.         CASE 1
883.             DriveType = "[BADROOT]"
884.         CASE 2
885.             DriveType = "[REMOVABLE]"
886.         CASE 3
887.             DriveType = "[FIXED]"
888.         CASE 4
889.             DriveType = "[REMOTE]"
890.         CASE 5
891.             DriveType = "[CDROM]"
892.         CASE 6
893.             DriveType = "[RAMDISK]"
894.     END SELECT
895.     IF VarX > 1 THEN
896.         DRIVEEXISTS = False
897.     ELSE
898.         DRIVEEXISTS = True
899.     END IF
900. END FUNCTION
901.  
902. ' get drive freespace
903. SUB FreeSpace (Var$)
904.     VarX$ = Var$ + ":\" + CHR$(0)
905.     Var$ = Nul
906.     IF DriveType = "[CDROM]" THEN
907.         EXIT SUB
908.     END IF
909.     IF DriveType = "[REMOVABLE]" THEN
910.         EXIT SUB
911.     END IF
912.     r = GetDiskFreeSpaceExA(VarX$, free~&&, total~&&, free2~&&)
913.     IF r THEN
914.         Var$ = LTRIM$(STR$(free~&&))
915.     END IF
916.     EXIT SUB
917.  
918.     r = GetDiskFreeSpaceA(VarX$, sectors&, bytes&, free&, total&)
919.     IF r THEN
920.         ' sectors per cluster * bytes per sector * free clusters
921.         x1# = CDBL(sectors&) * CDBL(bytes&) * CDBL(free&)
922.         Var$ = LTRIM$(STR$(x1#))
923.     END IF
924. END SUB
925.  
926. ' get drive totalspace
927. SUB TotalSpace (Var$)
928.     VarX$ = Var$ + ":\" + CHR$(0)
929.     Var$ = Nul
930.     IF DriveType = "[CDROM]" THEN
931.         EXIT SUB
932.     END IF
933.     IF DriveType = "[REMOVABLE]" THEN
934.         EXIT SUB
935.     END IF
936.     r = GetDiskFreeSpaceExA(VarX$, free~&&, total~&&, free2~&&)
937.     IF r THEN
938.         Var$ = LTRIM$(STR$(total~&&))
939.     END IF
940.     EXIT SUB
941.  
942.     r = GetDiskFreeSpaceA(VarX$, sectors&, bytes&, free&, total&)
943.     IF r THEN
944.         ' sectors per cluster * bytes per sector * total clusters
945.         x1# = CDBL(sectors&) * CDBL(bytes&) * CDBL(total&)
946.         Var$ = LTRIM$(STR$(x1#))
947.     END IF
948. END SUB
949.  
950. ' get volume label
951. SUB Vlabel (Var$)
952.     ' Note: in DOS the volume label was 8.3 format,
953.     '  however, in windows XP+ it is 32 char.
954.  
955.     ' get drive info.
956.     VarX$ = Var$ + ":\" + CHR$(0)
957.     Var$ = Nul
958.     Vname$ = SPACE$(MAX_PATH)
959.     Fname$ = SPACE$(MAX_PATH)
960.     R = GetVolumeInformationA(VarX$, Vname$, MAX_PATH, serial~&, empty1~&, empty2~&, Fname$, MAX_PATH)
961.     IF R THEN
962.         ' get volume label.
963.         Var$ = RTRIM$(Vname$)
964.         v = INSTR(Var$, CHR$(0))
965.         IF v THEN Var$ = LEFT$(Var$, v - 1)
966.     END IF
967. END SUB
968.  
969. ' get volume serial number
970. SUB Vserial (Var$)
971.  
972.     ' get drive info.
973.     VarX$ = Var$ + ":\" + CHR$(0)
974.     Var$ = Nul
975.     Vname$ = SPACE$(MAX_PATH)
976.     Fname$ = SPACE$(MAX_PATH)
977.     R = GetVolumeInformationA(VarX$, Vname$, MAX_PATH, serial~&, empty1~&, empty2~&, Fname$, MAX_PATH)
978.     IF R THEN
979.         ' serial number.
980.         Var$ = LEFT$(HEX$(serial~&), 4) + "-" + RIGHT$(HEX$(serial~&), 4)
981.     END IF
982. END SUB
983.  
984. ' get volume system type
985. SUB Vtype (Var$)
986.  
987.     ' get drive info.
988.     VarX$ = Var$ + ":\" + CHR$(0)
989.     Var$ = Nul
990.     Vname$ = SPACE$(MAX_PATH)
991.     Fname$ = SPACE$(MAX_PATH)
992.     R = GetVolumeInformationA(VarX$, Vname$, MAX_PATH, serial~&, empty1~&, empty2~&, Fname$, MAX_PATH)
993.     IF R THEN
994.         ' get volume system type.
995.         Var$ = RTRIM$(Fname$)
996.         v = INSTR(Var$, CHR$(0))
997.         IF v THEN Var$ = LEFT$(Var$, v - 1)
998.     END IF
999. END SUB
1000.  
1001. SUB Filtruj (maska AS STRING) 'prepise FileCount podle predimenzovaneho poctu zanamu do poli FileNames, FileSize, DateTimeFile a ShortNameFile. Zaznamy adresaru zustanou stejne!
1002.     DIM NewFileNames(1) AS STRING 'is for mask using. There was problem if is mask used directly, so this SUB is filtering all records in arrays for correct mask if is used.
1003.     DIM NewFileSize(1) AS DOUBLE
1004.     DIM NewDateTimeFile(1) AS STRING * 19
1005.     DIM NewShortNameFile(1) AS STRING
1006.     DIM NewAttrib(1) AS STRING
1007.     '    new = 1
1008.  
1009.     F$ = RIGHT$(maska$, 4): IF LEFT$(F$, 1) <> "." THEN BEEP: EXIT SUB 'invalid mask
1010.     FOR test = 1 TO FileCount
1011.         FileMask$ = RIGHT$(Filenames(test), 4)
1012.         IF FileMask$ = F$ THEN
1013.             New = New + 1
1014.             REDIM _PRESERVE NewFileNames(New) AS STRING
1015.             REDIM _PRESERVE NewFileSize(New) AS DOUBLE
1016.             REDIM _PRESERVE NewDateTimeFile(New) AS STRING * 19
1017.             REDIM _PRESERVE NewShortNameFile(New) AS STRING
1018.             REDIM _PRESERVE NewAttrib(New) AS STRING
1019.             NewFileNames(New) = Filenames(test)
1020.             NewFileSize(New) = FileSize(test)
1021.             NewDateTimeFile(New) = DateTimeFile(test)
1022.             NewShortNameFile(New) = ShortNameFile(test)
1023.  
1024.             'PRINT UBOUND(attrib), UBOUND(newattrib): SLEEP
1025.             'NewAttrib(New) = Attrib(DirCount + New)
1026.  
1027.         END IF
1028.     NEXT test
1029.     FileCount = New
1030.     REDIM Filenames(1) AS STRING
1031.     REDIM FileSize(1) AS DOUBLE
1032.     REDIM DateTimeFile(1) AS STRING * 19
1033.     REDIM ShortNameFile(1) AS STRING
1034.     '    REDIM Attrib(1) AS STRING
1035.  
1036.     ' REDIM _PRESERVE NewAttrib(UBOUND(newattrib) + DirCount) AS STRING
1037.     '   FOR DirAttrib = 1 TO DirCount
1038.     ' NewAttrib(DirAttrib) = Attrib(DirAttrib)
1039.     ' NEXT
1040.  
1041.     FOR ReWrite = 1 TO New
1042.  
1043.         REDIM _PRESERVE Filenames(ReWrite) AS STRING
1044.         REDIM _PRESERVE FileSize(ReWrite) AS DOUBLE
1045.         REDIM _PRESERVE DateTimeFile(ReWrite) AS STRING * 19
1046.         REDIM _PRESERVE ShortNameFile(ReWrite) AS STRING
1047.         REDIM _PRESERVE Attrib(DirCount + ReWrite) AS STRING
1048.  
1049.         Filenames(ReWrite) = NewFileNames(ReWrite)
1050.         FileSize(ReWrite) = NewFileSize(ReWrite)
1051.         DateTimeFile(ReWrite) = NewDateTimeFile(ReWrite)
1052.         ShortNameFile(ReWrite) = NewShortNameFile(ReWrite)
1053.         Attrib(ReWrite) = NewAttrib(ReWrite)
1054.     NEXT ReWrite
1055. END SUB
1056.  

[Petr]

I find original Erik´s source. Maybe it help more, because it is writed more clearly:

Code: QB64: [Select]

1. REM SOURCE BY EOREDSON!!!
2.  
3. REM sample program to get/list/sort lists of filenames/directories v1.0a PD.
4. ' detect operating system
5. $IF WIN = 0 THEN
6.     COLOR 15, 0
7.     CLS
8.     PRINT "Sorry, this program only works in Windows.."
9.     END
10. $END IF
11. REM $DYNAMIC
12. CONST MAX_PATH = 260
13. CONST INVALID_HANDLE_VALUE = -1
14.  
15. TYPE FILETIME
16.     dwLowDateTime AS _UNSIGNED LONG
17.     dwHighDateTime AS _UNSIGNED LONG
18. END TYPE
19.  
20. TYPE SYSTEMTIME
21.     wYear AS INTEGER
22.     wMonth AS INTEGER
23.     wDayOfWeek AS INTEGER
24.     wDay AS INTEGER
25.     wHour AS INTEGER
26.     wMinute AS INTEGER
27.     wSecond AS INTEGER
28.     wMilliseconds AS INTEGER
29. END TYPE
30.  
31. TYPE WIN32_FIND_DATAA
32.     dwFileAttributes AS _UNSIGNED LONG
33.     ftCreationTime AS FILETIME
34.     ftLastAccessTime AS FILETIME
35.     ftLastWriteTime AS FILETIME
36.     nFileSizeHigh AS _UNSIGNED LONG
37.     nFileSizeLow AS _UNSIGNED LONG
38.     dwReserved0 AS _UNSIGNED LONG
39.     dwReserved1 AS _UNSIGNED LONG
40.     cFileName AS STRING * MAX_PATH
41.     cAlternateFileName AS STRING * 14
42. END TYPE
43.  
44. DECLARE DYNAMIC LIBRARY "kernel32"
45.     FUNCTION FindFirstFileA~%& (BYVAL lpFileName~%&, BYVAL lpFindFileData~%&)
46.     FUNCTION FindNextFileA& (BYVAL hFindFile~%&, BYVAL lpFindFileData~%&)
47.     FUNCTION FindClose& (BYVAL hFindFile~%&)
48.     FUNCTION FileTimeToSystemTime& (lpFileTime AS FILETIME, lpSystemTime AS SYSTEMTIME)
49. END DECLARE
50.  
51. DIM SHARED Filenames(1) AS STRING
52. DIM SHARED Directories(1) AS STRING
53.  
54. DIM SHARED FileCount AS SINGLE
55. DIM SHARED DirCount AS SINGLE
56.  
57. DIM SHARED FileSize(1) AS DOUBLE
58.  
59. DIM SHARED DateTimeDir(1) AS STRING * 19 ' mm-dd-yyyy hh:mm:ss
60. DIM SHARED DateTimeFile(1) AS STRING * 19 ' mm-dd-yyyy hh:mm:ss
61.  
62. DIM SHARED AttributesDir(1) AS INTEGER
63. DIM SHARED AttributesFile(1) AS INTEGER
64.  
65. DIM SHARED ShortNameDir(1) AS STRING
66. DIM SHARED ShortNameFile(1) AS STRING
67.  
68. DIM SHARED LineCount AS INTEGER
69. DO
70.     PRINT "Filespec";
71.     INPUT Var$
72.     IF Var$ = "" THEN END
73.     CALL GetFiles(Var$)
74.     CALL SortFiles(-1)
75.     COLOR 14
76.     PRINT "Dirs:"; DirCount
77.     PRINT "Files:"; FileCount
78.     DO
79.         COLOR 15
80.         PRINT "Menu"
81.         PRINT "  (D)irs"
82.         PRINT "  (F)iles"
83.         PRINT "  (S)ort"
84.         PRINT "Option(Q to Quit)";
85.         LOCATE , , 1
86.         DO
87.             _LIMIT 50
88.             X$ = INKEY$
89.             IF LEN(X$) THEN
90.                 SELECT CASE LCASE$(X$)
91.                     CASE "q"
92.                         PRINT
93.                         EXIT DO
94.                     CASE "d"
95.                         PRINT
96.                         CALL ListDirs
97.                         EXIT DO
98.                     CASE "f"
99.                         PRINT
100.                         CALL ListFiles
101.                         EXIT DO
102.                     CASE "s"
103.                         PRINT
104.                         COLOR 15
105.                         PRINT "(A)scending, (D)escending?";
106.                         DO
107.                             _LIMIT 50
108.                             Q$ = INKEY$
109.                             IF LCASE$(Q$) = "a" THEN
110.                                 PRINT
111.                                 CALL SortFiles(-1)
112.                                 EXIT DO
113.                             END IF
114.                             IF LCASE$(Q$) = "d" THEN
115.                                 PRINT
116.                                 CALL SortFiles(0)
117.                                 EXIT DO
118.                             END IF
119.                         LOOP
120.                         LineCount = 25
121.                         N$ = MorePrompt$
122.                 END SELECT
123.             END IF
124.             IF LEN(Q$) THEN Q$ = "": EXIT DO
125.             IF LCASE$(X$) = "q" THEN EXIT DO
126.         LOOP
127.         IF LCASE$(X$) = "q" THEN EXIT DO
128.     LOOP
129. LOOP
130. END
131.  
132. SUB GetFiles (Var$)
133.     DIM Attribute AS INTEGER
134.     DIM ASCIIZ AS STRING * 260
135.     DIM finddata AS WIN32_FIND_DATAA
136.     DIM Wfile.Handle AS _UNSIGNED _OFFSET
137.     DIM SysTime AS SYSTEMTIME
138.  
139.     DirCount = 0!
140.     FileCount = 0!
141.     ASCIIZ = Var$ + CHR$(0)
142.     Wfile.Handle = FindFirstFileA(_OFFSET(ASCIIZ), _OFFSET(finddata))
143.     IF Wfile.Handle <> INVALID_HANDLE_VALUE THEN
144.         DO
145.             Attribute = finddata.dwFileAttributes
146.             Filename$ = finddata.cFileName
147.             Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
148.             IF Filename$ <> "." AND Filename$ <> ".." THEN
149.  
150.                 ' store date/time
151.                 x& = FileTimeToSystemTime&(finddata.ftLastWriteTime, SysTime)
152.                 Var$ = RIGHT$("00" + LTRIM$(STR$(SysTime.wMonth)), 2) + "-"
153.                 Var$ = Var$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wDay)), 2) + "-"
154.                 Var$ = Var$ + LTRIM$(STR$(SysTime.wYear)) + " "
155.                 Var$ = Var$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wMonth)), 2) + "-"
156.                 Var$ = Var$ + RIGHT$("00" + LTRIM$(STR$(SysTime.wDay)), 2) + "-"
157.                 Var$ = Var$ + LTRIM$(STR$(SysTime.wYear))
158.  
159.                 IF (Attribute AND &H10) = &H10 THEN
160.                     DirCount = DirCount + 1!
161.                     REDIM _PRESERVE Directories(DirCount) AS STRING
162.                     Directories(DirCount) = Filename$
163.  
164.                     REDIM _PRESERVE DateTimeDir(DirCount) AS STRING * 19
165.                     DateTimeDir(DirCount) = Var$
166.  
167.                     REDIM _PRESERVE AttributesDir(DirCount) AS INTEGER
168.                     AttributesDir(DirCount) = Attribute
169.  
170.                     Filename$ = finddata.cAlternateFileName
171.                     Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
172.                     REDIM _PRESERVE ShortNameDir(DirCount) AS STRING
173.                     ShortNameDir(DirCount) = Filename$
174.                 ELSE
175.                     FileCount = FileCount + 1!
176.                     REDIM _PRESERVE Filenames(FileCount) AS STRING
177.                     Filenames(FileCount) = Filename$
178.                     REDIM _PRESERVE FileSize(FileCount) AS DOUBLE
179.                     F# = finddata.nFileSizeHigh * &H100000000~&& OR finddata.nFileSizeLow
180.                     FileSize(FileCount) = F#
181.  
182.                     REDIM _PRESERVE DateTimeFile(FileCount) AS STRING * 19
183.                     DateTimeFile(FileCount) = Var$
184.  
185.                     REDIM _PRESERVE AttributesFile(FileCount) AS INTEGER
186.                     AttributesFile(FileCount) = Attribute
187.  
188.                     Filename$ = finddata.cAlternateFileName
189.                     Filename$ = LEFT$(Filename$, INSTR(Filename$, CHR$(0)) - 1)
190.                     REDIM _PRESERVE ShortNameFile(FileCount) AS STRING
191.                     ShortNameFile(FileCount) = Filename$
192.                 END IF
193.             END IF
194.         LOOP WHILE FindNextFileA(Wfile.Handle, _OFFSET(finddata))
195.         x = FindClose(Wfile.Handle)
196.     END IF
197. END SUB
198.  
199. SUB SortFiles (Var) ' Var=-1 ascending
200.     FOR X! = 1! TO DirCount
201.         FOR Y! = X! + 1! TO DirCount
202.             IF Var THEN
203.                 IF Directories(X!) > Directories(Y!) THEN
204.                     SWAP Directories(X!), Directories(Y!)
205.                     SWAP ShortNameDir(X!), ShortNameDir(Y!)
206.                     SWAP DateTimeDir(X!), DateTimeDir(Y!)
207.                     SWAP AttributesDir(X!), AttributesDir(Y!)
208.                 END IF
209.             ELSE
210.                 IF Directories(X!) < Directories(Y!) THEN
211.                     SWAP Directories(X!), Directories(Y!)
212.                     SWAP ShortNameDir(X!), ShortNameDir(Y!)
213.                     SWAP DateTimeDir(X!), DateTimeDir(Y!)
214.                     SWAP AttributesDir(X!), AttributesDir(Y!)
215.                 END IF
216.             END IF
217.         NEXT
218.     NEXT
219.     FOR X! = 1! TO FileCount
220.         FOR Y! = X! + 1! TO FileCount
221.             IF Var THEN
222.                 IF Filenames(X!) > Filenames(Y!) THEN
223.                     SWAP Filenames(X!), Filenames(Y!)
224.                     SWAP ShortNameFile(X!), ShortNameFile(Y!)
225.                     SWAP FileSize(X!), FileSize(Y!)
226.                     SWAP DateTimeFile(X!), DateTimeFile(Y!)
227.                     SWAP AttributesFile(X!), AttributesFile(Y!)
228.                 END IF
229.             ELSE
230.                 IF Filenames(X!) < Filenames(Y!) THEN
231.                     SWAP Filenames(X!), Filenames(Y!)
232.                     SWAP ShortNameFile(X!), ShortNameFile(Y!)
233.                     SWAP FileSize(X!), FileSize(Y!)
234.                     SWAP DateTimeFile(X!), DateTimeFile(Y!)
235.                     SWAP AttributesFile(X!), AttributesFile(Y!)
236.                 END IF
237.             END IF
238.         NEXT
239.     NEXT
240. END SUB
241.  
242. FUNCTION MorePrompt$
243.     LineCount = LineCount + 1
244.     IF LineCount >= 24 THEN
245.         LineCount = 2
246.         COLOR 15
247.         PRINT "-more-";
248.         DO
249.             _LIMIT 50
250.             X$ = INKEY$
251.             IF LEN(X$) THEN
252.                 PRINT
253.                 MorePrompt$ = LCASE$(X$)
254.                 EXIT FUNCTION
255.             END IF
256.         LOOP
257.     END IF
258. END FUNCTION
259.  
260. SUB ListFiles
261.  
262.     ' display header
263.     COLOR 15
264.     GOSUB TitleHeader
265.  
266.     LineCount = 3
267.     c = 0
268.     q = 0
269.     t = 0
270.     f! = 0!
271.     FOR VarQ = 1 TO FileCount
272.         f! = f! + 1!
273.         q = -1
274.         IF t THEN
275.             t = 0
276.             GOSUB TitleHeader
277.         END IF
278.  
279.         ' print shortfilename
280.         z$ = ShortNameFile(VarQ)
281.         z$ = RTRIM$(z$)
282.         IF z$ = "" THEN
283.             z$ = Filenames(VarQ)
284.         END IF
285.         IF LEN(z$) > 12 THEN
286.             z$ = LEFT$(z$, 12)
287.         END IF
288.         COLOR 14
289.         PRINT UCASE$(z$);
290.         IF LEN(z$) <= 14 THEN
291.             PRINT SPACE$(14 - LEN(z$));
292.         END IF
293.  
294.         ' print date/time
295.         COLOR 10
296.         PRINT DateTimeFile(VarQ);
297.  
298.         ' attributes of filename
299.         Var% = AttributesFile(VarQ)
300.         Attr$ = SPACE$(5)
301.         IF (Var% AND &H20) = &H20 THEN
302.             MID$(Attr$, 1, 1) = "A" ' archive
303.         END IF
304.         IF (Var% AND &H4) = &H4 THEN
305.             MID$(Attr$, 3, 1) = "S" ' system
306.         END IF
307.         IF (Var% AND &H2) = &H2 THEN
308.             MID$(Attr$, 4, 1) = "H" ' hidden
309.         END IF
310.         IF (Var% AND &H1) = &H1 THEN
311.             MID$(Attr$, 5, 1) = "R" ' read-only
312.         END IF
313.         COLOR 12
314.         PRINT "  "; Attr$; " ";
315.  
316.         ' print filesize
317.         Var# = FileSize(VarQ)
318.         VarX# = VarX# + Var# ' add bytes
319.         CALL Suffix(Var#, z$) ' 1,024.0 KB
320.         z$ = LEFT$(z$, 10)
321.         z$ = SPACE$(10 - LEN(z$)) + z$
322.         COLOR 11
323.         PRINT z$; " ";
324.  
325.         ' print longfilename
326.         z$ = Filenames(VarQ)
327.         z$ = RTRIM$(z$)
328.         IF LEN(z$) THEN
329.             IF LEN(z$) > 25 THEN
330.                 z$ = LEFT$(z$, 24) + "..."
331.             END IF
332.             COLOR 14
333.             PRINT z$;
334.         END IF
335.         PRINT
336.         IF MorePrompt$ = "n" THEN
337.             EXIT FOR
338.         END IF
339.     NEXT
340.     IF q = 0 THEN
341.         COLOR 14
342.         PRINT "No files found."
343.     END IF
344.  
345.     ' print totals
346.     COLOR 15
347.     PRINT "------------                             ----------"
348.     TotalLine$ = "Files " + FormatString$(CDBL(f!))
349.     TotalLine$ = LEFT$(TotalLine$, 40)
350.     TotalLine$ = TotalLine$ + SPACE$(40 - LEN(TotalLine$))
351.  
352.     CALL Suffix(VarX#, z$) ' 1,024.0 KB
353.     TotalLine$ = TotalLine$ + SPACE$(11 - LEN(z$)) + z$
354.     PRINT TotalLine$
355.     EXIT SUB
356.  
357.     TitleHeader:
358.     COLOR 15
359.     PRINT "Filename      Date        Time     Attr        Size Longfilename"
360.     PRINT "------------  ----------  -------- ----- ---------- ------------"
361.     RETURN
362. END SUB
363.  
364. SUB ListDirs
365.  
366.     ' display header
367.     COLOR 15
368.     GOSUB TitleHeader
369.  
370.     LineCount = 3
371.     c = 0
372.     q = 0
373.     t = 0
374.     f! = 0!
375.     FOR VarQ = 1 TO DirCount
376.         f! = f! + 1!
377.         q = -1
378.         IF t THEN
379.             t = 0
380.             GOSUB TitleHeader
381.         END IF
382.  
383.         ' print shortfilename
384.         z$ = ShortNameDir(VarQ)
385.         z$ = RTRIM$(z$)
386.         IF z$ = "" THEN
387.             z$ = Directories(VarQ)
388.         END IF
389.         IF LEN(z$) > 12 THEN
390.             z$ = LEFT$(z$, 12)
391.         END IF
392.         COLOR 14
393.         PRINT UCASE$(z$);
394.         IF LEN(z$) <= 14 THEN
395.             PRINT SPACE$(14 - LEN(z$));
396.         END IF
397.  
398.         ' print date/time
399.         COLOR 10
400.         PRINT DateTimeDir(VarQ);
401.  
402.         ' attributes of filename
403.         Var% = AttributesDir(VarQ)
404.         Attr$ = SPACE$(5)
405.         IF (Var% AND &H20) = &H20 THEN
406.             MID$(Attr$, 1, 1) = "A" ' archive
407.         END IF
408.         IF (Var% AND &H4) = &H4 THEN
409.             MID$(Attr$, 3, 1) = "S" ' system
410.         END IF
411.         IF (Var% AND &H2) = &H2 THEN
412.             MID$(Attr$, 4, 1) = "H" ' hidden
413.         END IF
414.         IF (Var% AND &H1) = &H1 THEN
415.             MID$(Attr$, 5, 1) = "R" ' read-only
416.         END IF
417.         COLOR 12
418.         PRINT "  "; Attr$; " ";
419.  
420.         ' print longfilename
421.         z$ = Directories(VarQ)
422.         z$ = RTRIM$(z$)
423.         IF LEN(z$) THEN
424.             IF LEN(z$) > 35 THEN
425.                 z$ = LEFT$(z$, 34) + "..."
426.             END IF
427.             COLOR 14
428.             PRINT z$;
429.         END IF
430.         PRINT
431.         IF MorePrompt$ = "n" THEN
432.             EXIT FOR
433.         END IF
434.     NEXT
435.     IF q = 0 THEN
436.         COLOR 14
437.         PRINT "No dirs found."
438.     END IF
439.  
440.     ' print totals
441.     COLOR 15
442.     PRINT "------------"
443.     TotalLine$ = "Dirs " + FormatString$(CDBL(f!))
444.     PRINT TotalLine$
445.     EXIT SUB
446.  
447.     TitleHeader:
448.     COLOR 15
449.     PRINT "Filename      Date        Time     Attr  Longfilename"
450.     PRINT "------------  ----------  -------- ----- ------------"
451.     RETURN
452. END SUB
453.  
454. ' formats a double numeric string
455. FUNCTION FormatString$ (s#)
456.     x$ = ""
457.     s$ = STR$(s#)
458.     IF INSTR(s$, "D") THEN ' return string
459.         FormatString$ = s$
460.         EXIT FUNCTION
461.     END IF
462.     IF LEFT$(s$, 1) = "-" THEN ' store sign
463.         e$ = "-"
464.         s$ = MID$(s$, 2)
465.     END IF
466.     s$ = LTRIM$(s$) ' format string
467.     IF INSTR(s$, ".") THEN
468.         q$ = MID$(s$, INSTR(s$, "."))
469.         s$ = LEFT$(s$, INSTR(s$, ".") - 1)
470.     END IF
471.     FOR l = LEN(s$) TO 3 STEP -3
472.         x$ = MID$(s$, l - 2, 3) + "," + x$
473.     NEXT
474.     IF l > 0 THEN
475.         x$ = MID$(s$, 1, l) + "," + x$
476.     END IF
477.     IF LEN(s$) < 3 THEN
478.         x$ = s$
479.     END IF
480.     IF RIGHT$(x$, 1) = "," THEN
481.         x$ = LEFT$(x$, LEN(x$) - 1)
482.     END IF
483.     x$ = e$ + x$ + q$ ' construct string
484.     FormatString$ = x$
485. END FUNCTION
486.  
487. ' calculate byte suffix
488. SUB Suffix (Var#, Var3$)
489.     REM B  (Byte) = 00x - 0FFx (hexidecimal zero-based)
490.     REM KB (Kilobyte) = 1024 B
491.     REM MB (Megabyte) = 1024 KB (1 MB B)
492.     REM GB (Gigabyte) = 1024 MB
493.     REM TB (Terabyte) = 1024 GB (1 MB MB)
494.     REM PB (Petabyte) = 1024 TB
495.     REM EB (Exabyte) = 1024 PB (1 MB TB)
496.  
497.     ' check double
498.     VarX# = Var#
499.     s$ = STR$(VarX#)
500.     IF INSTR(s$, "D") THEN
501.         Var3$ = s$
502.         EXIT SUB
503.     END IF
504.  
505.     ' get sign
506.     IF VarX# < 0# THEN
507.         Sign = True
508.         VarX# = ABS(VarX#)
509.     END IF
510.  
511.     ' calculate bytes
512.     TempA = False
513.     DO
514.         IF VarX# >= 1024 THEN
515.             VarX# = VarX# / 1024
516.             TempA = TempA + 1
517.             IF TempA = 6 THEN
518.                 EXIT DO
519.             END IF
520.         ELSE
521.             EXIT DO
522.         END IF
523.     LOOP
524.  
525.     ' calculate byte string
526.     Var3$ = FormatString$(VarX#)
527.     IF INSTR(Var3$, ".") THEN
528.         Var3$ = LEFT$(Var3$, INSTR(Var3$, ".") + 1)
529.     ELSE
530.         Var3$ = Var3$ + ".0"
531.     END IF
532.  
533.     ' calculate byte suffix
534.     Var$ = ""
535.     IF TempA > 0 THEN
536.         Var$ = MID$("KMGTPE", TempA, 1)
537.     END IF
538.     Var3$ = Var3$ + " " + Var$ + "B"
539.  
540.     ' calculate byte sign
541.     IF Sign THEN
542.         Var3$ = "-" + Var3$
543.     END IF
544. END SUB
545.  

[Cobalt]

Or Trim it outside of the loop if they're DIM AS STRING.
FOR I = 1 TO LIMIT
    FFiles(I).NameL = RTRIM$(FFiles(I).NameL)
NEXT
Then do the IFs and all.

Unfortuantly they are fixed length strings inside a TYPE.
I was going to break it down into a dozen DIMs cause the memory issue with large arrays i was having but your example in that post

DIM m AS _MEM, sz AS _INTEGER64
DO
    sz = sz + 10000000 '10 million bytes at a time
    PRINT sz
    m = _MEMNEW(sz) 'reserve a data space of proper size
    _MEMFREE m
LOOP

gave me the idea to try an use MEM to get it done, which works.(which my machine allowed 2 150 000 000 using MEM)
It would take quite a bit of recoding at this point to go back and DIM each element. now if we could use variable length strings in types that would change things but ,like arrays in type, that will never happen.

File omission would mean having a program that is not 100 percent. So I'll ask about the nature of the problem. How do you get a list of files on a disk? Are you using Linux and / or Windows?

true, but I'm willing to accept a certain % of error(in missed duplicates), and as there are only about 400 files with such characters its not really worth recoding a large portion to fix, I was just wondering if there was a simple solution I had missed, thought about bout using DIR and having it generate the 12 character file names too, thats how I accomplished this back in QB45. Didn't realize QB64 would need to go that route too. but thanks anyway, If I decide to revisit this endeavor in the future I'll keep that code in mind.

[Petr]

Okay, but Erik's program will return both types of fields, so 8.3 and long name. I think the adjustment should not be too drastic :-D

[PMACKAY]

_CONTROLCHR OFF 


NOT SURE BUT WONDER IF THE BOVE WILL WORK

[FellippeHeitor]

Not the same functionality. What _CONTROLCHR OFF does is prevent low ascii characters from performing as they usually do in terminals, like CHR$(10) creating a new line, CHR$(9) moving the cursor ahead etc.