« previous next »
Pages: [1]   Go Down

Author Topic: Binary (BCD) Clock  (Read 4263 times)

0 Members and 1 Guest are viewing this topic.

Offline RhoSigma

  • QB64 Developer
  • Forum Resident
  • Posts: 565
    • View Profile
Binary (BCD) Clock
« on: September 10, 2018, 06:41:39 pm »
Hi all,
wasn't in the mood to work on my GuiTools project today, instead I created this one, enjoy....

NOTE: On Linux/MacOS you probably need to adjust the _LOADFONT line.

Code: QB64: [Select]
  1. '+---------------+---------------------------------------------------+
  2. '| ###### ###### |     .--. .         .-.                            |
  3. '| ##  ## ##   # |     |   )|        (   ) o                         |
  4. '| ##  ##  ##    |     |--' |--. .-.  `-.  .  .-...--.--. .-.        |
  5. '| ######   ##   |     |  \ |  |(   )(   ) | (   ||  |  |(   )       |
  6. '| ##      ##    |     '   `'  `-`-'  `-'-' `-`-`|'  '  `-`-'`-      |
  7. '| ##     ##   # |                            ._.'                   |
  8. '| ##     ###### |  Sources & Documents placed in the Public Domain. |
  9. '+---------------+---------------------------------------------------+
  10. '|                                                                   |
  11. '| === BinClock.bas ===                                              |
  12. '|                                                                   |
  13. '| == A simple binary (BCD) clock inspired by the alien countdown    |
  14. '| == from the movie "Mission to Mars".                              |
  15. '|                                                                   |
  16. '+-------------------------------------------------------------------+
  17. '| Done by RhoSigma, R.Heyder, provided AS IS, use at your own risk. |
  18. '| Find me in the QB64 Forum or mail to support&rhosigma-cw.net for  |
  19. '| any questions or suggestions. Thanx for your interest in my work. |
  20. '+-------------------------------------------------------------------+
  21.  
  22. 'setup screen
  23. SCREEN _NEWIMAGE(875, 395, 256)
  24. scrFont& = _LOADFONT("C:\Windows\Fonts\timesbd.ttf", 72)
  25. _FONT scrFont&
  26.  
  27. '3D space origin is on these screen coordinates
  28. DIM SHARED cx%: cx% = 30
  29. DIM SHARED cy%: cy% = 250
  30.  
  31. 'init BCD discs
  32. TYPE Disc
  33.     x AS INTEGER
  34.     y AS INTEGER
  35.     z AS INTEGER
  36.     r AS INTEGER
  37.     a AS INTEGER
  39. DIM SHARED Discs(23) AS Disc
  40. InitDiscs
  41. DIM SHARED curState&: curState& = 0
  42. DIM SHARED newState&: newState& = 0
  43.  
  44. 'draw hour/minute/seconds separators
  45. Line3D 175, 0, 0, 175, 440, 0, 2
  46. Line3D 175, 0, 0, 175, 0, -110, 2
  47. Line3D 425, 0, 0, 425, 440, 0, 2
  48. Line3D 425, 0, 0, 425, 0, -110, 2
  49.  
  50. 'main loop
  53.     _LIMIT 1
  54.     FlipDiscs
  58. _FREEFONT scrFont&
  60.  
  61. 'run the clock
  62. SUB FlipDiscs
  63. t$ = TIME$
  64. newState& = (VAL(MID$(t$, 1, 1)) * (2 ^ 20)) + (VAL(MID$(t$, 2, 1)) * (2 ^ 16)) +_
  65.             (VAL(MID$(t$, 4, 1)) * (2 ^ 12)) + (VAL(MID$(t$, 5, 1)) * (2 ^ 8)) +_
  66.             (VAL(MID$(t$, 7, 1)) * (2 ^ 4)) + (VAL(MID$(t$, 8, 1)) * (2 ^ 0))
  67. diff& = curState& XOR newState&
  68. curState& = newState&
  69. FOR rot% = 1 TO 90
  70.     FOR n% = 0 TO 23
  71.         IF (n% MOD 4) = 0 THEN AxisSegments Discs(n%).x
  72.         IF diff& AND (2 ^ n%) THEN
  73.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a, 0
  74.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a + 1, 15
  75.             Discs(n%).a = Discs(n%).a + 1
  76.             IF Discs(n%).a = 180 THEN Discs(n%).a = 0
  77.         ELSE
  78.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a, 15
  79.         END IF
  80.     NEXT n%
  81.     IF rot% = 60 THEN
  82.         COLOR 1
  83.         _PRINTSTRING (50, 280), MID$(t$, 1, 2)
  84.         _PRINTSTRING (300, 280), MID$(t$, 4, 2)
  85.         _PRINTSTRING (550, 280), MID$(t$, 7, 2)
  86.     END IF
  87.     _DISPLAY
  88. NEXT rot%
  90.  
  91. 'setup start values for all discs
  92. SUB InitDiscs
  93. n% = 0
  94. FOR i% = 600 TO 500 STEP -100
  95.     FOR j% = 70 TO 370 STEP 100
  96.         Discs(n%).x = i%
  97.         Discs(n%).y = j%
  98.         Discs(n%).z = 0
  99.         Discs(n%).r = 30
  100.         Discs(n%).a = 0
  101.         n% = n% + 1
  102.     NEXT j%
  103. NEXT i%
  104. FOR i% = 350 TO 250 STEP -100
  105.     FOR j% = 70 TO 370 STEP 100
  106.         Discs(n%).x = i%
  107.         Discs(n%).y = j%
  108.         Discs(n%).z = 0
  109.         Discs(n%).r = 30
  110.         Discs(n%).a = 0
  111.         n% = n% + 1
  112.     NEXT j%
  113. NEXT i%
  114. FOR i% = 100 TO 0 STEP -100
  115.     FOR j% = 70 TO 370 STEP 100
  116.         Discs(n%).x = i%
  117.         Discs(n%).y = j%
  118.         Discs(n%).z = 0
  119.         Discs(n%).r = 30
  120.         Discs(n%).a = 0
  121.         n% = n% + 1
  122.     NEXT j%
  123. NEXT i%
  125.  
  126. 'draw rotation axis segments between discs
  127. SUB AxisSegments (x%)
  128. Line3D x%, 0, 0, x%, 40, 0, 4
  129. Line3D x%, 100, 0, x%, 140, 0, 4
  130. Line3D x%, 200, 0, x%, 240, 0, 4
  131. Line3D x%, 300, 0, x%, 340, 0, 4
  132. Line3D x%, 400, 0, x%, 440, 0, 4
  134.  
  135. SUB Line3D (x1%, y1%, z1%, x2%, y2%, z2%, col%)
  136. 'x1%/y1%/z1% = start, x2%/y2%/z2% = end, col% = color pen
  137. x1# = (x1% + (y1% * 0.5)): z1# = (z1% + (y1% * 0.5))
  138. x2# = (x2% + (y2% * 0.5)): z2# = (z2% + (y2% * 0.5))
  139. LINE (x1# + cx% - 1, -z1# + cy%)-(x2# + cx% - 1, -z2# + cy%), col%
  140. LINE (x1# + cx%, -z1# + cy%)-(x2# + cx%, -z2# + cy%), col%
  141. LINE (x1# + cx% + 1, -z1# + cy%)-(x2# + cx% + 1, -z2# + cy%), col%
  143.  
  144. SUB Circle3D (x%, y%, z%, r%, ba%, col%)
  145. 'x%/y%/z% = center, r% = radius, ba% = B-Axis angle, col% = color pen
  146. mx# = (x% + (y% * 0.5)): mz# = (z% + (y% * 0.5))
  147. zx# = r% * COS(ba% * 0.01745329)
  148. zz# = r% * SIN(ba% * 0.01745329)
  149. FOR cir% = 0 TO 359 STEP 5
  150.     x# = zx# * COS(cir% * 0.01745329)
  151.     y# = r% * SIN(cir% * 0.01745329)
  152.     z# = zz# * COS(cir% * 0.01745329)
  153.     x# = (x# + (y# * 0.5)): z# = (z# + (y# * 0.5))
  154.     LINE (x# + mx# + cx% - 1, -z# + -mz# + cy% - 1)-(x# + mx# + cx% + 1, -z# + -mz# + cy% + 1), col%, BF
  155. NEXT cir%
  157.  
  158.  
« Last Edit: January 27, 2022, 12:08:15 pm by RhoSigma »
Logged
My Projects:   https://qb64forum.alephc.xyz/index.php?topic=809
GuiTools - A graphic UI framework (can do multiple UI forms/windows in one program)
Libraries - ImageProcess, StringBuffers (virt. files), MD5/SHA2-Hash, LZW etc.
Bonus - Blankers, QB64/Notepad++ setup pack

Offline TerryRitchie

  • Seasoned Forum Regular
  • Posts: 495
  • Semper Fidelis
    • View Profile
Re: Binary (BCD) Clock
« Reply #1 on: September 10, 2018, 07:08:16 pm »
Awesome! I remember where that was in the movie too.
Logged
In order to understand recursion, one must first understand recursion.

Offline RhoSigma

  • QB64 Developer
  • Forum Resident
  • Posts: 565
    • View Profile
Re: Binary (BCD) Clock
« Reply #2 on: September 11, 2018, 01:47:47 am »
Glad, that you like it.
Logged
My Projects:   https://qb64forum.alephc.xyz/index.php?topic=809
GuiTools - A graphic UI framework (can do multiple UI forms/windows in one program)
Libraries - ImageProcess, StringBuffers (virt. files), MD5/SHA2-Hash, LZW etc.
Bonus - Blankers, QB64/Notepad++ setup pack

Offline TerryRitchie

  • Seasoned Forum Regular
  • Posts: 495
  • Semper Fidelis
    • View Profile
Re: Binary (BCD) Clock
« Reply #3 on: September 11, 2018, 02:05:23 am »
The wife saw it running and said, "Hey, isn't that like the clock on the floor from that Mars movie?" LOL
Logged
In order to understand recursion, one must first understand recursion.
Pages: [1]   Go Up
« previous next »