CLEARCOLOR not working.(figured out)

[Cobalt]

As the subject line says, I find myself in a situation where it appears that CLEARCOLOR wont work. Not completely as I have 2 layers that are is working and 2 layers where it is not working. In this code the layers that work are LOADIMAGE handles so I've tried to do the same with the layers that were not working but it still doesn't act right.
so in the demo here what is going on is, the layer for the drawn map(62) is placed first then the sprite layer(63) that has the peasant on it then the main window(HUMAN) is on top. then it repeats. I have added delays so you can see the series of events, without an epileptic seizure hopefully, and watch as the map layer erases the window layer, then the map layer gets erased by the sprite layer but the window layer doesn't erase the sprite layer. so the window layer's clear color of 0,0,0 is working but the other two layers that have the same clearcolor of 0,0,0 is not. (and if you just have drawsprite itself on top of something the background color of the peasant sprite sheet(224,224,224) is also clear and works properly.)

Maybe its some nuance with clearcolor I'm not picking up or I've missed something in-between.

Code: QB64: [Select]

1. 'WarCraft 64
2. '2018-08-29 00:10
3. 'last update 01:30 2018-09-01
4. 'Build Count 0013
5. 'Kobolt
6. '
7. 'Routine
8. 'SetPath (Path() AS Coord, StartPos AS Coord, TargetPos AS Coord, Map())
9. '  -Path()   - the array for the path found from StartPos to TargetPos   [UNITS.PATH()]
10. '  -StartPos - the Begining Location of the unit                         [Unit().Movement.MapX, Unit().Movement.MapY]
11. '  -TargetPos- where the player clicked the mouse to have unit reach     [MapClick.X, MapClick.Y]
12. '  -Map()    - the map array to search for a path in                     [Map()]
13. '
14. 'Loadlayers()
15. '  -Load sprite and tile sheets
16. '
17. 'MapDrawer (Lx%, Ly%, Sx~%%, Sy~%%, Scale%%, Sets%%, Lay%%)
18. '  -Lx%,Ly%    - screen pos to draw map
19. '  -Sx~%%,Sy~%%- start pos to read map data
20. '  -Scale%%    - tile size to display 1x or 2x
21. '  -Sets%%     - Tile Set to use, Plains[26] or Swamp[0] (and maybe Cave)
22. '  -Lay%%      - layer to draw map on
23. '
24. 'DrawSprite(Lx%, Ly%,Mx~%%, My~%%, Scale%%, D%%)
25. '  -Draws a Units sprites
26. '  -Lx%,Ly%    - screen pos to draw sprite
27. '  -Mx~%%,My~%%- Current start pos of the map being displayed
28. '  -Scale%%    - sprite size to display 1x or 2x
29. '  -D%%        - Destination layer to draw sprite on
30.  
31. TYPE Coord: x AS INTEGER: y AS INTEGER: END TYPE
32.  
33. TYPE PathCoord
34.  pos AS Coord ' Coordinates of position on map
35.  parent AS Coord ' Coordinates of previous position on path
36.  g AS INTEGER ' G cost value
37.  h AS INTEGER ' H cost value
38.  f AS INTEGER ' F = G + H (total movement cost)
39.  status AS INTEGER ' 0 for unsearched, 1 for open, 2 for closed (explored)
40. END TYPE
41.  
42. TYPE SpriteData
43.  IDmark AS _BYTE '    which sprite is it (1-Unit(0), 2-Peon ect...)
44.  MapX AS _BYTE '      current Map square occupied
45.  MapY AS _BYTE '      current Map square occupied
46.  xloc AS SINGLE '     screen x location
47.  yloc AS SINGLE '     screen y location
48.  MoveAngle AS SINGLE 'direction sprite is moving
49.  MoveSpeed AS SINGLE 'speed at which sprite is moving
50.  Direction AS _BYTE ' sprite image faceing direction
51.  Frame AS _BYTE '     which frame of animation sprite is on
52.  Is_Moving AS _BYTE '  is the unit currently moving?
53.  PathID AS _UNSIGNED _BYTE '
54. END TYPE
55.  
56. TYPE UnitData
57.  Movement AS SpriteData 'inherited data
58.  HP AS _UNSIGNED _BYTE ' a unit hit tolerance, includeing buildings and resources
59.  HPM AS _UNSIGNED _BYTE 'a units max hit tolerance
60.  Armor AS _BYTE '        units defence from an attack
61.  Range AS _BYTE '        distance a unit can attack from
62.  DamLo AS _BYTE '        minimal damage a unit can do
63.  DamHi AS _BYTE '        Maximum damage a unit can do
64.  CostG AS INTEGER '      Gold cost of unit to be produced
65.  CostW AS INTEGER '      Wood Cost of unit to be produced
66.  Act AS _BYTE '          is unit moving, mining, chopping wood, attacking, carrying wood or gold
67.  Build AS _BYTE '        Time in seconds to build unit Based on Normal Speed X2.25 on slowest  X0.45 Fastest
68. END TYPE
69.  
70. TYPE StructureData
71.  Structure AS SpriteData '   not all elements used
72.  HP AS _UNSIGNED INTEGER '   a structures remaining hit tolerance
73.  HPM AS _UNSIGNED INTEGER '  a structures Max hit tolerance
74.  Gold AS _UNSIGNED INTEGER ' a mines remaining gold reserve
75. END TYPE
76.  
77. TYPE MapAttrib
78.  TileId AS _UNSIGNED _BYTE
79.  Is_Walkable AS _BYTE
80. END TYPE
81.  
82. TYPE Gamedata
83.  MapX AS _BYTE 'top left corner of the area of map the player
84.  MapY AS _BYTE ' is currently veiwing
85. END TYPE
86.  
87. CONST TRUE = -1, FALSE = NOT TRUE 'Duh and DUH
88. CONST Ts = 17, Tc = 37 'tile box size, tile count per line
89. 'action constants
90. CONST Still = 0, Moving = 1, Mining = 2, LumberJack = 3, Attacking = 4, CarryWood = 5
91. CONST CarryGold = 6, Shooting = 7, Casting = 8, Decomposing = 9, Removal = 10
92. 'Direction constants
93. CONST North = 0, NorthEast = 1, East = 2, SouthEast = 3, South = 4, SouthWest = 5, West = 6, NorthWest = 7
94. 'Unit Constants
95. CONST Peasant = 1, Peon = 2, Footman = 3, Grunt = 4, Archer = 5, Spearman = 6, Knight = 7, Raider = 8
96. CONST Cleric = 9, Necrolyte = 10, Conjurer = 11, Warlock = 12, SkeletonO = 13, Skeleton = 14
97. CONST Deamon = 15, WaterElemt = 16, FireElemt = 17, Lothar = 18
98. 'Tile sets
99. CONST Plains = 26, Swamp = 0, Cave = 28
100. 'Player screens
101. CONST Human = 27, Orc = 28
102. 'Game Tile\Sprite scaling
103. CONST Scaling = 2
104.  
105. DIM SHARED Map(63, 63) AS MapAttrib
106. DIM SHARED Unit(255) AS UnitData, Units.Path(512) AS Coord
107. DIM SHARED Layer(64) AS _UNSIGNED LONG
108. DIM SHARED Anima(32, 7) AS _BYTE 'movement animation sequince
109. DIM SHARED Game AS Gamedata
110.  
111. DIM Path(2048) AS Coord '' Dimension array of path coords to be filled in later
112. DIM startpos AS Coord, targetpos AS Coord
113.  
114. LoadLayers
115. FOR AnimaA%% = 0 TO 2
116.  FOR AnimaB%% = 0 TO 7
117.   READ Anima(AnimaA%%, AnimaB%%)
118.  NEXT
119. NEXT
120.  
121. OPEN "testmap.dat" FOR BINARY AS #1
122. GET #1, , Map()
123. CLOSE #1
124.  
125. SCREEN _NEWIMAGE(640, 480, 32)
126. _CLEARCOLOR _RGB32(224, 224, 224), Layer(Peasant) 'works
127. _CLEARCOLOR _RGB32(0, 0, 0), Layer(62) 'does not work?
128. _CLEARCOLOR _RGB32(0, 0, 0), Layer(63) 'does not work?
129. _CLEARCOLOR _RGB32(0, 0, 0), Layer(Human) 'works
130.  
131.  
132. startpos.x = 40: startpos.y = 21
133. targetpos.x = 24: targetpos.y = 33
134.  
135. SetPath Path(), startpos, targetpos, Map()
136.  
137. Unit(0).Movement.xloc = 320
138. Unit(0).Movement.yloc = 200
139. Unit(0).Movement.Direction = North
140. Unit(0).Movement.IDmark = Peasant
141. Unit(0).Act = Moving
142. Unit(0).Movement.MapX = startpos.x
143. Unit(0).Movement.MapY = startpos.y
144. _PUTIMAGE (0, 0), Layer(Human), _DISPLAY
145. Game.MapX = 30
146. Game.MapY = 20
147.  
148. FOR i% = 2 TO Path(0).x
149.  'figure out spirte facing direction
150.  'the units MapX\Y are the previous location and Path is the next location
151.  IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY = Path(i%).y THEN Unit(0).Movement.Direction = West
152.  IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY = Path(i%).y THEN Unit(0).Movement.Direction = East
153.  IF Unit(0).Movement.MapX = Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = North
154.  IF Unit(0).Movement.MapX = Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = South
155.  IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = NorthWest
156.  IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = SouthWest
157.  IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = NorthEast
158.  IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = SouthEast
159.  
160.  'find units on screen location
161.  Unit(0).Movement.xloc = (Unit(0).Movement.MapX - Game.MapX) * (16 * Scaling)
162.  Unit(0).Movement.yloc = (Unit(0).Movement.MapY - Game.MapY) * (16 * Scaling)
163.  FOR F% = 0 TO 7
164.   _DEST Layer(62): LINE (0, 0)-(639, 399), _RGB32(0, 0, 0), BF
165.   _DEST Layer(63): LINE (0, 0)-(639, 399), _RGB32(0, 0, 0), BF
166.   _DEST _DISPLAY
167.   MapDrawer 144, 24, Game.MapX, Game.MapY, Scaling, Plains, 62
168.   DrawSprite 144, 24, Game.MapX, Game.MapY, Scaling, 63
169.   _PUTIMAGE (0, 0)-(639, 399), Layer(62), _DISPLAY
170.   _DELAY .5
171.   _PUTIMAGE (0, 0)-(639, 399), Layer(63), _DISPLAY
172.   _DELAY .5
173.   _PUTIMAGE (0, 0)-(639, 399), Layer(Human), _DISPLAY
174.   _DELAY .5
175.   IF INKEY$ = CHR$(27) THEN END
176.  NEXT F%
177.  'MapDrawer 144, 24, Game.MapX, Game.MapY, Scaling, Plains, _DISPLAY
178.  'DrawSprite 144, 24, Game.MapX, Game.MapY, Scaling, _DISPLAY
179.  _DELAY .1
180.  'update units pos
181.  Unit(0).Movement.MapX = Path(i%).x
182.  Unit(0).Movement.MapY = Path(i%).y
183. NEXT i%
184.  
185. '$include:'Movementdata.bi'
186.  
187. '$include:'Loadlayers.bi'
188. '$include:'Warpath.bi'
189. '$include:'MapDrawer.bi'
190. '$include:'DrawSprite.bi'
191.  

there is the main code, and below is the package of components needed to test it.

[Petr]

Hi Cobalt. I repair something in drawsprite.bi and something in your bas file in _Putimage loop . Look at it, if it solve your problem.

[Cobalt]

yes and no, that may look like it fixed that one issue but has created a host of other issues, I add the minimap display and it wont show up, the peasants shadow is now gone again, none of the debug information will display.. in fact nothing else shows up anymore beyond what is in that loop(even if i put it in that loop it still wont show)..  yeah..  not going to beable to use that solution. thank you though.

though looking at it differently made me realize I don't need to constantly remake the map layer, only if the player shifts the area to be displayed. not that it has any baring on this issue but should make a difference in the long run, thanks again.

[Petr]

J've looked at your program very quickly, I do not understand the context in such a short time, but the main problem, as I understand it, is that drawing SPRITE is still on the same screen that is then inserted all over. In order to disappear the previously drawn scene, I gave it before the new drawing of CLS. I do not know what is being rendered there, it is possible that something else is drawn on the same screen before moving. That's what the author knows. :-D It's in DrawSprite.BI, clearcolor took it correctly. Those commands setalpha what I added to the BAS file are unnecessary.

[Petr]

Yeah.... give back  MapDrawer call in to FOR NEXT loop in bas file...

[Cobalt]

but the main problem, as I understand it, is that drawing SPRITE is still on the same screen that is then inserted all over. In order to disappear the previously drawn scene,

no, the problem was that each layer erased the previous even though the CLEARCOLOR was set, it was as if the CLEARCOLOR was not what I set it to.

[Petr]

 I do not know why, but I learned to use the CLEARCOLOR commands as close as possible to the PUTIMAGE command. This has always proved to be good. I attach a resource in which I only corrected what I really wanted (in my opinion), with the DrawSprite.BI file from the previous attachment that works the way you wanted.

Code: QB64: [Select]

1. 'WarCraft 64
2. '2018-08-29 00:10
3. 'last update 01:30 2018-09-01
4. 'Build Count 0013
5. 'Kobolt
6. '
7. 'Routine
8. 'SetPath (Path() AS Coord, StartPos AS Coord, TargetPos AS Coord, Map())
9. '  -Path()   - the array for the path found from StartPos to TargetPos   [UNITS.PATH()]
10. '  -StartPos - the Begining Location of the unit                         [Unit().Movement.MapX, Unit().Movement.MapY]
11. '  -TargetPos- where the player clicked the mouse to have unit reach     [MapClick.X, MapClick.Y]
12. '  -Map()    - the map array to search for a path in                     [Map()]
13. '
14. 'Loadlayers()
15. '  -Load sprite and tile sheets
16. '
17. 'MapDrawer (Lx%, Ly%, Sx~%%, Sy~%%, Scale%%, Sets%%, Lay%%)
18. '  -Lx%,Ly%    - screen pos to draw map
19. '  -Sx~%%,Sy~%%- start pos to read map data
20. '  -Scale%%    - tile size to display 1x or 2x
21. '  -Sets%%     - Tile Set to use, Plains[26] or Swamp[0] (and maybe Cave)
22. '  -Lay%%      - layer to draw map on
23. '
24. 'DrawSprite(Lx%, Ly%,Mx~%%, My~%%, Scale%%, D%%)
25. '  -Draws a Units sprites
26. '  -Lx%,Ly%    - screen pos to draw sprite
27. '  -Mx~%%,My~%%- Current start pos of the map being displayed
28. '  -Scale%%    - sprite size to display 1x or 2x
29. '  -D%%        - Destination layer to draw sprite on
30.  
31. TYPE Coord: x AS INTEGER: y AS INTEGER: END TYPE
32.  
33. TYPE PathCoord
34.     pos AS Coord ' Coordinates of position on map
35.     parent AS Coord ' Coordinates of previous position on path
36.     g AS INTEGER ' G cost value
37.     h AS INTEGER ' H cost value
38.     f AS INTEGER ' F = G + H (total movement cost)
39.     status AS INTEGER ' 0 for unsearched, 1 for open, 2 for closed (explored)
40. END TYPE
41.  
42. TYPE SpriteData
43.     IDmark AS _BYTE '    which sprite is it (1-Unit(0), 2-Peon ect...)
44.     MapX AS _BYTE '      current Map square occupied
45.     MapY AS _BYTE '      current Map square occupied
46.     xloc AS SINGLE '     screen x location
47.     yloc AS SINGLE '     screen y location
48.     MoveAngle AS SINGLE 'direction sprite is moving
49.     MoveSpeed AS SINGLE 'speed at which sprite is moving
50.     Direction AS _BYTE ' sprite image faceing direction
51.     Frame AS _BYTE '     which frame of animation sprite is on
52.     Is_Moving AS _BYTE '  is the unit currently moving?
53.     PathID AS _UNSIGNED _BYTE '
54. END TYPE
55.  
56. TYPE UnitData
57.     Movement AS SpriteData 'inherited data
58.     HP AS _UNSIGNED _BYTE ' a unit hit tolerance, includeing buildings and resources
59.     HPM AS _UNSIGNED _BYTE 'a units max hit tolerance
60.     Armor AS _BYTE '        units defence from an attack
61.     Range AS _BYTE '        distance a unit can attack from
62.     DamLo AS _BYTE '        minimal damage a unit can do
63.     DamHi AS _BYTE '        Maximum damage a unit can do
64.     CostG AS INTEGER '      Gold cost of unit to be produced
65.     CostW AS INTEGER '      Wood Cost of unit to be produced
66.     Act AS _BYTE '          is unit moving, mining, chopping wood, attacking, carrying wood or gold
67.     Build AS _BYTE '        Time in seconds to build unit Based on Normal Speed X2.25 on slowest  X0.45 Fastest
68. END TYPE
69.  
70. TYPE StructureData
71.     Structure AS SpriteData '   not all elements used
72.     HP AS _UNSIGNED INTEGER '   a structures remaining hit tolerance
73.     HPM AS _UNSIGNED INTEGER '  a structures Max hit tolerance
74.     Gold AS _UNSIGNED INTEGER ' a mines remaining gold reserve
75. END TYPE
76.  
77. TYPE MapAttrib
78.     TileId AS _UNSIGNED _BYTE
79.     Is_Walkable AS _BYTE
80. END TYPE
81.  
82. TYPE Gamedata
83.     MapX AS _BYTE 'top left corner of the area of map the player
84.     MapY AS _BYTE ' is currently veiwing
85. END TYPE
86.  
87. CONST TRUE = -1, FALSE = NOT TRUE 'Duh and DUH
88. CONST Ts = 17, Tc = 37 'tile box size, tile count per line
89. 'action constants
90. CONST Still = 0, Moving = 1, Mining = 2, LumberJack = 3, Attacking = 4, CarryWood = 5
91. CONST CarryGold = 6, Shooting = 7, Casting = 8, Decomposing = 9, Removal = 10
92. 'Direction constants
93. CONST North = 0, NorthEast = 1, East = 2, SouthEast = 3, South = 4, SouthWest = 5, West = 6, NorthWest = 7
94. 'Unit Constants
95. CONST Peasant = 1, Peon = 2, Footman = 3, Grunt = 4, Archer = 5, Spearman = 6, Knight = 7, Raider = 8
96. CONST Cleric = 9, Necrolyte = 10, Conjurer = 11, Warlock = 12, SkeletonO = 13, Skeleton = 14
97. CONST Deamon = 15, WaterElemt = 16, FireElemt = 17, Lothar = 18
98. 'Tile sets
99. CONST Plains = 26, Swamp = 0, Cave = 28
100. 'Player screens
101. CONST Human = 27, Orc = 28
102. 'Game Tile\Sprite scaling
103. CONST Scaling = 2
104.  
105. DIM SHARED Map(63, 63) AS MapAttrib
106. DIM SHARED Unit(255) AS UnitData, Units.Path(512) AS Coord
107. DIM SHARED Layer(64) AS _UNSIGNED LONG
108. DIM SHARED Anima(32, 7) AS _BYTE 'movement animation sequince
109. DIM SHARED Game AS Gamedata
110.  
111. DIM Path(2048) AS Coord '' Dimension array of path coords to be filled in later
112. DIM startpos AS Coord, targetpos AS Coord
113.  
114. LoadLayers
115. FOR AnimaA%% = 0 TO 2
116.     FOR AnimaB%% = 0 TO 7
117.         READ Anima(AnimaA%%, AnimaB%%)
118.     NEXT
119. NEXT
120.  
121. OPEN "testmap.dat" FOR BINARY AS #1
122. GET #1, , Map()
123. CLOSE #1
124.  
125. SCREEN _NEWIMAGE(640, 480, 32)
126. _CLEARCOLOR _RGB32(224, 224, 224), Layer(Peasant) 'works
127. _CLEARCOLOR _RGB32(0, 0, 0), Layer(62) 'does not work?
128. _CLEARCOLOR _RGB32(0, 0, 0), Layer(63) 'does not work?
129. _CLEARCOLOR _RGB32(0, 0, 0), Layer(Human) 'works
130.  
131.  
132. startpos.x = 40: startpos.y = 21
133. targetpos.x = 24: targetpos.y = 33
134.  
135. SetPath Path(), startpos, targetpos, Map()
136.  
137. Unit(0).Movement.xloc = 320
138. Unit(0).Movement.yloc = 200
139. Unit(0).Movement.Direction = North
140. Unit(0).Movement.IDmark = Peasant
141. Unit(0).Act = Moving
142. Unit(0).Movement.MapX = startpos.x
143. Unit(0).Movement.MapY = startpos.y
144. _PUTIMAGE (0, 0), Layer(Human), _DISPLAY
145. Game.MapX = 30
146. Game.MapY = 20
147.  
148. FOR i% = 2 TO Path(0).x
149.     'figure out spirte facing direction
150.     'the units MapX\Y are the previous location and Path is the next location
151.     IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY = Path(i%).y THEN Unit(0).Movement.Direction = West
152.     IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY = Path(i%).y THEN Unit(0).Movement.Direction = East
153.     IF Unit(0).Movement.MapX = Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = North
154.     IF Unit(0).Movement.MapX = Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = South
155.     IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = NorthWest
156.     IF Unit(0).Movement.MapX > Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = SouthWest
157.     IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY > Path(i%).y THEN Unit(0).Movement.Direction = NorthEast
158.     IF Unit(0).Movement.MapX < Path(i%).x AND Unit(0).Movement.MapY < Path(i%).y THEN Unit(0).Movement.Direction = SouthEast
159.  
160.     'find units on screen location
161.     Unit(0).Movement.xloc = (Unit(0).Movement.MapX - Game.MapX) * (16 * Scaling)
162.     Unit(0).Movement.yloc = (Unit(0).Movement.MapY - Game.MapY) * (16 * Scaling)
163.     FOR F% = 0 TO 7
164.         _DEST Layer(62): LINE (0, 0)-(639, 399), _RGBA32(0, 0, 0, 0), BF
165.         _DEST Layer(63): LINE (0, 0)-(639, 399), _RGBA32(0, 0, 0, 0), BF
166.         _DEST _DISPLAY
167.         MapDrawer 144, 24, Game.MapX, Game.MapY, Scaling, Plains, 62
168.         DrawSprite 144, 24, Game.MapX, Game.MapY, Scaling, 63
169.         _PUTIMAGE (0, 0)-(639, 399), Layer(62), _DISPLAY
170.         '_DELAY 1
171.         _CLEARCOLOR 0, Layer(63)
172.         _PUTIMAGE (0, 0)-(639, 399), Layer(63), _DISPLAY
173.         '_DELAY 1
174.         _PUTIMAGE (0, 0)-(639, 399), Layer(Human), _DISPLAY
175.         '_DELAY 1
176.         IF INKEY$ = CHR$(27) THEN END
177.         _DISPLAY
178.     NEXT F%
179.     'MapDrawer 144, 24, Game.MapX, Game.MapY, Scaling, Plains, _DISPLAY
180.     'DrawSprite 144, 24, Game.MapX, Game.MapY, Scaling, _DISPLAY
181.     _DELAY .1
182.     'update units pos
183.     Unit(0).Movement.MapX = Path(i%).x
184.     Unit(0).Movement.MapY = Path(i%).y
185. NEXT i%
186.  
187. '$include:'Movementdata.bi'
188.  
189. '$include:'Loadlayers.bi'
190. '$include:'Warpath.bi'
191. '$include:'MapDrawer.bi'
192. '$include:'DrawSprite.bi'
193.  

[Petr]

Maybe.... if is first set CLEARCOLOR but then is something drawed to this screen, is MAYBE then previous CLEARCOLOR not accepted? I don´t know.

I test it and previous is not right. So -  next theorem is, that this is, because both use the same image. Its one image in memory. You use two pointers to one image. Maybe try it with two files - or better use copyimage and copy it, one clearcolor to one image, if it then help.

[Cobalt]

drawing to the layer basically undoes the CLEARCOLOR effect and would have to be done again.
Perhaps we need a transparent option for putimage? kindof like DQBPUT had back in the day.

[ExilePrisoner]

Gots these wokings

Code: QB64: [Select]

1. REM
2. DEFLNG A-Z
3. TheScreen& = _NEWIMAGE(800, 600, 32)
4.  
5.  
6. Layer1& = _LOADIMAGE("MyTile1.bmp", 32)
7. Layer2& = _LOADIMAGE("MyPeasant1.bmp", 32)
8. Layer3& = _LOADIMAGE("MyPeasant2.bmp", 32)
9.  
10.  
11. SCREEN TheScreen&
12. _PUTIMAGE , Layer1&, TheScreen&
13. SLEEP 1
14.  
15. _CLEARCOLOR _RGB32(0, 0, 0), Layer2&
16. _PUTIMAGE , Layer2&, TheScreen&
17. SLEEP 1
18.  
19. _CLEARCOLOR _RGB32(224, 224, 224), Layer3&
20. _PUTIMAGE , Layer3&, TheScreen&
21. SLEEP 1
22.  
23.  

This are correct nows?