Particle System

[johnno56]

I have been searching for a document(s), video, tutorials etc., on how to create a particle system. The problem is, I found heaps... My biggest problem is that the lack of information when it comes to Basic. I know that particle systems have been used in games etc. on this site. Which in itself is great. But, I seem to learn more from a tutorial as opposed to 'Monkey see. Monkey do.'  Copy and paste is fine, if only a result is needed, but that does not teach me how and why the code works... I am not sure I am making much sense. If I knew how to use all the other language examples that I have looked at, I probably would not be asking... Basic is what I know best... Basic examples/tutorials are what I am looking for... I would appreciate any assistance that you are willing to offer. Thank you.

[bplus]

@johnno56

This surprises me! You've done particle systems way back at SdlBasic, just fine!

You probably would like to do them with an array for each... I don't know what to call them Property? is the VB term, characteristic? oh what are they called?!

You could setup an UDT for them like this:
Type Particle
    As Single x, y, dx, dy, life, active
    As _unsigned Long colr
end Type
nParticles = 100
Dim Shared parts(nParticles) as Particle

or do it the old fashioned way
dim x(nParticles), y(nParticles), dx(nParticles), dy(nParticles), life(nParticles), active(nParticles)
dim as _unsigned long colr(nParticles)

Then it's good to have a Sub for creating a new particle depends on your app what to do
Sub NewParticle(index) 'where index is for the shared array Parts
     ' setup Parts(index) for you app here
end sub

I could probably dig up some of your code from SdlBasic for doing particles :)

[bplus]

Found it:
http://sdlbasic.epizy.com/showthread.php?tid=235

From 6 years ago!

You call the properties parameters here, OK :)

Oh come to think of it, I think you mentioned losing your computer and a bunch of old work. Well that link is to fine Particle System you did.

[_vince]

Found it:
http://sdlbasic.epizy.com/showthread.php?tid=235

Here is a simple particle system that I converted from Basic256. It has a lot of comments that explain what each step does.

Note: On my machine, the 'polygon' command, causes sdlbasic to freeze. SetPixel, Bar, fillcircle and Ployline all work just fine.

Wow, what is Basic256!?  There's a successor to ModernBASIC 128?

[bplus]

A little translation:

Code: QB64: [Select]

1. ' 2022-04-10 b+ translation of  http://sdlbasic.epizy.com/showthread.php?tid=235  
2. ' ***************
3. ' Particle System
4. ' ***************
5. ' maximum number of particles slots
6. ' lower this to get more fluent effect
7. maximum = 100
8.  
9. ' Each particle has 6 parameters
10. ' 0 : location on the x-axis
11. ' 1 : location on the y-axis
12. ' 2 : movement on the x-axis
13. ' 3 : movement on the y-axis
14. ' 4 : how old the particle can get
15. ' 5 : period where particle keeps the same color
16. Dim particle(maximum, 6)
17.  
18. ' ******************************
19. ' Boiler plate for a nice canvas
20. ' ******************************
21. 'setDisplay(700, 400, 32, 1)
22. Screen _NewImage(700, 400, 32)
23. f& = _LoadFont("Arial.ttf", 40) ' everyone has arial?
24. _Font f&
25.  
26. 'setCaption("Particles Example")
27. _Title "Particles Example"
28. _PrintMode _KeepBackground
29. 'autoback(-2)
30. 'hidemouse
31. _MouseHide
32. Randomize Timer
33. Dim As _Unsigned Long darkred, red, orange, yellow, white
34. darkred = _RGB32(128, 0, 0)
35. red = _RGB32(255, 0, 0)
36. orange = _RGB32(255, 128, 0)
37. yellow = _RGB32(255, 255, 0)
38. white = _RGB32(255, 255, 255)
39.  
40. ' *************************************************
41. ' pre-cache sin/cos calculations (small speed gain)
42. ' *************************************************
43. Dim degree(361, 2)
44. pi = 3.141592654
45. k = 0
46. For i = 0 To 2 * pi Step (2 * pi / 359)
47.     k = k + 1
48.     degree(k, 0) = Sin(i)
49.     degree(k, 1) = Cos(i)
50. Next
51.  
52. 'initialize text
53. text_count = 0
54. t1$ = "Particles Example"
55. t2$ = "( Cool, isn't it? )"
56. t3$ = "(   useless too  )"
57. t4$ = t2$
58. sw_text = 0
59.  
60. ' *************************************************
61. ' initial particle definition: all particles 'dead'
62. ' *************************************************
63. For i = 0 To maximum - 1
64.     particle(i, 4) = 0
65. Next
66.  
67. '**************************************************
68. ' main loop
69. '**************************************************
70. While _KeyDown(27) = 0
71.     Cls
72.     ' create new particles
73.     ' ********************
74.     ' select 7 random particles at each cycle
75.     ' play with this value to get the best result on your computer
76.     For k = 1 To 7
77.         spawni = rand(maximum)
78.  
79.         ' if age of the random particle = 0, create one
80.         If particle(spawni, 4) = 0 Then
81.  
82.             ' horizontal location
83.             If rand(100) / 100 > 0.5 Then
84.                 particle(spawni, 0) = 20
85.                 lings = 1
86.             Else
87.                 particle(spawni, 0) = 660
88.                 lings = 0
89.             End If
90.  
91.             ' vertical location
92.             particle(spawni, 1) = 350
93.             direction = rand(35) + 157
94.  
95.             ' horizontal speed vector
96.             If lings = 1 Then
97.                 particle(spawni, 2) = rand(6)
98.             Else
99.                 particle(spawni, 2) = 0 - (rand(6))
100.             End If
101.  
102.             ' falling speed vector
103.             particle(spawni, 3) = (0 - rand(6)) - 5
104.  
105.             ' particle age
106.             particle(spawni, 4) = 30 + rand(50)
107.  
108.             ' color aging
109.             particle(spawni, 5) = particle(spawni, 4) / 5
110.         End If
111.     Next
112.  
113.     ' update position on ALL live particles
114.     ' *************************************
115.     For i = 0 To maximum - 1
116.  
117.         ' for all live particles
118.         If particle(i, 4) > 0 Then
119.  
120.             ' calculate the new location
121.             particle(i, 0) = particle(i, 0) + particle(i, 2)
122.             particle(i, 1) = particle(i, 1) + particle(i, 3)
123.  
124.             ' increase the speed of falling
125.             particle(i, 3) = particle(i, 3) + (rand(100) / 100) / 3
126.  
127.             ' make the particle older
128.             particle(i, 4) = particle(i, 4) - 1
129.  
130.             ' if it hits the bottom, make it bounce up
131.             ' 0=no bounce, 1= full bounce,no damping
132.             If particle(i, 1) > 370 Then
133.                 particle(i, 3) = -particle(i, 3) * ((rand(100) / 100) / 2)
134.             End If
135.         End If
136.     Next
137.  
138.     ' Color determination of the particle
139.     Dim k As _Unsigned Long
140.     '************************************
141.     For i = 0 To maximum - 1
142.  
143.         ' for all live particles
144.         If particle(i, 4) > 0 Then
145.  
146.             ' color it darkred if less than 20% life left
147.             If particle(i, 4) < particle(i, 5) Then
148.                 k = darkred
149.             End If
150.  
151.             ' color it red if more than 20% life left
152.             If particle(i, 4) > (particle(i, 5)) Then
153.                 k = red
154.             End If
155.  
156.             ' color it orange if more than 40% life left
157.             If particle(i, 4) > (particle(i, 5) * 2) Then
158.                 k = orange
159.             End If
160.  
161.             ' color it yellow if more than 60% life left
162.             If particle(i, 4) > (particle(i, 5) * 3) Then
163.                 k = yellow
164.             End If
165.  
166.             ' color it white if more than 80% life left
167.             If particle(i, 4) > (particle(i, 5) * 4) Then
168.                 k = white
169.             End If
170.  
171.  
172.             '----------------------------
173.             ' PLOT ALL THE LIVE PARTICLES
174.             '----------------------------
175.  
176.  
177.             '--- circles ---
178.             'circle(particle(i,0), particle(i,1), 2+rand(4))
179.             '--- filled circles ---
180.             'fillcircle(particle(i,0), particle(i,1), 2+rand(4))
181.             '--- squares ---
182.             'polyline(particle(i,0), particle(i,1), particle(i,0)+6, particle(i,1), particle(i,0)+6, particle(i,1)+6, particle(i,0), particle(i,1)+6, particle(i,0), particle(i,1))
183.             '--- stars ---
184.             'polyline(particle(i,0)+4, particle(i,1), particle(i,0)+8, particle(i,1)+12, particle(i,0), particle(i,1)+4, particle(i,0)+12, particle(i,1)+4, particle(i,0)+2, particle(i,1)+12)
185.              star particle(i, 0), particle(i, 1), 8, 20, 5, 90, k
186.             '--- polygon seems to 'lock-up' ---
187.             'polygon(particle(i,0), particle(i,1), particle(i,0)+6, particle(i,1), particle(i,0)+6, particle(i,1)+6, particle(i,0), particle(i,1)+6, particle(i,0), particle(i,1))
188.             '--- filled squares ---
189.             'bar(particle(i,0), particle(i,1), particle(i,0)+2+rand(4), particle(i,1)+2+rand(4))
190.  
191.         End If
192.     Next
193.  
194.     Color _RGB32(255, 255, 255)
195.     _PrintString (190, 140), t1$
196.     Color _RGB32(0, 0, 255)
197.     _PrintString (192, 142), t1$
198.     If text_count < 300 Then
199.         'Text 223, 180, 24, t4$, &HFFFF0000
200.         Color _RGB32(255, 255, 255)
201.         _PrintString (213, 190), t4$
202.         Color _RGB32(255, 0, 0)
203.         _PrintString (215, 192), t4$
204.         text_count = text_count + 1
205.     Else
206.         If sw_text = 1 Then
207.             t4$ = t3$
208.             sw_text = 0
209.         Else
210.             t4$ = t2$
211.             sw_text = 1
212.         End If
213.         text_count = 0
214.     End If
215.     _Display
216.     _Limit 10
217. Wend
218.  
219. Function rand% (n)
220.     rand% = Int((n + 1) * Rnd)
221. End Function
222.  
223. Sub star (x, y, rInner, rOuter, nPoints, angleOffset, K As _Unsigned Long)
224.     ' x, y are same as for circle,
225.     ' rInner is center circle radius
226.     ' rOuter is the outer most point of star
227.     ' nPoints is the number of points,
228.     ' angleOffset = angle offset IN DEGREES, it will be converted to radians in sub
229.     ' this is to allow us to spin the polygon of n sides
230.     Dim pAngle, radAngleOffset, x1, y1, x2, y2, x3, y3, i As Long
231.  
232.     pAngle = _D2R(360 / nPoints): radAngleOffset = _D2R(angleOffset)
233.     x1 = x + rInner * Cos(radAngleOffset)
234.     y1 = y + rInner * Sin(radAngleOffset)
235.     For i = 0 To nPoints - 1
236.         x2 = x + rOuter * Cos(i * pAngle + radAngleOffset + .5 * pAngle)
237.         y2 = y + rOuter * Sin(i * pAngle + radAngleOffset + .5 * pAngle)
238.         x3 = x + rInner * Cos((i + 1) * pAngle + radAngleOffset)
239.         y3 = y + rInner * Sin((i + 1) * pAngle + radAngleOffset)
240.         ftri x1, y1, x2, y2, x3, y3, K
241.         'triangles leaked
242.         Line (x1, y1)-(x2, y2), K
243.         Line (x2, y2)-(x3, y3), K
244.         Line (x3, y3)-(x1, y1), K
245.         x1 = x3: y1 = y3
246.     Next
247.     Paint (x, y), K, K
248. End Sub
249.  
250. '2019-12-16 fix by Steve saves some time with STATIC and saves and restores last dest
251. Sub ftri (x1, y1, x2, y2, x3, y3, K As _Unsigned Long)
252.     Dim D As Long
253.     Static a&
254.     D = _Dest
255.     _PrintMode _KeepBackground
256.     If a& = 0 Then a& = _NewImage(1, 1, 32)
257.     _Dest a&
258.     _DontBlend a& '  '<<<< new 2019-12-16 fix
259.     PSet (0, 0), K
260.     _Blend a& '<<<< new 2019-12-16 fix
261.     _Dest D
262.     _MapTriangle _Seamless(0, 0)-(0, 0)-(0, 0), a& To(x1, y1)-(x2, y2)-(x3, y3)
263. End Sub
264.  
265. 'Sub Text (x, y, textHeight, txt$, k As _Unsigned Long)
266. '    Dim fg As _Unsigned Long, cur&, I&, multi, xlen
267. '    fg = _DefaultColor
268. '    'screen snapshot
269. '    cur& = _Dest
270. '    I& = _NewImage(8 * Len(txt$), 16, 32)
271. '    _Dest I&
272. '    Color k
273. '    _PrintString (0, 0), txt$
274. '    multi = textHeight / 16
275. '    xlen = Len(txt$) * 8 * multi
276. '    _PutImage (x, y)-Step(xlen, textHeight), I&, cur&
277. '    Color fg
278. '    _FreeImage I&
279. 'End Sub
280.  
281.  

[johnno56]

I have a feeling that I may have asked these questions before... Probably my age is showing... *sigh*

Bplus. Thank you for the sdl reference... Those programs were direct conversion from basic256 (No, Vince... Not a successor by a long mark... - Basic256 was used because it was easy for me to convert... lol) These were just plain conversions. No reference or documentation as to why or how it all works. A prime example, on my part, of Monkey see... Monkey do... But, I have to admit, their examples were indeed impressive... Not exactly Fireworks but still impressive...

There are many examples of particle systems 'out there' that explain, in detail, how it all works, but the coding languages that are used, may as well have been written in Romulan...  I would prefer references in Basic as I have spent my most of my adult life learning and tinkering with Basic. I cannot afford to dedicate a similar period of time in leaning a new language...

Some of the games I have cobbled together in the past are a little, shall we say boring or plain, and figured that particle effects might add a little extra... might be fun...

Many thanks for the pseudo code... That helps a lot...

[Richard Frost]

There are two "particle systems" in my old Moon Lander you could
study - the volcano and fireworks. 

The volcano demonstrates my theory that the Earth is made of cheese.
Why else would lava be orange?

[johnno56]

Cheese and lava... I would not have made the connection... I will be sure to check out your Moon Lander. Thank you.