Easter Egg Decorating

[bplus]

Looks pretty darn pointed to me!  😁

https://3c1703fe8d.site.internapcdn.net/newman/gfx/news/hires/2017/7-researchersp.jpg

WTH? https://www.google.com/search?q=Eggs+image&tbm=isch&chips=q:eggs+image,g_1:white:oGocWXeA-oc%3D&client=opera&hs=ZAc&hl=en&sa=X&ved=2ahUKEwjkz4H6nvD2AhWVj2oFHb00A-oQ4lYoAnoECAEQIQ&biw=1165&bih=606

White eggs do appear slightly more pointed than brown. But I am talking about chicken eggs, not whatever egg Steve found LOL!

[bplus]

Here's a more detailed description of the parameters:  https://nyaspubs.onlinelibrary.wiley.com/doi/10.1111/nyas.14771

The chicken eggs are not pointy but eggs of other bird species are, ie the "pyriform" shape https://bioone.org/journals/the-auk/volume-135/issue-4/AUK-18-38.1/The-pyriform-egg-of-the-Common-Murre-Uria-aalge-is/10.1642/AUK-18-38.1.full

That curve equation is supposed to be universal to all eggs.  From what I gather, you can set p(x) = x for a "good enough" approximation but there are several more complicated variants of p(x) that take into account more species of birds, ie that "pyriform" one

Ah that helps,   ... a bit.

[SMcNeill]

WTH? https://www.google.com/search?q=Eggs+image&tbm=isch&chips=q:eggs+image,g_1:white:oGocWXeA-oc%3D&client=opera&hs=ZAc&hl=en&sa=X&ved=2ahUKEwjkz4H6nvD2AhWVj2oFHb00A-oQ4lYoAnoECAEQIQ&biw=1165&bih=606

White eggs do appear slightly more pointed than brown. But I am talking about chicken eggs, not whatever egg Steve found LOL!

That's a pic of a quail egg, I think.

Truth is, most "natural" chicken eggs come in all sorts of shapes and sizes from my experience.  Some are extra long (usually with double yokes inside), while some are almost golf ball round.  When we raised chickens, we raised Bantam chickens, and we got everything from red to white to blue to green eggs -- and all from the same crazy ass chicken!

I'd say, "If it's close, it's close enough -- pointed or not!"  All the eggs you buy in the store are "Grade A" eggs, which is why they all look so uniform.  Look at the pictures of lower grade eggs some time.  I wouldn't be too surprised to find a dang pyramid or cube in some of them!  😂

I'll just stick to my simple little SIN stretching... Or elsejust use an actual picture of an egg and then colorit!  LOL!

See these: https://www.purinamills.com/2.purinamills.com/media/Images/Articles/PF_Quality-Eggs-Tile-Image.jpg?ext=.jpg

[bplus]

I am getting ideas for decorating from this:
 

Right up Pete's alley!

[bplus]

As Aurel would say, "Steve's got a right" some more on egg curves:
http://www.mathematische-basteleien.de/eggcurves.htm

[SierraKen]

I would say, if you know how to make a 3D ball using vectors, you might be able to figure out how to use the mouse to elongate one side of the ball to make it look just like an egg. Then you can copy the picture and save it. Or copy the variables and save them for an egg app. Wouldn't that be awesome! Don't look at me though, 3D vectors are a ways past my learning curve right now.

[SierraKen]

Here is my Easter Egg. Of course it's not as real looking as the ones you guys are doing. But at least it's something, maybe for our less-mathematically oriented people. :)

Code: QB64: [Select]

1. Screen _NewImage(800, 600, 32)
2. y = 300
3. cl = 100
4. cl2 = 20
5. egg = 1.25
6. sz = 100
7. For x = 400 To 410 Step .002
8.     sz = sz - .01
9.     egg = egg + .01
10.     cl = cl + .001
11.     cl2 = cl2 + 1
12.     If cl > 150 Then cl = 150
13.     Circle (x, y), sz, _RGB32(cl2, 255, cl), , , egg
14. Next x
15. Do: Loop Until InKey$ <> ""
16. End
17.  
18.  
19.  

[SMcNeill]

Code: QB64: [Select]

1. WorkScreen = _NewImage(800, 800, 32)
2. DisplayScreen = _NewImage(800, 800, 32)
3. egg = _LoadImage("egg.png", 32)
4. Screen DisplayScreen
5. _Delay .5
6. _ScreenMove _Middle
7.  
8. _Dest WorkScreen
9. _DontBlend
10. Stepp = 25 'change this for bigger or smaller bands of colors
11. For i = 0 To 800 Step Stepp
12.     Line (0, i)-Step(800, Stepp), &H88000000 + Rnd * &HFFFFFF, BF
13. Next
14. _Dest DisplayScreen
15. _Blend
16.  
17.  
18. For y = 0 To _Height(egg) - 1
19.     For x = 0 To _Width(egg) - 1
20.         _Source egg
21.         p&& = _Alpha(Point(x, y))
22.         If p&& > 200 Then
23.             _Source WorkScreen
24.             p&& = Point(x, y)
25.             PSet (x, y), p&&
26.         End If
27.     Next
28. Next
29. Sleep
30. System
31.  

 

(The base egg.png is included below for usage. )

[SMcNeill]

One quirk of doing things the way I have above, is that it allows us to basically take two distinct images and then merge them together into the final result.  I start with the image of an egg, and an image of a rainbow screen.  I then basically take the rainbow colors from it's screen, wherever the egg would appear on its screen, and then copy those onto the display screen...

Using this method, I could also, conceivably, take egg-shaped portions of screens from a movie and then put them onto the display, only showing the "egg portion" out of the movie screen.  Or I could take egg-shaped images from moving flames or raindrops falling, and then display them to the screen, as I'm not so much coloring an egg, as just taking the egg-shape color information from a different image.

Movie Easter Eggs -- how great is that concept?!!

[SierraKen]

That's awesome Steve! I got all kinds of ideas flowing.

[SierraKen]

Here is a mod from Steve's Easter Egg. It randomly makes an egg every second with different thickness of colors and it's either horizontal stripes or vertical stripes. Took me a little bit to figure that out. :) Press any key to stop it.

Code: QB64: [Select]

1. 'Steve's Easter Egg  - mod by SierraKen 3-31-2022
2. WorkScreen = _NewImage(800, 800, 32)
3. DisplayScreen = _NewImage(800, 800, 32)
4. egg = _LoadImage("egg.png", 32)
5. Screen DisplayScreen
6. _Delay .5
7. _ScreenMove _Middle
8. Randomize Timer
9. _Title "Steve's Easter Egg mod by SierraKen"
10. Do
11.     _Limit 30
12.     _Dest WorkScreen
13.     _DontBlend
14.  
15.     r = Int(Rnd * 2) + 1
16.     If r = 1 Then GoTo one:
17.     If r = 2 Then GoTo two:
18.  
19.     one:
20.     Stepp = Int(Rnd * 50) + 10 'change this for bigger or smaller bands of colors
21.     For i = 0 To 800 Step Stepp
22.         Line (i, 0)-Step(Stepp, 800), &H88000000 + Rnd * &HFFFFFF, BF
23.     Next
24.     _Dest DisplayScreen
25.     _Blend
26.     For y = 0 To _Height(egg) - 1
27.         For x = 0 To _Width(egg) - 1
28.             _Source egg
29.             p&& = _Alpha(Point(x, y))
30.             If p&& > 200 Then
31.                 _Source WorkScreen
32.                 p&& = Point(x, y)
33.                 PSet (x, y), p&&
34.             End If
35.         Next x
36.     Next y
37.     GoTo done:
38.     two:
39.     Stepp = Int(Rnd * 50) + 10 'change this for bigger or smaller bands of colors
40.     For i = 0 To 800 Step Stepp
41.         Line (0, i)-Step(800, Stepp), &H88000000 + Rnd * &HFFFFFF, BF
42.     Next
43.     _Dest DisplayScreen
44.     _Blend
45.     For x = 0 To _Width(egg) - 1
46.         For y = 0 To _Height(egg) - 1
47.             _Source egg
48.             p&& = _Alpha(Point(x, y))
49.             If p&& > 200 Then
50.                 _Source WorkScreen
51.                 p&& = Point(x, y)
52.                 PSet (x, y), p&&
53.             End If
54.         Next y
55.     Next x
56.     done:
57.     p&& = 0
58.     _Delay 1
59.     a$ = InKey$
60.     Cls
61. Loop Until a$ <> ""
62.  

[_vince]

I typed out the egg-case for that theory of everything egguation:

Code: QB64: [Select]

1. 'scale
2. s = 80
3.  
4. L = 5.4
5. B = 4.1
6. w = 0.4
7. D = 3.2
8.  
9.  
10. sw = 800
11. sh = 600
12. screen _newimage(sw, sh, 32)
13.  
14.  
15. for xx=-0.5*L*s to 0.5*L*s
16.         x = xx/s       
17.         a = (L*L - 4*x*x)/(L*L + 8*w*x + 4*w*w)
18.         y = 0.5*B*sqr(a)
19.         'you can stop here for p(x) = x
20.  
21.         a = sqr(5.5*L*L + 11*L*w + 4*w*w)
22.         a = a*(sqr(3)*B*L - 2*D*sqr(L*L + 2*w*L + 4*w*w))
23.         a = a/(sqr(3)*B*L*(sqr(5.5*L*L + 11*L*w + 4*w*w) - 2*sqr(L*L + 2*w*L + 4*w*w)))
24.  
25.         aa = L*(L*L + 8*w*x + 4*w*w)
26.         aa = aa/(2*(L - 2*w)*x*x + (L*L + 8*L*w - 4*w*w)*x + 2*L*w*w + L*L*w + L*L*L)
27.         aa = 1 - aa
28.  
29.         y = y*(1 - a*aa)
30.  
31.         line (sw/2 + xx, sh/2 - s*y)-(sw/2 + xx, sh/2 + s*y)
32. next
33.  
34. sleep
35. system
36.  
37.  

Note: I also got the coefficients by measuring a real egg with a ruler in centimeters, had to eyeball quite a bit.  You'd want some kind of scanner or at least calipers as the formula is pretty sensitive to certain parameters like w and D_{L/4}

[SMcNeill]

Matrix Rain Easter Egg!

Code: QB64: [Select]

1. WorkScreen = _NewImage(800, 800, 32)
2. DisplayScreen = _NewImage(800, 800, 32)
3. egg = _LoadImage("egg.png", 32)
4. Screen DisplayScreen
5. _Delay .5
6. _ScreenMove _Middle
7. Cls , -1
8.  
9. Dim m(1 To Int(_Width / _FontWidth))
10.  
11. For i = 1 To UBound(m)
12.     m(i) = -Int(Rnd * _Height)
13. Next
14.  
15.  
16.  
17.  
18.  
19. Do
20.  
21.     _Dest WorkScreen
22.     Line (0, 0)-(_Width, _Height), _RGBA32(0, 0, 0, 20), BF
23.  
24.     For i = 1 To UBound(m)
25.         Color _RGB32(0, 255, 0), 0
26.         m(i) = m(i) + _FontHeight
27.         If m(i) > 0 Then
28.             If m(i) > _Height Then m(i) = -Int(Rnd * _Height)
29.             _PrintString (i * _FontWidth - _FontWidth, m(i)), Chr$(_Ceil(Rnd * 254))
30.         End If
31.     Next
32.  
33.     For y = 0 To _Height(egg) - 1
34.         For x = 0 To _Width(egg) - 1
35.             _Source egg
36.  
37.             p&& = _Alpha(Point(x, y))
38.  
39.             _Source WorkScreen
40.             If p&& > 200 Then
41.                 p&& = Point(x, y)
42.                 _Dest DisplayScreen
43.                 PSet (x, y), p&&
44.             End If
45.         Next
46.     Next
47.     _Display
48. Loop Until _KeyDown(27)
49.  

Make certain to grab and use the egg.png from the previous post, if you need it in your QB64 folder.

This is basically just an example of what I was talking of above, about being able to place a flame, movie, or rain upon my egg.  I thought Ken might like it, and it might give him a few ideas for more neat little mods he can do with it.  ;)

[dbox]

When in Rome...

Here is a QBJS mod based on @vince's creation - Egg Designer 2000.

View on QBJS

Code: QB64: [Select]

1. _Title "Egg Designer 2000"
2. Dim Shared s, L, B, w, D, sw, sh, xx, x, a, y, aa
3. Dim Shared ctlS, ctlL, ctlB, ctlW, ctlD
4.  
5. sw = 800
6. sh = 600
7. Screen _NewImage(sw, sh, 32)
8. Color 15
9.  
10. InitControls
11. DrawEgg
12.  
13. Sub DrawEgg
14.     Cls
15.     s = ctlS.value
16.     L = ctlL.value / 10
17.     B = ctlB.value / 10
18.     w = ctlW.value / 10
19.     D = ctlD.value / 10
20.    
21.     For xx = -0.5 * L * s To 0.5 * L * s
22.         x = xx / s
23.         a = (L * L - 4 * x * x) / (L * L + 8 * w * x + 4 * w * w)
24.         y = 0.5 * B * Sqr(a)
25.         'you can stop here for p(x) = x
26.  
27.         a = Sqr(5.5 * L * L + 11 * L * w + 4 * w * w)
28.         a = a * (Sqr(3) * B * L - 2 * D * Sqr(L * L + 2 * w * L + 4 * w * w))
29.         a = a / (Sqr(3) * B * L * (Sqr(5.5 * L * L + 11 * L * w + 4 * w * w) - 2 * Sqr(L * L + 2 * w * L + 4 * w * w)))
30.  
31.         aa = L * (L * L + 8 * w * x + 4 * w * w)
32.         aa = aa / (2 * (L - 2 * w) * x * x + (L * L + 8 * L * w - 4 * w * w) * x + 2 * L * w * w + L * L * w + L * L * L)
33.         aa = 1 - aa
34.  
35.         y = y * (1 - a * aa)
36.  
37.         Line (sw / 2 + xx, sh / 2 - s * y)-(sw / 2 + xx, sh / 2 + s * y)
38.     Next
39. End Sub
40.  
41. Sub InitControls
42.     Dim c: c = DomCreate("div")
43.     c.style.padding = "20px"
44.    
45.     DomCreate "span", c, "s: "
46.     Dim e: e = DomCreate("input", c)
47.     e.type = "range"
48.     e.style.width = "125px"
49.     e.style.verticalAlign = "middle"
50.     e.min = 1
51.     e.max = 100
52.     e.step = 1
53.     e.value = 80
54.     ctlS = e
55.        
56.     e = DomCreate("span", c, "L: ")
57.     e.style.marginLeft = "20px"
58.     e = DomCreate("input", c)
59.     e.type = "range"
60.     e.style.verticalAlign = "middle"
61.     e.style.width = "125px"  
62.     e.min = 1
63.     e.max = 100
64.     e.value = 54
65.     ctlL = e
66.  
67.     e = DomCreate("span", c, "B: ")
68.     e.style.marginLeft = "20px"
69.     e = DomCreate("input", c)
70.     e.type = "range"
71.     e.style.verticalAlign = "middle"
72.     e.style.width = "125px"  
73.     e.min = 1
74.     e.max = 100
75.     e.value = 41
76.     ctlB = e
77.            
78.     e = DomCreate("span", c, "w: ")
79.     e.style.marginLeft = "20px"
80.     e = DomCreate("input", c)
81.     e.type = "range"
82.     e.style.verticalAlign = "middle"
83.     e.style.width = "125px"  
84.     e.min = 1
85.     e.max = 20
86.     e.value = 4
87.     ctlW = e
88.  
89.     e = DomCreate("span", c, "D: ")
90.     e.style.marginLeft = "20px"
91.     e = DomCreate("input", c)
92.     e.type = "range"
93.     e.style.verticalAlign = "middle"
94.     e.style.width = "125px"  
95.     e.min = 1
96.     e.max = 100
97.     e.value = 32
98.     ctlD = e
99.                        
100.     DomEvent ctlS, "input", sub_DrawEgg
101.     DomEvent ctlL, "input", sub_DrawEgg
102.     DomEvent ctlB, "input", sub_DrawEgg
103.     DomEvent ctlW, "input", sub_DrawEgg
104.     DomEvent ctlD, "input", sub_DrawEgg
105. End Sub
106.  

[STxAxTIC]

Holy crap, vince and dbox win. Bro, lemme make that link bigger:

THIS THIS THIS