Is there a way to print a permanent string at a specific location?

[FilipeEstima]

Hi guys, it's been a while I don't visit this forum. What brings me today is this: can QB64 print a permanent string at a specific location in the box? Say, "THIS IS A DEMO" in the last line and no matter what, it will not be overwritten (not even by scroll)?

[bplus]

You can put one in the _Title "This is a Demo" and it wont change unless you change it.

[FilipeEstima]

Problem is, I am already using _TITLE for something else 😬 It would be perfect if I could use a string printed in bright white color, maybe flashing inside the box.

[SMcNeill]

VIEW PRINT and VIEW SCREEN might be what you're looking for.

[bplus]

Yeah or just overlay an image after anything done on the screen.

[FilipeEstima]

Thanks for the suggestions, guys!

[FellippeHeitor]

If it's a text-only app, you can set an ON TIMER that calls a Sub every x milliseconds and prints to the screen. Just be sure to store _defaultcolor, _backgroundcolor, csrlin and pos(0) so you can restore color and cursor position after you've done printing.

Alternatively, store only _defaultcolor and _backgroundcolor and use _printstring, so cursor position is restored automatically.

[doppler]

That's introverted thinking (inside the box).  I always thought of you as an extrovert.
Or do you swing both ways ?

[FellippeHeitor]

Come again?

[doppler]

Come again?

You missed the joke.... never mind.

[SMcNeill]

I dunno why people like to make things so complicated.  As I mentioned last night (but was already in bed and just browsing on my ipad and not about to post an example then), the simplest and easiest solution to this type of problem is with VIEW PRINT.

Code: QB64: [Select]

1. 'Screen _NewImage(640, 480, 32)
2.  
3. Color 15 + 16 'blinking bringht white
4. Locate 25, 1: Print "This text will always remain on the screen.";
5. Color 15 'plain bright white text
6.  
7. View Print 1 To 24
8. For i = 1 To 30
9.     Print i
10.     Sleep
11. Next
12.  
13. System
14.  

"What brings me today is this: can QB64 print a permanent string at a specific location in the box? Say, "THIS IS A DEMO" in the last line and no matter what, it will not be overwritten (not even by scroll)?"....  CHECK!

"It would be perfect if I could use a string printed in bright white color, maybe flashing inside the box"....    CHECK!

Is there anything that I'm missing here?  We're printing on the last line.  Scroll isn't affecting it.  We can do bright white color, and we can flash it in SCREEN 0.  We can do a CLS 2 and only clear the text area, without clearing the view port. 

Isn't a simple VIEW PRINT statement all that's needed in this case?  Or am I missing something?

[FellippeHeitor]

I dunno why people like to make things so complicated.

It's a mystery.

[SMcNeill]

It's a mystery.

Sometimes I honestly feel like people like to over complicate things just to avoid those "Old Skool" commands, just to promote the "better, modern way" to do things.

It's like somebody asks, "What's two plus two?"

One guy answers, "Hold up two fingers on your left hand.  Hold up two fingers on your right hand.  Count them for your answer."

Then other folks come along and say, "OR...  Build a rocket.  Fly it 360 miles above the earth with a mirror on it.  Since light travels 180 miles per second, flash a light at the mirror and start a stopwatch.  When you see the light reflect off the mirror, stop the watch and it'll show your answer."

Sure, it works, but you have to be a rocket scientist to implement the solution!  😁

[bplus]

Aint that simple for graphics demo!

Code: QB64: [Select]

1. _Title "Flash Demo test" 'b+ 2022-02-13   how complicated can it be?
2. ' sample program to test FlashDemo
3.  
4. '_Title "Drawlandscape Parallax test" 'started 2019-03-27
5. 'test if can get end of landscape level to start for big looping background
6. '2019-03-27 a more gentle adjustment back to Mountain starting height for
7. 'more seamless connect of back end to front
8. '2019-03-27 start this file with parallax drawing test
9.  
10.  
11. Randomize Timer
12. Screen _NewImage(800, 600, 32)
13. _ScreenMove 100, 20
14. Type parallaxType
15.     handle As Long
16.     rate As Single 'number of pixels per frame added to le (leading edge)
17.     le As Single
18. End Type
19. Dim Shared nLevels As Integer
20. nLevels = 6
21. Dim Shared para(1 To nLevels) As parallaxType
22.  
23. Dim Shared scape&
24. LoadLandscape
25. scapeWidth = _Width(para(1).handle)
26. scapeHeight = _Height(para(1).handle)
27.  
28. ' flash Demo code added ===================================================================================
29. ft& = _FreeTimer
30. On Timer(ft&, 2) flashDemo
31. Timer(ft&) On
32. ' flash Demo end of code added ============================================================================
33.  
34. '' Try Steve simple little ditty ===========================================================================
35. 'Color 15 + 16 'blinking bringht white
36. 'Locate 25, 1: Print "This text will always remain on the screen.";
37. 'Color 15 'plain bright white text
38.  
39. 'View Print 1 To 24 ' doesn't seen to do anything ????
40. '' ==========================================================================================================
41.  
42. While t < 6000
43.     Cls
44.     For i = 1 To nLevels
45.         If para(i).le + 800 > scapeWidth Then
46.             te = scapeWidth - para(i).le
47.             _PutImage (0, 0)-(te, scapeHeight), para(i).handle, 0, (scapeWidth - te, 0)-(scapeWidth, scapeHeight)
48.             _PutImage (te, 0)-(800, scapeHeight), para(i).handle, 0, (0, 0)-(800 - te, scapeHeight)
49.  
50.         Else
51.             _PutImage (0, 0)-(800, scapeHeight), para(i).handle, 0, (para(i).le, 0)-(para(i).le + 800, scapeHeight)
52.         End If
53.  
54.         para(i).le = para(i).le - para(i).rate
55.         If para(i).le < 0 Then para(i).le = scapeWidth
56.     Next
57.     t = t + 1
58.     _Display
59.     _Limit 120
60. Wend
61.  
62. Sub LoadLandscape
63.     cur& = _Dest
64.     xmax = 800 * 3.25: ymax = 600
65.     hdl& = 1
66.     para(hdl&).handle = _NewImage(xmax, ymax, 32)
67.     _Dest para(hdl&).handle
68.  
69.     For i = 0 To ymax
70.         midInk 0, 0, 128, 128, 128, 200, i / ymax
71.         Line (0, i)-(xmax, i)
72.     Next
73.     'the land
74.     startH = ymax - 200
75.     rr = 70: gg = 70: bb = 90
76.     For mountain = 1 To nLevels
77.         If mountain > 1 Then
78.             para(mountain).handle = _NewImage(xmax, ymax, 32)
79.             _Dest para(mountain).handle
80.         End If
81.         Xright = 0
82.         y = startH
83.         Color _RGB(rr, gg, bb)
84.         While Xright < xmax - 50
85.             ' upDown = local up / down over range, change along Y
86.             ' range = how far up / down, along X
87.             upDown = (Rnd * .8 - .4) * (mountain * .5)
88.             range = Xright + rand%(15, 25) * 2.5 / mountain
89.             If range > xmax - 50 Then range = xmax - 50
90.             lastx = Xright - 1
91.             For x = Xright To range 'need less flat tops
92.                 test = y + upDown
93.                 test2 = y - upDown
94.                 If Abs(test - startH) < .13 * startH Then y = test Else y = test2: upDown = -upDown
95.                 Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
96.                 lastx = x
97.             Next
98.             Xright = range
99.         Wend
100.         x = lastx + 1
101.         dy = (startH - y) / 50 'more gentle adjustment back to start of screen
102.         While x <= xmax
103.             y = y + dy
104.             Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
105.             lastx = x
106.             x = x + 1
107.         Wend
108.         rr = rand%(rr - 15, rr): gg = rand%(gg - 15, gg): bb = rand%(bb - 25, bb)
109.         If rr < 0 Then rr = 0
110.         If gg < 0 Then gg = 0
111.         If bb < 0 Then bb = 0
112.         startH = startH + mountain * rand%(2, 10)
113.         para(mountain).le = xmax - 800
114.         para(mountain).rate = mountain * .5
115.     Next
116.     _Dest cur&
117. End Sub
118.  
119. Function rand% (lo%, hi%)
120.     rand% = Int(Rnd * (hi% - lo% + 1)) + lo%
121. End Function
122.  
123. Sub midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
124.     Color _RGB(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
125. End Sub
126.  
127. Sub flashDemo
128.     Static As Long beenHere, flash
129.     If beenHere = 0 Then
130.         flash = _NewImage(_Width, _Height, 32)
131.         sd& = _Dest
132.         _Dest flash
133.         sf& = _Font
134.         f& = _LoadFont("Arial.ttf", 64)
135.         _Font f&
136.         sc~& = _DefaultColor
137.         sb~& = _BackgroundColor
138.         Color &HFFFFFFFF, &H00000000
139.         _PrintString ((_Width - _PrintWidth("This is a Demo.")) / 2, (_Height - _FontHeight(f&)) / 2), "This is a Demo."
140.         _Dest sd&
141.         _Font sf&
142.         Color sc~&, sb~&
143.         beenHere = -1
144.     End If
145.     snap = _NewImage(_Width, _Height, 32)
146.     _PutImage , 0, snap
147.     _PutImage , flash, 0
148.     sa& = _AutoDisplay
149.     _Display
150.     _Delay .5
151.     _PutImage , snap, 0
152.     _Display
153.     If sa& Then _AutoDisplay
154.     _FreeImage snap
155. End Sub
156.  

[SMcNeill]

Aint that simple for graphics demo!

It is, unless you're trying to showcase rocket science as your demo!  :P

Code: QB64: [Select]

1. Screen _NewImage(640, 480, 32)
2.  
3.  
4. View Screen(0, 0)-(639, 460)
5. View Print 30 To 30
6.  
7.  
8. Print "This text stays at the bottom without being overwritten.";
9.  
10. changeX = 2: changeY = 2
11.  
12. Do
13.     Cls 1, -1 'white background for the graphics screen
14.     'moving red ball
15.     x = x + changeX
16.     y = y + changeY
17.     For i = 1 To 25
18.         Circle (x, y), i, &HFFFF0000 'red filled circle
19.     Next
20.     If x < 0 Or x > 640 Then changeX = -changeX
21.     If y < 0 Or y > 480 Then changeY = -changeY
22.     _Limit 60
23.     _Display
24. Loop Until _KeyHit

Text on the bottom line, that doesn't get overwritten by the graphics being drawn on the screen!

If you look, I can still plot to (640,480) with absolutely no issues, but by making use of VIEW SCREEN, I've designated that only (0,0) to (640,460) are suitable for graphical rendering.  The bottom line of the screen is reserved for my text, which isn't affected at all by my graphics -- not even by the call to CLS the graphical screen!