Little break to visualize prime numbers in a million real numbers.

[Phlashlite]

Thought I'd take a little break from "storm chasing" to wonder in the visualization of prime numbers. :)

WORKING CODE uploaded below.

Code: QB64: [Select]

1. _TITLE "The Patterns in Primes"
2.  
3. CONST WDTH = 999
4. CONST HGHT = 999
5.  
6. SCREEN _NEWIMAGE(WDTH, HGHT, 32)
7.  
8. DEFLNG A-Z
9.  
10. Limit = WDTH * HGHT
11.  
12. DIM Flags(Limit) AS LONG
13.  
14. Flags(0) = 0
15. Flags(1) = 0
16. FOR N = 2 TO SQR(Limit)
17.     IF Flags(N) = 0 THEN
18.         FOR K = N * N TO Limit STEP N
19.             Flags(K) = 1
20.         NEXT K
21.     END IF
22. NEXT N
23.  
24. ' Display the primes
25.  
26. 'Spiral________________________________________________________________________
27. 'N = 2
28. 'E = UBOUND(Flags)
29. 'Radius! = 0
30. 'HalfWdth = WDTH / 2
31. 'HalfHght = HGHT / 2
32.  
33. 'FOR i# = 0 TO Limit STEP .007
34. '    IF Flags(N) = 0 THEN
35. '        PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#)), _RGB(0, 160, 0)
36. '    ELSE
37. '        PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#)), _RGB(0, 0, 0)
38. '    END IF
39. '    IF N = E THEN EXIT FOR
40. '    N = N + 1
41. '    'PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#))
42. '    Radius# = Radius# + .0007
43. 'NEXT i#
44.  
45. 'L to R, T to B________________________________________________________________
46. E = UBOUND(Flags)
47. FOR X = 0 TO HGHT
48.     FOR Y = 0 TO WDTH
49.         IF Flags(N) = 0 THEN
50.             PSET (Y, X), _RGB(0, 160, 0)
51.         ELSE
52.             PSET (Y, X), _RGB(0, 0, 0)
53.         END IF
54.         IF N = E THEN EXIT FOR
55.         N = N + 1
56.     NEXT
57. NEXT
58.  
59.  
60.  

[Phlashlite]

Hmmm.... now that I start looking closely I'm not certain this is actually working correctly...

[dbox]

I think I can see Agent Smith.

[Phlashlite]

OK... this one works :)

It's interesting.  with WDTH and HGHT of 999... all the "4,5,6" line up and put clear vertical stripes  of non primes in the image.

Code: QB64: [Select]

1. '$DEBUG
2. _TITLE "The Patterns in Primes"
3.  
4. CONST WDTH = 1000
5. CONST HGHT = 1000
6.  
7. SCREEN _NEWIMAGE(WDTH, HGHT, 32)
8.  
9. DEFLNG A-Z
10.  
11. Limit = WDTH * HGHT
12.  
13. DIM Flags(Limit) AS LONG
14.  
15.  
16. Flags(0) = 1
17. Flags(1) = 1
18. Flags(2) = 0
19. Flags(3) = 0
20. FOR N = 2 TO SQR(Limit)
21.     IF Flags(N) = 0 THEN
22.         FOR K = N * N TO Limit STEP N
23.             Flags(K) = 1
24.         NEXT K
25.     END IF
26. NEXT N
27.  
28. ' Display the primes
29.  
30. 'Spiral________________________________________________________________________
31. 'N = 2
32. 'E = UBOUND(Flags)
33. 'Radius! = 0
34. 'HalfWdth = WDTH / 2
35. 'HalfHght = HGHT / 2
36.  
37. 'FOR i# = 0 TO Limit STEP .007
38. '    IF Flags(N) = 0 THEN
39. '        PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#)), _RGB(0, 160, 0)
40. '    ELSE
41. '        PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#)), _RGB(0, 0, 0)
42. '    END IF
43. '    IF N = E THEN EXIT FOR
44. '    N = N + 1
45. '    'PSET (HalfWdth + Radius# * COS(i#), HalfHght - Radius# * SIN(i#))
46. '    Radius# = Radius# + .0007
47. 'NEXT i#
48.  
49. 'L to R, T to B________________________________________________________________
50. N = 0
51. E = UBOUND(Flags)
52. FOR X = 0 TO HGHT
53.     FOR Y = 0 TO WDTH
54.         IF Flags(N) = 0 THEN
55.             PSET (Y, X), _RGB(0, 160, 0)
56.         ELSE
57.             PSET (Y, X), _RGB(0, 0, 0)
58.         END IF
59.         IF N = E THEN EXIT FOR
60.         N = N + 1
61.     NEXT
62. NEXT
63.  
64.  
65.  

[Phlashlite]

I think I can see Agent Smith.

That's a different program :)

[bplus]

Prime spiral with zoom in / out and number ID at mouse point:

Code: QB64: [Select]

1. _Title "Primes Blue, Composites Red:    i to focus in,    o to focus out"
2. 'ashish copy 2018-01-08
3.  
4. 'bplus mods:
5. '2018-01-08  mod of isPrime%% speeds up graphic
6. '2018-01-09  now with focus in and out!
7.  
8.  
9. w = 600
10. Screen _NewImage(w, w, 32)
11. Dim numData(w, w) As _Unsigned Integer
12.  
13. ox = w / 2
14. oy = w / 2
15. limit = w / 3
16. xx = ox
17. yy = oy
18. path = 1
19. direction = 1
20. numData(ox, oy) = 0
21. Do
22.     Select Case direction
23.         Case 1 'down
24.             For i = 1 To path
25.                 yy = yy + 1
26.                 n = n + 1
27.                 numData(xx, yy) = n
28.             Next
29.         Case 2 'right
30.             For i = 1 To path
31.                 xx = xx + 1
32.                 n = n + 1
33.                 numData(xx, yy) = n
34.             Next
35.             path = path + 1
36.         Case 3 'up
37.             For i = 1 To path
38.                 yy = yy - 1
39.                 n = n + 1
40.                 numData(xx, yy) = n
41.             Next
42.         Case 4 'left
43.             For i = 1 To path
44.                 xx = xx - 1
45.                 n = n + 1
46.                 numData(xx, yy) = n
47.             Next
48.             path = path + 1
49.     End Select
50.     direction = direction + 1
51.     If direction > 4 Then direction = 1
52. Loop Until path > w
53.  
54.  
55. sq = 3
56. Dim vs(path, path) As _Unsigned Integer
57. Color _RGB(255, 255, 255)
58. While 1
59.     yy = 0
60.     For y = Int(oy - path / (2 * sq) + 1) To Int(oy + path / (2 * sq) - 1)
61.         yy = yy + 1: xx = 0
62.         For x = Int(ox - path / (2 * sq) + 1) To Int(ox + path / (2 * sq) - 1)
63.             xx = xx + 1
64.             For vy = 0 To sq
65.                 If yy * sq - sq + vy >= 0 And yy * sq - sq + vy < path Then
66.                     For vx = 0 To sq
67.                         If xx * sq - sq + vx >= 0 And xx * sq - sq + vx < path Then
68.                             vs(xx * sq - sq + vx, yy * sq - sq + vy) = numData(x, y)
69.                         End If
70.                     Next
71.                 End If
72.             Next
73.             'LINE (xx * sq - 1, yy * sq - 1)-STEP(sq - 1, sq - 1), C&, BF
74.         Next
75.     Next
76.     Cls
77.     Do
78.         K$ = InKey$
79.         If K$ = Chr$(27) Then
80.             End 'escape clause
81.         ElseIf K$ = "i" Then
82.             If sq + 1 < 50 Then
83.                 sq = sq + 1
84.                 Exit Do
85.             End If
86.         ElseIf K$ = "o" Then
87.             If sq - 1 >= 3 Then
88.                 sq = sq - 3
89.                 Exit Do
90.             End If
91.         End If
92.         Cls
93.         yy = 0
94.         For y = Int(oy - path / (2 * sq) + 1) To Int(oy + path / (2 * sq) - 1)
95.             yy = yy + 1: xx = 0
96.             For x = Int(ox - path / (2 * sq) + 1) To Int(ox + path / (2 * sq) - 1)
97.                 xx = xx + 1
98.                 If isPrime(numData(x, y)) Then C& = _RGB(0, 0, 255) Else C& = _RGB(255, 0, 0)
99.                 Line (xx * sq - sq, yy * sq - sq)-Step(sq - 2, sq - 2), C&, BF
100.                 If x = ox And y = oy Then
101.                     Line (xx * sq - sq, yy * sq - sq)-Step(sq - 2, sq - 2), _RGB(255, 255, 0), BF
102.                 End If
103.             Next
104.         Next
105.  
106.         While _MouseInput: Wend
107.         mouseX = _MouseX
108.         mouseY = _MouseY
109.  
110.         If mouseX >= 0 And mouseY >= 0 And mouseX <= path And mouseY <= path Then
111.             t$ = LTrim$(Str$(vs(mouseX, mouseY)))
112.             If mouseX < 100 Then
113.                 xAdj = 10
114.             ElseIf mouseX > w - 100 Then
115.                 xAdj = -Len(t$) * 8 - 10
116.             Else
117.                 xAdj = -Len(t$) * 4
118.             End If
119.             If mouseY <= w / 2 Then yAdj = 20 Else yAdj = -20
120.  
121.             _PrintString (mouseX + xAdj, mouseY + yAdj), t$
122.             _Display
123.         End If
124.         _Display
125.         _Limit 60
126.     Loop
127. Wend
128.  
129. Function isPrime%% (num)
130.     If num Mod 2 = 0 Then
131.         If num = 2 Then isPrime%% = -1
132.         Exit Function
133.     Else
134.         If num = 1 Then
135.             Exit Function
136.         Else
137.             For i = 3 To Sqr(num) Step 2
138.                 If num Mod i = 0 Then Exit Function
139.             Next
140.             isPrime%% = -1
141.         End If
142.     End If
143. End Function
144.  
145.  

[_vince]

Prime spiral with zoom in / out and number ID at mouse point:

is this a Golden Spiral?

[bplus]

Heck no, it a simple little square spiral by a deranged spider :-))

[johnno56]

"I'm seeing spots before my eyes!"
"Have you seen a Doctor?"
"No. Just spots..."