Simple digital clock

[SquirrelMonkey]

Code: QB64: [Select]

1. _Title "Clock"
2. Screen 2
3. Locate 25, 1: Print String$(79, 220);: Locate 2, 1: Print String$(79, 223);
4. Locate 21, 2: Print String$(77, 176);: Locate 22, 2: Print String$(77, 177);
5. Locate 23, 2: Print String$(77, 178);: Locate 24, 2: Print String$(77, 219);
6. For a = 1 To 24
7.     Locate a + 1, 1: Print Chr$(219);
8.     Locate a + 1, 79: Print Chr$(219);
9. Next a: Palette 0, 1: Palette 1, 15
10. Do: Locate 1, 1: Print " "; Time$
11.     For b = 0 To 7: For a = 1 To 73: r$ = InKey$: If r$ <> "" Then End
12.         If Point(a, b) = 0 Then Locate b + 9, a + 1: Print Chr$(32); Else Print Chr$(Int((Rnd * 3) + 176));
13.         Next a
14.         teller = teller + 1
15.         If teller > 77 Then Locate 21, 2: Print String$(77, 176);
16.         If teller > 77 Then Locate 22, 2: Print String$(77, 177);
17.         If teller > 77 Then Locate 23, 2: Print String$(77, 178);
18.         If teller > 77 Then Locate 24, 2: Print String$(77, 219);
19.         If teller > 77 Then teller = 1
20.         Locate 21, teller + 1: Print Chr$(219);: Locate 22, teller + 1: Print Chr$(178);
21.         Locate 23, teller + 1: Print Chr$(177);: Locate 24, teller + 1: Print Chr$(176);
22.     Next b: _Delay 1: Sound 29948, 0.03
23. Loop
24.  
25.  
26.  

[bplus]

That's kinda interesting.

[bplus]

Here's a plasma version:

Code: QB64: [Select]

1. _Title "Plasma Time" ' b+ 2022-01-29
2. Screen _NewImage(720, 160, 32)
3. Color &HFF880000, &HFF000000
4. While _KeyDown(27) = 0
5.     Cls
6.     For y = 0 To 15
7.         If y < 10 Then
8.             Locate y + 1, 1
9.             For i = 1 To 10
10.                 Print Time$; " ";:
11.             Next
12.         End If
13.         For x = 0 To 63
14.             If Point(x, y) <> Point(0, 0) Then cN = cN + 1: Line (x * 10 + 40, y * 10)-Step(9, 9), _RGB(127 + 127 * Sin(1.2 * .3 * cN), 127 + 127 * Sin(.06 * .3 * cN), 127 + 127 * Sin(.82 * .3 * cN)), BF
15.         Next
16.     Next
17.     _Limit 1
18.     Sound 1500, .03
19.     _Display
20. Wend
21.  

 

[SierraKen]

Awesome guys! I just threw time$ on some 1990's code I have from the newsgroup comp.lang.basic.misc to make it 3D looking. Since it's 1990's it was Screen 13, so I am using _FULLSCREEN. Press any key to stop the program.

Code: QB64: [Select]

1. '3d Code from an old 1990's Internet Newsgroup comp.lang.basic.misc post.
2. Screen 13
3. _FullScreen
4. Do
5.     Locate 1, 32
6.     Color 1
7.     Print Time$
8.     For I = 118 To 820
9.         For j = 0 To 810
10.             If Point(I, j) > 0 Then Line ((I - 196) * 2, j * 2 + 50)-((I - 196) * 2 + 2, j * 2 + 52), 15, BF
11.         Next j
12.     Next I
13.  
14.     For I = 100 To 820
15.         For j = 49 To 875
16.             If Point(I, j) = 15 Then GoTo skip2j
17.             If Point(I + 1, j + 1) = 15 Then PSet (I, j), 50
18.             If Point(I, j + 1) = 15 Or Point(I + 1, j) = 15 Then PSet (I, j), 49
19.             If Point(I - 1, j + 1) = 15 Or Point(I + 1, j - 1) = 15 Then PSet (I, j), 48
20.             If Point(I, j - 1) = 15 Or Point(I - 1, j) = 15 Then PSet (I, j), 47
21.             If Point(I - 1, j - 1) = 15 Then PSet (I, j), 46
22.             skip2j:
23.         Next j
24.     Next I
25.     For I = 100 To 820
26.         For j = 49 To 875
27.             If Point(I, j) = 15 Then PSet (I, j), 32 - (j - 49)
28.         Next j
29.     Next I
30.  
31.     For I = 1 To 5
32.         n = I * 12
33.         c = n * 65536 + n * 256 + n
34.         Palette I + 45, c
35.     Next I
36.  
37.     Line (0, 0)-(320, 30), 0, BF
38.     _Display
39.     Cls
40. Loop Until InKey$ <> ""
41.  

[bplus]

Oh that's cool! That gives me an idea :-))

[bplus]

Code: QB64: [Select]

1. _Title "Plasma Time 3D" ' b+ 2022-01-29
2. Screen _NewImage(720, 160, 32)
3. Color &HFF880000, &HFF000000
4. While _KeyDown(27) = 0
5.     Cls
6.     For y = 0 To 15
7.         If y < 10 Then
8.             Locate y + 1, 1
9.             For i = 1 To 10
10.                 Print Time$; " ";:
11.             Next
12.         End If
13.         For x = 0 To 63
14.             For z = 0 To 10
15.                 If z < 10 Then
16.                     If Point(x, y) <> Point(0, 0) Then Line (x * 10 + 40 + z, y * 10 + z)-Step(9, 9), _RGB32(68), BF
17.                 Else
18.                     If Point(x, y) <> Point(0, 0) Then cN = cN + 1: Line (x * 10 + 40, y * 10)-Step(9, 9), _RGB(127 + 127 * Sin(1.2 * .3 * cN), 127 + 127 * Sin(.06 * .3 * cN), 127 + 127 * Sin(.82 * .3 * cN)), BF
19.                 End If
20.             Next
21.         Next
22.     Next
23.     _Limit 1
24.     Sound 1500, .03
25.     _Display
26. Wend
27.  

[SierraKen]

LOL B+ that's totally funky! I also like the sound.

[SierraKen]

Squirrel Monkey, I finally ran your clock. It's like seeing an old 80's LCD clock when you are half-asleep. WAY COOL! :-)

By the way, are you the same Squirrel Monkey on FaceBook that posts totally rad 80's or 90's technology stuff? They remake videos that are supposed to be from the 80's or 90's, for example, many of them are "THE WORLD WIDE WEB". Incredible stuff. :)