dynamically detect available # of text rows+columns under a custom screen size?

[madscijr]

I'm looking for something like the _WIDTH and _HEIGHT functions
https://wiki.qb64.org/wiki/WIDTH_(function)
https://wiki.qb64.org/wiki/HEIGHT
but for text, when the screen is not in text mode.

The docs say _WIDTH and _HEIGHT return the number of characters if the image is in text only mode, else it returns the number of pixels:

To get the width of the current program screen window use zero for the handle value or nothing: columns& = _WIDTH(0) or columns& = _WIDTH
To get the height of the current program screen window use zero for the handle value or nothing: lines& = _HEIGHT(0) or lines& = _HEIGHT
If the image specified by imageHandle& is in text only(SCREEN 0) mode, the number of characters per row is returned.
If the image specified by imageHandle& is in graphics mode, the number of pixels per row is returned.

The test program below returns the number of pixels.
How would you programmatically determine the number of characters (rows/columns) when the screen is not in text mode, for example Screen _NewImage(1280, 1024, 32) ?

Code: QB64: [Select]

1. Dim in$
2. Screen _NewImage(1280, 1024, 32): _ScreenMove 0, 0
3. CLS
4. PRINT "Showing available text rows/columns of Screen _NewImage(1280, 1024, 32)"
5. PRINT
6. PRINT "_WIDTH(0) = " + _TRIM$(STR$( _WIDTH(0) ))
7. PRINT "_HEIGHT(0) = " + _TRIM$(STR$( _HEIGHT(0) ))
8. PRINT
9. INPUT "PRESS <ENTER> TO CONTINUE";in$
10. SCREEN 0
11. SYSTEM
12. END
13.  

Much appreciated...

[bplus]

You can get the width of a string s$ with _PrintWidth(s$) and you can get the the height of a font with _FontHeight(FontHandle&), these are in pixels.

BTW you are usually in default font 16 = height

So you just loaded a font, how many whole rows will fit on the screen?
_Height\_FontHeight(FontHandle&)

First row at 0
next at FontHeight
next at 2*FontHeight
next at 3*FontHeight
...

[Petr]

Hi @madscijr

In graphical mode text use font (default is _FONT 16), so what you need is _FontHeight, _Fontwidth and _PrintWidth.
How much columns is on graphic screen: _Width \ _FontWidth, for rows _Height \ _FontHeight.
If you use other fonts, use MONOSPACE type.

Let say on screen 640 x 480 and default font it is 640 \ 8 = 80 columns and
                                                                        480 \ 16 = 30 rows

 

[madscijr]

In graphical mode text use font (default is _FONT 16), so what you need is _FontHeight, _Fontwidth and _PrintWidth.
How much columns is on graphic screen: _Width \ _FontWidth, for rows _Height \ _FontHeight.
Let say on screen 640 x 480 and default font it is 640 \ 8 = 80 columns and 480 \ 16 = 30 rows

That should work, thanks!

[madscijr]

You can get the width of a string s$ with _PrintWidth(s$) and you can get the the height of a font with _FontHeight(FontHandle&), these are in pixels.

Thanks - I have not used _PrintWidth, it seems like it could be useful!

[madscijr]

You can get the width of a string s$ with _PrintWidth(s$) and you can get the the height of a font with _FontHeight(FontHandle&), these are in pixels.
So you just loaded a font, how many whole rows will fit on the screen?
_Height\_FontHeight(FontHandle&)

In graphical mode text use font (default is _FONT 16), so what you need is _FontHeight, _Fontwidth and _PrintWidth.
How much columns is on graphic screen: _Width \ _FontWidth, for rows _Height \ _FontHeight.

OK, I have a followup question.

I wrote a test program that computes the expected number of text columns and rows for various resolutions,
and for each tries to print that amount of columns/rows to the screen.

However, for certain resolutions it isn't working as expected:

• at 800x600 we expect 100 columns, 38 rows. When the program tries to print the last row, there is an error #5 at "LOCATE 38,1".
• at 1920x1080 we expect 248 columns, 68 rows. When the program tries to print the last row, there is an error #5 at "LOCATE 68,1".
• at 2048x1152 we expect 256 columns, 72 rows. No errors, but only 70 rows and 255 columns fit on the screen (row 71 and column 256 are mostly cut off).
• at 3840x2160 we expect 480 columns, 135 rows. No errors, but only 133 rows and 479 columns fit on the screen (row 134 and column 134 are mostly cut off).

What gives?
Why does it throw an error for some resolutions but for others simply truncates the rows?
I am seeing the same results in both windowed and full screen modes.

My test program is below if you want to try replicating my results.
It catches errors on the LOCATE so it won't blow up.

Code: QB64: [Select]

1. ' Text rows/columns per screen resolution test
2. ' Version 1.0 by madscijr
3.  
4. ' boolean constants:
5. Const FALSE = 0
6. Const TRUE = Not FALSE
7.  
8. ' global variables
9. Dim Shared m_ProgramPath$: m_ProgramPath$ = Left$(Command$(0), _InStrRev(Command$(0), "\"))
10. Dim Shared m_ProgramName$: m_ProgramName$ = Mid$(Command$(0), _InStrRev(Command$(0), "\") + 1)
11. Dim Shared m_bTesting As Integer: m_bTesting = FALSE
12. Dim Shared m_sCode As String: m_sCode = ""
13. Dim Shared m_sError As String: m_sError = ""
14.  
15. ' LOCAL VARIABLES
16. Dim in$
17.  
18. ' ****************************************************************************************************************************************************************
19. ' ACTIVATE DEBUGGING WINDOW
20. If m_bTesting = TRUE Then
21.     $Console
22.     _Delay 4
23.     _Console On
24.     _Echo "Started " + m_ProgramName$
25.     _Echo "Debugging on..."
26. End If
27. ' ****************************************************************************************************************************************************************
28.  
29. ' =============================================================================
30. ' START THE MAIN ROUTINE
31. main
32.  
33. ' =============================================================================
34. ' FINISH
35. Screen 0
36. Print m_ProgramName$ + " finished."
37. Input "Press <ENTER> to continue", in$
38.  
39. ' ****************************************************************************************************************************************************************
40. ' DEACTIVATE DEBUGGING WINDOW
41. If m_bTesting = TRUE Then
42.     _Console Off
43. End If
44. ' ****************************************************************************************************************************************************************
45.  
46. System ' return control to the operating system
47. End
48.  
49. ' /////////////////////////////////////////////////////////////////////////////
50.  
51. ErrHandler:
52. m_sError = "Error #" + _Trim$(Str$(Err)) + " at line " + _Trim$(Str$(_ErrorLine)) + ": " + m_sCode
53. Resume Next
54.  
55. ' /////////////////////////////////////////////////////////////////////////////
56.  
57. Sub main
58.     Dim RoutineName As String: RoutineName = "main"
59.     Dim in$
60.     Dim result$
61.  
62.     Screen 0
63.     Do
64.         Cls
65.         Print m_ProgramName$
66.         Print
67.         Print "Screen resolution tests"
68.         Print
69.         Print "1. Count text width/height (windowed)"
70.         Print "2. Count text width/height (full screen)"
71.         Print
72.         Print "What to do? ('q' to exit)"
73.  
74.         Input in$: in$ = LCase$(Left$(in$, 1))
75.  
76.         If in$ = "1" Then
77.             result$ = GetTextWidthHeight$(FALSE)
78.         ElseIf in$ = "2" Then
79.             result$ = GetTextWidthHeight$(TRUE)
80.         End If
81.  
82.         If Len(result$) > 0 Then
83.             Print result$
84.         End If
85.  
86.     Loop Until in$ = "q"
87. End Sub ' main
88.  
89. ' /////////////////////////////////////////////////////////////////////////////
90. ' dynamically detect available # of text rows+columns under a custom screen size?
91. ' https://qb64forum.alephc.xyz/index.php?topic=4550.0
92.  
93. ' Petr:
94. ' In graphical mode text use font (default is _FONT 16),
95. ' so what you need is _FontHeight, _FontWidth and _PrintWidth.
96. ' How much columns is on graphic screen:
97. ' _Width \ _FontWidth, for rows _Height \ _FontHeight.
98. ' If you use other fonts, use MONOSPACE type.
99. ' Let say on screen 640 x 480 and default font
100. ' it is 640 \ 8 = 80 columns and 480 \ 16 = 30 rows
101.  
102. ' GetNextTextWidthHeight$  640,  480, "VGA (4:3)"
103. ' GetNextTextWidthHeight$  720,  480, "480p (4:3, 16:9)"
104. ' GetNextTextWidthHeight$  800,  600, "SVGA (4:3)"
105. ' GetNextTextWidthHeight$ 1024,  768, "XGA (4:3)"
106. ' GetNextTextWidthHeight$ 1280, 1024, "SXGA (5:4)"
107. ' GetNextTextWidthHeight$ 1920, 1080, "FHD (16:9)"
108. ' GetNextTextWidthHeight$ 2048, 1152, "QWXGA (16:9)"
109. ' GetNextTextWidthHeight$ 3840, 2160, "4K UHD (16:9)"
110. ' GetNextTextWidthHeight$ 7680, 4320, "8K UHD (16:9)"
111.  
112. Function GetNextTextWidthHeight$ (iScreenWidth As Integer, iScreenHeight As Integer, sDescription As String)
113.     Dim RoutineName As String: RoutineName = ""
114.  
115.     ' currently set up to not try to change screen resolution to less than VGA or bigger than 4k
116.     Dim iMinWidth As Integer: iMinWidth = 640
117.     Dim iMaxWidth As Integer: iMaxWidth = 3840
118.     Dim iMinHeight As Integer: iMinHeight = 480
119.     Dim iMaxHeight As Integer: iMaxHeight = 2160
120.  
121.     Dim in$
122.     Dim iCols As Integer
123.     Dim iRows As Integer
124.     Dim iLoopRows As Integer
125.     Dim iLoopCols As Integer
126.     Dim iCount As Integer
127.     Dim sResult As String: sResult = ""
128.     Dim bExit As Integer: bExit = FALSE
129.  
130.     ' ONLY TEST FOR ALLOWED RESOLUTIONS
131.     If (iScreenWidth >= iMinWidth) And (iScreenWidth <= iMaxWidth) And (iScreenHeight >= iMinHeight) And (iScreenHeight <= iMaxHeight) Then
132.         Do
133.             ' =============================================================================
134.             ' SHOW RESOLUTION AND EXPECTED # OF CHARACTERS TO FIT
135.             Screen 0
136.             Cls
137.  
138.             'PRINT "Screen size:"
139.             'PRINT "    _WIDTH(0)   = " + _TRIM$(STR$( _WIDTH(0) ))
140.             'PRINT "    _HEIGHT(0)  = " + _TRIM$(STR$( _HEIGHT(0) ))
141.             'Print "Font size:"
142.             'Print "    _FontWidth  = " + _Trim$(Str$(_FontWidth))
143.             'Print "    _FontHeight = " + _Trim$(Str$(_FontHeight))
144.             ' To measure actual available columns/rows:
145.             'iCols = _WIDTH(0) / _FontWidth
146.             'iRows = _HEIGHT(0) / _FontHeight
147.             'PRINT "Current characters per screen:"
148.             'PRINT "    # columns = _WIDTH(0)  / _FontWidth  = " + _TRIM$(STR$( _WIDTH(0) )) + " / " + _TRIM$(STR$(_FontWidth)) + " = " + _TRIM$(STR$(iCols))
149.             'PRINT "    #    rows = _HEIGHT(0) / _FontHeight = " + _TRIM$(STR$( _HEIGHT(0) )) + " / " + _TRIM$(STR$(_FontHeight)) + " = " + _TRIM$(STR$(iRows))
150.  
151.             ' Calculate for a hypothetical resolution:
152.             iCols = iScreenWidth / _FontWidth
153.             iRows = iScreenHeight / _FontHeight
154.  
155.             Print "Screen resolution: " + _Trim$(Str$(iScreenWidth)) + "x" + _Trim$(Str$(iScreenHeight)) + " " + sDescription
156.             Print "Font size        : " + _Trim$(Str$(_FontWidth)) + "x" + _Trim$(Str$(_FontHeight))
157.             Print "Text cols x rows : " + _Trim$(Str$(iCols)) + "x" + _Trim$(Str$(iRows))
158.             Print
159.             Print "Options"
160.             Print "-------"
161.             Print "R     test rows"
162.             Print "C     test columns"
163.             Print "ENTER continue to next resolution"
164.             Print "Q     quit testing resolutions"
165.             Print
166.             Input "What to do? "; in$
167.             in$ = Left$(LCase$(_Trim$(in$)), 1)
168.  
169.             ' -----------------------------------------------------------------------------
170.             ' TEST TO SEE IF THE # OF ROWS WE EXPECT REALLY DO FIT ON THE SCREEN
171.             If in$ = "r" Then
172.                 Screen _NewImage(iScreenWidth, iScreenHeight, 32): _ScreenMove 0, 0
173.                 Cls
174.                 For iLoopRows = 1 To iRows
175.                     On Error GoTo ErrHandler
176.                     m_sCode = "LOCATE " + cstr$(iLoopRows) + ", 1"
177.                     Locate iLoopRows, 1
178.                     On Error GoTo 0
179.  
180.                     If Len(m_sError) = 0 Then
181.                         Print cstr$(iLoopRows);
182.                     Else
183.                         Do
184.                             Locate 1, 1: Print String$(iCols, " ");
185.                             Locate 2, 1: Print String$(iCols, " ");
186.                             Locate 3, 1: Print String$(iCols, " ");
187.                             Locate 1, 1: Print m_sError
188.                             Locate 2, 1: Input "Type y to continue or n to exit this resolution"; in$
189.                             in$ = Left$(LCase$(_Trim$(in$)), 1)
190.                             If in$ = "n" Then
191.                                 bExit = TRUE
192.                                 Exit Do
193.                             ElseIf in$ = "y" Then
194.                                 Exit Do
195.                             End If
196.                         Loop
197.                     End If
198.  
199.                     If bExit = TRUE Then
200.                         bExit = FALSE
201.                         Exit For
202.                     End If
203.                 Next iLoopRows
204.  
205.                 If in$ = "y" Then
206.                     m_sError = "": m_sCode = ""
207.                 ElseIf in$ <> "y" And in$ <> "n" Then
208.                     Locate 1, 10
209.                     Print _Trim$(Str$(iRows)) + " rows expected at resolution " + cstr$(iScreenWidth) + "x" + cstr$(iScreenHeight)
210.                     Locate 2, 10
211.                     Input "Press <ENTER> to continue"; in$
212.                 End If
213.  
214.                 ' -----------------------------------------------------------------------------
215.                 ' TEST TO SEE IF THE # OF COLUMNS WE EXPECT REALLY DO FIT ON THE SCREEN
216.             ElseIf in$ = "c" Then
217.                 Screen _NewImage(iScreenWidth, iScreenHeight, 32): _ScreenMove 0, 0
218.                 Cls
219.                 Print _Trim$(Str$(iCols)) + " columns expected at resolution " + cstr$(iScreenWidth) + "x" + cstr$(iScreenHeight)
220.                 Print
221.  
222.                 ' print hundreds
223.                 iCount = 0
224.                 For iLoopCols = 1 To iCols
225.                     iCount = iCount + 1
226.                     If iLoopCols < iCols Then
227.                         Print Left$(Right$("   " + cstr$(iCount), 3), 1);
228.                     Else
229.                         Print Left$(Right$("   " + cstr$(iCount), 3), 1)
230.                     End If
231.                 Next iLoopCols
232.  
233.                 ' print tens
234.                 iCount = 0
235.                 For iLoopCols = 1 To iCols
236.                     iCount = iCount + 1
237.                     If iLoopCols < iCols Then
238.                         Print Mid$(Right$("   " + cstr$(iCount), 3), 2, 1);
239.                     Else
240.                         Print Mid$(Right$("   " + cstr$(iCount), 3), 2, 1)
241.                     End If
242.                 Next iLoopCols
243.  
244.                 ' print ones
245.                 iCount = 0
246.                 For iLoopCols = 1 To iCols
247.                     iCount = iCount + 1
248.                     If iLoopCols < iCols Then
249.                         Print Right$(cstr$(iCount), 1);
250.                     Else
251.                         Print Right$(cstr$(iCount), 1)
252.                     End If
253.                 Next iLoopCols
254.  
255.                 Print
256.                 Input "Press <ENTER> to continue"; in$
257.  
258.                 ' -----------------------------------------------------------------------------
259.                 ' EXIT + MOVE ON TO THE NEXT RESOLUTION
260.             Else
261.                 Exit Do
262.             End If
263.  
264.             If Len(m_sError) > 0 Then
265.                 m_sError = ""
266.                 m_sCode = ""
267.                 Exit Do
268.             End If
269.         Loop
270.     Else
271.         ' ASK THE USER IF THEY WANT TO MOVE ON TO THE NEXT RESOLUTION OR QUIT
272.         Input "Q to quit, or <ENTER> to continue to next resolution"; in$
273.         in$ = Left$(LCase$(_Trim$(in$)), 1)
274.     End If
275.  
276.     If in$ = "q" Then
277.         sResult = "q"
278.     End If
279.  
280.     CleanupAndExit:
281.     Screen 0
282.     GetNextTextWidthHeight$ = sResult
283.  
284. End Function ' GetNextTextWidthHeight$
285.  
286. ' /////////////////////////////////////////////////////////////////////////////
287.  
288. Function GetTextWidthHeight$ (bFullScreen As Integer)
289.     Dim sResult As String: sResult = ""
290.  
291.     If bFullScreen = TRUE Then
292.         _FullScreen _SquarePixels
293.     End If
294.  
295.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(640, 480, "VGA (4:3)")
296.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(720, 480, "480p (4:3, 16:9)")
297.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(800, 600, "SVGA (4:3)")
298.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1024, 768, "XGA (4:3)")
299.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1280, 1024, "SXGA (5:4)")
300.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1920, 1080, "FHD (16:9)")
301.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(2048, 1152, "QWXGA (16:9)")
302.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(3840, 2160, "4K UHD (16:9)")
303.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(7680, 4320, "8K UHD (16:9)")
304.  
305.     If bFullScreen = TRUE Then
306.         _FullScreen _Off
307.     End If
308.  
309.     GetTextWidthHeight$ = ""
310. End Function ' GetTextWidthHeight$
311.  
312.  
313. ' /////////////////////////////////////////////////////////////////////////////
314. ' Convert a value to string and trim it (because normal Str$ adds spaces)
315.  
316. Function cstr$ (myValue)
317.     'cstr$ = LTRIM$(RTRIM$(STR$(myValue)))
318.     cstr$ = _Trim$(Str$(myValue))
319. End Function ' cstr$
320.  
321. ' /////////////////////////////////////////////////////////////////////////////
322.  
323. Sub DebugPrint (s$)
324.     If m_bTesting = TRUE Then
325.         _Echo s$
326.     End If
327. End Sub ' DebugPrint
328.  
329.  

[bplus]

I will take on only one issue you mention @madscijr

at 800x600 we expect 100 columns, 38 rows. When the program tries to print the last row, there is an error #5 at "LOCATE 38,1".

600 /16 = 37.5 so you only have 37 whole rows.

Code: QB64: [Select]

1. Screen _NewImage(800, 600, 32)
2. _PrintString (0, 37 * 16), "hello world"
3.  
4. Print " see .5 hello world at bottom?  oh but! the first row is row 0 *16"
5. Print " so you go from 0 * 16 to 36 * 16  rows, press any"
6. Sleep
7. Cls
8. Print "rows go from 0 to 36 = 37 rows"
9. _PrintString (0, 36 * 16), "hello world, press any to finish"
10. Sleep
11.  

_Height\_FontHeight(FontHandle&)

Notice in your quote of me, I used a  \  not / that (the former \) is Integer Divide not float divide (the later /).

I've been advised and I pass it on to you, get in habit of _PrintString it wont give you errors that Locate does PLUS much more freedom on graphics screen to print text anywhere!

[madscijr]

I will take on only one issue you mention @madscijr
...
Notice in your quote of me, I used a  \  not / that (the former \) is Integer Divide not float divide (the later /).

Aha... I was erroneously doing regular division and not integer division. My bad!
Thanks for pointing that out.

I've been advised and I pass it on to you, get in habit of _PrintString it wont give you errors that Locate does PLUS much more freedom on graphics screen to print text anywhere!

Thanks for the tip!
I see it's pretty straightforward, you just need to calculate the x,y based on font width/height.

Code: QB64: [Select]

1. x% = _FontWidth * (col% - 1)
2. y% = _FontHeight * (row% - 1)
3. _PRINTSTRING (x%, y%), mystring$
4.  

So with that in place (updated code below), I am still seeing the last couple of rows/columns truncated for these resolutions

• at 2048x1152 we expect 256 columns, 72 rows. No errors, but only 70 rows and 255 columns fit on the screen (row 71 and column 256 are mostly cut off).
• at 3840x2160 we expect 480 columns, 135 rows. No errors, but only 133 rows and 479 columns fit on the screen (row 134 and column 134 are mostly cut off).

Any thoughts welcome, and thanks again!

Code: QB64: [Select]

1. ' Text rows/columns per screen resolution test
2. ' Version 1.03 by madscijr
3.  
4. ' boolean constants:
5. Const FALSE = 0
6. Const TRUE = Not FALSE
7.  
8. ' global variables
9. Dim Shared m_ProgramPath$: m_ProgramPath$ = Left$(Command$(0), _InStrRev(Command$(0), "\"))
10. Dim Shared m_ProgramName$: m_ProgramName$ = Mid$(Command$(0), _InStrRev(Command$(0), "\") + 1)
11. Dim Shared m_bTesting As Integer: m_bTesting = FALSE
12. Dim Shared m_sCode As String: m_sCode = ""
13. Dim Shared m_sError As String: m_sError = ""
14.  
15. ' LOCAL VARIABLES
16. Dim in$
17.  
18. ' ****************************************************************************************************************************************************************
19. ' ACTIVATE DEBUGGING WINDOW
20. If m_bTesting = TRUE Then
21.     $Console
22.     _Delay 4
23.     _Console On
24.     _Echo "Started " + m_ProgramName$
25.     _Echo "Debugging on..."
26. End If
27. ' ****************************************************************************************************************************************************************
28.  
29. ' =============================================================================
30. ' START THE MAIN ROUTINE
31. main
32.  
33. ' =============================================================================
34. ' FINISH
35. Screen 0
36. Print m_ProgramName$ + " finished."
37. Input "Press <ENTER> to continue", in$
38.  
39. ' ****************************************************************************************************************************************************************
40. ' DEACTIVATE DEBUGGING WINDOW
41. If m_bTesting = TRUE Then
42.     _Console Off
43. End If
44. ' ****************************************************************************************************************************************************************
45.  
46. System ' return control to the operating system
47. End
48.  
49. ' /////////////////////////////////////////////////////////////////////////////
50.  
51. ErrHandler:
52. m_sError = "Error #" + _Trim$(Str$(Err)) + " at line " + _Trim$(Str$(_ErrorLine)) + ": " + m_sCode
53. Resume Next
54.  
55. ' /////////////////////////////////////////////////////////////////////////////
56.  
57. Sub main
58.     Dim RoutineName As String: RoutineName = "main"
59.     Dim in$
60.     Dim result$
61.  
62.     Screen 0
63.     Do
64.         Cls
65.         Print m_ProgramName$
66.         Print
67.         Print "Screen resolution tests"
68.         Print
69.         Print "1. Count text width/height (windowed)"
70.         Print "2. Count text width/height (full screen)"
71.         Print
72.         Print "What to do? ('q' to exit)"
73.  
74.         Input in$: in$ = LCase$(Left$(in$, 1))
75.  
76.         If in$ = "1" Then
77.             result$ = GetTextWidthHeight$(FALSE)
78.         ElseIf in$ = "2" Then
79.             result$ = GetTextWidthHeight$(TRUE)
80.         End If
81.  
82.         If Len(result$) > 0 Then
83.             Print result$
84.         End If
85.  
86.     Loop Until in$ = "q"
87. End Sub ' main
88.  
89. ' /////////////////////////////////////////////////////////////////////////////
90. ' dynamically detect available # of text rows+columns under a custom screen size?
91. ' https://qb64forum.alephc.xyz/index.php?topic=4550.0
92.  
93. ' Petr:
94. ' In graphical mode text use font (default is _FONT 16),
95. ' so what you need is _FontHeight, _FontWidth and _PrintWidth.
96. ' How much columns is on graphic screen:
97. ' _Width \ _FontWidth, for rows _Height \ _FontHeight.
98. ' If you use other fonts, use MONOSPACE type.
99. ' Let say on screen 640 x 480 and default font
100. ' it is 640 \ 8 = 80 columns and 480 \ 16 = 30 rows
101.  
102. ' GetNextTextWidthHeight$  640,  480, "VGA (4:3)"
103. ' GetNextTextWidthHeight$  720,  480, "480p (4:3, 16:9)"
104. ' GetNextTextWidthHeight$  800,  600, "SVGA (4:3)"
105. ' GetNextTextWidthHeight$ 1024,  768, "XGA (4:3)"
106. ' GetNextTextWidthHeight$ 1280, 1024, "SXGA (5:4)"
107. ' GetNextTextWidthHeight$ 1920, 1080, "FHD (16:9)"
108. ' GetNextTextWidthHeight$ 2048, 1152, "QWXGA (16:9)"
109. ' GetNextTextWidthHeight$ 3840, 2160, "4K UHD (16:9)"
110. ' GetNextTextWidthHeight$ 7680, 4320, "8K UHD (16:9)"
111.  
112. Function GetNextTextWidthHeight$ (iScreenWidth As Integer, iScreenHeight As Integer, sDescription As String)
113.     Dim RoutineName As String: RoutineName = ""
114.  
115.     ' currently set up to not try to change screen resolution to less than VGA or bigger than 4k
116.     Dim iMinWidth As Integer: iMinWidth = 640
117.     Dim iMaxWidth As Integer: iMaxWidth = 3840
118.     Dim iMinHeight As Integer: iMinHeight = 480
119.     Dim iMaxHeight As Integer: iMaxHeight = 2160
120.  
121.     Dim in$
122.     Dim iCols As Integer
123.     Dim iRows As Integer
124.     Dim iLoopRows As Integer
125.     Dim iLoopCols As Integer
126.     Dim iCount As Integer
127.     Dim sResult As String: sResult = ""
128.     Dim bExit As Integer: bExit = FALSE
129.     Dim iX As Integer
130.     Dim iY As Integer
131.  
132.     ' ONLY TEST FOR ALLOWED RESOLUTIONS
133.     If (iScreenWidth >= iMinWidth) And (iScreenWidth <= iMaxWidth) And (iScreenHeight >= iMinHeight) And (iScreenHeight <= iMaxHeight) Then
134.         Do
135.             ' =============================================================================
136.             ' SHOW RESOLUTION AND EXPECTED # OF CHARACTERS TO FIT
137.             Screen 0
138.             Cls
139.  
140.             'PRINT "Screen size:"
141.             'PRINT "    _WIDTH(0)   = " + _TRIM$(STR$( _WIDTH(0) ))
142.             'PRINT "    _HEIGHT(0)  = " + _TRIM$(STR$( _HEIGHT(0) ))
143.             'Print "Font size:"
144.             'Print "    _FontWidth  = " + _Trim$(Str$(_FontWidth))
145.             'Print "    _FontHeight = " + _Trim$(Str$(_FontHeight))
146.             ' To measure actual available columns/rows:
147.             'iCols = _WIDTH(0) \ _FontWidth
148.             'iRows = _HEIGHT(0) \ _FontHeight
149.             'PRINT "Current characters per screen:"
150.             'PRINT "    # columns = _WIDTH(0)  \ _FontWidth  = " + _TRIM$(STR$( _WIDTH(0) )) + " \ " + _TRIM$(STR$(_FontWidth)) + " = " + _TRIM$(STR$(iCols))
151.             'PRINT "    #    rows = _HEIGHT(0) \ _FontHeight = " + _TRIM$(STR$( _HEIGHT(0) )) + " \ " + _TRIM$(STR$(_FontHeight)) + " = " + _TRIM$(STR$(iRows))
152.  
153.             ' Calculate for a hypothetical resolution: (thanks bplus and petr!)
154.             'iCols = iScreenWidth \ _FontWidth
155.             'iRows = iScreenHeight \ _FontHeight
156.             iCols = iScreenWidth \ _FontWidth
157.             iRows = iScreenHeight \ _FontHeight
158.  
159.             Print "Screen resolution: " + _Trim$(Str$(iScreenWidth)) + "x" + _Trim$(Str$(iScreenHeight)) + " " + sDescription
160.             Print "Font size        : " + _Trim$(Str$(_FontWidth)) + "x" + _Trim$(Str$(_FontHeight))
161.             Print "Text cols x rows : " + _Trim$(Str$(iCols)) + "x" + _Trim$(Str$(iRows))
162.             Print
163.             Print "Options"
164.             Print "-------"
165.             Print "R     test rows"
166.             Print "C     test columns"
167.             Print "ENTER continue to next resolution"
168.             Print "Q     quit testing resolutions"
169.             Print
170.             Input "What to do? "; in$
171.             in$ = Left$(LCase$(_Trim$(in$)), 1)
172.  
173.             ' -----------------------------------------------------------------------------
174.             ' TEST TO SEE IF THE # OF ROWS WE EXPECT REALLY DO FIT ON THE SCREEN
175.             If in$ = "r" Then
176.                 Screen _NewImage(iScreenWidth, iScreenHeight, 32): _ScreenMove 0, 0
177.                 Cls
178.                 For iLoopRows = 1 To iRows
179.                     iX = 0 ' _FontWidth * (iLoopCols - 1)
180.                     iY = _FontHeight * (iLoopRows - 1)
181.                     _PrintString (iX, iY), cstr$(iLoopRows)
182.                 Next iLoopRows
183.  
184.                 Locate 1, 10
185.                 Print _Trim$(Str$(iRows)) + " rows expected at resolution " + cstr$(iScreenWidth) + "x" + cstr$(iScreenHeight)
186.                 Locate 2, 10
187.                 Input "Press <ENTER> to continue"; in$
188.  
189.                 ' -----------------------------------------------------------------------------
190.                 ' TEST TO SEE IF THE # OF COLUMNS WE EXPECT REALLY DO FIT ON THE SCREEN
191.             ElseIf in$ = "c" Then
192.                 Screen _NewImage(iScreenWidth, iScreenHeight, 32): _ScreenMove 0, 0
193.                 Cls
194.                 Print _Trim$(Str$(iCols)) + " columns expected at resolution " + cstr$(iScreenWidth) + "x" + cstr$(iScreenHeight)
195.                 Print
196.  
197.                 ' print hundreds
198.                 iCount = 0
199.                 For iLoopCols = 1 To iCols
200.                     iCount = iCount + 1
201.                     If iLoopCols < iCols Then
202.                         Print Left$(Right$("   " + cstr$(iCount), 3), 1);
203.                     Else
204.                         Print Left$(Right$("   " + cstr$(iCount), 3), 1)
205.                     End If
206.                 Next iLoopCols
207.  
208.                 ' print tens
209.                 iCount = 0
210.                 For iLoopCols = 1 To iCols
211.                     iCount = iCount + 1
212.                     If iLoopCols < iCols Then
213.                         Print Mid$(Right$("   " + cstr$(iCount), 3), 2, 1);
214.                     Else
215.                         Print Mid$(Right$("   " + cstr$(iCount), 3), 2, 1)
216.                     End If
217.                 Next iLoopCols
218.  
219.                 ' print ones
220.                 iCount = 0
221.                 For iLoopCols = 1 To iCols
222.                     iCount = iCount + 1
223.                     If iLoopCols < iCols Then
224.                         Print Right$(cstr$(iCount), 1);
225.                     Else
226.                         Print Right$(cstr$(iCount), 1)
227.                     End If
228.                 Next iLoopCols
229.  
230.                 Print
231.                 Input "Press <ENTER> to continue"; in$
232.  
233.                 ' -----------------------------------------------------------------------------
234.                 ' EXIT + MOVE ON TO THE NEXT RESOLUTION
235.             Else
236.                 Exit Do
237.             End If
238.  
239.             If Len(m_sError) > 0 Then
240.                 m_sError = ""
241.                 m_sCode = ""
242.                 Exit Do
243.             End If
244.         Loop
245.     Else
246.         ' ASK THE USER IF THEY WANT TO MOVE ON TO THE NEXT RESOLUTION OR QUIT
247.         Input "Q to quit, or <ENTER> to continue to next resolution"; in$
248.         in$ = Left$(LCase$(_Trim$(in$)), 1)
249.     End If
250.  
251.     If in$ = "q" Then
252.         sResult = "q"
253.     End If
254.  
255.     CleanupAndExit:
256.     Screen 0
257.     GetNextTextWidthHeight$ = sResult
258.  
259. End Function ' GetNextTextWidthHeight$
260.  
261. ' /////////////////////////////////////////////////////////////////////////////
262.  
263. Function GetTextWidthHeight$ (bFullScreen As Integer)
264.     Dim sResult As String: sResult = ""
265.  
266.     If bFullScreen = TRUE Then
267.         _FullScreen _SquarePixels
268.     End If
269.  
270.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(640, 480, "VGA (4:3)")
271.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(720, 480, "480p (4:3, 16:9)")
272.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(800, 600, "SVGA (4:3)")
273.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1024, 768, "XGA (4:3)")
274.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1280, 1024, "SXGA (5:4)")
275.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(1920, 1080, "FHD (16:9)")
276.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(2048, 1152, "QWXGA (16:9)")
277.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(3840, 2160, "4K UHD (16:9)")
278.     If sResult <> "q" Then sResult = GetNextTextWidthHeight$(7680, 4320, "8K UHD (16:9)")
279.  
280.     If bFullScreen = TRUE Then
281.         _FullScreen _Off
282.     End If
283.  
284.     GetTextWidthHeight$ = ""
285. End Function ' GetTextWidthHeight$
286.  
287.  
288. ' /////////////////////////////////////////////////////////////////////////////
289. ' Convert a value to string and trim it (because normal Str$ adds spaces)
290.  
291. Function cstr$ (myValue)
292.     'cstr$ = LTRIM$(RTRIM$(STR$(myValue)))
293.     cstr$ = _Trim$(Str$(myValue))
294. End Function ' cstr$
295.  
296. ' /////////////////////////////////////////////////////////////////////////////
297.  
298. Sub DebugPrint (s$)
299.     If m_bTesting = TRUE Then
300.         _Echo s$
301.     End If
302. End Sub ' DebugPrint
303.  
304.  

[bplus]

OK remember in graphics screen rows and cols start at 0 (not 1 as used for Locate).

So if there are 480 cols they go from col# 0 to col 479# in text cells

likewise if there are 135 rows they will start at row#0 and go to row# 135-1=134

and with _PrintString you will have to mult col# by 8 and row# by 16 for default font.

[madscijr]

OK remember in graphics screen rows and cols start at 0 (not 1 as used for Locate).

So if there are 480 cols they go from col# 0 to col 479# in text cells

likewise if there are 135 rows they will start at row#0 and go to row# 135-1=134

and with _PrintString you will have to mult col# by 8 and row# by 16 for default font.

I have the rows / cols starting at 0 with _PrintString, it's just strange how the last couple rows/columsns get truncated at the higher resolutions... No 8k display here yet, so I can't test that one, lol

[SMcNeill]

I have the rows / cols starting at 0 with _PrintString, it's just strange how the last couple rows/columsns get truncated at the higher resolutions... No 8k display here yet, so I can't test that one, lol

They get truncated due to your screen resolution and font size.

For example, let's create a screen 1280 pixels wide.   Now, let's load a font that is 12 pixels wide.

1280 / 12 = 106 columns of characters.

Of that 106, we have a can print a full set of text starting at pixel 0, and going to pixel 1260.  This is column 0 to column 105 -- which is our 106 columns of full character displaying.

Now, printing on column 105 puts a character from pixel 1260 to 1271.  Our screen is 1280 pixels wide...  We have 8 pixels to the right of the screen that we can't print a full character on.

IF, however, we want to print at column 106 -- which is beyond the bounds of our calculations. (remember, 0 TO 105 is 106 characters, so when we calculate WIDE / _FONTWIDTH, we start our column count with BASE 0 and not BASE 1.) 

106 * 12 = 1272, which is where we start to print a 12 pixel wide character onto the screen, but have to stop due to the screen being only 1280 pixels total.  We only put 8 pixels to the screen (we stop at 1279, instead of 1280 once again, thanks to BASE 0 and not BASE 1 counting.  0 to 1279 *IS* a 1280-pixel wide screen), so the most you can toss is 2/3 of a character onto the screen.

If you don't want that 2/3 of a character cut-off, then leave those last 8 pixels blank as a border for your text and ONLY print from column 0 to column 105 -- which is the 106 columns you calculated with WIDTH \ FONTWIDTH.

The cutoff you keep talking about is coming from printing from 0 to width\fontwidth, instead of from 0 to width\fontwidth -1 to offset for BASE 0 calculations.

[SMcNeill]

So with that in place (updated code below), I am still seeing the last couple of rows/columns truncated for these resolutions

• at 2048x1152 we expect 256 columns, 72 rows. No errors, but only 70 rows and 255 columns fit on the screen (row 71 and column 256 are mostly cut off).
• at 3840x2160 we expect 480 columns, 135 rows. No errors, but only 133 rows and 479 columns fit on the screen (row 134 and column 134 are mostly cut off).

Here's a little program to show that the screen is indeed those dimensions:

Code: QB64: [Select]

1. 'at 2048x1152 we expect 256 columns, 72 rows. No errors, but only 70 rows and 255 columns fit on the screen
2. '    (row 71 and column 256 are mostly cut off).
3. $Resize:Smooth
4.  
5.  
6. Screen _NewImage(2048, 1152, 256)
7.  
8. For column = 1 To 256
9.     Color column Mod 100 + 1
10.     Locate 1, column: Print _Trim$(Str$(column \ 100));
11.     Locate 2, column:: Print _Trim$(Str$(column \ 10 Mod 10));
12.     Locate 3, column:: Print _Trim$(Str$(column Mod 10));
13. Next
14.  
15. Sleep
16. Cls
17. For row = 1 To 72
18.     Locate row, 1: Print "ROW:"; row;
19. Next
20. Sleep

As you can tell, there's no cut off with either row or column, as long as we print to starting from LOCATE position 1,1 to 72,256.

Now, if we if we going to use _PRINTSTING instead, we'd print from position(row-1, column-1) to ((72-1) * _Fontheight, (256-1) * _fontwidth), to print from 0 * fontheight,0 * fontwidth to 71 * fontheight,255 * fontwidth.

Printstring starts at 0,0.  Locate starts at 1,1.  You have to account for the difference in your starting position when swapping from locate to printstring.

[madscijr]

OK remember in graphics screen rows and cols start at 0 (not 1 as used for Locate).

As you can tell, there's no cut off with either row or column, as long as we print to starting from LOCATE position 1,1 to 72,256.

I just wanted to post a followup to let you know I figured out the issue I was having, in case anyone runs into this in the future.
There were two things causing what I was seeing

• Running in windowed mode for the highest resolution for my monitor, the rows were appearing cut off because (duh) the title bar of the window was taking the top n pixels. Running _FullScreen _SquarePixels solved the problem with the rows appearing cut off
• My display is a 4k TV with bezels around the edges which, from my viewing angle, hide the rightmost 1/4 inch of the screen. I leaned over a little and realized what I thought was being cut off was really just hidden behind the bezel. Doh!

So anyway, thank you guys for patiently explaining how the screen dimensions work and all.
I did learn from it, how to calculate the number of text rows+columns, and about _PrintString, which comes in useful!
Thanks again!

PS In case it helps anyone, the following function saves having to do the calculation and makes for cleaner looking code:

Code: QB64: [Select]

1. Sub PrintString (iRow As Integer, iCol As Integer, MyString As String)
2.     Dim iX As Integer
3.     Dim iY As Integer
4.     iX = _FontWidth * iCol
5.     iY = _FontHeight * iRow
6.     _PrintString (iX, iY), MyString
7. End Sub ' PrintString
8.  

[SMcNeill]

   iX = _FontWidth * iCol
   iY = _FontHeight * iRow


*As long as you remember to start your column and row counting at 0.  Otherwise, add a -1 in there to duplicate LOCATE coordinates fully.  ;)

[madscijr]

   iX = _FontWidth * iCol
   iY = _FontHeight * iRow
*As long as you remember to start your column and row counting at 0.  Otherwise, add a -1 in there to duplicate LOCATE coordinates fully.  ;)

Right on