How to remove title Bar from graphics screen?

[mpgcan]

I had a delay problem similar to this, one of you guys provided a neat solution which seems to work on this. At the top of your script add the following line :

Code: QB64: [Select]

1. Do: Loop Until _ScreenExists 'before using _WindowHandle or _title

Worked on this:

Code: QB64: [Select]

1. Do: Loop Until _ScreenExists 'before using _WindowHandle or _title
2.  
3. Const HWND_TOPMOST%& = -1
4. Const SWP_NOSIZE%& = &H1
5. Const SWP_NOMOVE%& = &H2
6. Const SWP_SHOWWINDOW%& = &H40
7.  
8. Declare Dynamic Library "User32"
9.     Function GetWindowLongA& (ByVal hwnd As Long, Byval nIndex As Long)
10.     Function SetWindowPos& (ByVal hWnd As Long, Byval hWndInsertAfter As _Offset, Byval X As Integer, Byval Y As Integer, Byval cx As Integer, Byval cy As Integer, Byval uFlags As _Offset)
11.     Function SetWindowLongA& (ByVal hwnd As Long, Byval nIndex As Long, Byval dwNewLong As Long)
12.     Function GetForegroundWindow&
13.     Function SetLayeredWindowAttributes& (ByVal hwnd As Long, Byval crKey As Long, Byval bAlpha As _Unsigned _Byte, Byval dwFlags As Long)
14. End Declare
15. Screen _NewImage(600, 480, 32)
16. GWL_STYLE = -16
17. ws_border = &H800000
18. WS_VISIBLE = &H10000000
19. _Title "Borderless Window"
20. Dim hwnd As Long
21. hwnd = _WindowHandle
22. _Delay .1
23. Level = 175
24. SetWindowOpacity hwnd, Level
25.  
26. winstyle2& = GetWindowLongA&(hwnd, GWL_STYLE)
27. winstyle& = -12582913
28. a& = SetWindowLongA&(hwnd, GWL_STYLE, winstyle& And WS_VISIBLE) ' AND NOT WS_VSCROLL) ' AND NOT ws_border)
29. a& = SetWindowPos&(hwnd, 0, 0, 0, 0, 0, 39)
30. msg$ = "Welcome to Translucent Windows Without Borders!"
31. i = 16
32. Color &HFFFFFFFF, &H0 ' white foreground, transparent background
33. Do
34.     _Limit 60
35.     FGwin& = GetForegroundWindow&
36.     If hwnd <> FGwin& Then ' QB64 no longer in focus.
37.         While _MouseInput: Wend
38.         a& = SetWindowPos&(hwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE + SWP_NOSIZE + SWP_SHOWWINDOW)
39.         Do: _Limit 30: Loop Until hwnd = GetForegroundWindow&
40.     End If
41.     If InKey$ = Chr$(27) Then Exit Do
42.     For y = 480 To 0 Step -1
43.         For x = 640 To 0 Step -1
44.             PSet (x, 480 - y), _RGB(y / 2 Mod 256, 100, 200) ' (x MOD 512 XOR y) MOD 256, y MOD 256)
45.         Next
46.     Next
47.     _PrintString (92, 1), msg$
48.     _PrintString (1, 464), "Press Esc to quit."
49.     _PrintString (250, i), "Hi Chez-Pete!"
50.     _Display
51.     i = i + 1
52.     If i > 464 Then i = 16
53. Loop
54. System
55.  
56. Sub SetWindowOpacity (hwnd As Long, Level)
57.     Dim Msg As Long
58.     Const G = -20
59.     Const LWA_ALPHA = &H2
60.     Const WS_EX_LAYERED = &H80000
61.     Msg = GetWindowLongA&(hwnd, G)
62.     Msg = Msg Or WS_EX_LAYERED
63.     action = SetWindowLongA&(hwnd, G, Msg)
64.     action = SetLayeredWindowAttributes(hwnd, 0, Level, LWA_ALPHA)
65. End Sub
66.  

All the best.

[Pete]

That solution created a memory problem. In other words, I forgot that keyword existed! Oh well, by tomorrow I'll forget how $^$%# I got about forgetting about _SCREENEXISTS, so I've got that going for me.

Well thanks for that, and for the further discussion of race conditions by Steve. Now here's a couple more things for discussion...

1) Don't you guys think _SCREEEXISTS should just be an inherent part of all SCREEN commands? In otherwords the code doesn't precede until the SCREEN is rendered?

2) In my code that @mpgcan modified, I would have put _SCREENEXISTS after the screen call:

SCREEN _NEWIMAGE(600, 480, 32)

but he put it at the beginning of the program, and it still worked. To me, that indicates the race problem is not with making the graphics screen, but with making the start up, SCREEN 0 screen. @SMcNeill  Does that assumption seem correct?

Pete

[SMcNeill]

@Pete The problem, I found in the past, with ScreenExists is it's an internal one-time flag.  (Unless it's been modified to be different over time.)

This means ScreenExists starts as a 0 (False) value.  Then, once that initial SCREEN 0 screen is created, it gets a value of -1 (True).  From that point on, it stays true as you will always have a visible screen for your program.

The issue can arise as in the code above (or as simplified below):

DO: LOOP UNTIL _SCREENEXISTS 'This will pause your program until that initial SCREEN 0 is generated and registered properly.
SCREEN _NEWIMAGE(640, 480, 32)
PRINT _WINDOWHANDLE

That Print statement above may, or may not, work as intended.  You might get the handle for the initial SCREEN 0.  You might get the handle 0 where it was freed, but the new screen isn't registered back to us yet.  You might get what you expect.

The screen does indeed exist at this point, but we're swapping screens and as such Windows may not be reporting what the updated handle is back to us just yet.

As I mentioned above, I'd play it safe and *always* toss a _DELAY .2 in there after initializing that screen for the first time, just to be safe. 

The reason why you don't want an automatic delay in all SCREEN commands would be for something a little unusual like this:

ScreenOne = _NEWIMAGE(640, 480, 32)
ScreenTwo = _NEWIMAGE(640, 480, 32)

Do
    i= i + 1 MOD 2
    IF i THEN SCREEN ScreenOne ELSE ScreenTwo

We create the screens above, then flip between them alternating like we used to do with multiple pages in the old days...  You certainly  don't want to add in a .2 second delay in those instances, now do you?

Sometimes, it's best to leave some things up to the programmer to sort out themselves.  ;D

[bplus]

I remember Dav's Pipe program for which this:

Code: QB64: [Select]

1. DO: LOOP UNTIL _SCREENEXISTS

did not work but a simple _Delay .25 did for _Screenmove _Middle

[Pete]

@bplus Yes, I've had to use a small delay before using _SCREENMOVE as well. From our discussion so far, it appears likely  the delay is needed for the screen to be rendered, before it can be moved. In Dav's "Pipes" game, I did not experience the failure to move the screen, as you did. In other words I ran the code both with and without that .25 delay, and it centered the screen both times. My question would be if you moved his Do: Loop Until _ScreenExists statement to the top of the program and removed your delay, would it work?

@SMcNeill I agree a method that provides the freedom to choose outweighs a one size that doesn't always fit all method. I'm also in favor of improvements, and if it is possible to make a _SCREENEXISTS statement identify with each screen statement and reset itself to zero when the screen is rendered, that would be an improvement. That would require dynamic arrays and using preserve in QB64. I'm not familiar with a different method for C/C++.

These situations make me more appreciative of code that runs as expected. With this, and statements like SCREENPRINT and SCREENCLICK, the benchmark seems to be a .2 delay. The question is will .2 always be enough? As I mentioned, I could run Dav's program without the delay Mark needed. So if a faster, slower, or different systems with some different run-time priorities are involved, what good is a delay that falls a millisecond short? Again, the only ironclad system is a feedback one. That's a tall order, I know, as more than just screen rendering would need to be included.

Pete

[bplus]

My question would be if you moved his Do: Loop Until _ScreenExists statement to the top of the program and removed your delay, would it work?

No, it didn't. @Pete

[Dav]

Hmm, now I see what the original poster is referring to, still seeing the title bar.  There seems to be a difference between QB64 versions and removing the title bar.  When I run Pete's code, using a very long delay, in v1.5 and lower I get this on my Win7 laptop - no title bar and no borders at all.

  [ You are not allowed to view this attachment ]  

But when I run it in QB64 v2 I get this, a black title bar and border, no matter how long a delay I add.

  [ You are not allowed to view this attachment ]  

That's just for Petes code.  I can remove the title bar and border using other API code, like this one here which does work as expected in QB64 v2..

- Dav

Code: QB64: [Select]

1. '================
2. 'WindowRegion.bas v1.1
3. '================
4. 'Uses Windows API to create a non-standard looking window.
5. 'Using this you could use an image as the entire window instead.
6. 'Coded by Dav, JULY/2020
7.  
8. 'I used API information found on this page....
9. 'http://allapi.mentalis.org/apilist/apilist.php
10.  
11.  
12. TYPE POINTAPI
13.     x AS LONG
14.     y AS LONG
15. END TYPE
16. DIM apixy AS POINTAPI 'mouse x/y for the GetCursorPos function
17.  
18. DECLARE DYNAMIC LIBRARY "user32"
19.     'sets a created window region
20.     'http://allapi.mentalis.org/apilist/SetWindowRgn.shtml
21.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
22.     'get current mouse x/y position
23.     'http://allapi.mentalis.org/apilist/GetCursorPos.shtml
24.     FUNCTION GetCursorPos% (lpPoint AS POINTAPI)
25. END DECLARE
26.  
27.  
28. DECLARE DYNAMIC LIBRARY "gdi32"
29.     'creates a rectangular region
30.     'http://allapi.mentalis.org/apilist/CreateRectRgn.shtml
31.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
32.     'creates an elliptical region
33.     'http://allapi.mentalis.org/apilist/CreateEllipticRgn.shtml
34.     FUNCTION CreateEllipticRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
35.     'creates a rectangular region with rounded corners
36.     'http://allapi.mentalis.org/apilist/CreateRoundRectRgn.shtml
37.     FUNCTION CreateRoundRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&, BYVAL x3&, BYVAL y3&)
38. END DECLARE
39.  
40. controls& = BASIMAGE1& 'Make Minimize & Exit controls image
41. _ICON controls& 'might as well make it the program icon too...
42.  
43. hwnd& = _WINDOWHANDLE 'need the windows handle to play with it
44.  
45. 'Create a rounded rectangular region...
46. rgn& = CreateRoundRectRgn(30, 30, 650, 650, 240, 240)
47.  
48. 'you can try these also...
49. 'rgn& = CreateEllipticRgn(30, 30, 650, 650)
50. 'rgn& = CreateRectRgn(30, 30, 650, 650)
51.  
52. 'Set the created region...
53. try& = SetWindowRgn(hwnd&, rgn&, 0)
54. 'Returns zero if failed...
55. IF try& = 0 THEN
56.     PRINT "Failed...": END
57. END IF
58.  
59. 'Setup screen....
60. SCREEN _NEWIMAGE(680, 680, 32)
61. FOR y = 1 TO 680
62.     LINE (0, y)-(680, y), _RGB(c, c, 64), BF
63.     c = c + 1: IF c > 32 THEN c = 0
64. NEXT
65.  
66. 'Draw a top highlighted bar
67. LINE (0, 0)-(680, 80), _RGB(64, 64, 196), BF
68. 'draw minimize and exit image
69. _PUTIMAGE (500, 30), controls&
70.  
71. DO
72.  
73.     p = _MOUSEINPUT
74.     mx = _MOUSEX: my = _MOUSEY
75.  
76.     'LOCATE 12, 12: PRINT mx, my; _MOUSEBUTTON(1); 'testing info
77.  
78.     IF _MOUSEBUTTON(1) AND mx < 500 AND mx > 0 AND my < 80 AND mx > 0 THEN
79.  
80.         'get orig mouse x/y using api
81.         tmp = GetCursorPos(apixy)
82.         origx = apixy.x: origy = apixy.y
83.  
84.         DO
85.             p = _MOUSEINPUT: IF _MOUSEBUTTON(1) = 0 THEN EXIT DO
86.  
87.             'poll mouse x/y
88.             tmp = GetCursorPos(apixy)
89.             mx = apixy.x: my = apixy.y
90.  
91.             _SCREENMOVE _SCREENX - (origx - mx), _SCREENY + (my - origy)
92.  
93.             origx = mx: origy = my
94.  
95.         LOOP
96.  
97.  
98.     END IF
99.  
100.     'see if user clicked minimized area
101.     IF _MOUSEBUTTON(1) AND mx > 500 AND mx < 540 AND my > 29 AND my < 66 THEN
102.         'wait until button up to continue
103.         DO: p = _MOUSEINPUT
104.             IF _MOUSEBUTTON(1) = 0 THEN EXIT DO
105.         LOOP
106.         'minimize program
107.         _SCREENICON
108.     END IF
109.  
110.     'see if user clicked exit area
111.     IF _MOUSEBUTTON(1) AND mx > 540 AND mx < 580 AND my > 29 AND my < 66 THEN
112.         IF _MOUSEBUTTON(1) = -1 THEN
113.             SYSTEM
114.         END IF
115.     END IF
116.  
117. LOOP UNTIL INKEY$ = CHR$(27)
118. SYSTEM
119.  
120.  
121. 'This function creates the control image.
122. 'It was made with my BASIMAGE.BAS program .
123. FUNCTION BASIMAGE1& 'controls.png
124.     v& = _NEWIMAGE(80, 40, 32)
125.     DIM m AS _MEM: m = _MEMIMAGE(v&)
126.     A$ = ""
127.     A$ = A$ + "haIkH_oCCM5007_l#P28JF6a`HbL3iIKY?hEO#aOHKJ04W^9ciLDX::aXbn1"
128.     A$ = A$ + "U]iFfD7?4#4T7jLZK4#A5:<L;Z0^T]Q#L6aU\HbRVmO04PO081n]c>WcUc]g"
129.     A$ = A$ + "KkmNJ[m2SOhfT?inXWk]GnN_]gFZ\b:1E:c_=a4C\ZbZaS9Q>6UkWde_7jhF"
130.     A$ = A$ + ";K6]_KcJ\nkQW7=P3<Jm[S^nC#Gmn_[J8g?Y_OS?hmHmdQ^_X6Oh11oUGjY?"
131.     A$ = A$ + "H8_6]nM^cokP6Jk5B\WcZ^Fn7<W[k5PVJML#c]lTUlH\jKL4<Qjg8>jU1lJT"
132.     A$ = A$ + "7fW3`HoDo2Jd1hk9go^^Qki2JhNNQFoZj\o6XV6O^?[ZU9bmCjkg#Mn3l<LG"
133.     A$ = A$ + "o8[1i0]l#G_3NN#gM2ne^_QXnSNkaYnjU5nlEo>`W_Xe__lD33nZ_mI2:_]F"
134.     A$ = A$ + "6VVg<FgPFo9[jI<>mOc>?]aCfVR?d8RB^OBOoLdJCHmeFcH3LYFMjb]cj>Oo"
135.     A$ = A$ + "5an5>^37olE^T7=P0Xe_SDAoPSNRa54i_MQNPFoF\F<6J\TiY=N4J]C\nMmj"
136.     A$ = A$ + "ZQA3e2^Ame2^McWSE?GXAFT>c5Yi8>Jo2\j71fOG9di3Jm[db^9hPOjS5T5C"
137.     A$ = A$ + "k5cC=Q<6JSS\_Tkg:Oo^fIn6\>Zn<HMMfZahfET^K\>\KeD32B\^;DkkUC_Y"
138.     A$ = A$ + "e?Kf_9h07kADIfh79JK8mQfcI4^mNZKbmKi_OT6BjWKM4Rd#aJY_d#YZOLK8"
139.     A$ = A$ + "]FiJg#<UUgg>ajGKOfaIenWO2`E?mGcS[GOBdI]EaX^Za`m^nJhQL];g[O9M"
140.     A$ = A$ + "WdI?e_R?lX2ZTb7SW\Q]01eU5GLAAQ_V;cmPi;]C^O;?mcVY\LbRA#9iH2cF"
141.     A$ = A$ + ">VaC;eZI6iV3`N^F0fgREFUo^_=?79_]QMhlg6XR]W??7]`l17K75h6Jm;^="
142.     A$ = A$ + "o5PgBK7n4=Yad`iWONgPOO;liO3eGSQV[jLNXXC]5ZTkWdg_DEX0C=B0:0J2"
143.     A$ = A$ + ":0FY5LPlXM=1aCJQ4<;MQ52;m:35H8l`0Y7QB<3[=LNB?Z805THlPMZ:IZmC"
144.     A$ = A$ + "QRg3X8ZFm9a]Yg7gYiVK>gPFOLKJG`aeRh2Z1A9DoD_DkD1UbBCE]D;E50cD"
145.     A$ = A$ + "Nc783JmEcBhfG^=6eGmAbdEjm[#PR`Jf[4C\5RQJd\c>[X#?ojOUg1SF[Tkg"
146.     A$ = A$ + ":Co8_oUd=bba7IX2noZ`OT`jS4c0\QXgOSJXDd?Bg#VIVIl8bHme6:g?Y_OZ"
147.     A$ = A$ + "hd>ETkS0i]OGNOi1ihf0WkahakOXllDAJgdC?]PldcQfNNkCoXOYjBoFHQ5T"
148.     A$ = A$ + "DTnY3nIQYkEmKWRNOBdmAA#k_YVJ:g#N]8SQfh8k;5AdTLoFQk7K_LU7^?f;"
149.     A$ = A$ + "3bO7I0kFFA6>8ce6Q7jg^015Mc2R\_VLb9M3ncJCX8<dHS?aR`X=NT0OEin]"
150.     A$ = A$ + "Bg?]`FaU^PHT#D:UlkoJ=ihafj6S1\KE91n#=Y#]O[K3E0D^aV4DBYl1H2mj"
151.     A$ = A$ + "PF?kHS]AWKCbkFha3G?BX`aj[m;k`F3F61706IIS:3Q_823c4lkLPH6nMOck"
152.     A$ = A$ + "eSQWRP=1I?`^`e7[C=HOje`cWT^F#aIXSJoN]=OL#\jn>ob6Dg6?AcMN?lkM"
153.     A$ = A$ + "mVOo[Lol_nI?3mHFP=97XmVJB<DW2HO#fdZ6[HMJhaVnd0UH#;;K`FDBVja8"
154.     A$ = A$ + "kcBcb0?fc>MFU2]OCIB]OYJhTPD\NIOFRFJGdeWXi;b:NS]`KI?A^OBOo>XU"
155.     A$ = A$ + "\UL70f5GGGIXYiH4k#8F=1:?GcDkGfF?5HkkoNnU2]OGNcSD`;9QjgZ9[6?V"
156.     A$ = A$ + "4jHD^OBCoT9ko3o7Ml:S%%%0"
157.     btemp$ = ""
158.     FOR i& = 1 TO LEN(A$) STEP 4: B$ = MID$(A$, i&, 4)
159.         IF INSTR(1, B$, "%") THEN
160.             FOR C% = 1 TO LEN(B$): F$ = MID$(B$, C%, 1)
161.                 IF F$ <> "%" THEN C$ = C$ + F$
162.             NEXT: B$ = C$: END IF: FOR j = 1 TO LEN(B$)
163.             IF MID$(B$, j, 1) = "#" THEN
164.         MID$(B$, j) = "@": END IF: NEXT
165.         FOR t% = LEN(B$) TO 1 STEP -1
166.             B& = B& * 64 + ASC(MID$(B$, t%)) - 48
167.             NEXT: X$ = "": FOR t% = 1 TO LEN(B$) - 1
168.             X$ = X$ + CHR$(B& AND 255): B& = B& \ 256
169.     NEXT: btemp$ = btemp$ + X$: NEXT
170.     btemp$ = _INFLATE$(btemp$)
171.     _MEMPUT m, m.OFFSET, btemp$: _MEMFREE m
172.     BASIMAGE1& = _COPYIMAGE(v&): _FREEIMAGE v&
173. END FUNCTION
174.  
175.  

[Richard]

@Dav

Using your code from reply just above - I tried to have a window 640 x 320 without Title Bar or borders/sliders but it did not work for me.

I essentially removed any code referring to MOUSE or CONTROL Buttons to have a plain 640 x 320 graphics box with a diagonal line between screen corners.

Code: QB64: [Select]

1. 'WindowRegion.bas v1.1      ' ### MODIFIED program written by Dav
2.  
3. DECLARE DYNAMIC LIBRARY "user32"
4.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
5. END DECLARE
6. DECLARE DYNAMIC LIBRARY "gdi32"
7.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
8. END DECLARE
9. hwnd& = _WINDOWHANDLE 'need the windows handle to play with it
10. rgn& = CreateRectRgn( 0, 0, 640, 320)'Create a rectangular region...
11. try& = SetWindowRgn(hwnd&, rgn&, 0)  'Set the created region...
12. IF try& = 0 THEN PRINT "Failed...": system 'Returns zero if failed...
13.  
14. SCREEN _NEWIMAGE(640, 320, 32)  'Setup screen.... 640x320 BLACK background
15. line(0,0)-(639,319),&Hff00ff00~&& 'TESTING display GREEN LINE (0,0)-(bottom RH corner)
16.  
17. _delay 30:system    ' ### TERMINATE program after 30 seconds
18.  

  [ You are not allowed to view this attachment ]  




Using Windows 10 x64 Pro Build 21H1 (oct updated)  with  QB64 v2.1 dev c48bf67

[Pete]

@Dav

Using your code from reply just above - I tried to have a window 640 x 320 without Title Bar or borders/sliders but it did not work for me.

I essentially removed any code referring to MOUSE or CONTROL Buttons to have a plain 640 x 320 graphics box with a diagonal line between screen corners.

Okay, it didn't remove the title bar for me, either. Also, I had to add the delay indicated in the code below, between the two declare library statements, or the handle for SetWindowRgn would fail to register.

Code: QB64: [Select]

1. 'WindowRegion.bas v1.1      ' ### MODIFIED program written by Dav
2.  
3. DECLARE DYNAMIC LIBRARY "user32"
4.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
5. END DECLARE
6. _DELAY .2 ' <---------------On my system, this delay is needed or it will fail.
7. DECLARE DYNAMIC LIBRARY "gdi32"
8.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
9. END DECLARE
10. hwnd& = _WINDOWHANDLE 'need the windows handle to play with it
11. rgn& = CreateRectRgn(0, 0, 640, 320) 'Create a rectangular region...
12. try& = SetWindowRgn(hwnd&, rgn&, 0) 'Set the created region...
13. IF try& = 0 THEN PRINT "Failed...": SLEEP: SYSTEM 'Returns zero if failed...
14.  
15. SCREEN _NEWIMAGE(640, 320, 32) 'Setup screen.... 640x320 BLACK background
16. LINE (0, 0)-(639, 319), &HFF00FF00~&& 'TESTING display GREEN LINE (0,0)-(bottom RH corner)
17.  
18. _DELAY 30: SYSTEM ' ### TERMINATE program after 30 seconds
19.  

Pete

[Dav]

@Richard. That's because of the CreateRectRgn(0, 0, 640, 320) settings.  In your code the x1 and y1 is set to 0 which puts it inside the title bar area, so the title bar is drawn now. I really don't know well how it works, but I noticed I had to increase those numbers to keep title bar from popping back up, which is why in my code I had it set higher.  If you change your code to CreateRectRgn(10, 30, 640, 320) it should stay gone, but of course this puts x/y out of wack when drawing stuff because part of the screen is hidden.  I need to learn more about using these API's.  Maybe @SpriggsySpriggs can shed more light on this for us.   @Pete, the _DELAY was needed in it again because the _ICON call was removed.  With _ICON in play the _DELAY doesn't seem to be needed. 

- Dav

[SMcNeill]

Part of the issue may be command depreciation.  Windows documentation now tells us that GetWindowLong and SetWindowLong has now been depreciated, and GetWindowLongPtr and SetWindowLongPtr should now be used instead.  (Particularly on 64-bit systems.)

You guys might try swapping to those calls and see what it changes.  (You might need to check to make certain SetWindowPos hasn't changed as well.  I'm not at home atm, so didn't bother to keep digging since I can't actually test anything at the moment anyway.)


May also want to try the SetWindowPos with the last value being 38 rather than 39.

SWP_DRAWFRAME -- 0x0020 -- Draws a frame (defined in the window's class description) around the window.
SWP_NOMOVE -- 0x0002 -- Retains the current position (ignores the x and y members).
SWP_NOSIZE -- 0x0001 -- Retains the current size (ignores the cx and cy members).
SWP_NOZORDER  -- 0x0004 -- Retains the current Z order (ignores the hwndInsertAfter member).

That 39 is basically made up of all the flags above, but it seems to me that the NOSIZE right be an issue if windows counts the title bar height as being inclusive to the overall window size.  It wouldn't hurt to test it once without it.  :P

[Pete]

@Dav I'll speculate it's the process of getting the icon, the time it takes, provides the necessary delay for the race condition to catch up, but how would I know, as I graduated top of my class of zero. You ask, "how can you have a class of zero?" Simple, I was the only one in the class, and I never showed up.

Your "trick" of hiding the title bar reminded me of my trick of making the screen size the desktop size plus the height of the title bar and using _SCREENMOVE with a negative second parameter to move the screen up just far enough to hide the title bar.

Pete

[mpgcan]

I have looked at removing borders and I offer my solution on this problem the following works on Windows 8.1

Code: QB64: [Select]

1. Option _Explicit
2. Do: Loop Until _ScreenExists 'run before using _WindowHandle or _title
3. '####################################################
4. '# Name:     no_border_no_caption.bas
5. '# Author:   MPG
6. '# Purpose:  Remove border and caption. Remaing area
7. '#           is all client.
8. '#           Items commented out may be required.
9. '#           Do: Loop Until _ScreenExists required
10. '#           on Windows 8.1
11. '# Revision: November 1 2021 - initial version
12. '####################################################
13.  
14. Declare CustomType Library
15.     Function FindWindow& (ByVal ClassName As _Offset, WindowName$)
16. End Declare
17.  
18. Declare Dynamic Library "User32"
19.     Function GetWindowLongA& (ByVal hWnd As _Offset, Byval nIndex As Long)
20.     Function SetWindowLongA& (ByVal hWnd As _Offset, Byval nIndex As Long, Byval dwNewLong As Long)
21.     Function SetWindowPos& (ByVal hWnd As _Offset, Byval hWndInsertAfter As Long, Byval x As Long, Byval y As Long, Byval cx As Long, Byval cy As Long, Byval wFlags As Long)
22.     '    Function ShowScrollBar& (ByVal hWnd As _Offset, Byval wBar As Long, Byval bShow As Long)
23. End Declare
24.  
25. Const GWL_STYLE = -16
26. Const WS_BORDER = &H800000
27. Const WS_CAPTION = &H00C00000
28. Const WS_THICKFRAME = &H00040000
29. Const WS_MINIMIZEBOX = &H00020000
30. Const WS_MAXIMIZEBOX = &H00010000
31. Const WS_SYSMENU = &H00080000
32. 'Const SB_BOTH = 3
33.  
34. Dim hwnd As _Offset
35. Dim As Long winstyle, Style, a
36.  
37. hwnd = _WindowHandle
38. winstyle = GetWindowLongA(hwnd, GWL_STYLE)
39. Style = (WS_CAPTION Or WS_THICKFRAME Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX Or WS_SYSMENU)
40. a = SetWindowLongA&(hwnd, GWL_STYLE, winstyle And Not Style)
41. 'a = ShowScrollBar(hwnd, SB_BOTH, false)
42.  
43.  
44. Screen _NewImage(640, 320, 32)
45. 'Cls
46. Line (0, 0)-(639, 319), &HFF00FF00~&&
47. Line (300, 0)-(300, 320), &HFF00FF00~&&
48. Line (0, 150)-(640, 150), &HFF00FF00~&&
49.  
50. Line (639, 0)-(639, 100), &HFF00FF00~&&
51. Line (0, 0)-(0, 100), &HFF00FF00~&&
52.  
53. Line (400, 0)-(500, 0), &HFF00FF00~&&
54. Line (400, 319)-(500, 319), &HFF00FF00~&&
55.  
56.  
57. _PrintString (100, 100), "Press any key to end...": Sleep
58. Print "The end Note:Location"
59.  

With the do-loop enabled. Shows borders and caption removed .
  [ You are not allowed to view this attachment ]  

All the best.

[Richard]

@mpgcan 

Thanks




  [ You are not allowed to view this attachment ]  





Windows 10 x64 Pro  21H1 (OCT updated)   with v2.1 dev build c48bf67






Many thanks again

[SMcNeill]

Good catch with the WS_SYSMENU flag.   To completely remove the window, you need to remove both it and the WS_CAPTION flag from the options.

Code: QB64: [Select]

1. Option _Explicit
2. Do: Loop Until _ScreenExists 'run before using _WindowHandle or _title
3. '####################################################
4. '# Name:     no_border_no_caption.bas
5. '# Author:   MPG
6. '# Purpose:  Remove border and caption. Remaing area
7. '#           is all client.
8. '#           Items commented out may be required.
9. '#           Do: Loop Until _ScreenExists required
10. '#           on Windows 8.1
11. '# Revision: November 1 2021 - initial version
12. '####################################################
13.  
14. Declare CustomType Library
15.     Function FindWindow& (ByVal ClassName As _Offset, WindowName$)
16. End Declare
17.  
18. Declare Dynamic Library "User32"
19.     Function GetWindowLongA& (ByVal hWnd As _Offset, Byval nIndex As Long)
20.     Function SetWindowLongA& (ByVal hWnd As _Offset, Byval nIndex As Long, Byval dwNewLong As Long)
21.     Function SetWindowPos& (ByVal hWnd As _Offset, Byval hWndInsertAfter As Long, Byval x As Long, Byval y As Long, Byval cx As Long, Byval cy As Long, Byval wFlags As Long)
22.     '    Function ShowScrollBar& (ByVal hWnd As _Offset, Byval wBar As Long, Byval bShow As Long)
23. End Declare
24.  
25. Const GWL_STYLE = -16
26. Const WS_BORDER = &H800000
27. Const WS_CAPTION = &H00C00000
28. Const WS_THICKFRAME = &H00040000
29. Const WS_MINIMIZEBOX = &H00020000
30. Const WS_MAXIMIZEBOX = &H00010000
31. Const WS_SYSMENU = &H00080000
32. 'Const SB_BOTH = 3
33.  
34. Dim hwnd As _Offset
35. Dim As Long winstyle, Style, a
36.  
37. hwnd = _WindowHandle
38. winstyle = GetWindowLongA(hwnd, GWL_STYLE)
39. Style = (WS_CAPTION Or WS_SYSMENU)
40. a = SetWindowLongA&(hwnd, GWL_STYLE, winstyle And Not Style)
41. 'a = ShowScrollBar(hwnd, SB_BOTH, false)
42.  
43.  
44. Screen _NewImage(640, 320, 32)
45. 'Cls
46. Line (0, 0)-(639, 319), &HFF00FF00~&&
47. Line (300, 0)-(300, 320), &HFF00FF00~&&
48. Line (0, 150)-(640, 150), &HFF00FF00~&&
49.  
50. Line (639, 0)-(639, 100), &HFF00FF00~&&
51. Line (0, 0)-(0, 100), &HFF00FF00~&&
52.  
53. Line (400, 0)-(500, 0), &HFF00FF00~&&
54. Line (400, 319)-(500, 319), &HFF00FF00~&&
55.  
56.  
57. _PrintString (100, 100), "Press any key to end...": Sleep
58. Print "The end Note:Location"
59.  
60.  

Style = (WS_CAPTION Or WS_SYSMENU)

What the wiki has is the simple WS_CAPTION being removed, but that doesn't also remove the WS_SYSMENU, which is what's reserving that blank space up top for the titlebar that we're no longer making use of.  Getting rid of both fixes the issue for good.  ;)