Do I need to need a directory path for creating a file?

[Donald Foster]

Hello Everyone,

          It's been over 20 years since I created any sequential or random access files and I didn't have to provide directory path. Is there a preferred directory I should use for storing player game information. I'm planning on creating sequential for player info for my solo version of Lucky Numbers. I'm thinking of using a max. of 8 player's names and the level their currently on that way different household members may be sharing a computer, they can save and load their game by their name similar to DOOM where the unused spaces will display EMPTY. Or am I going down the wrong path and is there a better method?

Thanks, Donald   

[bplus]

Yeah sure, keep the data file(s) in same folder as the source and exe, no path needed.

Haven't you used image files or sound files with your games?

[Pete]

You don't need a separate path, but you may want to make a separate game folder, and save your program and scoring files in that directory. However, if you decide you do want a separate directory folder, inside your local game folder, you can either use the full path, like C:\qb64|mygame\scores\ or just the relative path, scores\ in the file access statement. You can also use QB64 keywords like _CWD$ to find the path you are running in, if you want to use a full path call.

Anyway, I use RA files, so I can overwrite scores. You may want to take a look at my ASCII Invaders game, in the Competition Discussion thread. Sequential files are fine, but you generally have to load the whole file into an array, change the arrays based upon game results, and then open the file for OUTPUT and write the arrays back into the file. I suppose if you don't want to use fields or make a fixed length file, as used in RA files, sequential is your best bet.

Pete 

[Donald Foster]

Thanks for the advice. I never made an RA file, but I'll look into it.

thanks, Donald

[bplus]

I did a Top 10 tracker a couple years ago. Just checked it out and fixed for QB64 v2.0
https://www.qb64.org/forum/index.php?topic=1511.msg107586#msg107586

Code's all done for you, if the function returns an empty string then the player wants to play Again. I combined Top Ten tracking with Go Again question. Just call the function with the score.

[Cobalt]

Anyway, I use RA files, so I can overwrite scores. You may want to take a look at my ASCII Invaders game, in the Competition Discussion thread. Sequential files are fine, but you generally have to load the whole file into an array, change the arrays based upon game results, and then open the file for OUTPUT and write the arrays back into the file. I suppose if you don't want to use fields or make a fixed length file, as used in RA files, sequential is your best bet.
Pete

You can do the same thing with Binary files too, just tell it the byte to start on in the GET and PUT statements.

PUT #1, Bytes_in_Record*X, Record

where X is the number of the Record you want to over write.

[Pete]

@Cobalt Love to see a binary example, if you have one.

@Donald Foster  Here is a stripped down no-frills top 5 scoring RA files method I used in my ASCII Invaders game.

It makes a file called: ascii-invaders-high-score.dat

Code: QB64: [Select]

1. DIM SHARED score$
2. _SCREENMOVE 0, 0
3. CLS
4. LINE INPUT "Score: "; score$
5. IF LEN(score$) <> 6 THEN BEEP: RUN
6.  
7. CALL displayhighscores
8.  
9. WHILE LEN(INKEY$): WEND
10. SLEEP 1
11. IF INKEY$ = CHR$(27) THEN SYSTEM
12.  
13. RUN
14.  
15. SUB displayhighscores
16.  
17.     DIM hs AS STRING * 25
18.     REDIM highscore$(6), hsdata$(6)
19.     DO
20.         IF _FILEEXISTS("ascii-invaders-high-score.dat") THEN
21.             OPEN "ascii-invaders-high-score.dat" FOR RANDOM AS #1 LEN = 25
22.             FOR i = 1 TO 5
23.                 GET #1, i, hs
24.                 highscore$(i) = MID$(hs, 10, 6): hsdata$(i) = hs
25.             NEXT
26.             CLOSE #1
27.         ELSE
28.             FOR i = 1 TO 5
29.                 hsdata$(i) = SPACE$(25)
30.             NEXT
31.         END IF
32.  
33.         IF VAL(score$) > VAL(highscore$(5)) THEN
34.  
35.             IF VAL(score$) > VAL(highscore$(1)) THEN
36.                 msg$ = " <<< HIGH SCORE / Enter Your Initials >>> "
37.             ELSE
38.                 msg$ = " <<< Top 5 Score. Enter Your Initials >>> "
39.             END IF
40.  
41.             GOSUB hiscore
42.  
43.             LOCATE 4, 41 - LEN(msg$) \ 2
44.             PRINT msg$;
45.  
46.             bxy% = 6
47.             bxx% = 26
48.             t$ = " " + CHR$(218) + STRING$(27, CHR$(196)) + CHR$(191) + " "
49.  
50.             LOCATE bxy%, bxx% - 1: PRINT t$;
51.  
52.             FOR i = 1 TO 11
53.                 t$ = " " + CHR$(179) + STRING$(27, CHR$(32)) + CHR$(179) + " "
54.                 LOCATE bxy% + i, bxx% - 1: PRINT t$;
55.             NEXT
56.  
57.             t$ = " " + CHR$(192) + STRING$(27, CHR$(196)) + CHR$(217) + " "
58.  
59.             LOCATE bxy% + i, bxx% - 1: PRINT t$
60.  
61.             t$ = "    NAME   SCORE    DATE   "
62.  
63.             LOCATE bxy% + 1, bxx% + 1: PRINT t$
64.  
65.             FOR i = 1 TO 5
66.                 t$ = hsdata$(i)
67.                 LOCATE bxy% + 1 + i * 2, bxx% + 2: PRINT t$
68.             NEXT
69.  
70.             DO
71.                 LOCATE 7 + rank * 2, bxx% + 6: PRINT "   ";
72.                 LOCATE 7 + rank * 2, bxx% + 6: LINE INPUT ; initials$
73.                 IF LEN(initials$) = 3 THEN EXIT DO
74.                 BEEP
75.             LOOP
76.  
77.             hsname$ = initials$
78.  
79.             MID$(hsdata$(rank), 5, 3) = hsname$ + SPACE$(3 - LEN(hsname$))
80.             OPEN "ascii-invaders-high-score.dat" FOR RANDOM AS #1 LEN = 25
81.             FOR i = 1 TO 5
82.                 hs = hsdata$(i)
83.                 IF LEFT$(hs, 1) = "" THEN MID$(hs, 1, 2) = "0" + LTRIM$(STR$(i))
84.                 PUT #1, i, hs
85.             NEXT
86.             CLOSE #1
87.  
88.             EXIT DO
89.         ELSE
90.             EXIT DO ' Not in the top 5 highest scores so exit sub.
91.         END IF
92.     LOOP
93.     EXIT SUB
94.  
95.     hiscore:
96.     FOR i = 1 TO 5
97.         IF VAL(score$) > VAL(highscore$(i)) THEN rank = i: EXIT FOR
98.     NEXT
99.  
100.     hsdata$(6) = SPACE$(25)
101.     MID$(hsdata$(6), 10, 6) = score$
102.     MID$(hsdata$(6), 18, 8) = MID$(DATE$, 1, 6) + MID$(DATE$, 9, 2)
103.     highscore$(6) = score$
104.     FOR i = 1 TO 6
105.         FOR j = 1 TO 6
106.             IF i <> j THEN
107.                 IF VAL(highscore$(i)) > VAL(highscore$(j)) THEN
108.                     SWAP highscore$(i), highscore$(j)
109.                     SWAP hsdata$(i), hsdata$(j)
110.                 END IF
111.             END IF
112.         NEXT
113.     NEXT
114.     FOR i = 1 TO 5
115.         MID$(hsdata$(i), 1, 2) = "0" + LTRIM$(STR$(i))
116.     NEXT
117.  
118.     RETURN
119.  
120. END SUB

Pete

[bplus]

Binary, RA,... blah who wants to worry about fixed strings, it's only, what, 10 lines? 8 players according to OP.

These can be sorted as you load them from file, KISS ;-))

A sequential file you can edit if things go wrong.

44 LOC! https://www.qb64.org/forum/index.php?topic=1511.msg107586#msg107586

[Pete]

I say KIRAM it! (Keep it RA, Mark. )

KISS for programmers... (Keep it sequential, stupid.)

Pete 🤣

[SMcNeill]

@Cobalt Love to see a binary example, if you have one.

Here's you a quick example which shows that RANDOM files and BINARY files are basically interchangeable:

Code: QB64: [Select]

1. Type HighScore_Type
2.     Name As String * 30
3.     score As Long
4. End Type
5.  
6. Dim HighScores(10) As HighScore_Type
7. Dim Whut(10) As HighScore_Type
8.  
9. HighScores(0).Name = "Pete"
10. HighScores(1).Name = "Petr"
11. HighScores(2).Name = "Steve"
12. HighScores(3).Name = "Bplus"
13. HighScores(4).Name = "Luke"
14. HighScores(5).Name = "Felippe"
15. HighScores(6).Name = "Richard"
16. HighScores(7).Name = "Me"
17. HighScores(8).Name = "You"
18. HighScores(9).Name = "And"
19. HighScores(10).Name = "Dog"
20.  
21. For i = 10 To 0 Step -1
22.     total = total + Int(Rnd * 10000)
23.     HighScores(i).score = total
24. Next
25.  
26. Open "Temp.txt" For Random As #1 Len = Len(HighScores(0))
27. For i = 0 To 10
28.     Put #1, i + 1, HighScores(i) 'The Put is at position +1 here as we start at RECORD 1, not RECORD 0
29. Next
30. Close
31.  
32. Open "Temp.txt" For Binary As #1
33. For i = 0 To 10
34.     Get #1, i * Len(HighScores(0)) + 1, Whut(i) 'The Get is at byte +1 here, as we start getting at byte 1, not Byte 0
35. Next
36. Close
37.  
38. For i = 0 To 10
39.     Print HighScores(i).Name; HighScores(i).score, Whut(i).Name; Whut(i).score
40. Next

If you notice, I write to a RANDOM file, but then read that data back via BINARY access.

The only difference between the two is that RANDOM tracks your data by FILE NUMBER, while BINARY tracks the same data by BYTE POSITION.

If a Random file has records that are 100 bytes each in size, then the Binary file is going to be read at byte 1, 101, 201, 301, 401, 501 -- every 100 bytes, rather than at Record 1, 2, 3, 4, 5....

That's the only real difference in the two!

[Pete]

Got it.

So in a pure BINARY make to BINARY read method, we would have...

Code: QB64: [Select]

1. TYPE HighScore_Type
2.     Name AS STRING * 30
3.     score AS LONG
4. END TYPE
5.  
6. DIM HighScores(10) AS HighScore_Type
7. DIM Whut(10) AS HighScore_Type
8.  
9. HighScores(0).Name = "Pete"
10. HighScores(1).Name = "Petr"
11. HighScores(2).Name = "Steve"
12. HighScores(3).Name = "Bplus"
13. HighScores(4).Name = "Luke"
14. HighScores(5).Name = "Felippe"
15. HighScores(6).Name = "Richard"
16. HighScores(7).Name = "Me"
17. HighScores(8).Name = "You"
18. HighScores(9).Name = "And"
19. HighScores(10).Name = "Dog"
20.  
21. FOR i = 10 TO 0 STEP -1
22.     total = total + INT(RND * 10000)
23.     HighScores(i).score = total
24. NEXT
25.  
26. OPEN "Temp.txt" FOR OUTPUT AS #1: CLOSE #1
27.  
28. OPEN "Temp.txt" FOR BINARY AS #1 'LEN = LEN(HighScores(0))
29. FOR i = 0 TO 10
30.     PUT #1, i * LEN(HighScores(0)) + 1, HighScores(i) 'The Put is at position +1 here as we start at RECORD 1, not RECORD 0
31. NEXT
32. CLOSE
33.  
34. OPEN "Temp.txt" FOR BINARY AS #1
35. FOR i = 0 TO 10
36.     GET #1, i * LEN(HighScores(0)) + 1, Whut(i) 'The Get is at byte +1 here, as we start getting at byte 1, not Byte 0
37. NEXT
38. CLOSE
39.  
40. FOR i = 0 TO 10
41.     Print HighScores(i).Name; HighScores(i).score, Whut(i).Name; Whut(i).score
42. NEXT
43.  

Pete

[Donald Foster]

Thank you Everyone,

I used a sequential file along with _FileExits and it works great so far, but I far from done with the game.
I am very happy with the progress. Actually, it's been over 30 years since I created files.
By the way, bplus, none of game use image or sound files. All of my games are hand drawn using graphics statements.

[bplus]

By the way, bplus, none of game use image or sound files. All of my games are hand drawn using graphics statements.

Yep, that's something to brag about IMHO. :)