Match Three

[SMcNeill]

Code: QB64: [Select]

1. Type GameTurn_Type
2.     GridSize As _Byte
3.     Matches As _Byte
4. End Type
5. Dim Shared WS, GridSize, Choice, Matches, Center, Guess$, Guess, DisplayScreen, score
6. Dim GameTurn(10) As GameTurn_Type
7.  
8. ReDim Shared Grid(0, 0) As _Byte
9. Choice = 1
10.  
11. Randomize Timer
12. GameLimit = 3
13. GameTurn(0).GridSize = 8: GameTurn(0).Matches = 3
14. GameTurn(1).GridSize = 12: GameTurn(1).Matches = 3
15. GameTurn(2).GridSize = 12: GameTurn(2).Matches = 4
16. GameTurn(3).GridSize = 8: GameTurn(3).Matches = 4
17.  
18. renewgrid = -1
19.  
20.  
21. t# = Timer
22. Do
23.     If renewgrid Then
24.         GridSize = GameTurn(GameOn).GridSize: Matches = GameTurn(GameOn).Matches
25.         GameOn = GameOn + 1
26.         If GameOn > GameLimit Then Exit Do
27.         MakeGrid
28.         DisplayScreen = 0
29.         renewgrid = 0
30.     End If
31.     DisplayGrid
32.     UserInput
33.     _Limit 2
34.     Choice = (Choice + 1) Mod GridSize
35.     If Choice = 0 Then Choice = GridSize
36.     If checkwin Then
37.         score = score + Int(t# - Timer) * 5
38.         ShowScore
39.         renewgrid = -1
40.         t# = Timer
41.     End If
42. Loop
43. Screen 0: _FreeImage WS
44. WS = _NewImage(240, 240, 32)
45. Screen WS
46. _Font 8
47.  
48. Cls
49. Print "YOU ARE A BIG WEENER!! YAAAYYY!!"
50. _FreeImage DisplayScreen
51. DisplayScreen = 0
52. AutoScale
53.  
54. _KeyClear
55. Sleep
56. System
57.  
58.  
59. Function checkwin
60.     For x = 1 To GridSize
61.         For y = 1 To GridSize
62.             If Grid(x, y) <> 0 Then Exit Function
63.     Next y, x
64.     checkwin = -1
65. End Function
66.  
67. Sub UserInput
68.     C = Choice - 1
69.     If C = 0 Then C = GridSize
70.     k = _KeyHit
71.     Select Case k
72.         Case 27
73.             Screen 0: _FreeImage WS
74.             WS = _NewImage(240, 240, 32)
75.             Screen WS
76.             _Font 8
77.  
78.             Cls
79.             Print "YOU ARE A BIG LOSER!! HAHAHAHA!!"
80.             _FreeImage DisplayScreen
81.             DisplayScreen = 0
82.             AutoScale
83.             _KeyClear
84.             Sleep
85.             System
86.  
87.  
88.         Case 32
89.             For y = GridSize To 1 Step -1
90.                 If Grid(C, y) <> 0 Then Exit For
91.             Next
92.             If y <> 0 Then
93.                 '             If Grid(C, y) <> 0 Then
94.                 If Grid(C, y) = Guess Or Guess = 0 Then
95.                     Guess = Grid(C, y)
96.                     Guess$ = Guess$ + _Trim$(Str$(Guess))
97.                     Grid(C, y) = 0
98.                     If Len(Guess$) = Matches Then
99.                         Guess$ = ""
100.                         Guess = 0
101.                         score = score + 10 ^ Matches
102.                     End If
103.                     DisplayGrid
104.                 End If
105.                 '        End If
106.             End If
107.     End Select
108.     _KeyClear
109. End Sub
110.  
111.  
112. Sub ShowScore
113.     If WS <> 0 Then Screen 0: _FreeImage WS
114.  
115.     WS = _NewImage(240, 240, 32)
116.     Screen WS
117.     _Font 8
118.     Cls , -1
119.     Color &HFF000000, 0
120.     Print "Round", "Score"
121.  
122.     Print _Trim$(Str$(GameOn + 1)), _Trim$(Str$(score))
123.     DisplayScreen = 0
124.     AutoScale
125.     _Delay 2
126.     _KeyClear
127.     Sleep
128.     _KeyClear
129. End Sub
130.  
131.  
132.  
133. Sub DisplayGrid
134.     Cls
135.     For x = 1 To GridSize: For y = 1 To GridSize
136.         If Grid(x, y) Then Locate y, x: Print _Trim$(Str$(Grid(x, y)));
137.     Next y, x
138.     Locate y, Choice: Print "^";
139.     Center = 640 - _PrintWidth(String$(Matches, " ")) / 2
140.     Line (0, GridSize * 8 + 8)-Step(639, 16), -1, BF
141.     PW = _PrintWidth(String$(Matches, " "))
142.     Line ((GridSize * 8 - PW) \ 2, GridSize * 8 + 8)-Step(PW, 8), &HFF000000, BF
143.     _PrintString ((GridSize * 8 - PW) \ 2, GridSize * 8 + 8), Guess$
144.     AutoScale
145. End Sub
146.  
147. Sub MakeGrid
148.     If WS <> 0 Then Screen 0: _FreeImage WS
149.  
150.     WS = _NewImage(GridSize * 8, GridSize * 8 + 16, 32)
151.     Screen WS
152.     _Font 8 'this creates a 30x32 screen
153.     ReDim Grid(1 To GridSize, 1 To GridSize) As _Byte
154.  
155.     count = -1: value = -1
156.     For x = 1 To GridSize: For y = 1 To GridSize
157.         count = (count + 1) Mod Matches
158.         If count = 0 Then value = (value + 1) Mod Matches
159.             Grid(y, x) = value + 1
160.     Next y, x
161.     If count <> Matches - 1 Then
162.         For i = count To 0 Step -1
163.             Grid(GridSize - i, GridSize) = 0
164.         Next
165.     End If
166.  
167.  
168.     For x = 1 To GridSize: For y = 1 To GridSize
169.         xswap = Int(Rnd * GridSize) + 1: yswap = Int(Rnd * GridSize) + 1
170.         If Grid(x, y) <> 0 And Grid(xswap, yswap) <> 0 Then Swap Grid(xswap, yswap), Grid(x, y) 'Shuffle the grid
171.     Next y, x
172.     Guess$ = ""
173.     Guess = 0
174. End Sub
175.  
176. Sub AutoScale
177.     If DisplayScreen = 0 Then
178.         DW = _DesktopWidth
179.         DH = _DesktopHeight
180.         $If WIN Then
181.             Declare Library "th"
182.                 Function taskbar_height& ()
183.             End Declare
184.             TH = taskbar_height
185.         $End If
186.         If TH >= DH Or TH = 0 Then TH = 100
187.         Scale = (DH - TH) / 640
188.         DisplayScreen = _NewImage(640 * Scale, 640 * Scale, 32)
189.         Screen DisplayScreen
190.         ScreenMove (DW - _Width(DisplayScreen)) \ 2, 0
191.         _Source WS: _Dest WS
192.     End If
193.     _PutImage , WS, DisplayScreen
194.     _Display
195. End Sub
196.  
197. Sub ScreenMove (x, y)
198.     $If BORDERDEC = UNDEFINED Then
199.         $Let BORDERDEC = TRUE
200.         Declare Library
201.             Function glutGet& (ByVal what&)
202.         End Declare
203.     $End If
204.     BorderWidth = glutGet(506)
205.     TitleBarHeight = glutGet(507)
206.     _ScreenMove x - BorderWidth, y - BorderWidth - TitleBarHeight
207. End Sub
208.  

Game now runs for multiple rounds before ending, as well as having a scoring system in it.   Bplus's glitch with the autoscale not working should be fixed, and the taskbar height routine shouldn't be an issue for folks on Linux or Mac now. 

At this point, the game is basically finished, unless I want to swap in some bells and whistles like music and images instead of the plain old numbers which we're using here.  In a lot of ways, I kind of like just sticking with the numbers for a sort of retro-Screen 0 type feel for everything.  A simple high score system would be nice to add, but it's a pain in the rump to add and deal with, while sticking to the single-input rule, and my time is limited here before Halloween.  Maybe I'll take time and add that into the game after the holiday comes around and passes.  LOL!  :P

Anywho, test it out.  Tell me what you think, and let me know if you run into any glitches or unexpected behavior with everything.

[Pete]

If you decide you want to add a top five scoring system, here's my stripped down version using LINE INPUT: https://www.qb64.org/forum/index.php?topic=4339.msg137511#msg137511

I think we both have custom keyboard input programs, which could substitute for the LINE INPUT statement.

The ASCII Invaders game uses the 1-key method: https://www.qb64.org/forum/index.php?topic=4245.msg137017#msg137017

I might even still have the stripped down 1-key input method, if you're interested.

Pete