EBAC Calculator

[George McGinn]

This is a rework of a post I made a few months ago.

I converted my EBAC Calculator from Zenity to now use InForm, and uses many of it's features.

I've included all the files needed to compile it, and have tested it on Linux and MAC OSX. It should also run on Windows (I don't have a Windows OS installed).

Below is the main program for those who want to look at it, but you will need the files/directories in the .ZIP file if you want to compile it. You do not need InForm to compile and use the program. Just the files provided.

Here's the main source:

Code: QB64: [Select]

1. REM $TITLE: ebacCalculator.bas Version 1.0  04/01/2021 - Last Update: 10/14/2021
2. _TITLE "ebacCalculator.bas"
3. ' ebacCalculator.bas    Version 2.0  10/14/2021
4. '-----------------------------------------------------------------------------------
5. '       PROGRAM: ebacCalculator.bas
6. '        AUTHOR: George McGinn
7. '
8. '  DATE WRITTEN: 04/01/2021
9. '       VERSION: 2.0
10. '       PROJECT: Estimated Blood-Alcohol Content Calculator
11. '
12. '   DESCRIPTION: Program shows many of the functions of using InForm while using
13. '                most of the original code from the Zenity project. This can now
14. '                run on all systems (Linux, MAC and Windows).
15. '
16. ' Written by George McGinn
17. ' Copyright (C)2021 by George McGinn - All Rights Reserved
18. ' Version 1.0 - Created 04/01/2021
19. ' Version 2.0 - Created 10/14/2021
20. '
21. ' CHANGE LOG
22. '-----------------------------------------------------------------------------------
23. ' 04/01/2021 v1.0  GJM - New Program (TechBASIC and C++ Versions).
24. ' 06/19/2021 v1.5  GJM - Updated to use Zenity and SHELL commands to run on Linux with
25. '                        a simple GUI.
26. ' 10/14/2021 v2.0  GJM - Updated to use InForm GUI in place of Zenity an SHELL commands.
27. '                        Can now run on any OS
28. '-----------------------------------------------------------------------------------
29. '  Copyright (C)2021 by George McGinn.  All Rights Reserved.
30. '
31. ' untitled.bas by George McGinn is licensed under a Creative Commons
32. ' Attribution-NonCommercial 4.0 International. (CC BY-NC 4.0)
33. '
34. ' Full License Link: https://creativecommons.org/licenses/by-nc/4.0/legalcode
35. '
36. '-----------------------------------------------------------------------------------
37. ' PROGRAM NOTES
38. '
39. ': This program uses
40. ': InForm - GUI library for QB64 - v1.3
41. ': Fellippe Heitor, 2016-2021 - fellippe@qb64.org - [member=2]FellippeHeitor[/member]
42. ': https://github.com/FellippeHeitor/InForm
43. '-----------------------------------------------------------------------------------
44.  
45. ': Controls' IDs: ------------------------------------------------------------------
46. DIM SHARED maleRB AS LONG
47. DIM SHARED femaleRB AS LONG
48. DIM SHARED AgreeCB AS LONG
49. DIM SHARED AGREEBT AS LONG
50. DIM SHARED ebacFRM AS LONG
51. DIM SHARED SexLB AS LONG
52. DIM SHARED weightLB AS LONG
53. DIM SHARED nbrdrinksLB AS LONG
54. DIM SHARED timeLB AS LONG
55. DIM SHARED EnterInformationLB AS LONG
56. DIM SHARED WeightTB AS LONG
57. DIM SHARED nbrDrinksTB AS LONG
58. DIM SHARED TimeTB AS LONG
59. DIM SHARED CancelBT AS LONG
60. DIM SHARED OKBT AS LONG
61. DIM SHARED HELPBT AS LONG
62. DIM SHARED QUITBT AS LONG
63. DIM SHARED displayResults AS LONG
64. DIM SHARED informationLB AS LONG
65.  
66. ': User-defined Variables: ---------------------------------------------------------
67. DIM SHARED AS STRING HELPFile
68. DIM SHARED AS INTEGER l, SOBER, legalToDrive
69. DIM SHARED AS STRING Sex
70. DIM SHARED AS DOUBLE A, T
71. DIM SHARED AS SINGLE B, OZ, Wt, EBAC
72. DIM SHARED numeric(255)
73.  
74. DIM SHARED AS STRING helpcontents, prt_text
75.  
76.  
77.  
78. ': External modules: ---------------------------------------------------------------
79. '$INCLUDE:'InForm/InForm.bi'
80. '$INCLUDE:'InForm/xp.uitheme'
81. '$INCLUDE:'ebacCalculator.frm'
82.  
83.  
84.  
85. ': Event procedures: ---------------------------------------------------------------
86. SUB __UI_BeforeInit
87.  
88. END SUB
89.  
90. SUB __UI_OnLoad
91.  
92. ' *** Initialize Variables
93.     A = 0
94.     Wt = 0
95.     B = .0
96.     T = 0: St = 0
97.     I = 0
98.     Bdl = 1.055
99.     OZ = .5
100.     SOBER = False: legalToDrive = False
101.     HELPFile = "EBACHelp.txt"
102.     displayDisclaimer
103.  
104. END SUB
105.  
106. SUB __UI_BeforeUpdateDisplay
107.     'This event occurs at approximately 60 frames per second.
108.     'You can change the update frequency by calling SetFrameRate DesiredRate%
109.  
110. END SUB
111.  
112. SUB __UI_BeforeUnload
113.     'If you set __UI_UnloadSignal = False here you can
114.     'cancel the user's request to close.
115.  
116. END SUB
117.  
118. SUB __UI_Click (id AS LONG)
119.     SELECT CASE id
120.         CASE maleRB
121.             Sex = "M"
122.  
123.         CASE femaleRB
124.             Sex = "F"
125.  
126.         CASE AGREEBT
127.             Answer = MessageBox("Do you want to perform another calculation?             ", "", MsgBox_YesNo + MsgBox_Question)
128.             IF Answer = MsgBox_Yes THEN
129.                 Control(AgreeCB).Value = False
130.                 Control(AGREEBT).Disabled = True
131.             ELSE
132.                 Answer = MessageBox("Thank You for using EBAC Calculator. Please Don't Drink and Drive.", "", MsgBox_Ok + MsgBox_Information)
133.                SYSTEM
134.             END IF
135.  
136.         CASE CancelBT
137.             ResetForm
138.  
139.         CASE OKBT
140.             IF Control(maleRB).Value = False AND Control(femaleRB).Value = False THEN
141.                 Answer = MessageBox("Invalid: You must select either M (male) or F (female). Please Correct.", "", MsgBox_Ok + MsgBox_Information)
142.                 EXIT SUB
143.             END IF
144.             A = Control(nbrDrinksTB).Value
145.             Wt = Control(WeightTB).Value
146.             T = Control(TimeTB).Value
147.             calcEBAC
148.             Control(QUITBT).Disabled = True
149.             ResetList displayResults
150.             Text(displayResults) = prt_text
151.  
152.         CASE HELPBT
153.             ResetList displayResults
154.             IF _FILEEXISTS(HELPFile) THEN
155.                 DIM fh AS LONG
156.                 fh = FREEFILE
157.                 OPEN HELPFile FOR INPUT AS #fh
158.                 DO UNTIL EOF(fh)
159.                     LINE INPUT #fh, helpcontents
160.                     AddItem displayResults, helpcontents
161.                 LOOP
162.                 CLOSE #fh
163.                 Control(displayResults).LastVisibleItem = 0
164.             ELSE
165.                 Answer = MessageBox("HELP File " + HELPFile$ + " Not Found                             ", "", MsgBox_Ok + MsgBox_Question)
166.                 SYSTEM 1
167.             END IF
168.  
169.         CASE QUITBT
170.             Answer = MessageBox("Are you sure you want to QUIT?                     ", "", MsgBox_YesNo + MsgBox_Question)
171.             IF Answer = MsgBox_Yes THEN
172.                 Answer = MessageBox("Thank You for using EBAC Calculator. Please Don't Drink and Drive.", "", MsgBox_Ok + MsgBox_Information)
173.                 SYSTEM
174.             END IF
175.  
176.     END SELECT
177. END SUB
178.  
179. SUB __UI_MouseEnter (id AS LONG)
180. END SUB
181.  
182. SUB __UI_MouseLeave (id AS LONG)
183. END SUB
184.  
185. SUB __UI_FocusIn (id AS LONG)
186. END SUB
187.  
188. SUB __UI_FocusOut (id AS LONG)
189.     'This event occurs right before a control loses focus.
190.     'To prevent a control from losing focus, set __UI_KeepFocus = True below.
191. END SUB
192.  
193. SUB __UI_MouseDown (id AS LONG)
194. END SUB
195.  
196. SUB __UI_MouseUp (id AS LONG)
197. END SUB
198.  
199. SUB __UI_KeyPress (id AS LONG)
200.     'When this event is fired, __UI_KeyHit will contain the code of the key hit.
201.     'You can change it and even cancel it by making it = 0
202. END SUB
203.  
204. SUB __UI_TextChanged (id AS LONG)
205.     SELECT CASE id
206.  
207.         CASE WeightTB
208.             Control(AgreeCB).Value = False
209.             Control(AGREEBT).Disabled = True
210.  
211.         CASE nbrDrinksTB
212.             Control(AgreeCB).Value = False
213.             Control(AGREEBT).Disabled = True
214.  
215.         CASE TimeTB
216.             Control(AgreeCB).Value = False
217.             Control(AGREEBT).Disabled = True
218.  
219.     END SELECT
220. END SUB
221.  
222. SUB __UI_ValueChanged (id AS LONG)
223.     SELECT CASE id
224.  
225.         CASE maleRB
226.             Control(AgreeCB).Value = False
227.             Control(AGREEBT).Disabled = True
228.  
229.         CASE femaleRB
230.             Control(AgreeCB).Value = False
231.             Control(AGREEBT).Disabled = True
232.  
233.         CASE AgreeCB
234.             IF Control(AgreeCB).Value = True THEN
235.                 Control(AGREEBT).Disabled = False
236.                 Control(QUITBT).Disabled = False
237.             ELSE
238.                 Control(AGREEBT).Disabled = True
239.                 Control(QUITBT).Disabled = True
240.             END IF
241.  
242.     END SELECT
243. END SUB
244.  
245. SUB __UI_FormResized
246. END SUB
247.  
248. '$INCLUDE:'InForm/InForm.ui'
249.  
250.  
251. ': User FUNCTIONS/SUBROUTINES: ---------------------------------------------------------------
252.  
253. SUB displayDisclaimer
254.  
255. '    prt_text = "*** DISCLAIMER ***" + CHR$(10)
256.     prt_text = "Unless otherwise separately undertaken by the Licensor, to the extent" + CHR$(10)
257.     prt_text = prt_text + "possible, the Licensor offers the Licensed Material as-is and" + CHR$(10)
258.     prt_text = prt_text + "as-available, and makes no representations or warranties of any kind" + CHR$(10)
259.     prt_text = prt_text + "concerning the Licensed Material, whether express, implied, statutory," + CHR$(10)
260.     prt_text = prt_text + "or other. This includes, without limitation, warranties of title," + CHR$(10)
261.     prt_text = prt_text + "merchantability, fitness for a particular purpose, non-infringement," + CHR$(10)
262.     prt_text = prt_text + "absence of latent or other defects, accuracy, or the presence or absence" + CHR$(10)
263.     prt_text = prt_text + "of errors, whether or not known or discoverable. Where disclaimers of" + CHR$(10)
264.     prt_text = prt_text + "warranties are not allowed in full or in part, this disclaimer may not" + CHR$(10)
265.     prt_text = prt_text + "apply to You." + CHR$(10) + CHR$(10)
266.  
267.     prt_text = prt_text + "To the extent possible, in no event will the Licensor be liable to You" + CHR$(10)
268.     prt_text = prt_text + "on any legal theory (including, without limitation, negligence) or" + CHR$(10)
269.     prt_text = prt_text + "otherwise for any direct, special, indirect, incidental, consequential," + CHR$(10)
270.     prt_text = prt_text + "punitive, exemplary, or other losses, costs, expenses, or damages" + CHR$(10)
271.     prt_text = prt_text + "arising out of this Public License or use of the Licensed Material, even" + CHR$(10)
272.     prt_text = prt_text + "if the Licensor has been advised of the possibility of such losses," + CHR$(10)
273.     prt_text = prt_text + "costs, expenses, or damages. Where a limitation of liability is not" + CHR$(10)
274.     prt_text = prt_text + "allowed in full or in part, this limitation may not apply to You." + CHR$(10) + CHR$(10)
275.  
276.     prt_text = prt_text + "The disclaimer of warranties and limitation of liability provided above" + CHR$(10)
277.     prt_text = prt_text + "shall be interpreted in a manner that, to the extent possible, most" + CHR$(10)
278.     prt_text = prt_text + "closely approximates an absolute disclaimer and waiver of all liability." + CHR$(10)
279.  
280.     Answer = MessageBox(prt_text, "*** DISCLAIMER ***", MsgBox_YesNo + MsgBox_Question)
281.     IF Answer = MsgBox_No THEN
282.         Answer = MessageBox("Sorry you don't agree. Please Don't Drink and Drive.", "", MsgBox_Ok + MsgBox_Information)
283.         SYSTEM
284.     END IF
285.  
286. END SUB
287.  
288.  
289. SUB ResetForm
290.     Control(nbrDrinksTB).Value = 0
291.     Control(WeightTB).Value = 0
292.     Control(TimeTB).Value = 0
293.     Control(AgreeCB).Value = False
294.     Control(AGREEBT).Disabled = True
295.     Control(maleRB).Value = False
296.     Control(femaleRB).Value = False
297.     ResetList displayResults
298.     Sex = ""
299. END SUB
300.  
301.  
302. SUB calcEBAC
303. '-------------------------------------------------------------
304. ' *** Convert Drinks into Fluid Ounces of EtOH (Pure Alcohol).
305. ' *** A is number of drinks. 1 drink is about .6 FLoz of alcohol
306.     FLoz = A * OZ
307.     legalToDrive = False
308.  
309. '-----------------------------------------------------
310. ' *** Set/calculate EBAC values based on Sex
311.     SELECT CASE Sex
312.         CASE "M"
313.             B = .017
314.             EBAC = 7.97 * FLoz / Wt - B * T
315.         CASE "F"
316.             B = .019
317.             EBAC = 9.86 * FLoz / Wt - B * T
318.     END SELECT
319.  
320.     IF EBAC < 0 THEN EBAC = 0
321.  
322. '----------------------------------------------------------------------------------------------
323. ' *** Populate the EBAC string with the EBAC value formatted to 3 decimal places for FORM output
324.     prt_text = "ESTIMATED BLOOD ALCOHOL CONTENT (EBAC) in g/dL = " + strFormat$(STR$(EBAC), "###.###") + CHR$(10) + CHR$(10)
325.  
326.  
327. '-----------------------------------------------------------------------------------------
328. ' *** Based on EBAC range values, populate the FORM output string with the approriate text
329.     SELECT CASE EBAC
330.         CASE .500 TO 100.9999
331.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, DEATH LIKELY" + CHR$(10)
332.             prt_text = prt_text + "Unconsious/coma, unresponsive, high likelihood of death. It is illegal" + CHR$(10) + _
333.                                   "to operate a motor vehicle at this level of intoxication in all states." + CHR$(10)
334.         CASE .400 TO .4999
335.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, DEATH POSSIBLE" + CHR$(10)
336.             prt_text = prt_text + "Onset of coma, and possible death due to respiratory arrest. It is illegal" + CHR$(10) + _
337.                                   "to operate a motor vehicle at this level of intoxication in all states." + CHR$(10)
338.         CASE .350 TO .3999
339.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, SEVERE ALCOHOL POISONING" + CHR$(10)
340.             prt_text = prt_text + " Coma is possible. This is the level of surgical anesthesia. It is illegal" + CHR$(10) + _
341.                                   "to operate a motor vehicle at this level of intoxication in all states." + CHR$(10)
342.         CASE .300 TO .3499
343.             prt_text = prt_text + "*** ALERT: YOU ARE IN A DRUNKEN STUP0R, AT RISK TO PASSING OUT" + CHR$(10)
344.             prt_text = prt_text + "STUPOR. You have little comprehension of where you are. You may pass out" + CHR$(10) + _
345.                                   "suddenly and be difficult to awaken. It is illegal to operate a motor" + CHR$(10) + _
346.                                   "vehicle at this level of intoxication in all states." + CHR$(10)
347.         CASE .250 TO .2999
348.             prt_text = prt_text + "*** ALERT: SEVERLY IMPAIRED - DRUNK ENOUGH TO CAUSE SEVERE INJURY/DEATH TO SELF" + CHR$(10)
349.             prt_text = prt_text + "All mental, physical and sensory functions are severely impaired." + CHR$(10) + _
350.                                   "Increased risk of asphyxiation from choking on vomit and of seriously injuring" + CHR$(10) + _
351.                                   "yourself by falls or other accidents. It is illegal to operate a motor" + CHR$(10) + _
352.                                   "vehicle at this level of intoxication in all states." + CHR$(10)
353.         CASE .200 TO .2499
354.             prt_text = prt_text + "YOU ARE EXTREMELY DRUNK" + CHR$(10)
355.             prt_text = prt_text + "Feeling dazed/confused or otherwise disoriented. May need help to" + CHR$(10) + _
356.                                   "stand/walk. If you injure yourself you may not feel the pain. Some" + CHR$(10) + _
357.                                   "people have nausea and vomiting at this level. The gag reflex" + CHR$(10) + _
358.                                   "is impaired and you can choke if you do vomit. Blackouts are likely" + CHR$(10) + _
359.                                   "at this level so you may not remember what has happened. It is illegal" + CHR$(10) + _
360.                                   "to operate a motor vehicle at this level of intoxication in all states." + CHR$(10)
361.         CASE .160 TO .1999
362.             prt_text = prt_text + "YOUR ARE SEVERLY DRUNK - ENOUGH TO BECOME VERY SICK" + CHR$(10)
363.             prt_text = prt_text + "Dysphoria* predominates, nausea may appear. The drinker has the appearance" + CHR$(10) + _
364.                                   "of a 'sloppy drunk.' It is illegal to operate a motor vehicle at this level" + CHR$(10) + _
365.                                   "of intoxication in all states." + CHR$(10) + CHR$(10) + _
366.                                   "* Dysphoria: An emotional state of anxiety, depression, or unease." + CHR$(10)
367.         CASE .130 TO .1599
368.             prt_text = prt_text + "YOU ARE VERY DRUNK - ENOUGH TO LOSE PHYSICAL & MENTAL CONTROL" + CHR$(10)
369.             prt_text = prt_text + "Gross motor impairment and lack of physical control. Blurred vision and major" + CHR$(10) + _
370.                                   "loss of balance. Euphoria is reduced and dysphoria* is beginning to appear." + CHR$(10) + _
371.                                   "Judgment and perception are severely impaired. It is illegal to operate a " + CHR$(10) + _
372.                                   "motor vehicle at this level of intoxication in all states." + CHR$(10) + CHR$(10)
373.             prt_text = prt_text + "* Dysphoria: An emotional state of anxiety, depression, or unease." + CHR$(10)
374.         CASE .100 TO .1299
375.             prt_text = prt_text + "YOU ARE LEGALLY DRUNK" + CHR$(10)
376.             prt_text = prt_text + "Significant impairment of motor coordination and loss of good judgment." + CHR$(10) + _
377.                                   "Speech may be slurred; balance, vision, reaction time and hearing will be" + CHR$(10) + _
378.                                   "impaired. Euphoria. It is illegal to operate a motor vehicle at this level" + CHR$(10) + _
379.                                   "of intoxication in all states." + CHR$(10)
380.         CASE .070 TO .0999
381.             prt_text = prt_text + "YOU MAY BE LEGALLY DRUNK" + CHR$(10)
382.             prt_text = prt_text + "Slight impairment of balance, speech, vision, reaction time, and hearing." + CHR$(10) + _
383.                                   "Euphoria. Judgment and self-control are reduced, and caution, reason and" + CHR$(10) + _
384.                                   "memory are impaired (in some* states .08 is legally impaired and it is illegal" + CHR$(10) + _
385.                                   "to drive at this level). You will probably believe that you are functioning" + CHR$(10) + _
386.                                   "better than you really are." + CHR$(10) + CHR$(10)
387.             prt_text = prt_text + "(*** As of July, 2004 ALL states had passed .08 BAC Per Se Laws. The final" + CHR$(10) + _
388.                                   "one took effect in August of 2005.)" + CHR$(10)
389.         CASE .040 TO .0699
390.             prt_text = prt_text + "YOU MAY BE LEGALLY BUZZED" + CHR$(10)
391.             prt_text = prt_text + "Feeling of well-being, relaxation, lower inhibitions, sensation of warmth." + CHR$(10) + _
392.                                   "Euphoria. Some minor impairment of reasoning and memory, lowering of caution." + CHR$(10) + _
393.                                   "Your behavior may become exaggerated and emotions intensified (Good emotions" + CHR$(10) + _
394.                                   "are better, bad emotions are worse)" + CHR$(10)
395.         CASE .020 TO .0399
396.             prt_text = prt_text + "YOU MAY BE OK TO DRIVE, BUT IMPAIRMENT BEGINS" + CHR$(10)
397.             prt_text = prt_text + "No loss of coordination, slight euphoria and loss of shyness. Depressant effects" + CHR$(10) + _
398.                                   "are not apparent. Mildly relaxed and maybe a little lightheaded." + CHR$(10)
399.         CASE .000 TO .0199
400.             prt_text = prt_text + "YOU ARE OK TO DRIVE" + CHR$(10)
401.     END SELECT
402.  
403. '-----------------------------------------------------------
404. '*** Determine if Drunk (>.08 EBAC) and calculate:
405. '***    - When user will be less than .08
406. '***    - How long it will take to become completely sober
407.     IF EBAC > .08 THEN
408.         SOBER = False
409.         CEBAC = EBAC
410.         st = T
411.         DO UNTIL SOBER = True
412.             T = T + 1
413.             IF CEBAC > .0799 THEN I = I + 1
414.  
415.             SELECT CASE Sex
416.                 CASE "M"
417.                     B = .017
418.                     CEBAC = 7.97 * FLoz / Wt - B * T
419.                 CASE "F"
420.                     B = .019
421.                     CEBAC = 9.86 * FLoz / Wt - B * T
422.             END SELECT
423.  
424.             IF legalToDrive = False THEN
425.                 IF CEBAC < .08 THEN
426.                     prt_text = prt_text + CHR$(10) + CHR$(10) + "It will take about " + strFormat$(STR$(I), "##") + " hours from your last drink to be able to drive." + CHR$(10)
427.                     legalToDrive = True
428.                 END IF
429.             END IF
430.  
431.             IF CEBAC <= 0 THEN
432.                 prt_text = prt_text + "It will take about " + strFormat$(STR$(T - st), "##") + " hours from your last drink to be completely sober."
433.                 SOBER = True
434.             END IF
435.         LOOP
436.     END IF
437.  
438. END SUB
439.  
440.  
441. FUNCTION strFormat$ (text AS STRING, template AS STRING)
442. '-----------------------------------------------------------------------------
443. ' *** Return a formatted string to a variable
444. '
445.     d = _DEST: s = _SOURCE
446.     n = _NEWIMAGE(80, 80, 0)
447.     _DEST n: _SOURCE n
448.     PRINT USING template; VAL(text)
449.     FOR i = 1 TO 79
450.         t$ = t$ + CHR$(SCREEN(1, i))
451.     NEXT
452.     IF LEFT$(t$, 1) = "%" THEN t$ = MID$(t$, 2)
453.     strFormat$ = _TRIM$(t$)
454.     _DEST d: _SOURCE s
455.     _FREEIMAGE n
456. END FUNCTION
457.  
458.  

And the Form file:

Code: QB64: [Select]

1. ': This form was generated by
2. ': InForm - GUI library for QB64 - v1.3
3. ': Fellippe Heitor, 2016-2021 - fellippe@qb64.org - [member=2]FellippeHeitor[/member]
4. ': https://github.com/FellippeHeitor/InForm
5. '-----------------------------------------------------------
6. SUB __UI_LoadForm
7.  
8.     DIM __UI_NewID AS LONG, __UI_RegisterResult AS LONG
9.  
10.     __UI_NewID = __UI_NewControl(__UI_Type_Form, "ebacFRM", 618, 630, 0, 0, 0)
11.     __UI_RegisterResult = 0
12.     SetCaption __UI_NewID, "EBAC - ESTIMATED BLOOD ALCOHOL CONTENT CALCULATOR"
13.     Control(__UI_NewID).Font = SetFont("Fonts/arial.ttf", 16)
14.     Control(__UI_NewID).HasBorder = False
15.  
16.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "SexLB", 40, 26, 232, 64, 0)
17.     __UI_RegisterResult = 0
18.     SetCaption __UI_NewID, "Sex:"
19.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
20.     Control(__UI_NewID).HasBorder = False
21.     Control(__UI_NewID).VAlign = __UI_Middle
22.  
23.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "weightLB", 99, 25, 173, 91, 0)
24.     __UI_RegisterResult = 0
25.     SetCaption __UI_NewID, "Weight (lbs):"
26.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
27.     Control(__UI_NewID).HasBorder = False
28.     Control(__UI_NewID).VAlign = __UI_Middle
29.  
30.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "nbrdrinksLB", 138, 25, 134, 121, 0)
31.     __UI_RegisterResult = 0
32.     SetCaption __UI_NewID, "Number of drinks:"
33.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
34.     Control(__UI_NewID).HasBorder = False
35.     Control(__UI_NewID).VAlign = __UI_Middle
36.  
37.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "timeLB", 202, 25, 70, 151, 0)
38.     __UI_RegisterResult = 0
39.     SetCaption __UI_NewID, "Time (hrs) from first drink:"
40.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
41.     Control(__UI_NewID).HasBorder = False
42.     Control(__UI_NewID).VAlign = __UI_Middle
43.  
44.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "EnterInformationLB", 440, 31, 16, 17, 0)
45.     __UI_RegisterResult = 0
46.     SetCaption __UI_NewID, "Enter information about your or your friend:"
47.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 18)
48.     Control(__UI_NewID).HasBorder = False
49.     Control(__UI_NewID).VAlign = __UI_Middle
50.  
51.     __UI_NewID = __UI_NewControl(__UI_Type_TextBox, "WeightTB", 50, 23, 278, 92, 0)
52.     __UI_RegisterResult = 0
53.     Control(__UI_NewID).Font = SetFont("", 16)
54.     Control(__UI_NewID).HasBorder = True
55.     Control(__UI_NewID).Min = -32768
56.     Control(__UI_NewID).Max = 32767
57.     Control(__UI_NewID).CanHaveFocus = True
58.     Control(__UI_NewID).BorderSize = 1
59.     Control(__UI_NewID).NumericOnly = __UI_NumericWithBounds
60.  
61.     __UI_NewID = __UI_NewControl(__UI_Type_TextBox, "nbrDrinksTB", 50, 23, 278, 121, 0)
62.     __UI_RegisterResult = 0
63.     Control(__UI_NewID).Font = SetFont("", 16)
64.     Control(__UI_NewID).HasBorder = True
65.     Control(__UI_NewID).Min = -32768
66.     Control(__UI_NewID).Max = 32767
67.     Control(__UI_NewID).CanHaveFocus = True
68.     Control(__UI_NewID).BorderSize = 1
69.     Control(__UI_NewID).NumericOnly = __UI_NumericWithBounds
70.  
71.     __UI_NewID = __UI_NewControl(__UI_Type_TextBox, "TimeTB", 50, 25, 277, 151, 0)
72.     __UI_RegisterResult = 0
73.     Control(__UI_NewID).Font = SetFont("", 16)
74.     Control(__UI_NewID).HasBorder = True
75.     Control(__UI_NewID).Min = -32768
76.     Control(__UI_NewID).Max = 32767
77.     Control(__UI_NewID).CanHaveFocus = True
78.     Control(__UI_NewID).BorderSize = 1
79.     Control(__UI_NewID).NumericOnly = __UI_NumericWithBounds
80.  
81.     __UI_NewID = __UI_NewControl(__UI_Type_Button, "CancelBT", 99, 30, 435, 99, 0)
82.     __UI_RegisterResult = 0
83.     SetCaption __UI_NewID, "&Cancel"
84.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
85.     Control(__UI_NewID).HasBorder = False
86.     Control(__UI_NewID).CanHaveFocus = True
87.  
88.     __UI_NewID = __UI_NewControl(__UI_Type_Button, "OKBT", 99, 30, 435, 63, 0)
89.     __UI_RegisterResult = 0
90.     SetCaption __UI_NewID, "&OK"
91.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
92.     Control(__UI_NewID).HasBorder = False
93.     Control(__UI_NewID).CanHaveFocus = True
94.  
95.     __UI_NewID = __UI_NewControl(__UI_Type_Button, "HELPBT", 99, 30, 435, 134, 0)
96.     __UI_RegisterResult = 0
97.     SetCaption __UI_NewID, "&HELP"
98.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
99.     Control(__UI_NewID).HasBorder = False
100.     Control(__UI_NewID).CanHaveFocus = True
101.  
102.     __UI_NewID = __UI_NewControl(__UI_Type_Button, "QUITBT", 99, 30, 435, 170, 0)
103.     __UI_RegisterResult = 0
104.     SetCaption __UI_NewID, "&QUIT"
105.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
106.     Control(__UI_NewID).HasBorder = False
107.     Control(__UI_NewID).CanHaveFocus = True
108.  
109.     __UI_NewID = __UI_NewControl(__UI_Type_Label, "informationLB", 210, 17, 22, 194, 0)
110.     __UI_RegisterResult = 0
111.     SetCaption __UI_NewID, "Information Display"
112.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
113.     Control(__UI_NewID).HasBorder = False
114.     Control(__UI_NewID).VAlign = __UI_Middle
115.     Control(__UI_NewID).BorderSize = 1
116.  
117.     __UI_NewID = __UI_NewControl(__UI_Type_ListBox, "displayResults", 576, 320, 20, 213, 0)
118.     __UI_RegisterResult = 0
119.     Control(__UI_NewID).Font = SetFont("Fonts/Courier New.ttf", 12)
120.     Control(__UI_NewID).HasBorder = True
121.     Control(__UI_NewID).CanHaveFocus = True
122.     Control(__UI_NewID).BorderSize = 2
123.  
124.     __UI_NewID = __UI_NewControl(__UI_Type_Button, "AGREEBT", 99, 31, 495, 574, 0)
125.     __UI_RegisterResult = 0
126.     SetCaption __UI_NewID, "&AGREE"
127.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
128.     Control(__UI_NewID).HasBorder = False
129.     Control(__UI_NewID).CanHaveFocus = True
130.     Control(__UI_NewID).Disabled = True
131.  
132.     __UI_NewID = __UI_NewControl(__UI_Type_CheckBox, "AgreeCB", 564, 23, 26, 544, 0)
133.     __UI_RegisterResult = 0
134.     SetCaption __UI_NewID, "I agree that this programand its results are not legally binding."
135.     Control(__UI_NewID).HasBorder = False
136.     Control(__UI_NewID).CanHaveFocus = True
137.  
138.     __UI_NewID = __UI_NewControl(__UI_Type_RadioButton, "maleRB", 40, 23, 277, 64, 0)
139.     __UI_RegisterResult = 0
140.     SetCaption __UI_NewID, "M"
141.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
142.     Control(__UI_NewID).HasBorder = False
143.     Control(__UI_NewID).CanHaveFocus = True
144.  
145.     __UI_NewID = __UI_NewControl(__UI_Type_RadioButton, "femaleRB", 40, 23, 322, 64, 0)
146.     __UI_RegisterResult = 0
147.     SetCaption __UI_NewID, "F"
148.     Control(__UI_NewID).Font = SetFont("Fonts/Arial Black.ttf", 14)
149.     Control(__UI_NewID).HasBorder = False
150.     Control(__UI_NewID).CanHaveFocus = True
151.  
152. END SUB
153.  
154. SUB __UI_AssignIDs
155.     ebacFRM = __UI_GetID("ebacFRM")
156.     SexLB = __UI_GetID("SexLB")
157.     weightLB = __UI_GetID("weightLB")
158.     nbrdrinksLB = __UI_GetID("nbrdrinksLB")
159.     timeLB = __UI_GetID("timeLB")
160.     EnterInformationLB = __UI_GetID("EnterInformationLB")
161.     WeightTB = __UI_GetID("WeightTB")
162.     nbrDrinksTB = __UI_GetID("nbrDrinksTB")
163.     TimeTB = __UI_GetID("TimeTB")
164.     CancelBT = __UI_GetID("CancelBT")
165.     OKBT = __UI_GetID("OKBT")
166.     HELPBT = __UI_GetID("HELPBT")
167.     QUITBT = __UI_GetID("QUITBT")
168.     informationLB = __UI_GetID("informationLB")
169.     displayResults = __UI_GetID("displayResults")
170.     AGREEBT = __UI_GetID("AGREEBT")
171.     AgreeCB = __UI_GetID("AgreeCB")
172.     maleRB = __UI_GetID("maleRB")
173.     femaleRB = __UI_GetID("femaleRB")
174. END SUB
175.  

Here is the complete ZIP file, that contains all the source, fonts, and text files needed to run the program: 

ebacCalculator.zip

[FellippeHeitor]

Great adaptation, George - precisely the kind of app that benefits from InForm, due to the type of input. Thanks for sharing!

[Pete]

Interesting. A program that merits both cheers and booze.

Pete

[George McGinn]

I'll drink to that!  Cheers!

Interesting. A program that merits both cheers and booze.

Pete

[Qwerkey]

Great to have a member writing InForm programs.

Very small point: your form has a typo: "I agree that this programand its results are not legally binding." Space missing after 'program'.

Richard

[George McGinn]

Caught that after I posted.

Great to have a member writing InForm programs.

Very small point: your form has a typo: "I agree that this programand its results are not legally binding." Space missing after 'program'.

Richard