Looking for Way to Fade In (or Out) an Image

[bplus]

This question came up last night with Dav's Pipe Connecting Puzzle:

Is there a way to fade an image in or out without having to resort to a pixel at a time with Point?

That would be so nice to use for ghostly faces and other Halloween tricks.

[SMcNeill]

Cover it with an alpha colored box.

Image is from (100,100)-(200,200)

FOR I = 1 TO 10
   LINE(100,100)-(200,200), _RGBA(0, 0, 0, 100), BF
NEXT

Will fade to black over multiple passes.

[SMcNeill]

Or pre-alpha your image to various levels and save an array of them.  Then you can pick and choose which one you need for the current stage of the effect.

FOR I = 1 TO 10
    CLS, RED
    PUTIMAGE (x, y), faded_image(i)
    SLEEP
NEXT

^fresh red background with you putting 10 different alpha backgrounds over it one at a time.

Which might also be accomplished via SETALPHA.

https://www.qb64.org/wiki/SETALPHA

[Cobalt]

There is a routine in the wiki to do just that.... give me a second...

cant quite remember where it is in the wiki but here is the copy I've been using(how things fade in Dragon Warrior)

Code: QB64: [Select]

1. SUB Fade_Out (L&)
2.  FOR n! = 1 TO 0.00 STEP -0.05
3.   i2& = _COPYIMAGE(L&)
4.   DarkenImage i2&, n!
5.   _PUTIMAGE (0, 0), i2&, Layer(0)
6.   _FREEIMAGE i2&
7.   _DELAY .06
8.  NEXT
9. END SUB
10.  
11. SUB Fade_In (L&)
12.  FOR n! = 0.01 TO 1 STEP 0.05
13.   i2& = _COPYIMAGE(L&)
14.   DarkenImage i2&, n!
15.   _PUTIMAGE (0, 0), i2&, Layer(0)
16.   _FREEIMAGE i2&
17.   _DELAY .06
18.  NEXT
19. END SUB
20.  
21. SUB DarkenImage (Image AS LONG, Value_From_0_To_1 AS SINGLE)
22.  IF Value_From_0_To_1 <= 0 OR Value_From_0_To_1 >= 1 OR _PIXELSIZE(Image) <> 4 THEN EXIT SUB
23.  DIM Buffer AS _MEM: Buffer = _MEMIMAGE(Image) 'Get a memory reference to our image
24.  DIM Frac_Value AS LONG: Frac_Value = Value_From_0_To_1 * 65536 'Used to avoid slow floating point calculations
25.  DIM O AS _OFFSET, O_Last AS _OFFSET
26.  O = Buffer.OFFSET 'We start at this offset
27.  O_Last = Buffer.OFFSET + _WIDTH(Image) * _HEIGHT(Image) * 4 'We stop when we get to this offset
28.  'use on error free code ONLY!
29.  $CHECKING:OFF
30.  DO
31.   _MEMPUT Buffer, O, _MEMGET(Buffer, O, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
32.   _MEMPUT Buffer, O + 1, _MEMGET(Buffer, O + 1, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
33.   _MEMPUT Buffer, O + 2, _MEMGET(Buffer, O + 2, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
34.   O = O + 4
35.  LOOP UNTIL O = O_Last
36.  'turn checking back on when done!
37.  $CHECKING:ON
38.  _MEMFREE Buffer
39. END SUB
40.  

[bplus]

Thanks again Steve, _SetAlpha is probably the tool I had in mind.

I think I meant to say I wanted a transparent image laid over an background and gradually change from transparent to opaque.

Actually I started to consider random filling another image over a background image with Point at a low to middle transparency.

Oh Cobalt has posted, I will read next.

[bplus]

@Colbalt very interesting, thank you.

[Cobalt]

Your Welcome.
I've found it to be useful.
Layer(0) is basically _DISPLAY
Adjusting the _DELAY can make it fade slower or faster was well as the STEP in the FOR.
And of course you don't have to fade all the way in or out, you can have it stop where ever, but I've only ever used it for full in and outs.

[Pete]

Didn't we go over this in my Ghost Town game thread?

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2.  
3. img& = _LOADIMAGE("C:\QB64\YS.png")
4.  
5. DO
6.     FOR i = 0 TO 255
7.         CLS
8.         addAlpha2Img img&, -1 'subtract 1 alpha value from each pixel.
9.         _PUTIMAGE (0, 0)-(600, 600), img&
10.         _LIMIT 40
11.         _DISPLAY
12.     NEXT
13.  
14.     FOR i = 255 TO 0 STEP -1
15.         addAlpha2Img img&, 1 'subtract 1 alpha value from each pixel.
16.         _PUTIMAGE (0, 0)-(600, 600), img&
17.         _LIMIT 40
18.         _DISPLAY
19.         CLS
20.     NEXT
21. LOOP
22.  
23. SUB addAlpha2Img (img&, alpha AS INTEGER)
24.     IF img& >= -1 THEN EXIT SUB
25.     DIM buffer AS _MEM, o AS _OFFSET, o2 AS _OFFSET
26.     DIM b AS _UNSIGNED _BYTE
27.     $CHECKING:OFF
28.     buffer = _MEMIMAGE(img&)
29.     o = buffer.OFFSET
30.     o2 = o + _WIDTH(img&) * _HEIGHT(img&) * 4
31.     DO
32.         b = _MEMGET(buffer, o + 3, _UNSIGNED _BYTE)
33.         IF (b + alpha) > 0 AND (b + alpha) < 255 THEN
34.             _MEMPUT buffer, o + 3, (b + alpha) AS _UNSIGNED _BYTE
35.         END IF
36.         o = o + 4
37.     LOOP UNTIL o = o2
38.     _MEMFREE buffer
39.     $CHECKING:ON
40. END SUB
41.  

To run code, download my Yosemite Sam avatar to the QB64 folder and rename it as YS.png.

Credit to Ashish, who I believe created this effect a few years back. My apologies to whomever did create it, if I got that wrong.

Pete

[bplus]

Yeah that was Ashish but I had something more ghostly:
https://www.qb64.org/forum/index.php?topic=4118.msg134736#msg134736

[bplus]

@Pete That wasn't a Fade In / Out that was only blocking out the background image.

[Pete]

Sam with a pair of phasers, maybe. Sam with a pair of light sabres, never!

Pete

[bplus]

Sam with a pair of phasers, maybe. Sam with a pair of light sabres, never!

Pete

Like say, over your dead body! :)