Plotting / erasing points on a circle

[bplus]

Why is Mars bigger than Earth?

Good question.

Radius was same as planet index in the drawing. I guess that was not considered as important in this problem.

Code: QB64: [Select]

1.     Circle (CX, CY), 6, _RGB32(255, 255, 0)
2.     For i = 1 To 4
3.         Circle (planet(i).x, planet(i).y), i, &HFFFFFFFF
4.         Select Case i
5.             Case 1: c~& = &HFFFF0000
6.             Case 2: c~& = &HFF00FFFF
7.             Case 3: c~& = &HFF0000AA
8.             Case 4: c~& = &HFFAA6600
9.         End Select
10.         Paint (planet(i).x, planet(i).y), c~&, &HFFFFFFFF
11.     Next
12.  

Oh Hey! @Cobalt nice little drawing of Earth! :)

[Petr]

Hi guys. I see that the thread is moving on with its life for the time being ... this fascinated me (the cars), so I tried to add a straight forward and backward movement. Yeah, it works ... but I can't complete the drive to turn right. Does anyone want to deal with this? The center of rotation must change - move in the X axis, the S position must change by 180 degrees ... Because of that, I didn't add anything to my program again today, it happens to me all the time, something interests me here and then time goes crazy...

But really, very good theme, this!

use arrows

Code: QB64: [Select]

1. SCREEN 12
2.  
3. DIM SHARED Xcenter, Ycenter, Radius
4. CONST Pi = 3.1415926
5. Radius = 80
6. Xcenter = 325
7. Ycenter = 225
8.  
9. WHILE _KEYDOWN(27) = 0
10.     CarAngleGAS = RadianAngle + _D2R(270)
11.     CarAngleBRAKE = RadianAngle + _D2R(90)
12.     K& = _KEYHIT
13.     SELECT CASE K&
14.         CASE 18432 'arrow UP is gas
15.             Xcenter = 2 * COS(CarAngleGAS) + Xcenter
16.             Ycenter = 2 * SIN(CarAngleGAS) + Ycenter
17.             X = 2 * COS(CarAngleGAS) + X
18.             Y = 2 * SIN(CarAngleGAS) + Y
19.             GOTO dr
20.  
21.         CASE 20480 'arrow DOWN is brake
22.             Xcenter = 2 * COS(CarAngleBRAKE) + Xcenter
23.             Ycenter = 2 * SIN(CarAngleBRAKE) + Ycenter
24.             X = 2 * COS(CarAngleBRAKE) + X
25.             Y = 2 * SIN(CarAngleBRAKE) + Y
26.             GOTO dr
27.  
28.         CASE 19712
29.             S = S + 1 'to right
30.             GOTO dr
31.  
32.         CASE 19200
33.             S = S - 1 'to left
34.     END SELECT
35.  
36.  
37.  
38.     CLS
39.     'S = S + 1 ' increase 1 degree
40.     'CIRCLE (Xcenter, Ycenter), Radius, 6
41.  
42.     'Print "For Degrees: 0 = east, 90 = south, 180 = west, 270 = north"
43.     'Input "Enter Degree Angle for point  > ", s
44.     RadianAngle = _D2R(S) ' _D2R converts Degrees 2 (to) Radians which is what Sin and Cos process
45.  
46.     X = Radius * COS(RadianAngle) + Xcenter
47.     Y = Radius * SIN(RadianAngle) + Ycenter
48.  
49.     dr:
50.     RadianAngle = _D2R(S)
51.     LINE (X - 5, Y - 5)-STEP(10, 10), 14, BF ' yellow square 10x10 at point x, y
52.     drawRect X, Y, 20, 40, RadianAngle + _PI / 2, 9
53.     drawRect X, Y, 15, 15, RadianAngle + _PI / 2, 15
54.     _DISPLAY ' stop flicker
55.     _LIMIT 60 ' loops per sec
56.     'Locate 28, 40: Print "ZZZ...";
57.     'Sleep
58. WEND '
59.  
60. SUB drawRect (x, y, w, h, raHeading, c AS _UNSIGNED LONG)
61.     ' from x,y draw midY h/2 towards raHeading
62.     X1 = x + h / 2 * COS(raHeading)
63.     Y1 = y + h / 2 * SIN(raHeading)
64.     X2 = X1 + w / 2 * COS(raHeading + _PI / 2)
65.     Y2 = Y1 + w / 2 * SIN(raHeading + _PI / 2)
66.     x3 = X1 + w / 2 * COS(raHeading - _PI / 2)
67.     y3 = Y1 + w / 2 * SIN(raHeading - _PI / 2)
68.  
69.     x4 = x + h / 2 * COS(raHeading - _PI)
70.     y4 = y + h / 2 * SIN(raHeading - _PI)
71.     x5 = x4 + w / 2 * COS(raHeading + _PI / 2)
72.     y5 = y4 + w / 2 * SIN(raHeading + _PI / 2)
73.     x6 = x4 + w / 2 * COS(raHeading - _PI / 2)
74.     y6 = y4 + w / 2 * SIN(raHeading - _PI / 2)
75.  
76.     LINE (X2, Y2)-(x3, y3), c
77.     LINE (x3, y3)-(x6, y6), c
78.     LINE (x6, y6)-(x5, y5), c
79.     LINE (x5, y5)-(X2, Y2), c
80.     PAINT (x, y), c, c
81. END SUB
82.  

[bplus]

So Petr, you want to drive a car? Hope you like Blue and white :)

When you hit the border of screen your speed will be stopped, just turn and hit gas again.

Think of blue.ra as the current heading or direction the car is going 0 = east, 90 = south ...
but just drive the car with left and right arrows as steering wheel. The white edge is the front end.

Code: QB64: [Select]

1. _Title "Drive Car" 'b+ 2021-09-29
2. Screen 12
3. Type car
4.     As Single x, y, w, h, ra, speed
5.     As _Unsigned Long c
6. End Type
7.  
8. Dim blue As car
9. blue.x = _Width / 2: blue.y = _Height / 2
10. blue.w = 20: blue.h = 40
11. blue.ra = _Pi / 2: blue.speed = 2
12. blue.c = 9
13.  
14. While _KeyDown(27) = 0
15.     CarAngle = CarAngle + _D2R(s)
16.     K& = _KeyHit
17.     Select Case K&
18.         Case 18432 'arrow UP is gas
19.             blue.speed = blue.speed + .1
20.             If blue.speed > 5 Then blue.speed = 5
21.         Case 20480 'arrow DOWN slow down
22.             blue.speed = blue.speed - .1
23.             If blue.speed < 0 Then blue.speed = 0
24.         Case 19712
25.             s = s + 2 'to right
26.         Case 19200
27.             s = s - 2 'to left
28.     End Select
29.     Cls
30.     blue.ra = _D2R(s)
31.     blue.x = blue.x + blue.speed * Cos(blue.ra)
32.     blue.y = blue.y + blue.speed * Sin(blue.ra)
33.     If blue.x < 10 Or blue.x > _Width - 10 Then blue.speed = 0
34.     If blue.y < 10 Or blue.y > _Height - 10 Then blue.speed = 0
35.     drawCar blue
36.     _Display ' stop flicker
37.     _Limit 30 ' loops per sec
38. Wend
39.  
40. Sub drawCar (a As car)
41.     ' code not optimized for speed  just proff of concept
42.     X1 = a.x + a.h / 2 * Cos(a.ra)
43.     Y1 = a.y + a.h / 2 * Sin(a.ra)
44.     X2 = X1 + a.w / 2 * Cos(a.ra + _Pi / 2)
45.     Y2 = Y1 + a.w / 2 * Sin(a.ra + _Pi / 2)
46.     X3 = X1 + a.w / 2 * Cos(a.ra - _Pi / 2)
47.     Y3 = Y1 + a.w / 2 * Sin(a.ra - _Pi / 2)
48.  
49.     x4 = a.x + a.h / 2 * Cos(a.ra - _Pi)
50.     y4 = a.y + a.h / 2 * Sin(a.ra - _Pi)
51.     x5 = x4 + a.w / 2 * Cos(a.ra + _Pi / 2)
52.     y5 = y4 + a.w / 2 * Sin(a.ra + _Pi / 2)
53.     x6 = x4 + a.w / 2 * Cos(a.ra - _Pi / 2)
54.     y6 = y4 + a.w / 2 * Sin(a.ra - _Pi / 2)
55.  
56.     Line (X2, Y2)-(X3, Y3), a.c
57.     Line (X3, Y3)-(x6, y6), a.c
58.     Line (x6, y6)-(x5, y5), a.c
59.     Line (x5, y5)-(X2, Y2), a.c
60.     Paint (a.x, a.y), a.c, a.c
61.     Line (X2, Y2)-(X3, Y3), 15 ' give car a front
62.  
63.     ' white top  for all cars for future numbers maybe
64.     X1 = a.x + a.h / 4 * Cos(a.ra)
65.     Y1 = a.y + a.h / 4 * Sin(a.ra)
66.     X2 = X1 + (a.w / 2 - 3) * Cos(a.ra + _Pi / 2)
67.     Y2 = Y1 + (a.w / 2 - 3) * Sin(a.ra + _Pi / 2)
68.     X3 = X1 + (a.w / 2 - 3) * Cos(a.ra - _Pi / 2)
69.     Y3 = Y1 + (a.w / 2 - 3) * Sin(a.ra - _Pi / 2)
70.  
71.     x4 = a.x + a.h / 4 * Cos(a.ra - _Pi)
72.     y4 = a.y + a.h / 4 * Sin(a.ra - _Pi)
73.     x5 = x4 + (a.w / 2 - 3) * Cos(a.ra + _Pi / 2)
74.     y5 = y4 + (a.w / 2 - 3) * Sin(a.ra + _Pi / 2)
75.     x6 = x4 + (a.w / 2 - 3) * Cos(a.ra - _Pi / 2)
76.     y6 = y4 + (a.w / 2 - 3) * Sin(a.ra - _Pi / 2)
77.  
78.     Line (X2, Y2)-(X3, Y3), 15
79.     Line (X3, Y3)-(x6, y6), 15
80.     Line (x6, y6)-(x5, y5), 15
81.     Line (x5, y5)-(X2, Y2), 15
82.     Paint (a.x, a.y), 15, 15
83. End Sub
84.  
85.  
86.  

[Petr]

Thanks a lot, BPlus. I thought that the previous example would like to modify a lot for this purpose. Great work again. Thank you.

[Pete]

Nice.

though why is Mars bigger than Earth?

A better question would be, "Where did Saturn get it's rings? At previous engagements, but I digress. Of course Mark would make Mars bigger than Earth. It's a point of pride. Did you guys forget about his previous Marvin the Martian avatar? I still can't understand why Marvin chose to wear a skirt, especially with those legs, but hey, again it's all about ego. Martian, Martian, Martian.

I liked it better when the planets were all gas powered, you know, the era before they were converted to a Solar System.

Pete

[bplus]

One of the first things I ever did with an image was a cartoon with Marvin. It was called. "Marvin has a ball". Maybe johnno remembers it.

@Pete it's called a Pteruges

Pteruges formed a defensive skirt of leather or multi-layered fabric (linen) strips or lappets worn dependant from the waists of Roman and Greek cuirasses of warriors and soldiers, defending the hips and thighs.

[Pete]

And a purse is just a really BIG wallet, with a strap.

Pete :D

[bplus]

Nah a really big wallet is a bank.

And I am getting ideas for cars navigating tracks, maybe with some banks.

[Statsman1]

I feel like my inquiry really started something.....

[bplus]

I feel like my inquiry really started something.....

Yeah maybe, how are you coming along?

[Statsman1]

Yeah maybe, how are you coming along?

Well, I got away from it for a few days with other stuff to do (bought an Apple III, 6 Apple IIe and a II+), and chores and the like, but got back to it last night and things seem to be coming together.

I have decided, though, to use the framework I have created and instead of auto racing (which would involve collision detection and user inputs, and an AI I am prepared for just yet), I am going to make this a horse racing program.  Wagering model, stable management, etc.

One of my favorite games ever was Sport of Kings by Omni-Play (later Virgin)…

https://www.myabandonware.com/game/sport-of-kings-19p

…so why not?

[bplus]

Yes good to start with clear goal in mind. Then you learn allot as you work your way to it, even if you don't make it right away it remains in back burner cooking, ripening.

Here is handy collision Function for 2 boxes, returns -1 = True they overlap or 0 = False no overlap:

Code: QB64: [Select]

1. 'very handy function to detect if 2 boxes will overlap, given their top left corner and width and height, Thanks Johnno
2. Function collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
3.     ' yes a type smaller than integer might be used
4.     ' x, y represent the box left most x and top most y
5.     ' w, h represent the box width and height which is the usual way sprites / tiles / images are described
6.     ' such that boxbottom = by + bh
7.     '        and boxright = bx + bw
8.     'so the specific gosub above is gerealized to a function procedure here!
9.     If (b1y + b1h < b2y) Or (b1y > b2y + b2h) Or (b1x > b2x + b2w) Or (b1x + b1w < b2x) Then
10.         collision% = 0
11.     Else
12.         collision% = -1
13.     End If
14. End Function
15.  

Assuming these are boxes that align with x and y axis ie what Line command draws with B or BF option and what _PutImage uses.