Possible error in INTEGER64 calculations

[david_uwi]

Sorry I've not got the latest version, so if this has been sorted you can delete this.

DIM z AS _INTEGER64
z = 7 ^ 19
PRINT z

The answer should end in ..373143, but the above gives ...373144

[bplus]

^ power is imprecise:

Code: QB64: [Select]

1. Dim z As _Integer64
2. z = 7 ^ 19
3. Print z
4. z = 1
5. For i = 1 To 19
6.     z = z * 7
7. Next
8. Print z
9.  
10.  

[SMcNeill]

This may be a case of intermediary math issues, where the program is storing theresults as the wrong type as it calculates the answer.

To explain what I’m speaking of, think of how that end result is PROCESSED.

z = 7 ^ 19

Somewhere in our math processors, the computer will take those two numbers (7 and 19) and then process them according to the operator between them…

z is an INTEGER64, as you’ve defined it, but what are 7 and 19??  I’m thinking they’re probably SINGLE values, since that’s what QB64 types are by default.  If so, what do you think the internal registers use to store the result of a SINGLE raised to a SINGLE? 

I’d imagine that intermediate step would store the math result in a SINGLE, and your end result is so large you lose perfect precision.

I’m not at a PC right now (and my ipad can’t compile QB64 programs), but see what the results look like if you specify 7 and 19 as INT64 values:

z = 7&& ^ 19&&

It may end up making a world of difference!

[bplus]

Nope it's ^ it uses formulas LOG or EXP with lots of digits to do ^ calcs, multiplying with * is more precise.
 

[bplus]

Nope it's ^ it uses formulas LOG or EXP with lots of digits to do ^ calcs, multiplying with * is more precise.

The beauty of ^ is that you are not limited to integers.

[david_uwi]

Interesting. I will bear that in mind when using ^.
I note that 7^21 is even further out
..284007 is correct putting in 7^21 the number ends in ends in ..284032 (25 too big).
"casting" (as I believe it is called) 7&&^21&& gives the same value as 7^21.

[random1]

I've ran into similar problems in dealing with very large numbers
but was never able to find a work-around.  Hope someone here
can help with a solution.
R1     

[Pete]

Another argument for String Math! I haven't done powers with it, but it would be as simple as a multiplication loop. I'm not sure if poers has any tricks, like finding square roots. Anyway, anything _INTEGER64 can do String Math can do better.

Pete

[david_uwi]

It certainly could catch out the unaware.
That said it is integer arithmetic - both arguments 7 and 21 are integer so the answer is integer.
As long as there are no overflows it is reasonable to assume that the integer answer should be the correct answer, but it is not.

The compiler should not default to floats when doing integer calculations (but what do I know I've never tried to write a compiler so I have no clue as to the difficulties)

[bplus]

The way I think of ^ is like /, you use it then you have lost pure integer returns from the operator.

^ still very good up to 14 digits.

@david_uwi  you could setup your own Power&& function to be assured integers (or error flag).

[jack]

something like this

Code: QB64: [Select]

1. Function ipower&& (x As _Integer64, e As _Unsigned Integer)
2.     'take x to an integer power
3.     Dim As _Integer64 z, y
4.     Dim As _Unsigned Integer n
5.     y = x
6.     n = e
7.     z = 1&&
8.     While n > 0
9.         While (n Mod 2) = 0
10.             n = n \ 2
11.             y = y * y
12.         Wend
13.         n = n - 1
14.         z = y * z
15.     Wend
16.     ipower = z
17. End Function
18.  

[jack]

you could also substitute WHILE (n MOD 2) = 0 with While (n And 1) = 0 which might be faster

[bplus]

I wonder why the middle stuff?

Code: QB64: [Select]

1. Print ipower&&(7, 21)
2.  
3. Function ipower&& (x As _Integer64, e As _Unsigned Integer)
4.     'take x to an integer power
5.     Dim As _Integer64 z, y
6.     Dim As _Unsigned Integer n
7.     y = x
8.     n = e
9.     z = 1&&
10.     While n > 0
11.         'While (n Mod 2) = 0  ' why have this?
12.         '    n = n \ 2
13.         '    y = y * y
14.         'Wend
15.         n = n - 1
16.         z = y * z
17.     Wend
18.     ipower = z
19. End Function
20.  
21.  
22.  

Seems to work for the one sample I tested. ;-))

Good to make copies of arguments and use a While loop as opposed to For.

[SMcNeill]

*Bplus — half the loops.

3 ^ 12 = 3*3*3*3*3*3*3*3*3*3*3
9 ^ 6 = (3*3)*(3*3)*(3*3)*(3*3)*(3*3)*(3*3)
81 ^ 3 = you get the point.  :P

[bplus]

Oh so if e where a power of 2, then only one outer loop, clever!

Code: QB64: [Select]

1. Print ipower&&(7, 16)
2.  
3. Function ipower&& (x As _Integer64, e As _Unsigned Integer)
4.     'take x to an integer power
5.     Dim As _Integer64 z, y
6.     Dim As _Unsigned Integer n
7.     y = x
8.     n = e
9.     z = 1&&
10.     While n > 0
11.         outer = outer + 1
12.         While (n Mod 2) = 0 ' why have this?
13.             inner = inner + 1
14.             n = n \ 2
15.             y = y * y
16.         Wend
17.         n = n - 1
18.         z = y * z
19.     Wend
20.     ipower = z
21.     Print outer, inner
22. End Function
23.