Why am I getting this result? [question about wrong calculations]

[Cobalt]

For some strange reason, that I can not see, I am getting a result that shouldn't be possible.
my little terrain generator should start the left side at 225 +\- 25. And there fore should not start higher than 200, but if you look at the screen cap below that left side is a heck of a lot higher than 200px. 
Can anyone see what I am missing as to why it would do this? there is not a lot of code, probably more comment than actual code.

Code: QB64: [Select]

1. CONST TRUE = -1, FALSE = NOT TRUE
2. SCREEN _NEWIMAGE(640, 350, 9): CLS: RANDOMIZE TIMER
3.  
4. DO
5.  CLS
6.  DrawTerrain 225
7.  _DELAY .7
8. LOOP UNTIL INKEY$ = CHR$(27)
9.  
10. SUB DrawTerrain (BaseHeight%)
11.  StartY% = BaseHeight% + INT(RND * 50) - 25
12.  CurrentHeight% = StartY% 'keep track of the current Y of the land
13.  PSET (0, StartY%), 2
14.  DO
15.   RunLength% = INT(RND * 50) + 25 'how far does this lay run?
16.   HeightChange% = INT(RND * 100) - 50 'where the elevation go?
17.   CurrentHeight% = CurrentHeight% + HeightChange% 'monitor the change in the land's Y
18.   'if the land goes to low then reverse the height change+25
19.   IF CurrentHeight% > 320 THEN CurrentHeight% = CurrentHeight% - (HeightChange% * 2) - 25: HeightChange% = -(HeightChange% + 25)
20.   'now check that the land does not go to high
21.   IF CurrentHeight% < 50 THEN CurrentHeight% = CurrentHeight% + ABS(HeightChange% * 2) + 25: HeightChange% = ABS(HeightChange% + 25)
22.  
23.   LINE -STEP(RunLength% - 1, HeightChange%), 2 'run this section
24.   totalrun% = totalrun% + RunLength% 'track how far along it is
25.   IF totalrun% > 645 THEN ScreenEnd%% = TRUE 'terrain is now done.
26.  LOOP UNTIL ScreenEnd%%
27.  PAINT (320, 340), 2, 2 'ahh lovely green grass land!
28.  IF POINT(1, 1) = 2 THEN CLS: DrawTerrain (basehieght%) 'whole screen is green so try again(why though?)
29. END SUB
30.  

[bplus]

Typo on line 28

What is leaking that causes the flood of green is the real question.

[Cobalt]

Typo on line 28

What is leaking that causes the flood of green is the real question.

Ahh! another case of staring at the code for too long. Thanks for the second set of eyes.

But yeah, not sure on the flood either, the IF\THEN that makes sure the ground doesn't go too low should prevent the PAINT from happening on the wrong side of the line. and it starts at 0 and goes to atleast 645, which should be off screen. so how the paint floods the screen is mystifying!

[bplus]

Here's one that wont flood:

Code: [Select]

Const TRUE = -1, FALSE = Not TRUE
Screen _NewImage(640, 350, 9): Cls: Randomize Timer

Do
    Cls
    DrawTerrain 225, 10
    Sleep 5
Loop Until InKey$ = Chr$(27)


Sub DrawTerrain (h, modN) ' modN for ruggedness the higher the less smooth
    For x = 0 To _Width
        If x Mod modN = 0 Then ' adjust mod number for ruggedness the higher the number the more jagged
            If h < 350 - modN And h > 50 + modN Then
                dy = Rnd * 20 - 10
            ElseIf h >= 350 - modN Then
                dy = Rnd * -10
            ElseIf h <= 50 + modN Then
                dy = Rnd * 10
            End If
        End If
        h = h + .1 * dy
        Line (x, _Height)-(x, h), 2
    Next
End Sub



[bplus]

Code: QB64: [Select]

1. Screen _NewImage(640, 350, 32)
2. Dim k As _Unsigned Long
3. Color , _RGB32(200, 200, 250)
4. Do
5.     Cls
6.     DrawTerrain 100, 50, &HFF336688
7.     DrawTerrain 150, 25, &HFF448888
8.     DrawTerrain 200, 12, &HFF55AA88
9.     DrawTerrain 250, 6, &HFF66CC88
10.     DrawTerrain 300, 3, &HFF77EE88
11.     Sleep 5
12. Loop Until _KeyDown(27)
13.  
14. Sub DrawTerrain (h, modN, c As _Unsigned Long) ' modN for ruggedness the higher the less smooth
15.     For x = 0 To _Width
16.         If x Mod modN = 0 Then ' adjust mod number for ruggedness the higher the number the more jagged
17.             If h < 350 - modN And h > 50 + modN Then
18.                 dy = Rnd * 20 - 10
19.             ElseIf h >= 350 - modN Then
20.                 dy = Rnd * -10
21.             ElseIf h <= 50 + modN Then
22.                 dy = Rnd * 10
23.             End If
24.         End If
25.         h = h + .1 * dy
26.         Line (x, _Height)-(x, h), c
27.     Next
28. End Sub
29.  
30.  
31.  
32.  

[FellippeHeitor]

Option _Explicit. Time saver.

[SpriggsySpriggs]

Option _Explicit is your friend

[bplus]

Back to why the paint was flooding, it was because the line wasn't always getting drawn all the way to the edge of the screen:

You can see it here

Code: QB64: [Select]

1. Const TRUE = -1, FALSE = Not TRUE
2. Screen _NewImage(640, 350, 9): Cls: Randomize Timer
3. 'check something
4. 'Print _Width, _Height
5. 'End
6.  
7. Do
8.     Cls
9.     DrawTerrain 225
10.     Sleep 5
11. Loop Until InKey$ = Chr$(27)
12.  
13. Sub DrawTerrain (BaseHeight%)
14.     StartY% = BaseHeight% + Int(Rnd * 50) - 25
15.     CurrentHeight% = StartY% 'keep track of the current Y of the land
16.     PSet (0, StartY%), 2
17.     Do
18.         RunLength% = Int(Rnd * 50) + 25 'how far does this lay run?
19.         HeightChange% = Int(Rnd * 100) - 50 'where the elevation go?
20.         CurrentHeight% = CurrentHeight% + HeightChange% 'monitor the change in the land's Y
21.         'if the land goes to low then reverse the height change+25
22.         If CurrentHeight% > 320 Then CurrentHeight% = CurrentHeight% - (HeightChange% * 2) - 25: HeightChange% = -(HeightChange% + 25)
23.         'now check that the land does not go to high
24.         If CurrentHeight% < 50 Then CurrentHeight% = CurrentHeight% + Abs(HeightChange% * 2) + 25: HeightChange% = Abs(HeightChange% + 25)
25.  
26.         Line -Step(RunLength% - 1, HeightChange%), 2 'run this section
27.         totalrun% = totalrun% + RunLength% 'track how far along it is
28.         If totalrun% > 645 Then ScreenEnd%% = TRUE 'terrain is now done.
29.     Loop Until ScreenEnd%%
30.  
31.     'box in the paint area, nope that wasn't it
32.     Line (0, StartY%)-(0, _Height), 2
33.     Line (0, _Height)-(_Width, _Height), 2
34.     Line (_Width, 0)-(_Width, _Height), 2
35.  
36.  
37.     Sleep 5 'but look before you paint
38.  
39.     Paint (320, 340), 2, 2 'ahh lovely green grass land!
40.     'screw this
41.     '''''''''If Point(1, 1) = 2 Then Cls: DrawTerrain (basehieght%) 'whole screen is green so try again(why though?)
42. End Sub
43.  
44.  
45.  

[bplus]

It was coming up short because of line:

Code: QB64: [Select]

1.         LINE -STEP(RunLength% - 1, HeightChange%), 2 'run this section

the -1 was making it too short.

Code: QB64: [Select]

1. Const TRUE = -1, FALSE = Not TRUE
2. Screen _NewImage(640, 350, 9): Cls: Randomize Timer
3. 'check something
4. 'Print _Width, _Height
5. 'End
6.  
7. Do
8.     Cls
9.     DrawTerrain 225
10.     _Limit 2
11. Loop Until InKey$ = Chr$(27)
12.  
13. Sub DrawTerrain (BaseHeight%)
14.     StartY% = BaseHeight% + Int(Rnd * 50) - 25
15.     CurrentHeight% = StartY% 'keep track of the current Y of the land
16.     PSet (0, StartY%), 2
17.     Do
18.         RunLength% = Int(Rnd * 50) + 25 'how far does this lay run?
19.         HeightChange% = Int(Rnd * 100) - 50 'where the elevation go?
20.         CurrentHeight% = CurrentHeight% + HeightChange% 'monitor the change in the land's Y
21.         'if the land goes to low then reverse the height change+25
22.         If CurrentHeight% > 320 Then CurrentHeight% = CurrentHeight% - (HeightChange% * 2) - 25: HeightChange% = -(HeightChange% + 25)
23.         'now check that the land does not go to high
24.         If CurrentHeight% < 50 Then CurrentHeight% = CurrentHeight% + Abs(HeightChange% * 2) + 25: HeightChange% = Abs(HeightChange% + 25)
25.  
26.         Line -Step(RunLength%, HeightChange%), 2 '>>>>>>>>>>>>>>>>>>>>>> this line fixed!!!!!!!!111
27.         totalrun% = totalrun% + RunLength% 'track how far along it is
28.         If totalrun% > 645 Then ScreenEnd%% = TRUE 'terrain is now done.
29.     Loop Until ScreenEnd%%
30.  
31.     'box in the paint area
32.     'Line (0, StartY%)-(0, _Height), 2
33.     'Line (0, _Height)-(_Width, _Height), 2
34.     'Line (_Width, 0)-(_Width, _Height), 2
35.     'Sleep 5
36.     Paint (320, 340), 2, 2 'ahh lovely green grass land!
37.     'screw this
38.     '''''''''If Point(1, 1) = 2 Then Cls: DrawTerrain (basehieght%) 'whole screen is green so try again(why though?)
39. End Sub
40.  
41.  
42.  

[TempodiBasic]

Option explicit and Option explictiArray are 2 dear friends that help to avoid to crash own head on some kind of troubles...
So if you don't use an external IDE (Notepad++ with RhoSigma package, Dav Ide)
spent that few seconds to type Option explicitArray (if you use array) and Option Explicit as the first 2 lines of code.


Yes I can agree that you can have the sensation to code in Pascal but don't mind, you'll gain in amount of time dedicated to the family or whateveryouwant.

PS Bplus has nailed the origin of the problem a Typo error.

[bplus]

@TempodiBasic

You might have missed the point. The typo on the line added was to try and fix the flooding problem caused by PAINT. That line would not have been needed if the PAINT floodings were fixed.

So why was the PAINT flooding? because Cobalt was subtracting 1 in his line commands meanwhile his accumulator for total distance across was getting 1 ahead each time he drew a line, so when he used more than 6 lines to go from one end to the other the PAINT leaked through right side because of gap at the edge.

[TempodiBasic]

@bplus
Yeah, I have verified to understand.
So the

Code: QB64: [Select]

1.  Line -Step(RunLength%-1, HeightChange%), 2

was the origin of the error
and its solution is

Code: QB64: [Select]

1.  Line -Step(RunLength%, HeightChange%), 2

while di typo error was in the fixing code Basehiegth% in the place of BaseHeight%.
Thanks to point this.

[Cobalt]

It was coming up short because of line:

Code: QB64: [Select]

1.         LINE -STEP(RunLength% - 1, HeightChange%), 2 'run this section

the -1 was making it too short.

Wonder why it didn't fail every time?
Not that I remember why it was -1..... doesn't need to be... hmmmmm? Left overs perhaps?

Option _Explicit is your friend

Option _Explicit. Time saver.

I'll Flirt with Disaster...
I'll Court the Maidens of Doom...
But I will never sleep with the Devil. XD



"All my kingdom for some smilies!"

[bplus]

Wonder why it didn't fail every time?

Hi Colbalt,

Remember you added 5 to width so if the number of lines drawn was 6 or less you were covered (645-6 = 639)  but if number of lines exceeded 6 then you'd end up short of the edge.

[bplus]

BTW I picked up on the typo because BaseHeight% was not capitalized here:

Code: QB64: [Select]

1. If Point(1, 1) = 2 Then Cls: DrawTerrain (basehieght%)
2.  

It sure wasn't from spell checking :)