Author Topic: Simple example of LAN game with 2-4 PCs? (Read 3838 times)

madscijr · « **on:** July 02, 2021, 04:21:03 pm »

Hi all,
I'm interested in writing a simple local network game for 2-4 PCs.
I have no idea how to approach it, and am not too knowledgable about networking, so would like to keep it as simple as possible while still following whatever the standard practices are. It should not require the users to know much about networking or mess with the networking/firewall settings on their computer (if possible?)
Can anyone either post some code or maybe a link to a simple & minimal example of a game for 2-4 computers (preferably connected together via a wired hub)?
Any info would be much appreciated...

PS If it makes any difference, this would be for lower bandwidth games, stuff like Battleship, Spacewar, Pong, Roguelikes - not any kind of super fast MMO 3D game sending/receiving a ton of data.

SpriggsySpriggs · « **Reply #1 on:** July 02, 2021, 04:23:29 pm »

@FellippeHeitor Sounds like a job for Amongst

FellippeHeitor · « **Reply #2 on:** July 02, 2021, 06:32:29 pm »

Hehe 🤩

https://github.com/FellippeHeitor/amongst <-- run the server once, up to 10 clients can connect

madscijr · « **Reply #3 on:** July 02, 2021, 08:30:26 pm »

Quote from: FellippeHeitor on July 02, 2021, 06:32:29 pm

Hehe 🤩

https://github.com/FellippeHeitor/amongst <-- run the server once, up to 10 clients can connect

That looks really neat, I will give it a look. Thanks!

Cobalt · « **Reply #4 on:** July 03, 2021, 11:22:14 am »

Can always check out my BattleShip game, it has LAN options.
https://www.qb64.org/forum/index.php?topic=826.msg100326

madscijr · « **Reply #5 on:** July 12, 2021, 09:05:20 am »

Quote from: Cobalt on July 03, 2021, 11:22:14 am

Can always check out my BattleShip game, it has LAN options.
https://www.qb64.org/forum/index.php?topic=826.msg100326

Thanks I will do that. The week turned out to be a little busy but I will get back to this in the next couple of days and post an update. Thanks again everybody.

madscijr · « **Reply #6 on:** July 12, 2021, 10:32:49 am »

Quote from: Cobalt on July 03, 2021, 11:22:14 am

Can always check out my BattleShip game, it has LAN options.
https://www.qb64.org/forum/index.php?topic=826.msg100326

Question, what format file is "battleship.gfx", and how would you edit it?
Thanks...

madscijr · « **Reply #7 on:** July 13, 2021, 01:13:35 pm »

Quote from: Cobalt on July 03, 2021, 11:22:14 am

Can always check out my BattleShip game, it has LAN options.
https://www.qb64.org/forum/index.php?topic=826.msg100326

I was looking at your code, and got the genius idea (I hope you are picking up on the sarcasm here)
to rename the variables a little less ambiguously to help me follow what the code is doing,
and I seem to have introduced a little bug where when you place a ship on the board, it disappears.
If you have any bandwidth, and could quickly zero in on the line that might be making that happen,
that would be very much appreciated... No pressure or anything, LoL

Code: QB64: [Select]

' ################################################################################################################################################################
' Battle Ship 64 by Cobalt
' ################################################################################################################################################################
 
' =============================================================================
' CHANGE LOG
 
' WHEN         WHO            WHAT
' 11/23/2018   Cobalt David   Started (30 mins)
' 11/23/2018   Cobalt David   V0.0a inital build (45 mins)
'                             inital types and diminsions in place
' 11/24/2018   Cobalt David   V0.0b build (30 mins)
'                             added Title screen
'                             loaded sprite sheet
' 11/27/2018   Cobalt David   V0.1a First Run Build (300 mins)
'                             Added\Finished ship deployment
'                             added auto deployment for computer opponent
'                             added yellow selection color for ship placement and shot selection
'                             started shot taking routine
'                             added Who goes first test
'                             (made audio files for posible add-in later)
'                             (ripped video files for posible add-in later)
' 11/28/2018   Cobalt David   V0.1b Build (240 mins)
'                             Added Hit and Miss images
'                             added player shot routines
'                             added ship sunk routines
'                             added Gameover state
'                             added Computer shooting routine
' 11/29/2018   Cobalt David   V0.1C Build (150 mins)
'                             fixed Computer Shooting routine, computer can now hit players ships.
'                             fixed message timing, so its a hit shows before ship sunk message
'                             set randomize to TIMER
'                             game level Easy, Computer AI: STUPID(always random shots)
'                             added graphics loading rountine
'                             public release
' 11/29/2018   Cobalt David   V0.1D Build (10 mins)
'                             fixed oversight found by Bplus were autoplace doesn't clear board first
'                             adding extra 'ghost' ships to the layout.
'                             Added Title bar info.
' 11/30/2018   Cobalt David   V0.2A Build (540 mins)
'                             Added Menu and options
'                             Added ChangeColor routine
'                             added fonts
'                             added instruction page 1
'                             fixed bug if player pressed Reset with ship selected ship stayed selected as a phantom ship.
'                             Updated GFX file
'                             Began networking routines
'                             first successful log in of clients
' 12/01/2018   Cobalt David   V0.5A Build (300 mins)
'                             Ripped Functions\Subs for network retooling.
'                             Added Networking types\variables\arrays\consts
'                             added\fixed host startup and client startup
'                             added communication decodeing
'                             added Opponent shot for multiplayer games
' 12/02/2018   Cobalt David   V0.7A build (210 mins)
'                             fixed networking protocol
'                             fixed minor bugs related to network game communication
'                             added IP address entry to join network screen
'                             reconsistuted routines into main BAS file
'                             First successful LAN game at 19:55 EST
' 07/12/2021   madscijr       Prettified code a little, renamed variables with Hungarian notation
'                             to easily identify which ones are shared, constants, arrays, UDTs, etc.
'                             Broke something so now when you place a ship, it disappears! DOH!
 
' =============================================================================
' NOTES:
' fonts:Vecteezy.com/free-fonts.com/Geronimo Font Studios[dafont.com]
 
' QB64 variable types:
' a$  = string
' i%  = integer
' L&  = long
' s!  = single
' d#  = double
' b%% = byte
 
' -----------------------------------------------------------------------------
' A Short Course in Hungarian Notation
' http://www.imm.dtu.dk/~alan/hungarian.html
 
' In general, Hungarian notation names a variable with a lower-case prefix
' to identify the class or usage of the variable. There is no such thing as
' standard HN, so the point here is to create a consistent notation system.
' In this class, we'll use the following standards.
'       c: signed character <- *** NOT USED IN THIS PROGRAM c SPECIFIES CONSTANTS ***
'      uc: unsigned character
'       i: integer
'      ui: unsigned integer
'      si: short integer
'      li: long integer
'       n: an integer number where the actual size is irrelevant
'       f: float
'       d: double
'       s: string of characters
'      sz: string of characters, terminated by a null character
'       b: an integer or character being used as a boolean value
'      by: single byte
'      ct: an integer being used as a counter or tally
'       p: pointer to a structure or general void pointer
'     pfs: file stream pointer
'     pfn: pointer to a function
'      px: pointer to a variable of class x, e.g. pi, pf, pli
'
' Other prefixes:
'       c: constant
'       m: shared (module-level) variable
'      st: static variable
'     arr: array
 
' Suffixes:
'     {name}_Type: user-defined types (UDTs) end with "_Type"
 
' =============================================================================
' USER-DEFINED TYPES (UDTs)
 
Type Pos_Hits_Type
    Xpos As _Byte
    Ypos As _Byte
    Orent As _Byte
    Hits As _Byte
    sunk As _Byte
    placed As _Byte
End Type ' Pos_Hits_Type
 
Type Ships_Type
    Carrier As Pos_Hits_Type
    Battle As Pos_Hits_Type
    Destroyer As Pos_Hits_Type
    Submarine As Pos_Hits_Type
    Patrol As Pos_Hits_Type
End Type ' Ships_Type
 
Type Ship_Board_Offsets_Type
    Board_VX As _Byte
    Board_VY As _Byte
    Board_HX As _Byte
    Board_HY As _Byte
    RedBoard_VX As Integer
    RedBoard_VY As Integer
    RedBoard_HX As Integer
    RedBoard_HY As Integer
    ShipYard_X As Integer
    ShipYard_Y As Integer
End Type ' Ship_Board_Offsets_Type
 
Type Networking_Type
    Host As Long ' host ID
    Client As Long ' Client ID
    Users As _Byte ' Clients Connected, 2 max
    Ready As _Byte ' Opponent has placed ships
    X As _Byte ' Opponents shot X location
    Y As _Byte ' Opponents shot Y location
End Type ' Networking_Type
 
Type Client_Type
    PingTime As Long
    Id As Long
End Type ' Client_Type
 
Type Game_Data_Type
    PlayerDead As _Byte
    OpponentDead As _Byte
    GameOver As _Byte
    WhoIsUp As _Byte
    NetWork As Networking_Type
    Mode As _Byte
    Debug As _Byte
End Type ' Game_Data_Type
 
' =============================================================================
' GLOBAL DECLARATIONS
 
Dim Shared m_arrBoard(10, 10, 2) As _Byte ' 1-player layout\OPPONENT shots 2-player shots
Dim Shared m_arrFleet(2) As Ships_Type ' *** IS THIS USED?
Dim Shared m_arrOffs(5) As Ship_Board_Offsets_Type
Dim Shared m_GameData As Game_Data_Type
Dim Shared m_arrShip(10) As Pos_Hits_Type ' 1-5 player 6-10 OPPONENT
Dim Shared m_arrShipName$(5) ' names of ship types
Dim Shared m_arrLayer(10) As _Unsigned Long
Dim Shared m_byStarts As _Byte ' *** IS THIS USED?
Dim Shared m_arrFFX(12) As _Unsigned Long
Dim Shared m_arrUser(2) As Client_Type
Dim Shared m_Message$
Dim Shared m_Listen&
Dim Shared m_Cancel%%
 
Const c_CARRIER = 1, c_BATTLESHIP = 2, c_DESTROYER = 3, c_SUBMARINE = 4, c_PTBOAT = 5
Const TRUE = -1, FALSE = Not TRUE
Const c_HORZ = 11, c_VERT = 12
Const c_MIX = 1, c_TITLE = 2, c_SHEET = 3, c_SHIPS = 4, c_SHOTS = 5, c_BOARD = 6, c_PEGS = 7, c_MENU = 8, c_LAN = 9
Const c_PLAYER = 1, c_OPPONENT = 2, c_LANCLIENT = 3
Const c_BlueBoard~& = _RGBA32(7, 15, 212, 48)
Const c_RedBoard~& = _RGBA32(212, 15, 7, 48)
Const c_YellowSelect~& = _RGBA32(212, 192, 7, 80)
Const c_HIT = -1, c_MISS = -2, c_BAD = 4
 
' ship yard horzontal offsets
ShipYardOffsetsData:
Data 68,316,68,343,68,367,68,393,66,416
 
ShipBoardOffsetsData:
Data 57,55,58,57,55,58,56,60,55,58
Data 54,58,56,57,57,55,59,57,58,55
 
ShipBoardOffsetsRedData:
Data 347,55,347,57,343,58,345,60,343,58
Data 343,58,344,57,345,55,347,57,346,55
 
ShipNamesData:
Data "Carrier","Battle Ship","Destroyer","Submarine","PT Boat"
 
m_Listen& = _FreeTimer
On Timer(m_Listen&, .1) MessageCheck ' timer for Host status.
 
Screen _NewImage(640, 480, 32)
INIT ' load screens, load data, set randomizer
 
' Title Screen
_PutImage , m_arrLayer(c_TITLE), LayerD&
_Delay 5.5
 
' *****************************************************************************
m_GameData.Debug = FALSE
' *****************************************************************************
 
SetUpGameBoard
MainMenu
End
 
' /////////////////////////////////////////////////////////////////////////////
' Game Menu
 
Sub MainMenu
    _Font m_arrFFX(2), m_arrLayer(c_MIX)
    ExitFlag%% = FALSE
 
    Do
        _PutImage , m_arrLayer(c_MENU), m_arrLayer(c_MIX)
        If m_GameData.Mode = c_LAN Then
            ChangeColor _RGB32(248, 48, 64), m_arrLayer(c_MIX)
            _PrintString (0, 450), "CONNECTED", m_arrLayer(c_MIX)
        End If
        ChangeColor _RGB32(48, 48, 64), m_arrLayer(c_MIX) ' BASE COLOR
        _PrintString (280, 150), "PLAY GAME", m_arrLayer(c_MIX)
        If m_GameData.Mode <> c_LAN Then
            _PrintString (280, 180), "START NETWORK GAME", m_arrLayer(c_MIX)
        Else
            _PrintString (280, 180), "STOP NETWORK GAME", m_arrLayer(c_MIX)
        End If
        _PrintString (280, 210), "JOIN NETWORK GAME", m_arrLayer(c_MIX)
        _PrintString (280, 240), "INSTRUCTION!", m_arrLayer(c_MIX)
        _PrintString (280, 270), "QUIT GAME", m_arrLayer(c_MIX)
 
        If over%% Then ' hi-lite option mouse is over
            ChangeColor _RGB32(248, 248, 48), m_arrLayer(c_MIX) ' Hover color
            Select Case over%%
                Case 1
                    _PrintString (280, 150), "PLAY GAME", m_arrLayer(c_MIX)
                Case 2
                    If m_GameData.Mode <> c_LAN Then
                        _PrintString (280, 180), "START NETWORK GAME", m_arrLayer(c_MIX)
                    Else
                        _PrintString (280, 180), "STOP NETWORK GAME", m_arrLayer(c_MIX)
                    End If
                Case 3
                    _PrintString (280, 210), "JOIN NETWORK GAME", m_arrLayer(c_MIX)
                Case 4
                    _PrintString (280, 240), "INSTRUCTION!", m_arrLayer(c_MIX)
                Case 5
                    _PrintString (280, 270), "QUIT GAME", m_arrLayer(c_MIX)
            End Select
        End If
 
        If _MouseButton(1) Then ' player clicked on option
            Select Case over%%
                Case 1 ' play the game
                    DeployFleet
                    AutoPlaceShips c_OPPONENT
                    ClearArea
                    GamePlay
                    _Font m_arrFFX(2), m_arrLayer(c_MIX)
                Case 2 ' start host for network game
                    If m_GameData.Mode = c_LAN Then
                        ' close down host and host's client reset game to normal mode
                        ' turn off network listening timer
                        Close #6
                        Timer(m_Listen&) Off
                        Close #m_GameData.NetWork.Client
                        Close #m_GameData.NetWork.Host
                        m_GameData.Mode = FALSE
                    Else
                        'IF m_GameData.Debug THEN OPEN "Debughost.txt" FOR OUTPUT AS #6
                        CreateNetworkGame
                    End If
                    UpDate%% = TRUE
                Case 3 ' find network game on server list and join
                    'IF m_GameData.Debug THEN OPEN "debugclient.txt" FOR OUTPUT AS #6
                    JoinNetworkGame
                    If Not m_Cancel%% Then
                        ' -----------------------------------------------------------------------------
                        ' game is now in network mode
 
                        ' start game directly
                        DeployFleet
                        ClearArea
                        GamePlay
                    Else
                        m_Cancel%% = FALSE ' player hit ESC
                    End If
                    Timer(m_Listen&) Off
                    Close #m_GameData.NetWork.Client
                    _Font m_arrFFX(2), m_arrLayer(c_MIX)
                Case 4 ' instructions! heck its point and click ppl!
                    Instruction
                Case 5 ' quit game
                    ExitFlag%% = TRUE
            End Select
            ' trap mouse button down
            Do: null = _MouseInput: _Delay .025: Loop While _MouseButton(1)
        End If
 
        _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
 
        Do
            _Delay .025
            If InKey$ = Chr$(27) Then ExitFlag%% = TRUE
        Loop Until _MouseInput Or ExitFlag%% Or UpDate%%
 
        UpDate%% = FALSE
        x% = _MouseX: y% = _MouseY
        If x% > 280 And x% < 630 Then ' if mouse is in correct X region
            If y% > 150 And y% < 300 Then ' if mouse is in correct Y region
                over%% = (y% - 150) \ 30 + 1
            End If
        Else ' off menu region
            over%% = 0
        End If
        Do: Loop While _MouseInput
    Loop Until ExitFlag%%
 
    ExitFlag%% = FALSE ' reset flag
    ChangeColor &HFFFFFFFF, m_arrLayer(c_MIX)
    _Font 16
    ' ----------------------------------
End Sub ' MainMenu
 
' /////////////////////////////////////////////////////////////////////////////
 
Function StartHost (port%)
    If port% = 0 Then default% = 1979 Else default% = port%
    ID$ = "TCP/IP:" + LTrim$(Str$(default%))
    HostID& = _OpenHost(ID$) ' begin new host
    Result = HostID&
    StartHost = Result
End Function ' StartHost
 
' /////////////////////////////////////////////////////////////////////////////
' catch user connection
 
Sub MessageCheck
    ' -----------------------------------------------------------------------------
    ' only if HOST
    If m_GameData.Mode = c_LAN Then
        newclient = _OpenConnection(m_GameData.NetWork.Host) ' receive any new connection
        If newclient Then
            m_GameData.NetWork.Users = m_GameData.NetWork.Users + 1
            m_arrUser(m_GameData.NetWork.Users).Id = newclient
            If m_GameData.Debug Then Print #6, "add:" + Str$(newclient)
        End If
    End If
 
    ' -----------------------------------------------------------------------------
    ' Listen for communication from Players-
    If m_GameData.Mode = c_LAN Then ' host game only listens for player 2
        If m_GameData.NetWork.Users = 2 Then ' only listen once hosts has both users
            Get #m_arrUser(2).Id, , m_Message$
            If m_GameData.Debug And m_Message$ <> "" Then Print #6, "REC:" + Str$(m_arrUser(I%%).Id) + ":" + m_Message$
        End If
    Else ' while player two just listens
        Get #m_GameData.NetWork.Client, , m_Message$
        If m_GameData.Debug And m_Message$ <> "" Then Print #6, "REC:" + Str$(m_arrUser(I%%).Id) + ":" + m_Message$
    End If
 
    ' -----------------------------------------------------------------------------
    If m_Message$ <> "" Then ProcessMessage
End Sub ' MessageCheck
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub ProcessMessage
    Select Case Left$(m_Message$, 5)
        Case "[SHP]" ' ship xy and orentation data
            txt$ = Mid$(m_Message$, 6, 30)
            For i%% = 6 To 10
                x%% = Val(Mid$(txt$, 1, 2))
                y%% = Val(Mid$(txt$, 3, 2))
                o%% = Val(Mid$(txt$, 5, 2))
                txt$ = Mid$(txt$, 7)
                m_arrShip(i%%).Xpos = x%%
                m_arrShip(i%%).Ypos = y%%
                m_arrShip(i%%).Orent = o%%
                PlaceShipOnBoard i%%
            Next i%%
            m_GameData.NetWork.Ready = TRUE
        Case "[SHT]" ' players Shot xy data
            txt$ = Mid$(m_Message$, 6, 4)
            x%% = Val(Mid$(txt$, 1, 2))
            y%% = Val(Mid$(txt$, 3, 2))
            m_GameData.NetWork.X = x%%
            m_GameData.NetWork.Y = y%%
        Case "[FST]" ' who goes first number chance
            ' go ahead and use x value for this.
            m_GameData.NetWork.X = Val(Mid$(m_Message$, 6, 2))
        Case "[PKN]" ' who goes first number
            m_GameData.NetWork.Y = Val(Mid$(m_Message$, 6, 2))
    End Select
End Sub ' ProcessMessage
 
' /////////////////////////////////////////////////////////////////////////////
 
Function ConnectClient (port%, IPA$)
    If port% = 0 Then default% = 1979 Else default% = port%
    If IPA$ = "0" Then IP$ = ":localhost" Else IP$ = ":" + IPA$
    ID$ = "TCP/IP:" + LTrim$(Str$(default%)) + IP$
    connection& = _OpenClient(ID$) ' Attempt to connect to local host as a client
    Result = connection&
    If m_GameData.Debug Then Print #6, ID$ + " " + Str$(Result)
    ConnectClient = Result
End Function ' ConnectClient
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub SendMessage
    If m_GameData.Debug Then Print #6, "SND:" + Str$(m_arrUser(2).Id) + ":" + Str$(m_GameData.Mode)
    If m_GameData.Mode = c_LAN Then
        If m_GameData.Debug Then Print #6, "SND:" + Str$(m_arrUser(2).Id) + ":" + m_Message$
        Put #m_arrUser(2).Id, , m_Message$
    Else
        If m_GameData.Debug Then Print #6, "SND:" + Str$(m_GameData.NetWork.Client) + ":" + m_Message$
        Put #m_GameData.NetWork.Client, , m_Message$
    End If
    m_Message$ = ""
End Sub ' SendMessage
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub AutoPlaceShips (Who%%)
    If Who%% = c_PLAYER Then A%% = 0 Else A%% = 5
    For i%% = 1 + A%% To 5 + A%% ' take each ship starting with Carrier
        limit! = Timer
        Do: Good%% = FALSE
            x%% = Int(Rnd * 10) + 1 ' pick a spot and orentation
            y%% = Int(Rnd * 10) + 1
            If Int(Rnd * 100) + 1 > 50 Then o%% = c_HORZ Else o%% = c_VERT
            If CheckShipPos(x%%, y%%, o%%, i%%) Then Good%% = TRUE ' check that it fits and doesn't overlap
            If Timer > limit! + .5 Then Print "AUTO PLACE ERROR, TIME EXCEEDED!": End
        Loop Until Good%%
        m_arrShip(i%%).Xpos = x%%
        m_arrShip(i%%).Ypos = y%%
        m_arrShip(i%%).Orent = o%%
        PlaceShipOnBoard (i%%)
    Next i%%
End Sub ' AutoPlaceShips
 
' /////////////////////////////////////////////////////////////////////////////
' change text color(value~&) on specified m_arrLayer(id~&)
 
Sub ChangeColor (value~&, id~&)
    old~& = _Dest
    _Dest id~&
    Color value~&
    _Dest old~&
End Sub ' ChangeColor
 
' /////////////////////////////////////////////////////////////////////////////
 
Function CheckShipPos (xt%%, yt%%, ot%%, tt%%)
    ' copy values to local variables
    ' lets not change a variable by accident
    x%% = xt%%
    y%% = yt%%
    o%% = ot%%
    t%% = tt%%
 
    If t%% > 5 Then w%% = 2: t%% = t%% - 5 Else w%% = 1 ' >5 OPPONENT ships
    result%% = TRUE
 
    Select Case t%% ' first check to see if ship will fit on board
        Case c_CARRIER
            If o%% = c_HORZ And x%% > 6 Then result%% = FALSE
            If o%% = c_VERT And y%% > 6 Then result%% = FALSE
        Case c_BATTLESHIP
            If o%% = c_HORZ And x%% > 7 Then result%% = FALSE
            If o%% = c_VERT And y%% > 7 Then result%% = FALSE
        Case c_DESTROYER, c_SUBMARINE
            If o%% = c_HORZ And x%% > 8 Then result%% = FALSE
            If o%% = c_VERT And y%% > 8 Then result%% = FALSE
        Case c_PTBOAT
            If o%% = c_HORZ And x%% > 9 Then result%% = FALSE
            If o%% = c_VERT And y%% > 9 Then result%% = FALSE
    End Select
 
    If result%% Then ' if fit test passed make sure no ships in way
        Select Case t%%
            Case c_CARRIER
                If o%% = c_HORZ Then
                    For i%% = 0 To 4
                        If m_arrBoard(x%% + i%%, y%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
                If o%% = c_VERT Then
                    For i%% = 0 To 4
                        If m_arrBoard(x%%, y%% + i%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
            Case c_BATTLESHIP
                If o%% = c_HORZ Then
                    For i%% = 0 To 3
                        If m_arrBoard(x%% + i%%, y%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
                If o%% = c_VERT Then
                    For i%% = 0 To 3
                        If m_arrBoard(x%%, y%% + i%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
            Case c_DESTROYER, c_SUBMARINE
                If o%% = c_HORZ Then
                    For i%% = 0 To 2
                        If m_arrBoard(x%% + i%%, y%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
                If o%% = c_VERT Then
                    For i%% = 0 To 2
                        If m_arrBoard(x%%, y%% + i%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
            Case c_PTBOAT
                If o%% = c_HORZ Then
                    For i%% = 0 To 1
                        If m_arrBoard(x%% + i%%, y%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
                If o%% = c_VERT Then
                    For i%% = 0 To 1
                        If m_arrBoard(x%%, y%% + i%%, w%%) Then result%% = FALSE: i%% = 5
                    Next i%%
                End If
        End Select
    End If
    CheckShipPos = result%%
End Function ' CheckShipPos
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub CheckShips
    Static st_arrKnown(10) As _Byte
 
    ' check for sunk ship on player
    m_GameData.PlayerDead = TRUE
    For i%% = 1 To 5
        If m_arrShip(i%%).sunk And (Not st_arrKnown(i%%)) Then
            MessageHandler "Opponent Sunk players " + m_arrShipName$(i%%) + " !"
            _Delay .75
            st_arrKnown(i%%) = TRUE
        End If
        If m_arrShip(i%%).sunk = FALSE Then m_GameData.PlayerDead = FALSE
    Next i%%
 
    ' check for sunk ship on opponent
    m_GameData.OpponentDead = TRUE
    For i%% = 6 To 10
        If m_arrShip(i%%).sunk And (Not st_arrKnown(i%%)) Then
            MessageHandler "Player Sunk Opponents " + m_arrShipName$(i%% - 5) + " !"
            _Delay .75
            st_arrKnown(i%%) = TRUE
        End If
        If m_arrShip(i%%).sunk = FALSE Then m_GameData.OpponentDead = FALSE
    Next i%%
 
    If m_GameData.PlayerDead Or m_GameData.OpponentDead Then m_GameData.GameOver = TRUE
End Sub ' CheckShips
 
' /////////////////////////////////////////////////////////////////////////////
' Clear deploy information area
 
Sub ClearArea
    _Dest m_arrLayer(c_BOARD)
    Line (0, 300)-(639, 479), _RGB32(0, 0, 0), BF
    _Dest m_arrLayer(0)
    _Dest m_arrLayer(c_SHIPS)
    Line (0, 300)-(639, 479), _RGB32(0, 0, 0), BF
    _Dest m_arrLayer(0)
    _PutImage , m_arrLayer(c_BOARD), m_arrLayer(c_MIX)
    _PutImage , m_arrLayer(c_SHIPS), m_arrLayer(c_MIX)
    _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
End Sub ' ClearArea
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub ClearLayer (id%%)
    old& = _Dest
    _Dest m_arrLayer(id%%)
    Cls
    _Dest old&
End Sub ' ClearLayer
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub ComputerShot
    Do: Good%% = FALSE ' run until an unfired upon area is found
        x%% = Int(Rnd * 10) + 1
        y%% = Int(Rnd * 10) + 1
        If m_arrBoard(x%%, y%%, 1) >= 0 Then Good%% = TRUE
    Loop Until Good%%
 
    MessageHandler "Computer fires at " + Chr$(64 + y%%) + Str$(x%%)
    _Delay .5
 
    Select Case SendShot(x%%, y%%, c_OPPONENT)
        Case c_HIT ' Computer hits players ship
            MessageHandler "Computer Hits!"
            CheckShips
        Case c_MISS ' Computer missed players ship
            MessageHandler "Computer Misses"
        Case c_BAD ' Computer already fired upon this space ERROR
            MessageHandler "Computer has been Hitting the juice again, fired an error"
    End Select
 
    _Delay .5
End Sub ' ComputerShot
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub DisplayShip (X%, Y%, ID%%, Orentation%%, LayerD&)
    Select Case ID%%
        Case c_CARRIER
            If Orentation%% = c_HORZ Then _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (500, 277)-(611, 299) Else _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (592, 165)-(614, 276)
        Case c_BATTLESHIP
            If Orentation%% = c_HORZ Then _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (500, 303)-(588, 321) Else _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (570, 165)-(589, 253)
        Case c_DESTROYER
            If Orentation%% = c_HORZ Then _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (500, 324)-(570, 341) Else _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (551, 165)-(568, 235)
        Case c_SUBMARINE
            If Orentation%% = c_HORZ Then _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (500, 344)-(568, 357) Else _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (534, 165)-(548, 233)
        Case c_PTBOAT
            If Orentation%% = c_HORZ Then _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (500, 360)-(546, 375) Else _PutImage (X%, Y%), m_arrLayer(c_SHEET), LayerD&, (516, 165)-(531, 211)
    End Select
End Sub ' DisplayShip
 
' /////////////////////////////////////////////////////////////////////////////
' start game
 
Sub GamePlay
    WhoIsFirst ' find who gets to shoot first!
 
    Do
        If m_GameData.WhoIsUp = c_PLAYER Then
 
            ' shooting routine PLAYER
            Do: ShotFired%% = FALSE
                ' mix layers and display
                _PutImage , m_arrLayer(c_BOARD), m_arrLayer(c_MIX)
                _PutImage , m_arrLayer(c_SHIPS), m_arrLayer(c_MIX)
                _PutImage , m_arrLayer(c_PEGS), m_arrLayer(c_MIX)
                _PutImage (0, 0), m_arrLayer(c_MIX), m_arrLayer(0), (0, 0)-(639, 300)
 
                x% = _MouseX: y% = _MouseY ' get mouse location
 
                If x% > 344 And y% > 54 And x% < 582 And y% < 294 Then ' mouse over enemy board
                    ' highlite grid block that mouse is over(grid blocks are 22x22[24x24WL])
                    hx%% = ((x% - 344) \ 24) + 1: hy%% = ((y% - 54) \ 24) + 1
                    Line (344 + ((hx%% - 1) * 24), 54 + ((hy%% - 1) * 24))-(367 + ((hx%% - 1) * 24), 77 + ((hy%% - 1) * 24)), c_YellowSelect~&, BF
                End If
 
                ' *****************************************************************************
                ' debug information
                Locate 1, 1: Print Chr$(64 + hy%%); hx%%
                ' *****************************************************************************
 
                If m_GameData.GameOver = FALSE Then
                    ' Main input loop
                    Do: _Delay .025
                        KBD$ = InKey$
                        Select Case KBD$
                            Case Chr$(27)
                                ExitFlag%% = TRUE
                                m_GameData.GameOver = TRUE
                        End Select
                    Loop Until _MouseInput Or ExitFlag%%
 
                    ' Player shoots
                    If _MouseButton(1) Then
                        If x% > 344 And y% > 54 And x% < 582 And y% < 294 Then ' only shoot if player is over shot board.
                            MessageHandler "Player Fires at: " + Chr$(64 + hy%%) + Str$(hx%%)
                            _Delay .5
                            If m_GameData.Mode Then
                                If hx%% < 10 Then m$ = "0" + LTrim$(Str$(hx%%)) Else m$ = LTrim$(Str$(hx%%))
                                m_Message$ = "[SHT]" + m$
                                If hy%% < 10 Then m$ = "0" + LTrim$(Str$(hy%%)) Else m$ = LTrim$(Str$(hy%%))
                                m_Message$ = m_Message$ + m$
                                SendMessage
                            End If
                            Select Case SendShot(hx%%, hy%%, c_PLAYER)
                                'Case HIT%% ' player hit enemy  ship
                                Case c_HIT%% ' player hit enemy  ship
                                    MessageHandler "Player Hits!"
                                    ShotFired%% = TRUE
                                    CheckShips
                                    'Case MISS%% ' player missed enemy ship
                                Case c_MISS%% ' player missed enemy ship
                                    MessageHandler "Player Misses"
                                    ShotFired%% = TRUE
                                    'Case BAD%% ' player already fired upon this space
                                Case c_BAD%% ' player already fired upon this space
                                    MessageHandler "Space Already Fired at, pick again"
                            End Select
                        End If
                        _Delay 1.5
                    End If
 
                Else
                    ExitFlag%% = TRUE
                    m_GameData.GameOver = TRUE
                End If
                Do: Loop While _MouseInput
            Loop Until ShotFired%% Or m_GameData.GameOver
 
        ElseIf m_GameData.WhoIsUp = c_OPPONENT Then ' opponents turn to shoot!
            ' mix layers and display
            _PutImage , m_arrLayer(c_BOARD), m_arrLayer(c_MIX)
            _PutImage , m_arrLayer(c_SHIPS), m_arrLayer(c_MIX)
            _PutImage , m_arrLayer(c_PEGS), m_arrLayer(c_MIX)
            _PutImage (0, 0), m_arrLayer(c_MIX), m_arrLayer(0), (0, 0)-(639, 300)
 
            If m_GameData.Mode Then OpponentShot Else ComputerShot
            If m_GameData.GameOver Then ExitFlag%% = TRUE
        End If
 
        ' whos turn is it now?
        If m_GameData.WhoIsUp = c_PLAYER Then m_GameData.WhoIsUp = c_OPPONENT Else m_GameData.WhoIsUp = c_PLAYER
    Loop Until ExitFlag%%
 
    ' dumpboard
    If m_GameData.PlayerDead Then MessageHandler "You have lost this round."
    If m_GameData.OpponentDead Then MessageHandler "Congratulations You are Victorious!"
    If Not m_GameData.PlayerDead And Not m_GameData.OpponentDead Then MessageHandler "Game quit..."
 
    MessageHandler "Press any key to return to menu"
    Do: Loop While InKey$ = ""
End Sub ' GamePlay
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub HitShip (id%%)
    ' ID%%-number of the ship, 1-5 player 6-10 opponent
    m_arrShip(id%%).Hits = m_arrShip(id%%).Hits + 1
    Select Case id%%
        Case c_CARRIER, c_CARRIER + 5
            If m_arrShip(id%%).Hits = 5 Then m_arrShip(id%%).sunk = TRUE
        Case c_BATTLESHIP, c_BATTLESHIP + 5
            If m_arrShip(id%%).Hits = 4 Then m_arrShip(id%%).sunk = TRUE
        Case c_DESTROYER, c_DESTROYER + 5
            If m_arrShip(id%%).Hits = 3 Then m_arrShip(id%%).sunk = TRUE
        Case c_SUBMARINE, c_SUBMARINE + 5
            If m_arrShip(id%%).Hits = 3 Then m_arrShip(id%%).sunk = TRUE
        Case c_PTBOAT, c_PTBOAT + 5
            If m_arrShip(id%%).Hits = 2 Then m_arrShip(id%%).sunk = TRUE
    End Select
End Sub ' HitShip
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub INIT
    Dim arrSize(64) As Long
    Dim arrFOffset&(64)
 
    Open "battleship.gfx" For Binary As #1
    Get #1, , c~%% ' number of records
    For w% = 1 To c~%%
        Get #1, , arrFOffset&(w%)
        Get #1, , arrSize(w%)
        arrFOffset&(w%) = arrFOffset&(w%) + 1
    Next w%
 
    m_arrLayer(0) = _Display
    m_arrLayer(c_MIX) = _NewImage(640, 480, 32) ' composite layer
    m_arrLayer(c_TITLE) = LoadGFX&(arrFOffset&(1), arrSize(1))
    m_arrLayer(c_SHEET) = LoadGFX&(arrFOffset&(2), arrSize(2))
    m_arrLayer(c_SHIPS) = _NewImage(640, 480, 32)
    m_arrLayer(c_SHOTS) = _NewImage(640, 480, 32)
    m_arrLayer(c_BOARD) = _NewImage(640, 480, 32)
    m_arrLayer(c_PEGS) = _NewImage(640, 480, 32)
    m_arrLayer(c_MENU) = LoadGFX&(arrFOffset&(3), arrSize(3))
    m_arrLayer(c_LAN) = LoadGFX&(arrFOffset&(4), arrSize(4)) ' _LOADIMAGE("Networking.bmp", 32)
 
    m_arrFFX(1) = LoadFFX&(arrFOffset&(5), arrSize(5), 30) ' _LOADFONT("gunmetl.ttf", 30, "monospace")
    m_arrFFX(2) = LoadFFX&(arrFOffset&(6), arrSize(6), 18) ' _LOADFONT("ARGEBL.ttf", 18, "monospace")
    m_arrFFX(3) = LoadFFX&(arrFOffset&(7), arrSize(7), 18) ' _LOADFONT("TechnoLCD.ttf", 18, "monospace")
    m_arrFFX(4) = LoadFFX&(arrFOffset&(8), arrSize(8), 24) ' _LOADFONT("TechnicznaPomocR.ttf", 24, "monospace")
    m_arrFFX(5) = LoadFFX&(arrFOffset&(5), arrSize(5), 48) ' _LOADFONT("gunmetl.ttf", 30, "monospace")
    m_arrFFX(6) = LoadFFX&(arrFOffset&(5), arrSize(5), 24) ' _LOADFONT("gunmetl.ttf", 30, "monospace")
 
    _PrintMode _KeepBackground , m_arrLayer(c_MIX)
    _PrintMode _KeepBackground , m_arrLayer(c_LAN)
 
    ClearLayer c_BOARD
    _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_SHEET)
    _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_SHIPS)
    _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_SHOTS)
    _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_PEGS)
 
    LoadData
 
    Randomize Timer
    Close #1
 
    If _FileExists("temp.dat") Then Kill "temp.dat" ' make sure we clean up temp files.
 
    _ScreenMove 25, 25
    _Title "BattleShip 64 V0.7A"
End Sub ' INIT
 
' /////////////////////////////////////////////////////////////////////////////
' who%%- which player board to add hit 1-PLAYER, 2-OPPONENT
' put red peg in board and tally hits to ships
 
Sub ItsAHit (x%%, y%%, Who%%)
    HitShip m_arrBoard(x%%, y%%, Who%%) + ((Who%% - 1) * 5)
    m_arrBoard(x%%, y%%, Who%%) = c_HIT
End Sub ' ItsAHit
 
' /////////////////////////////////////////////////////////////////////////////
' who%%- which player board to add hit 1-PLAYER, 2-OPPONENT
' put white peg in board
 
Sub ItsAMiss (x%%, y%%, Who%%)
    m_arrBoard(x%%, y%%, Who%%) = c_MISS
End Sub ' ItsAMiss
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub LoadData
    Restore ShipYardOffsetsData
    For i%% = 1 To 5
        Read m_arrOffs(i%%).ShipYard_X
        Read m_arrOffs(i%%).ShipYard_Y
    Next i%%
 
    Restore ShipBoardOffsetsData
    For i%% = 1 To 5
        Read m_arrOffs(i%%).Board_HX
        Read m_arrOffs(i%%).Board_HY
    Next i%%
    For i%% = 1 To 5
        Read m_arrOffs(i%%).Board_VX
        Read m_arrOffs(i%%).Board_VY
    Next i%%
 
    Restore ShipBoardOffsetsRedData
    For i%% = 1 To 5
        Read m_arrOffs(i%%).RedBoard_HX
        Read m_arrOffs(i%%).RedBoard_HY
    Next i%%
    For i%% = 1 To 5
        Read m_arrOffs(i%%).RedBoard_VX
        Read m_arrOffs(i%%).RedBoard_VY
    Next i%%
 
    Restore ShipNamesData
    For i%% = 1 To 5
        Read m_arrShipName$(i%%)
    Next i%%
End Sub ' LoadData
 
' /////////////////////////////////////////////////////////////////////////////
 
Function LoadGFX& (Foff&, Size&)
    If _FileExists("temp.dat") Then Kill "temp.dat"
    Open "temp.dat" For Binary As #3
    dat$ = Space$(Size&)
    Get #1, Foff&, dat$
    Put #3, , dat$
    Close #3
    LoadGFX& = _LoadImage("temp.dat", 32)
End Function ' LoadGFX&
 
' /////////////////////////////////////////////////////////////////////////////
 
Function LoadFFX& (Foff&, Size&, Fize%%)
    If _FileExists("temp.dat") Then Kill "temp.dat"
    Open "temp.dat" For Binary As #3
    dat$ = Space$(Size&)
    Get #1, Foff&, dat$
    Put #3, , dat$
    Close #3
    LoadFFX& = _LoadFont("temp.dat", Fize%%, "monospace")
End Function ' LoadFFX&
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub MessageHandler (txt$)
    ' define message area
    View Print 20 To 25
 
    ' display message
    Locate 25, 1: Print txt$
 
    ' restore screen area
    View Print
End Sub ' MessageHandler
 
' /////////////////////////////////////////////////////////////////////////////
' w%%- Which board to place ship 1-player 2-Opponent
' o%%= ships Orentation c_VERT or c_HORZ
' idx%%- Ident of ship to place c_CARRIER to c_PTBOAT
 
Sub PlaceShipOnBoard (id%%)
    If id%% <= 5 Then ' players ships
        w%% = 1: idx%% = id%%
    Else ' OPPONENT ships
        w%% = 2: idx%% = id%% - 5 ' correction for Enemy ships 6-10
    End If
    o%% = m_arrShip(id%%).Orent
 
    Select Case idx%%
        Case c_CARRIER
            If o%% = c_HORZ Then For i%% = 0 To 4: m_arrBoard(m_arrShip(id%%).Xpos + i%%, m_arrShip(id%%).Ypos, w%%) = c_CARRIER: Next i%%
            If o%% = c_VERT Then For i%% = 0 To 4: m_arrBoard(m_arrShip(id%%).Xpos, m_arrShip(id%%).Ypos + i%%, w%%) = c_CARRIER: Next i%%
        Case c_BATTLESHIP
            If o%% = c_HORZ Then For i%% = 0 To 3: m_arrBoard(m_arrShip(id%%).Xpos + i%%, m_arrShip(id%%).Ypos, w%%) = c_BATTLESHIP: Next i%%
            If o%% = c_VERT Then For i%% = 0 To 3: m_arrBoard(m_arrShip(id%%).Xpos, m_arrShip(id%%).Ypos + i%%, w%%) = c_BATTLESHIP: Next i%%
        Case c_DESTROYER
            If o%% = c_HORZ Then For i%% = 0 To 2: m_arrBoard(m_arrShip(id%%).Xpos + i%%, m_arrShip(id%%).Ypos, w%%) = c_DESTROYER: Next i%%
            If o%% = c_VERT Then For i%% = 0 To 2: m_arrBoard(m_arrShip(id%%).Xpos, m_arrShip(id%%).Ypos + i%%, w%%) = c_DESTROYER: Next i%%
        Case c_SUBMARINE
            If o%% = c_HORZ Then For i%% = 0 To 2: m_arrBoard(m_arrShip(id%%).Xpos + i%%, m_arrShip(id%%).Ypos, w%%) = c_SUBMARINE: Next i%%
            If o%% = c_VERT Then For i%% = 0 To 2: m_arrBoard(m_arrShip(id%%).Xpos, m_arrShip(id%%).Ypos + i%%, w%%) = c_SUBMARINE: Next i%%
        Case c_PTBOAT
            If o%% = c_HORZ Then For i%% = 0 To 1: m_arrBoard(m_arrShip(id%%).Xpos + i%%, m_arrShip(id%%).Ypos, w%%) = c_PTBOAT: Next i%%
            If o%% = c_VERT Then For i%% = 0 To 1: m_arrBoard(m_arrShip(id%%).Xpos, m_arrShip(id%%).Ypos + i%%, w%%) = c_PTBOAT: Next i%%
    End Select
End Sub ' PlaceShipOnBoard
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub ResetBoard
    For iz%% = 0 To 2
        For ix%% = 0 To 10
            For iy%% = 0 To 10
                m_arrBoard(ix%%, iy%%, iz%%) = FALSE
            Next iy%%
        Next ix%%
    Next iz%%
End Sub ' ResetBoard
 
' /////////////////////////////////////////////////////////////////////////////
 
Function SendShot (x%%, y%%, Who%%)
    If Who%% = c_PLAYER Then
        ' Player shooting, check enemy board
        If m_arrBoard(x%%, y%%, c_OPPONENT) > 0 Then
            ItsAHit x%%, y%%, c_OPPONENT
            Result%% = c_HIT
        ElseIf m_arrBoard(x%%, y%%, c_OPPONENT) < 0 Then ' already hit or miss
            Result%% = c_BAD
        Else ' space is empty so its a miss
            ItsAMiss x%%, y%%, c_OPPONENT
            Result%% = c_MISS
        End If
    Else
        ' Opponent shooting, check player board
        If m_arrBoard(x%%, y%%, c_PLAYER) > 0 Then
            ItsAHit x%%, y%%, c_PLAYER
            Result%% = c_HIT
        ElseIf m_arrBoard(x%%, y%%, c_PLAYER) < 0 Then ' already hit or miss
            Result%% = c_BAD
        Else ' space is empty so its a miss
            ItsAMiss x%%, y%%, c_PLAYER
            Result%% = c_MISS
        End If
    End If
 
    UpdatePegLayer
    SendShot = Result%%
End Function ' SendShot
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub SetUpGameBoard
    _Dest m_arrLayer(c_BOARD)
    _PutImage (32, 32), m_arrLayer(c_SHEET), m_arrLayer(c_BOARD), (0, 0)-(262, 262)
    _PutImage (320, 32), m_arrLayer(c_SHEET), m_arrLayer(c_BOARD), (0, 0)-(262, 262)
    Line (32, 32)-(294, 294), c_BlueBoard~&, BF
    Line (320, 32)-(582, 294), c_RedBoard~&, BF
    _PutImage , m_arrLayer(c_BOARD), _Display
 
    _PrintString (64, 16), "Your fleet"
    _PrintString (352, 16), "Enemy fleet"
    _Dest m_arrLayer(0)
End Sub ' SetUpGameBoard
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub ShowShips (Who%%)
    If Who%% = c_PLAYER Then
        For i%% = 1 To 5
            If m_arrShip(i%%).Orent = c_HORZ Then
                DisplayShip m_arrOffs(i%%).Board_HX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%%).Board_HY + (m_arrShip(i%%).Ypos - 1) * 24, i%%, m_arrShip(i%%).Orent, m_arrLayer(c_SHIPS) ' display ships in Board area
            Else
                DisplayShip m_arrOffs(i%%).Board_VX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%%).Board_VY + (m_arrShip(i%%).Ypos - 1) * 24, i%%, m_arrShip(i%%).Orent, m_arrLayer(c_SHIPS) ' display ships in Board area
            End If
        Next i%%
    Else
        For i%% = 6 To 10
            If m_arrShip(i%%).Orent = c_VERT Then
                DisplayShip m_arrOffs(i%% - 5).RedBoard_VX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%% - 5).RedBoard_VY + (m_arrShip(i%%).Ypos - 1) * 24, i%% - 5, m_arrShip(i%%).Orent, m_arrLayer(c_SHIPS) ' display ships in Board area
            Else
                DisplayShip m_arrOffs(i%% - 5).RedBoard_HX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%% - 5).RedBoard_HY + (m_arrShip(i%%).Ypos - 1) * 24, i%% - 5, m_arrShip(i%%).Orent, m_arrLayer(c_SHIPS) ' display ships in Board area
            End If
        Next i%%
    End If
End Sub ' ShowShips
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub UpdatePegLayer
    For z%% = 1 To 2
        If z%% = 1 Then ofx% = 55: ofy% = 55 Else ofx% = 343: ofy% = 55
        For y%% = 1 To 10
            For x%% = 1 To 10
                Select Case m_arrBoard(x%%, y%%, z%%)
                    Case c_HIT
                        _PutImage (ofx% + (x%% - 1) * 24, ofy% + (y%% - 1) * 24), m_arrLayer(c_SHEET), m_arrLayer(c_PEGS), (305, 144)-(327, 166)
                    Case c_MISS
                        _PutImage (ofx% + (x%% - 1) * 24, ofy% + (y%% - 1) * 24), m_arrLayer(c_SHEET), m_arrLayer(c_PEGS), (329, 144)-(350, 166)
                End Select
            Next x%%
        Next y%%
    Next z%%
End Sub ' UpdatePegLayer
 
' /////////////////////////////////////////////////////////////////////////////
' Pick Who Goes first
 
Sub WhoIsFirst
    starter%% = Int(Rnd * 100) + 1
    Locate 20, 1: Input "Pick Number 1-100"; P%%
 
    If m_GameData.Mode = FALSE Then ' if not a network game
        computer%% = Int(Rnd * 100) + 1
 
    Else
        ' if game is network then
        If m_GameData.Mode = c_LAN Then ' if this program is host game then send pick to player2
            If starter%% < 10 Then m$ = "0" + LTrim$(Str$(starter%%)) Else m$ = LTrim$(Str$(starter%%))
            m_Message$ = "[PKN]" + m$
            SendMessage
 
        ElseIf m_GameData.Mode = c_LANCLIENT Then ' if this program is player 2 then wait for number
            Print "Awaiting Pick Number..."
            Do
                _Delay .005
            Loop Until m_GameData.NetWork.Y
            starter%% = m_GameData.NetWork.Y
            m_GameData.NetWork.Y = 0
        End If
 
        ' client sends number first then waits.
        ' host waits first then sends number.
        If m_GameData.Mode = c_LANCLIENT Then
            If P%% < 10 Then m$ = "0" + LTrim$(Str$(P%%)) Else m$ = LTrim$(Str$(P%%))
            m_Message$ = "[FST]" + m$
            SendMessage
            _Delay .025
        End If
 
        Locate 21, 1: Print "Waiting for Opponents pick..."
        Do
            _Delay .005
        Loop Until m_GameData.NetWork.X
 
        computer%% = m_GameData.NetWork.X ' set player 2's number
        m_GameData.NetWork.X = 0
 
        If m_GameData.Mode = c_LAN Then ' send player 1's number to player 2
            If P%% < 10 Then m$ = "0" + LTrim$(Str$(P%%)) Else m$ = LTrim$(Str$(P%%))
            m_Message$ = "[FST]" + m$
            SendMessage
        End If
    End If
 
    If P%% < 1 Or P%% > 100 Then ' player auto lose
        Print "Opponent wins because you can not follow instructions."
        computer%% = starter%%
    Else ' player entered correct ranged value
        Print "Opponent picks:"; computer%%
    End If
 
    testp%% = Abs(starter%% - P%%) ' find how far off player is.
    testc%% = Abs(starter%% - computer%%) ' find how far off computer is.
    If testp%% = testc%% Then winner%% = c_PLAYER ' in a tie player wins
    If testp%% < testc%% Then winner%% = c_PLAYER ' player closer wins
    If testp%% > testc%% Then winner%% = c_OPPONENT ' computer closer wins
    _Delay 1.25
 
    Print "Control number was:";
    _Delay .75
 
    Print starter%%
    _Delay .75
 
    If winner%% = c_PLAYER Then Print "You Win the chance to shoot first" Else Print "Opponent shoots first"
 
    m_GameData.WhoIsUp = winner%% ' store who starts for later
    _Delay 1.5
    ' ---------------------------------------------
End Sub ' WhoIsFirst
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub DeployFleet
    Static st_arrPicked(5)
 
    _PutImage , m_arrLayer(c_BOARD), m_arrLayer(0)
    _PutImage (64, 300), m_arrLayer(c_SHEET), m_arrLayer(c_BOARD), (304, 6)-(499, 142)
 
    _PrintString (304, 320), "Place Your fleet.", m_arrLayer(c_BOARD)
    _PrintString (304, 336), "Space to rotate ship.", m_arrLayer(c_BOARD)
    _PrintString (304, 352), "Left Click to select and place ship.", m_arrLayer(c_BOARD)
    _PrintString (304, 368), "Right Click to abort Placement.", m_arrLayer(c_BOARD)
 
    If m_GameData.Mode = c_LAN Or m_GameData.Mode = c_LANCLIENT Then _PrintString (304, 384), "Game is in Network Mode.", m_arrLayer(c_BOARD)
 
    _PutImage (304, 400), m_arrLayer(c_SHEET), m_arrLayer(c_BOARD), (24, 279)-(180, 322) ' accept button
    _PutImage (480, 400), m_arrLayer(c_SHEET), m_arrLayer(c_BOARD), (182, 279)-(338, 322) ' Reset button
    _Font 16, m_arrLayer(c_MIX)
 
    Do
        AllPlaced%% = TRUE
        For i%% = 1 To 5
            If Not st_arrPicked(i%%) Then ' is ship 'in hand' or placed on board already?
                DisplayShip m_arrOffs(i%%).ShipYard_X, m_arrOffs(i%%).ShipYard_Y, i%%, c_HORZ, m_arrLayer(c_SHIPS) ' display ships in ShipYard area
                AllPlaced%% = FALSE
            Else
                _PutImage (64, 316 + (i%% - 1) * 24), m_arrLayer(c_SHEET), m_arrLayer(c_SHIPS), (304, 22)-(424, 46) ' Erase ships from ShipYard area
                ' display ships placed on board
                If m_arrShip(i%%).Xpos <> 0 Then ' if ship has valid xpos then place on board
                    If m_arrShip(i%%).Orent = c_HORZ Then
                        DisplayShip m_arrOffs(i%%).Board_HX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%%).Board_HY + (m_arrShip(i%%).Ypos - 1) * 24, i%%, m_arrShip(i%%).Orent, m_arrLayer(SHIPS) ' display ships in Board area
                    Else
                        DisplayShip m_arrOffs(i%%).Board_VX + (m_arrShip(i%%).Xpos - 1) * 24, m_arrOffs(i%%).Board_VY + (m_arrShip(i%%).Ypos - 1) * 24, i%%, m_arrShip(i%%).Orent, m_arrLayer(SHIPS) ' display ships in Board area
                    End If
                End If ' otherwise ship must still be 'in-hand'
            End If
        Next i%%
 
        ' move image to screen
        ' avoids flicker for the most part.
        _PutImage , m_arrLayer(c_BOARD), m_arrLayer(c_MIX)
        _PutImage , m_arrLayer(c_SHIPS), m_arrLayer(c_MIX)
        If ShipSelection%% Then DisplayShip x% - 6, y% - 6, ShipSelection%%, ShipOrentation%%, m_arrLayer(c_MIX)
 
        If m_GameData.Mode = c_LAN Then
            If m_GameData.NetWork.Ready Then
                _PrintString (304, 454), "Opponent is ready", m_arrLayer(c_MIX)
            Else
                _PrintString (304, 454), "Awaiting Opponent ship placement", m_arrLayer(c_MIX)
            End If
        End If
 
        _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
 
        ' *****************************************************************************
        ' debug information
        Locate 1, 1: Print Chr$(64 + hy%%); hx%%
        ' *****************************************************************************
 
        x% = _MouseX: y% = _MouseY ' get mouse location
        If x% > 54 And y% > 54 And x% < 294 And y% < 294 Then ' mouse over player board
            ' highlite grid block that mouse is over(grid blocks are 22x22[24x24WL])
            hx%% = ((x% - 54) \ 24) + 1: hy%% = ((y% - 54) \ 24) + 1
            Line (54 + ((hx%% - 1) * 24), 54 + ((hy%% - 1) * 24))-(77 + ((hx%% - 1) * 24), 77 + ((hy%% - 1) * 24)), c_YellowSelect~&, BF
 
            ' place ship on player board
            If _MouseButton(1) And ShipSelection%% <> 0 Then
                If CheckShipPos(hx%%, hy%%, ShipOrentation%%, ShipSelection%%) Then ' make sure ship fits
                    m_arrShip(ShipSelection%%).Xpos = hx%%
                    m_arrShip(ShipSelection%%).Ypos = hy%%
                    m_arrShip(ShipSelection%%).Orent = ShipOrentation%%
                    PlaceShipOnBoard ShipSelection%%
                    held%% = 0
                    ShipSelection%% = 0
                    _MouseShow
                End If
            End If
        End If
 
        ' -----------------------------------------------------------------------------
        ' Main input loop
        Do: _Delay .025
            KBD$ = InKey$
            Select Case KBD$
                Case Chr$(13)
                    If AllPlaced%% And (held%% = FALSE) Then exitflag%% = TRUE
                Case Chr$(27)
                    'exitflag%% = TRUE
                Case Chr$(32)
                    If ShipOrentation%% = c_HORZ Then ShipOrentation%% = c_VERT Else ShipOrentation%% = c_HORZ
                    UpDateFlag%% = TRUE
                Case Chr$(65)
                    If Not AutoFlag%% Then
                        For i%% = 1 To 5
                            st_arrPicked(i%%) = TRUE ' set true before using autopick
                            m_arrShip(i%%).Xpos = 0
                            m_arrShip(i%%).Ypos = 0
                            m_arrShip(i%).Orent = 0
                        Next i%%
                        ResetBoard
                        ClearLayer c_SHIPS
                        _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_SHIPS)
                        AutoPlaceShips c_PLAYER
                        UpDateFlag%% = TRUE
                        AutoFlag%% = TRUE
                    End If
            End Select
        Loop Until _MouseInput Or exitflag%% Or UpDateFlag%%
        UpDateFlag%% = FALSE
 
        ' -----------------------------------------------------------------------------
        ' Ship Selection to place
        If x% > 64 And y% > 316 And x% < 245 And y% < 432 Then ' player over ship yard
            If _MouseButton(1) Then
                If ShipSelection%% = 0 Then
                    hy2%% = ((y% - 316) \ 24) + 1
                    If Not st_arrPicked(hy2%%) Then ' make sure ship is still in the yard.
                        Select Case hy2%%
                            Case c_CARRIER
                                ShipSelection%% = c_CARRIER: ShipOrentation%% = c_HORZ: st_arrPicked(1) = TRUE: held%% = 1
                            Case c_BATTLESHIP
                                ShipSelection%% = c_BATTLESHIP: ShipOrentation%% = c_HORZ: st_arrPicked(2) = TRUE: held%% = 2
                            Case c_DESTROYER
                                ShipSelection%% = c_DESTROYER: ShipOrentation%% = c_HORZ: st_arrPicked(3) = TRUE: held%% = 3
                            Case c_SUBMARINE
                                ShipSelection%% = c_SUBMARINE: ShipOrentation%% = c_HORZ: st_arrPicked(4) = TRUE: held%% = 4
                            Case c_PTBOAT
                                ShipSelection%% = c_PTBOAT: ShipOrentation%% = c_HORZ: st_arrPicked(5) = TRUE: held%% = 5
                        End Select
                    End If
                    If ShipSelection%% <> 0 Then _MouseHide
                End If
            End If
        End If
 
        ' -----------------------------------------------------------------------------
        If x% > 304 And y% > 400 And x% < 460 And y% < 443 Then ' accept button
            If _MouseButton(1) And AllPlaced%% And (held%% = FALSE) Then
                exitflag%% = TRUE
                _PutImage (304, 400), m_arrLayer(c_SHEET), m_arrLayer(0), (24, 324)-(180, 367) ' accept button down
            End If
        End If
 
        If x% > 480 And y% > 400 And x% < 636 And y% < 443 Then ' reset button
            If _MouseButton(1) Then
                _PutImage (480, 400), m_arrLayer(c_SHEET), m_arrLayer(0), (182, 324)-(338, 367) ' Reset button down
                For i%% = 1 To 5
                    st_arrPicked(i%%) = FALSE
                    m_arrShip(i%%).Xpos = 0
                    m_arrShip(i%%).Ypos = 0
                    m_arrShip(i%).Orent = 0
                Next i%%
                held%% = 0: ShipSelection%% = 0
                _MouseShow
                ResetBoard
                If AutoFlag%% Then AutoFlag%% = FALSE
                ClearLayer c_SHIPS
                _ClearColor _RGB32(0, 0, 0), m_arrLayer(c_SHIPS)
            End If
        End If
 
        If _MouseButton(2) Then ShipSelection%% = 0: st_arrPicked(held%%) = FALSE: held%% = 0: _MouseShow ' Deselect ship for placement
 
        Do: Loop While _MouseInput
    Loop Until exitflag%%
 
    ' player is done but if network game pause here until Opponent is ready
 
    ClearArea
 
    If Not m_GameData.NetWork.Ready Then
        _PrintString (304, 320), "Awaiting Opponent ship placement...", m_arrLayer(0)
        _PrintString (304, 336), "You are Ready...", m_arrLayer(0)
    End If
 
    If m_GameData.Mode = c_LAN Then
        Do
            _Delay .05
        Loop Until m_GameData.NetWork.Ready
 
        ' once client has given ship locations send hosts
        m_Message$ = "[SHP]"
        For i%% = 1 To 5
            If m_arrShip(i%%).Xpos < 10 Then m$ = "0" + LTrim$(Str$(m_arrShip(i%%).Xpos)) Else m$ = LTrim$(Str$(m_arrShip(i%%).Xpos))
            m_Message$ = m_Message$ + m$
            If m_arrShip(i%%).Ypos < 10 Then m$ = "0" + LTrim$(Str$(m_arrShip(i%%).Ypos)) Else m$ = LTrim$(Str$(m_arrShip(i%%).Ypos))
            m_Message$ = m_Message$ + m$
            m_Message$ = m_Message$ + LTrim$(Str$(m_arrShip(i%%).Orent))
        Next i%%
        SendMessage
    End If
 
    If m_GameData.Mode = c_LANCLIENT Then
        ' send host ship placement
        m_Message$ = "[SHP]"
        For i%% = 1 To 5
            If m_arrShip(i%%).Xpos < 10 Then m$ = "0" + LTrim$(Str$(m_arrShip(i%%).Xpos)) Else m$ = LTrim$(Str$(m_arrShip(i%%).Xpos))
            m_Message$ = m_Message$ + m$
            If m_arrShip(i%%).Ypos < 10 Then m$ = "0" + LTrim$(Str$(m_arrShip(i%%).Ypos)) Else m$ = LTrim$(Str$(m_arrShip(i%%).Ypos))
            m_Message$ = m_Message$ + m$
            m_Message$ = m_Message$ + LTrim$(Str$(m_arrShip(i%%).Orent))
        Next i%%
        SendMessage
        Do
            _Delay .05
        Loop Until m_GameData.NetWork.Ready
    End If
    If m_GameData.Debug Then dumpboard
End Sub ' DeployFleet
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub OpponentShot
    Do ' wait until opponent sends shot packet
        _Delay .01
        ' if something happens to Opponent
        If InKey$ = Chr$(27) Then m_GameData.NetWork.X = 1: m_GameData.NetWork.Y = 1: m_GameData.GameOver = TRUE
    Loop Until m_GameData.NetWork.X
 
    x%% = m_GameData.NetWork.X
    y%% = m_GameData.NetWork.Y
    m_GameData.NetWork.X = 0
    m_GameData.NetWork.Y = 0
 
    MessageHandler "Opponent fires at " + Chr$(64 + y%%) + Str$(x%%)
    _Delay .5
 
    Select Case SendShot(x%%, y%%, c_OPPONENT)
        Case c_HIT ' Hits players ship
            MessageHandler "Opponent Hits!"
            CheckShips
        Case c_MISS ' Missed players ship
            MessageHandler "Opponent Misses"
        Case c_BAD ' Already fired upon this space ERROR
            MessageHandler "Opponent has been Hitting the juice again, fired an error"
    End Select
    _Delay .5
End Sub ' OpponentShot
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub CreateNetworkGame
    Cls
    ClearLayer c_MIX
 
    _Font m_arrFFX(1), m_arrLayer(c_LAN)
    _PrintString (128, 32), "PORT ADDRESS FOR HOST", m_arrLayer(c_LAN)
    _Font m_arrFFX(6), m_arrLayer(c_LAN)
    _PrintString (96, 64), "VALUE MUST BE GREATER THAN 1000", m_arrLayer(c_LAN)
    _PrintString (200, 84), "0 FOR DEFUALT PORT", m_arrLayer(c_LAN)
    _Font m_arrFFX(5), m_arrLayer(c_MIX)
    ChangeColor _RGB32(63, 208, 63), m_arrLayer(c_MIX)
 
    port$ = "1945" ' defualt WWII port address
    Do
        Port% = Val(port$)
        _PutImage , m_arrLayer(c_LAN), m_arrLayer(c_MIX)
        _PrintString (268, 117), LTrim$(Str$(Port%)), m_arrLayer(c_MIX)
        _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
        x% = _FontWidth(m_arrFFX(5)) * Len(port$)
        Line (268 + x%, 158)-(292 + x%, 162), _RGB32(255, 255, 0), BF
        Do
            KBD$ = InKey$
            Select Case KBD$
                Case Chr$(8) ' backspace
                    If port$ <> "" Then port$ = Mid$(port$, 1, Len(port$) - 1)
                    UpDate%% = TRUE
                Case Chr$(13)
                    If Len(port$) = 4 Then
                        Port% = Val(port$): ExitFlag%% = TRUE
                    ElseIf port$ = "" Or port$ = "0" Then
                        Port% = 0: ExitFlag%% = TRUE
                    End If
                Case Chr$(27)
                    ExitFlag%% = TRUE
                Case Chr$(48) TO Chr$(57) ' numbers
                    If Len(port$) < 4 Then port$ = port$ + KBD$
                    UpDate%% = TRUE
            End Select
            _Delay .025
        Loop Until _MouseInput Or ExitFlag%% Or UpDate%%
        UpDate%% = FALSE
    Loop Until ExitFlag%%
 
    ExitFlag%% = FALSE
 
    _Font 16, m_arrLayer(c_LAN)
    _PrintString (8, 464), "Starting up host...", m_arrLayer(0)
 
    m_GameData.NetWork.Host = StartHost(Port%)
    If m_GameData.NetWork.Host Then _Delay 1.5 ' give host a few secs to start up
    m_GameData.Mode = c_LAN
 
    Timer(m_Listen&) On ' turn on the timer to listen for opponent chatter
 
    ' connect host user
    _PrintString (256, 464), "Connecting to host...", m_arrLayer(0)
    _Delay .5
 
    m_GameData.NetWork.Client = ConnectClient(Port%, "0")
    ' game is now in network mode
 
    _Font m_arrFFX(2), m_arrLayer(c_MIX)
End Sub ' CreateNetworkGame
 
' /////////////////////////////////////////////////////////////////////////////
 
Sub JoinNetworkGame
    Cls
    ClearLayer c_MIX
 
    _Font m_arrFFX(1), m_arrLayer(c_LAN)
    _PrintString (128, 32), "PORT ADDRESS CONNECT TO", m_arrLayer(c_LAN)
    _PrintString (144, 168), "IP ADDRESS CONNECT TO", m_arrLayer(c_LAN)
    _Font m_arrFFX(6), m_arrLayer(c_LAN)
    _PrintString (200, 84), "0 FOR DEFUALT PORT", m_arrLayer(c_LAN)
    _PutImage (32, 200), m_arrLayer(c_SHEET), m_arrLayer(c_LAN), (0, 376)-(575, 430)
 
    _Font m_arrFFX(5), m_arrLayer(c_MIX)
    ChangeColor _RGB32(63, 208, 63), m_arrLayer(c_MIX)
    port$ = "1945" ' defualt WWII port address
    If IPA$ = "" Then IPA$ = "LOCALHOST"
    selection%% = 2
    Do
        Port% = Val(port$)
        _PutImage , m_arrLayer(c_LAN), m_arrLayer(c_MIX)
        _PrintString (268, 117), LTrim$(Str$(Port%)), m_arrLayer(c_MIX)
 
        _PrintString (320 - ((Len(IPA$) \ 2) * _FontWidth(m_arrFFX(5))), 208), IPA$, m_arrLayer(c_MIX)
        _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
 
        x% = _MouseX: y% = _MouseY ' get mouse location
 
        If _MouseButton(1) Then
            If x% > 220 And x% < 450 And y% > 112 And y% < 162 Then selection%% = 1 ' port address
            If x% > 40 And x% < 600 And y% > 200 And y% < 250 Then selection%% = 2 ' IP address
            update%% = TRUE
        End If
 
        If selection%% = 1 Then
            x% = _FontWidth(m_arrFFX(5)) * Len(port$)
            Line (268 + x%, 158)-(292 + x%, 162), _RGB32(255, 255, 0), BF
        ElseIf selection%% = 2 Then
            x% = 320 - ((Len(IPA$) \ 2) * _FontWidth(m_arrFFX(5))) + (Len(IPA$) * _FontWidth(m_arrFFX(5)))
            Line (x%, 249)-(x% + 24, 253), _RGB32(255, 255, 0), BF
        End If
        Do
            KBD$ = InKey$
            Select Case KBD$
                Case Chr$(8) ' backspace
                    If selection%% = 1 Then
                        If port$ <> "" Then port$ = Mid$(port$, 1, Len(port$) - 1)
                    ElseIf selection%% = 2 Then
                        If IPA$ <> "" Then IPA$ = Mid$(IPA$, 1, Len(IPA$) - 1)
                    End If
                    update%% = TRUE
                Case Chr$(13)
                    If Len(port$) = 4 Then
                        If IPA$ = "" Or UCase$(IPA$) = "LOCALHOST" Then IPA$ = "0"
                        Port% = Val(port$): ExitFlag%% = TRUE
                    ElseIf port$ = "" Or port$ = "0" Then
                        Port% = 0: ExitFlag%% = TRUE
                    End If
                Case Chr$(27)
                    ExitFlag%% = TRUE: m_Cancel%% = TRUE
                Case Chr$(48) TO Chr$(57), Chr$(46) ' numbers and .
                    If selection%% = 1 Then
                        If Len(port$) < 4 Then port$ = port$ + KBD$
                    ElseIf selection%% = 2 Then
                        If Len(IPA$) < 15 Then IPA$ = IPA$ + KBD$
                    End If
                    update%% = TRUE
            End Select
            _Delay .025
        Loop Until _MouseInput Or ExitFlag%% Or update%%
        update%% = FALSE
        Do: Loop While _MouseInput
 
    Loop Until ExitFlag%%
    ExitFlag%% = FALSE
 
    _Font 16, m_arrLayer(c_LAN)
 
    ' connect host user
    If Not m_Cancel%% Then
        _PrintString (256, 464), "Connecting to host...", m_arrLayer(0)
        _Delay .5
        m_GameData.NetWork.Client = ConnectClient(Port%, IPA$)
        If m_GameData.NetWork.Client Then m_GameData.Mode = c_LANCLIENT
        Timer(m_Listen&) On ' turn on the timer to listen for opponent chatter
    End If
End Sub ' JoinNetworkGame
 
' /////////////////////////////////////////////////////////////////////////////
' Instructions
 
Sub Instruction
    _Font m_arrFFX(1), m_arrLayer(c_MIX)
    ChangeColor _RGB32(212, 212, 212), m_arrLayer(c_MIX) ' Hover color
    ClearLayer c_MIX
 
    _PrintString (200, 16), "BATTLESHIP 64", m_arrLayer(c_MIX)
    _PrintString (64, 48), "SHIP STATS:", m_arrLayer(c_MIX)
 
    For i%% = 1 To 5
        DisplayShip 32, 64 + (32 * i%%), i%%, c_HORZ, m_arrLayer(c_MIX)
    Next i%%
 
    _PrintString (160, 96), "CARRIER TAKES 5 HITS", m_arrLayer(c_MIX)
    _PrintString (160, 128), "BATTLESHIP TAKES 4 HITS", m_arrLayer(c_MIX)
    _PrintString (160, 160), "DESTROYER TAKES 3 HITS", m_arrLayer(c_MIX)
    _PrintString (160, 192), "SUBMARINE TAKES 3 HITS", m_arrLayer(c_MIX)
    _PrintString (160, 224), "PT BOAT TAKES 2 HITS", m_arrLayer(c_MIX)
 
    _Font m_arrFFX(4), m_arrLayer(c_MIX)
    _PrintString (32, 256), "Ships can be palced vertically", m_arrLayer(c_MIX)
    _PrintString (32, 288), "on the game board by pressing", m_arrLayer(c_MIX)
    _PrintString (32, 320), "the space bar while the ship", m_arrLayer(c_MIX)
    _PrintString (32, 352), "is selected.", m_arrLayer(c_MIX)
 
    _PutImage (32, 400), m_arrLayer(c_SHEET), m_arrLayer(c_MIX), (305, 144)-(327, 166)
    _PutImage (32, 432), m_arrLayer(c_SHEET), m_arrLayer(c_MIX), (329, 144)-(350, 166)
 
    _PrintString (64, 400), "-Denotes a hit.", m_arrLayer(c_MIX)
    _PrintString (64, 432), "-Denotes a miss.", m_arrLayer(c_MIX)
 
    _Font 16, m_arrLayer(c_MIX)
    _PrintString (8, 464), "Press any key to return to menu", m_arrLayer(c_MIX)
 
    _PutImage , m_arrLayer(c_MIX), m_arrLayer(0)
 
    _Font m_arrFFX(2), m_arrLayer(c_MIX)
 
    Do: Loop While InKey$ = ""
    _KeyClear
End Sub ' Instruction
 
' ****************************************************************************************************************************************************************
' BEGIN DEBUGGING ROUTINES
' Routines Beyond are not Game nessesary
' ****************************************************************************************************************************************************************
 
' /////////////////////////////////////////////////////////////////////////////
' debugging
 
Sub dumpboard
    For z%% = 1 To 2
        For y%% = 1 To 10
            For x%% = 1 To 10
                Print #6, m_arrBoard(x%%, y%%, z%%);
            Next x%%
            Print #6,
        Next y%%
        Print #6,: Print #6,
    Next z%%
End Sub ' dumpboard
 
' /////////////////////////////////////////////////////////////////////////////
 
' ****************************************************************************************************************************************************************
' END DEBUGGING ROUTINES
' ****************************************************************************************************************************************************************
 

Cobalt · « **Reply #8 on:** July 13, 2021, 11:29:22 pm »

Quote from: madscijr on July 12, 2021, 10:32:49 am

Question, what format file is "battleship.gfx", and how would you edit it?
Thanks...

Its an outdated version of my MFI proprietary packing format. Not really editable in the easy sense.
I've never had to "de-compile" a resource file before so I have never developed a program to unpack one.

I think I still have all the resource material floating around somewhere though.

Cobalt · « **Reply #9 on:** July 14, 2021, 12:47:10 am »

Quote from: madscijr on July 13, 2021, 01:13:35 pm

I was looking at your code, and got the genius idea (I hope you are picking up on the sarcasm here)
to rename the variables a little less ambiguously to help me follow what the code is doing,
and I seem to have introduced a little bug where when you place a ship on the board, it disappears.
If you have any bandwidth, and could quickly zero in on the line that might be making that happen,
that would be very much appreciated... No pressure or anything, LoL

Besides obfuscating my code, you apparently changed something that must not be changed. What that is I have no clue, but the ships don't actually disappear, they now flicker(faintly) on my machine. So by changing names you have changed the order of operations somewhere and the board now gets drawn over the ships instead of the ships getting drawn over the board. Believe it or not sometimes names matter, when it comes to variables and what not. (no sarcasm, just a grain of salt. take it how you will XD)

Guessing you used the CHANGE ALL command and just bulk changed things? If so, that is certainly what did it. (I have accidentally done similar things) I would suggest you pull a clean copy and if you really, REALLY, REALLY! need to change variable names then use the FIND AND VERIFY option and confirm that each change is in fact the exact variable you are trying to rename. I would highly advise against messing with the LAYER array name. or any names pertaining to Graphics layers (ie variables in _putimage lines, _loadimage lines, or _newimage lines) as they tend to be important.

but reviewing this code, man! there are things which I would never do anymore. to think in only like 2 1\2 years I have found so many better ways to do things. And I never did add sound... :(
but that would be why there is no SFX file. May have just given me a reason to revisit this project an maybe get it up to Ver 1.0(or at least 0.9)

News:

Author Topic: Simple example of LAN game with 2-4 PCs? (Read 3838 times)

madscijr

Simple example of LAN game with 2-4 PCs?

SpriggsySpriggs

Re: Simple example of LAN game with 2-4 PCs?

FellippeHeitor

Re: Simple example of LAN game with 2-4 PCs?

madscijr

Re: Simple example of LAN game with 2-4 PCs?

Cobalt

Re: Simple example of LAN game with 2-4 PCs?

madscijr

Re: Simple example of LAN game with 2-4 PCs?

madscijr

Re: Simple example of LAN game with 2-4 PCs?

madscijr

Re: Simple example of LAN game with 2-4 PCs?

Cobalt

Re: Simple example of LAN game with 2-4 PCs?

Cobalt

Re: Simple example of LAN game with 2-4 PCs?